C4/XSLT.pm

   1 package C4::XSLT;
   2
   3 # Copyright (C) 2006 LibLime
   4 # <jmf at liblime dot com>
   5 # Parts Copyright Katrin Fischer 2011
   6 # Parts Copyright ByWater Solutions 2011
   7 # Parts Copyright Biblibre 2012
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 use Modern::Perl;
  25
  26 use C4::Context;
  27 use C4::Koha qw( xml_escape );
  28 use C4::Biblio qw( GetAuthorisedValueDesc GetFrameworkCode GetMarcStructure );
  29 use Koha::AuthorisedValues;
  30 use Koha::ItemTypes;
  31 use Koha::RecordProcessor;
  32 use Koha::XSLT::Base;
  33 use Koha::Libraries;
  34 use Koha::Recalls;
  35
  36 my $engine; #XSLT Handler object
  37
  38 our (@ISA, @EXPORT_OK);
  39 BEGIN {
  40     require Exporter;
  41     @ISA = qw(Exporter);
  42     @EXPORT_OK = qw(
  43         buildKohaItemsNamespace
  44         XSLTParse4Display
  45     );
  46     $engine=Koha::XSLT::Base->new( { do_not_return_source => 1 } );
  47 }
  48
  49 =head1 NAME
  50
  51 C4::XSLT - Functions for displaying XSLT-generated content
  52
  53 =head1 FUNCTIONS
  54
  55 =head2 XSLTParse4Display
  56
  57 Returns xml for biblionumber and requested XSLT transformation.
  58 Returns undef if the transform fails.
  59
  60 Used in OPAC results and detail, intranet results and detail, list display.
  61 (Depending on the settings of your XSLT preferences.)
  62
  63 The helper function _get_best_default_xslt_filename is used in a unit test.
  64
  65 =cut
  66
  67 sub _get_best_default_xslt_filename {
  68     my ($htdocs, $theme, $lang, $base_xslfile) = @_;
  69
  70     my @candidates = (
  71         "$htdocs/$theme/$lang/xslt/${base_xslfile}", # exact match
  72         "$htdocs/$theme/en/xslt/${base_xslfile}",    # if not, preferred theme in English
  73         "$htdocs/prog/$lang/xslt/${base_xslfile}",   # if not, 'prog' theme in preferred language
  74         "$htdocs/prog/en/xslt/${base_xslfile}",      # otherwise, prog theme in English; should always
  75                                                      # exist
  76     );
  77     my $xslfilename;
  78     foreach my $filename (@candidates) {
  79         $xslfilename = $filename;
  80         if (-f $filename) {
  81             last; # we have a winner!
  82         }
  83     }
  84     return $xslfilename;
  85 }
  86
  87 sub get_xslt_sysprefs {
  88     my $sysxml = "<sysprefs>\n";
  89     foreach my $syspref ( qw/ hidelostitems OPACURLOpenInNewWindow
  90                               DisplayOPACiconsXSLT URLLinkText viewISBD
  91                               OPACBaseURL TraceCompleteSubfields UseICUStyleQuotes
  92                               UseAuthoritiesForTracings TraceSubjectSubdivisions
  93                               Display856uAsImage OPACDisplay856uAsImage
  94                               UseControlNumber IntranetBiblioDefaultView BiblioDefaultView
  95                               OPACItemLocation DisplayIconsXSLT
  96                               AlternateHoldingsField AlternateHoldingsSeparator
  97                               TrackClicks opacthemes IdRef OpacSuppression
  98                               OPACResultsLibrary OPACShowOpenURL
  99                               OpenURLResolverURL OpenURLImageLocation
 100                               OPACResultsMaxItems OPACResultsMaxItemsUnavailable OPACResultsUnavailableGroupingBy
 101                               OpenURLText OPACShowMusicalInscripts OPACPlayMusicalInscripts / )
 102     {
 103         my $sp = C4::Context->preference( $syspref );
 104         next unless defined($sp);
 105         $sysxml .= "<syspref name=\"$syspref\">$sp</syspref>\n";
 106     }
 107
 108     # singleBranchMode was a system preference, but no longer is
 109     # we can retain it here for compatibility
 110     my $singleBranchMode = Koha::Libraries->search->count == 1 ? 1 : 0;
 111     $sysxml .= "<syspref name=\"singleBranchMode\">$singleBranchMode</syspref>\n";
 112
 113     $sysxml .= "</sysprefs>\n";
 114     return $sysxml;
 115 }
 116
 117 sub get_xsl_filename {
 118     my ( $xslsyspref ) = @_;
 119
 120     my $lang   = C4::Languages::getlanguage();
 121
 122     my $xslfilename = C4::Context->preference($xslsyspref) || "default";
 123
 124     if ( $xslfilename =~ /^\s*"?default"?\s*$/i ) {
 125
 126         my ( $htdocs, $theme, $xslfile );
 127
 128         if ($xslsyspref eq "XSLTDetailsDisplay") {
 129             $htdocs  = C4::Context->config('intrahtdocs');
 130             $theme   = C4::Context->preference("template");
 131             $xslfile = C4::Context->preference('marcflavour') .
 132                        "slim2intranetDetail.xsl";
 133         } elsif ($xslsyspref eq "XSLTResultsDisplay") {
 134             $htdocs  = C4::Context->config('intrahtdocs');
 135             $theme   = C4::Context->preference("template");
 136             $xslfile = C4::Context->preference('marcflavour') .
 137                         "slim2intranetResults.xsl";
 138         } elsif ($xslsyspref eq "OPACXSLTDetailsDisplay") {
 139             $htdocs  = C4::Context->config('opachtdocs');
 140             $theme   = C4::Context->preference("opacthemes");
 141             $xslfile = C4::Context->preference('marcflavour') .
 142                        "slim2OPACDetail.xsl";
 143         } elsif ($xslsyspref eq "OPACXSLTResultsDisplay") {
 144             $htdocs  = C4::Context->config('opachtdocs');
 145             $theme   = C4::Context->preference("opacthemes");
 146             $xslfile = C4::Context->preference('marcflavour') .
 147                        "slim2OPACResults.xsl";
 148         } elsif ($xslsyspref eq 'XSLTListsDisplay') {
 149             # Lists default to *Results.xslt
 150             $htdocs  = C4::Context->config('intrahtdocs');
 151             $theme   = C4::Context->preference("template");
 152             $xslfile = C4::Context->preference('marcflavour') .
 153                         "slim2intranetResults.xsl";
 154         } elsif ($xslsyspref eq 'OPACXSLTListsDisplay') {
 155             # Lists default to *Results.xslt
 156             $htdocs  = C4::Context->config('opachtdocs');
 157             $theme   = C4::Context->preference("opacthemes");
 158             $xslfile = C4::Context->preference('marcflavour') .
 159                        "slim2OPACResults.xsl";
 160         }
 161         $xslfilename = _get_best_default_xslt_filename($htdocs, $theme, $lang, $xslfile);
 162     }
 163
 164     if ( $xslfilename =~ m/\{langcode\}/ ) {
 165         $xslfilename =~ s/\{langcode\}/$lang/;
 166     }
 167
 168     return $xslfilename;
 169 }
 170
 171 sub XSLTParse4Display {
 172     my ( $params ) = @_;
 173
 174     my $biblionumber = $params->{biblionumber};
 175     my $record       = $params->{record};
 176     my $xslsyspref   = $params->{xsl_syspref};
 177     my $fixamps      = $params->{fix_amps};
 178     my $hidden_items = $params->{hidden_items} || [];
 179     my $variables    = $params->{xslt_variables};
 180     my $items_rs     = $params->{items_rs};
 181     my $interface    = C4::Context->interface;
 182
 183     die "Mandatory \$params->{xsl_syspref} was not provided, called with biblionumber $params->{biblionumber}"
 184         if not defined $params->{xsl_syspref};
 185
 186     my $xslfilename = get_xsl_filename( $xslsyspref);
 187
 188     my $frameworkcode = GetFrameworkCode($biblionumber) || '';
 189     my $record_processor = Koha::RecordProcessor->new(
 190         {
 191             filters => [ 'ExpandCodedFields' ],
 192             options => {
 193                 interface     => $interface,
 194                 frameworkcode => $frameworkcode
 195             }
 196         }
 197     );
 198     $record_processor->process($record);
 199
 200     # grab the XML, run it through our stylesheet, push it out to the browser
 201     my $itemsxml;
 202     if ( $xslsyspref eq "OPACXSLTDetailsDisplay" || $xslsyspref eq "XSLTDetailsDisplay" || $xslsyspref eq "XSLTResultsDisplay" ) {
 203         $itemsxml = ""; #We don't use XSLT for items display on these pages
 204     } else {
 205         $itemsxml = buildKohaItemsNamespace($biblionumber, $hidden_items, $items_rs);
 206     }
 207     my $xmlrecord = $record->as_xml(C4::Context->preference('marcflavour'));
 208
 209     $variables ||= {};
 210     my $biblio;
 211     if ( $interface eq 'opac' && C4::Context->preference('OPACShowOpenURL')) {
 212         my @biblio_itemtypes;
 213         $biblio //= Koha::Biblios->find($biblionumber);
 214         if (C4::Context->preference('item-level_itypes')) {
 215             @biblio_itemtypes = $biblio->items->get_column("itype");
 216         } else {
 217             push @biblio_itemtypes, $biblio->itemtype;
 218         }
 219         my @itypes = split( /\s/, C4::Context->preference('OPACOpenURLItemTypes') );
 220         my %original = ();
 221         map { $original{$_} = 1 } @biblio_itemtypes;
 222         if ( grep { $original{$_} } @itypes ) {
 223             $variables->{OpenURLResolverURL} = $biblio->get_openurl;
 224         }
 225     }
 226
 227     my $varxml = "<variables>\n";
 228     while (my ($key, $value) = each %$variables) {
 229         $value //= q{};
 230         $varxml .= "<variable name=\"$key\">$value</variable>\n";
 231     }
 232     $varxml .= "</variables>\n";
 233
 234     my $sysxml = get_xslt_sysprefs();
 235     $xmlrecord =~ s/\<\/record\>/$itemsxml$sysxml$varxml\<\/record\>/;
 236     if ($fixamps) { # We need to correct the ampersand entities that Zebra outputs
 237         $xmlrecord =~ s/\&amp;amp;/\&amp;/g;
 238         $xmlrecord =~ s/\&amp\;lt\;/\&lt\;/g;
 239         $xmlrecord =~ s/\&amp\;gt\;/\&gt\;/g;
 240     }
 241     $xmlrecord =~ s/\& /\&amp\; /;
 242     $xmlrecord =~ s/\&amp\;amp\; /\&amp\; /;
 243
 244     #If the xslt should fail, we will return undef (old behavior was
 245     #raw MARC)
 246     #Note that we did set do_not_return_source at object construction
 247     return $engine->transform($xmlrecord, $xslfilename ); #file or URL
 248 }
 249
 250 =head2 buildKohaItemsNamespace
 251
 252     my $items_xml = buildKohaItemsNamespace( $biblionumber, [ $hidden_items, $items ] );
 253
 254 Returns XML for items. It accepts two optional parameters:
 255 - I<$hidden_items>: An arrayref of itemnumber values, for items that should be hidden
 256 - I<$items>: A Koha::Items resultset, for the items to be returned
 257
 258 If both parameters are passed, I<$items> is used as the basis resultset, and I<$hidden_items>
 259 are filtered out of it.
 260
 261 Is only used in this module currently.
 262
 263 =cut
 264
 265 sub buildKohaItemsNamespace {
 266     my ($biblionumber, $hidden_items, $items_rs) = @_;
 267
 268     $hidden_items ||= [];
 269
 270     my $query = {};
 271     $query = { 'me.itemnumber' => { not_in => $hidden_items } }
 272       if $hidden_items;
 273
 274     unless ( $items_rs && ref($items_rs) eq 'Koha::Items' ) {
 275         $query->{'me.biblionumber'} = $biblionumber;
 276         $items_rs = Koha::Items->new;
 277     }
 278
 279     my $items = $items_rs->search( $query, { prefetch => [ 'branchtransfers', 'reserves' ] } );
 280
 281     my $shelflocations =
 282       { map { $_->{authorised_value} => $_->{opac_description} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => "", kohafield => 'items.location' } ) };
 283     my $ccodes =
 284       { map { $_->{authorised_value} => $_->{opac_description} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => "", kohafield => 'items.ccode' } ) };
 285
 286     my %branches = map { $_->branchcode => $_->branchname } Koha::Libraries->search({}, { order_by => 'branchname' })->as_list;
 287
 288     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search->unblessed } };
 289     my $xml = '';
 290     my %descs = map { $_->{authorised_value} => $_ } Koha::AuthorisedValues->get_descriptions_by_koha_field( { kohafield => 'items.notforloan' } );
 291     my $ref_status = C4::Context->preference('Reference_NFL_Statuses') || '1|2';
 292
 293     while ( my $item = $items->next ) {
 294         my $status;
 295         my $substatus = '';
 296         my $recalls_count;
 297
 298         if ( C4::Context->preference('UseRecalls') ) {
 299             $recalls_count = Koha::Recalls->search({ item_id => $item->itemnumber, status => 'waiting' })->count;
 300         }
 301
 302         if ($recalls_count) {
 303             # recalls take priority over holds
 304             $status = 'other';
 305             $substatus = 'Recall waiting';
 306         }
 307         elsif ( $item->has_pending_hold ) {
 308             $status = 'other';
 309             $substatus = 'Pending hold';
 310         }
 311         elsif ( $item->holds->waiting->count ) {
 312             $status = 'other';
 313             $substatus = 'Hold waiting';
 314         }
 315         elsif ($item->get_transfer) {
 316             $status = 'other';
 317             $substatus = 'In transit';
 318         }
 319         elsif ($item->damaged) {
 320             $status = 'other';
 321             $substatus = "Damaged";
 322         }
 323         elsif ($item->itemlost) {
 324             $status = 'other';
 325             $substatus = "Lost";
 326         }
 327         elsif ( $item->withdrawn) {
 328             $status = 'other';
 329             $substatus = "Withdrawn";
 330         }
 331         elsif ($item->onloan) {
 332             $status = 'other';
 333             $substatus = "Checked out";
 334         }
 335         elsif ( $item->notforloan ) {
 336             $status = $item->notforloan =~ /^($ref_status)$/
 337                 ? "reference"
 338                 : "reallynotforloan";
 339             $substatus = exists $descs{$item->notforloan} ? $descs{$item->notforloan}->{opac_description} : "Not for loan";
 340         }
 341         elsif ( exists $itemtypes->{ $item->effective_itemtype }
 342             && $itemtypes->{ $item->effective_itemtype }->{notforloan}
 343             && $itemtypes->{ $item->effective_itemtype }->{notforloan} == 1 )
 344         {
 345             $status = "1" =~ /^($ref_status)$/
 346                 ? "reference"
 347                 : "reallynotforloan";
 348             $substatus = "Not for loan";
 349         }
 350         else {
 351             $status = "available";
 352         }
 353         my $homebranch     = C4::Koha::xml_escape($branches{$item->homebranch});
 354         my $holdingbranch  = C4::Koha::xml_escape($branches{$item->holdingbranch});
 355         my $resultbranch   = C4::Context->preference('OPACResultsLibrary') eq 'homebranch' ? $homebranch : $holdingbranch;
 356         my $location       = C4::Koha::xml_escape($item->location && exists $shelflocations->{$item->location} ? $shelflocations->{$item->location} : $item->location);
 357         my $ccode          = C4::Koha::xml_escape($item->ccode    && exists $ccodes->{$item->ccode}            ? $ccodes->{$item->ccode}            : $item->ccode);
 358         my $itemcallnumber = C4::Koha::xml_escape($item->itemcallnumber);
 359         my $stocknumber    = C4::Koha::xml_escape($item->stocknumber);
 360         $xml .=
 361             "<item>"
 362           . "<homebranch>$homebranch</homebranch>"
 363           . "<holdingbranch>$holdingbranch</holdingbranch>"
 364           . "<resultbranch>$resultbranch</resultbranch>"
 365           . "<location>$location</location>"
 366           . "<ccode>$ccode</ccode>"
 367           . "<status>".( $status // q{} )."</status>"
 368           . "<substatus>$substatus</substatus>"
 369           . "<itemcallnumber>$itemcallnumber</itemcallnumber>"
 370           . "<stocknumber>$stocknumber</stocknumber>"
 371           . "</item>";
 372     }
 373     $xml = "<items xmlns=\"http://www.koha-community.org/items\">".$xml."</items>";
 374     return $xml;
 375 }
 376
 377 =head2 engine
 378
 379 Returns reference to XSLT handler object.
 380
 381 =cut
 382
 383 sub engine {
 384     return $engine;
 385 }
 386
 387 1;
 388
 389 __END__
 390
 391 =head1 AUTHOR
 392
 393 Joshua Ferraro <jmf@liblime.com>
 394
 395 Koha Development Team <http://koha-community.org/>
 396
 397 =cut