Koha/ArticleRequest.pm

   1 package Koha::ArticleRequest;
   2
   3 # Copyright ByWater Solutions 2015
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use Koha::Database;
  24 use Koha::Patrons;
  25 use Koha::Biblios;
  26 use Koha::Items;
  27 use Koha::Libraries;
  28 use Koha::DateUtils qw( dt_from_string );
  29 use Koha::ArticleRequest::Status;
  30 use Koha::Exceptions::ArticleRequest;
  31
  32 use base qw(Koha::Object);
  33
  34 =head1 NAME
  35
  36 Koha::ArticleRequest - Koha Article Request Object class
  37
  38 =head1 API
  39
  40 =head2 Class methods
  41
  42 =cut
  43
  44 =head3 request
  45
  46     $article_request->request;
  47
  48 Marks the article as requested. Send a notification if appropriate.
  49
  50 =cut
  51
  52 sub request {
  53     my ($self) = @_;
  54
  55     Koha::Exceptions::ArticleRequest::LimitReached->throw(
  56         error => 'Patron cannot request more articles for today'
  57     ) unless $self->borrower->can_request_article;
  58
  59     $self->status(Koha::ArticleRequest::Status::Requested);
  60     $self->SUPER::store();
  61     $self->notify();
  62     return $self;
  63 }
  64
  65 =head3 set_pending
  66
  67     $article_request->set_pending;
  68
  69 Marks the article as pending. Send a notification if appropriate.
  70
  71 =cut
  72
  73 sub set_pending {
  74     my ($self) = @_;
  75
  76     $self->status(Koha::ArticleRequest::Status::Pending);
  77     $self->SUPER::store();
  78     $self->notify();
  79     return $self;
  80 }
  81
  82 =head3 process
  83
  84     $article_request->process;
  85
  86 Marks the article as in process. Send a notification if appropriate.
  87
  88 =cut
  89
  90 sub process {
  91     my ($self) = @_;
  92
  93     $self->status(Koha::ArticleRequest::Status::Processing);
  94     $self->store();
  95     $self->notify();
  96     return $self;
  97 }
  98
  99 =head3 complete
 100
 101     $article_request->complete;
 102
 103 Marks the article as completed. Send a notification if appropriate.
 104
 105 =cut
 106
 107 sub complete {
 108     my ($self) = @_;
 109
 110     $self->status(Koha::ArticleRequest::Status::Completed);
 111     $self->store();
 112     $self->notify();
 113     return $self;
 114 }
 115
 116 =head3 cancel
 117
 118     $article_request->cancel;
 119
 120 Marks the article as cancelled. Send a notification if appropriate.
 121
 122 =cut
 123
 124 sub cancel {
 125     my ( $self, $cancellation_reason, $notes ) = @_;
 126
 127     $self->status(Koha::ArticleRequest::Status::Canceled);
 128     $self->cancellation_reason($cancellation_reason) if $cancellation_reason;
 129     $self->notes($notes) if $notes;
 130     $self->store();
 131     $self->notify();
 132     return $self;
 133 }
 134
 135 =head3 biblio
 136
 137 Returns the Koha::Biblio object for this article request
 138
 139 =cut
 140
 141 sub biblio {
 142     my ($self) = @_;
 143
 144     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 145
 146     return $self->{_biblio};
 147 }
 148
 149 =head3 item
 150
 151 Returns the Koha::Item object for this article request
 152
 153 =cut
 154
 155 sub item {
 156     my ($self) = @_;
 157
 158     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 159
 160     return $self->{_item};
 161 }
 162
 163 =head3 borrower
 164
 165 Returns the Koha::Patron object for this article request
 166
 167 =cut
 168
 169 sub borrower {
 170     my ($self) = @_;
 171
 172     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 173
 174     return $self->{_borrower};
 175 }
 176
 177 =head3 branch
 178
 179 Returns the Koha::Library object for this article request
 180
 181 =cut
 182
 183 sub branch {
 184     my ($self) = @_;
 185
 186     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 187
 188     return $self->{_branch};
 189 }
 190
 191 =head3 store
 192
 193 Override the default store behavior so that new opac requests
 194 will have notifications sent.
 195
 196 =cut
 197
 198 sub store {
 199     my ($self) = @_;
 200     if ( $self->in_storage ) {
 201         return $self->SUPER::store;
 202     } else {
 203         $self->created_on( dt_from_string() );
 204         return $self->request;
 205     }
 206 }
 207
 208 =head2 Internal methods
 209
 210 =head3 notify
 211
 212     $self->notify();
 213
 214 internal method to be called when changing an article request status.
 215 If a letter exists for the new status, it enqueues it.
 216
 217 =cut
 218
 219 sub notify {
 220     my ($self) = @_;
 221
 222     my $status = $self->status;
 223     my $reason = $self->notes;
 224     if ( !defined $reason && $self->cancellation_reason ) {
 225         my $av = Koha::AuthorisedValues->search(
 226             {
 227                 category            => 'AR_CANCELLATION',
 228                 authorised_value    => $self->cancellation_reason
 229             }
 230         )->next;
 231         $reason = $av->lib_opac ? $av->lib_opac : $av->lib if $av;
 232     }
 233
 234     require C4::Letters;
 235     if (
 236         my $letter = C4::Letters::GetPreparedLetter(
 237             module                 => 'circulation',
 238             letter_code            => "AR_$status", # AR_REQUESTED, AR_PENDING, AR_PROCESSING, AR_COMPLETED, AR_CANCELED
 239             message_transport_type => 'email',
 240             lang                   => $self->borrower->lang,
 241             tables                 => {
 242                 article_requests => $self->id,
 243                 borrowers        => $self->borrowernumber,
 244                 biblio           => $self->biblionumber,
 245                 biblioitems      => $self->biblionumber,
 246                 items            => $self->itemnumber,
 247                 branches         => $self->branchcode,
 248             },
 249             substitute => {
 250                 reason => $reason,
 251             },
 252         )
 253       )
 254     {
 255         C4::Letters::EnqueueLetter(
 256             {
 257                 letter                 => $letter,
 258                 borrowernumber         => $self->borrowernumber,
 259                 message_transport_type => 'email',
 260             }
 261         ) or warn "can't enqueue letter " . $letter->{code};
 262     }
 263 }
 264
 265 =head3 _type
 266
 267 =cut
 268
 269 sub _type {
 270     return 'ArticleRequest';
 271 }
 272
 273 =head1 AUTHOR
 274
 275 Kyle M Hall <kyle@bywatersolutions.com>
 276
 277 =cut
 278
 279 1;