Koha/Authority.pm

   1 package Koha::Authority;
   2
   3 # Copyright 2015 Koha Development Team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use base qw(Koha::Object);
  23
  24 use Koha::Authority::ControlledIndicators;
  25 use Koha::SearchEngine::Search;
  26
  27 =head1 NAME
  28
  29 Koha::Authority - Koha Authority Object class
  30
  31 =head1 API
  32
  33 =head2 Instance Methods
  34
  35 =head3 get_usage_count
  36
  37     $count = $self->get_usage_count;
  38
  39     Returns the number of linked biblio records.
  40
  41 =cut
  42
  43 sub get_usage_count {
  44     my ( $self ) = @_;
  45     return Koha::Authorities->get_usage_count({ authid => $self->authid });
  46 }
  47
  48 =head3 linked_biblionumbers
  49
  50     my @biblios = $self->linked_biblionumbers({
  51         [ max_results => $max ], [ offset => $offset ],
  52     });
  53
  54     Returns an array of biblionumbers.
  55
  56 =cut
  57
  58 sub linked_biblionumbers {
  59     my ( $self, $params ) = @_;
  60     $params->{authid} = $self->authid;
  61     return Koha::Authorities->linked_biblionumbers( $params );
  62 }
  63
  64 =head3 controlled_indicators
  65
  66     Some authority types control the indicators of some corresponding
  67     biblio fields (especially in MARC21).
  68     For example, if you have a PERSO_NAME authority (report tag 100), the
  69     first indicator of biblio field 600 directly comes from the authority,
  70     and the second indicator depends on thesaurus settings in the authority
  71     record. Use this method to obtain such controlled values. In this example
  72     you should pass 600 in the biblio_tag parameter.
  73
  74     my $result = $self->controlled_indicators({
  75         record => $auth_marc, biblio_tag => $bib_tag
  76     });
  77     my $ind1 = $result->{ind1};
  78     my $ind2 = $result->{ind2};
  79     my $subfield_2 = $result->{sub2}; # Optional subfield 2 when ind==7
  80
  81     If an indicator is not controlled, the result hash does not contain a key
  82     for its value. (Same for the sub2 key for an optional subfield $2.)
  83
  84     Note: The record parameter is a temporary bypass in order to prevent
  85     needless conversion of $self->marcxml.
  86
  87 =cut
  88
  89 sub controlled_indicators {
  90     my ( $self, $params ) = @_;
  91     my $tag = $params->{biblio_tag} // q{};
  92     my $record = $params->{record};
  93
  94     my $flavour = C4::Context->preference('marcflavour') eq 'UNIMARC'
  95         ? 'UNIMARCAUTH'
  96         : 'MARC21';
  97     if( !$record ) {
  98         $record = MARC::Record->new_from_xml(
  99             $self->marcxml, 'UTF-8', $flavour );
 100     }
 101
 102     if( !$self->{_report_tag} ) {
 103         my $authtype = Koha::Authority::Types->find( $self->authtypecode );
 104         return {} if !$authtype; # very exceptional
 105         $self->{_report_tag} = $authtype->auth_tag_to_report;
 106     }
 107
 108     $self->{_ControlledInds} //= Koha::Authority::ControlledIndicators->new;
 109     return $self->{_ControlledInds}->get({
 110         auth_record => $record,
 111         report_tag  => $self->{_report_tag},
 112         biblio_tag  => $tag,
 113         flavour     => $flavour,
 114     });
 115 }
 116
 117 =head3 get_identifiers
 118
 119     my $identifiers = $author->get_identifiers;
 120
 121 Return a list of identifiers of the authors which are in 024$2$a
 122
 123 =cut
 124
 125 sub get_identifiers {
 126     my ( $self, $params ) = @_;
 127
 128     my $flavour =
 129       C4::Context->preference('marcflavour') eq 'UNIMARC'
 130       ? 'UNIMARCAUTH'
 131       : 'MARC21';
 132     my $record =
 133       MARC::Record->new_from_xml( $self->marcxml, 'UTF-8', $flavour );
 134
 135     my @identifiers;
 136     for my $field ( $record->field('024') ) {
 137         my $sf_2 = $field->subfield('2');
 138         my $sf_a = $field->subfield('a');
 139         next unless $sf_2 && $sf_a;
 140         push @identifiers, {source => $sf_2, number => $sf_a, };
 141     }
 142
 143     return \@identifiers;
 144 }
 145
 146 =head2 Class Methods
 147
 148 =head3 type
 149
 150 =cut
 151
 152 sub _type {
 153     return 'AuthHeader';
 154 }
 155
 156 1;