Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use vars qw(@ISA @EXPORT_OK);
  25 BEGIN {
  26     require Exporter;
  27     @ISA = qw(Exporter);
  28
  29     @EXPORT_OK = qw(
  30         dt_from_string
  31         output_pref
  32         format_sqldatetime
  33         flatpickr_date_format
  34     );
  35 }
  36
  37 =head1 DateUtils
  38
  39 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  40
  41 =head1 DESCRIPTION
  42
  43 Koha has historically only used dates not datetimes and been content to
  44 handle these as strings. It also has confused formatting with actual dates
  45 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  46
  47 =cut
  48
  49 =head2 dt_ftom_string
  50
  51 $dt = dt_from_string($date_string, [$format, $timezone ]);
  52
  53 Passed a date string returns a DateTime object format and timezone default
  54 to the system preferences. If the date string is empty DateTime->now is returned
  55
  56 =cut
  57
  58 sub dt_from_string {
  59     my ( $date_string, $date_format, $tz ) = @_;
  60
  61     return if $date_string and $date_string =~ m|^0000-0|;
  62
  63     my $do_fallback = defined($date_format) ? 0 : 1;
  64     my $server_tz = C4::Context->tz;
  65     $tz = C4::Context->tz unless $tz;
  66
  67     return DateTime->now( time_zone => $tz ) unless $date_string;
  68
  69     $date_format = C4::Context->preference('dateformat') unless $date_format;
  70
  71     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  72         return $date_string;
  73     }
  74
  75     my $regex;
  76
  77     # The fallback format is sql/iso
  78     my $fallback_re = qr|
  79         (?<year>\d{4})
  80         -
  81         (?<month>\d{2})
  82         -
  83         (?<day>\d{2})
  84     |xms;
  85
  86     if ( $date_format eq 'metric' ) {
  87         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  88         $regex = qr|
  89             (?<day>\d{2})
  90             /
  91             (?<month>\d{2})
  92             /
  93             (?<year>\d{4})
  94         |xms;
  95     }
  96     elsif ( $date_format eq 'dmydot' ) {
  97         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  98         $regex = qr|
  99             (?<day>\d{2})
 100             .
 101             (?<month>\d{2})
 102             .
 103             (?<year>\d{4})
 104         |xms;
 105     }
 106     elsif ( $date_format eq 'us' ) {
 107         # us format is "mm/dd/yyyy[ hh:mm:ss]"
 108         $regex = qr|
 109             (?<month>\d{2})
 110             /
 111             (?<day>\d{2})
 112             /
 113             (?<year>\d{4})
 114         |xms;
 115     }
 116     elsif ( $date_format eq 'rfc3339' ) {
 117         $regex = qr/
 118             (?<year>\d{4})
 119             -
 120             (?<month>\d{2})
 121             -
 122             (?<day>\d{2})
 123             ([Tt\s])
 124             (?<hour>\d{2})
 125             :
 126             (?<minute>\d{2})
 127             :
 128             (?<second>\d{2})
 129             (\.\d{1,3})?(([Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):(?<minutes>[0-5][0-9])))
 130         /xms;
 131
 132         # Default to UTC (when 'Z' is passed) for inbound timezone.
 133         # The regex above succeeds for both 'z', 'Z' and '+/-' offset.
 134         # We set tz as though Z was passed by default and then correct it later if an offset is detected
 135         # by the presence fo the <offset> variable.
 136         $tz = DateTime::TimeZone->new( name => 'UTC' );
 137     }
 138     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 139         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 140         $regex = $fallback_re;
 141     }
 142     else {
 143         die "Invalid dateformat parameter ($date_format)";
 144     }
 145
 146     # Add the facultative time part including time zone offset; ISO8601 allows +02 or +0200 too
 147     my $time_re = qr{
 148             (
 149                 [Tt]?
 150                 \s*
 151                 (?<hour>\d{2})
 152                 :
 153                 (?<minute>\d{2})
 154                 (
 155                     :
 156                     (?<second>\d{2})
 157                 )?
 158                 (
 159                     \s
 160                     (?<ampm>\w{2})
 161                 )?
 162                 (
 163                     (?<utc>[Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):?(?<minutes>[0-5][0-9])?)
 164                 )?
 165             )?
 166     }xms;
 167     $regex .= $time_re unless ( $date_format eq 'rfc3339' );
 168     $fallback_re .= $time_re;
 169
 170     # Ensure we only accept date strings and not other characters.
 171     $regex = '^' . $regex . '$';
 172     $fallback_re = '^' . $fallback_re . '$';
 173
 174     my %dt_params;
 175     my $ampm;
 176     if ( $date_string =~ $regex ) {
 177         %dt_params = (
 178             year   => $+{year},
 179             month  => $+{month},
 180             day    => $+{day},
 181             hour   => $+{hour},
 182             minute => $+{minute},
 183             second => $+{second},
 184         );
 185         $ampm = $+{ampm};
 186         if ( $+{utc} ) {
 187             $tz = DateTime::TimeZone->new( name => 'UTC' );
 188         }
 189         if ( $+{offset} ) {
 190             # If offset given, set inbound timezone using it.
 191             $tz = DateTime::TimeZone->new( name => $+{offset} . $+{hours} . ( $+{minutes} || '00' ) );
 192         }
 193     } elsif ( $do_fallback && $date_string =~ $fallback_re ) {
 194         %dt_params = (
 195             year   => $+{year},
 196             month  => $+{month},
 197             day    => $+{day},
 198             hour   => $+{hour},
 199             minute => $+{minute},
 200             second => $+{second},
 201         );
 202         $ampm = $+{ampm};
 203     }
 204     else {
 205         die "The given date ($date_string) does not match the date format ($date_format)";
 206     }
 207
 208     # system allows the 0th of the month
 209     $dt_params{day} = '01' if $dt_params{day} eq '00';
 210
 211     # Set default hh:mm:ss to 00:00:00
 212     my $date_only = ( !defined( $dt_params{hour} )
 213         && !defined( $dt_params{minute} )
 214         && !defined( $dt_params{second} ) );
 215     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 216     $dt_params{minute} = 00 unless defined $dt_params{minute};
 217     $dt_params{second} = 00 unless defined $dt_params{second};
 218
 219     if ( $ampm ) {
 220         if ( $ampm eq 'AM' ) {
 221             $dt_params{hour} = 00 if $dt_params{hour} == 12;
 222         } elsif ( $dt_params{hour} != 12 ) { # PM
 223             $dt_params{hour} += 12;
 224             $dt_params{hour} = 00 if $dt_params{hour} == 24;
 225         }
 226     }
 227
 228     my $floating = 0;
 229     my $dt = eval {
 230         DateTime->new(
 231             %dt_params,
 232             # No TZ for dates 'infinite' => see bug 13242
 233             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 234         );
 235     };
 236     if ($@) {
 237         $tz = DateTime::TimeZone->new( name => 'floating' );
 238         $floating = 1;
 239         $dt = DateTime->new(
 240             %dt_params,
 241             # No TZ for dates 'infinite' => see bug 13242
 242             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 243         );
 244     }
 245
 246     # Convert to configured timezone (unless we started with a dateonly string or had to drop to floating time)
 247     $dt->set_time_zone($server_tz) unless ( $date_only || $floating );
 248
 249     return $dt;
 250 }
 251
 252 =head2 output_pref
 253
 254 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 255 $date_string = output_pref( $dt );
 256
 257 Returns a string containing the time & date formatted as per the C4::Context setting,
 258 or C<undef> if C<undef> was provided.
 259
 260 This routine can either be passed a DateTime object or or a hashref.  If it is
 261 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 262 an optional 'dateformat' to override the dateformat system preference, an
 263 optional 'timeformat' to override the TimeFormat system preference value,
 264 and an optional 'dateonly' to specify that only the formatted date string
 265 should be returned without the time.
 266
 267 =cut
 268
 269 sub output_pref {
 270     my $params = shift;
 271     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 272     if ( ref $params eq 'HASH' ) {
 273         $dt         = $params->{dt};
 274         $str        = $params->{str};
 275         $force_pref = $params->{dateformat};         # if testing we want to override Context
 276         $force_time = $params->{timeformat};
 277         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 278         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 279     } else {
 280         $dt = $params;
 281     }
 282
 283     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 284
 285     if ( $str ) {
 286         local $@;
 287         $dt = eval { dt_from_string( $str ) };
 288         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 289     }
 290
 291     return if !defined $dt; # NULL date
 292     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 293
 294     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 295     if ( $dt->ymd !~ /^9999/ ) {
 296         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 297         eval { $dt->set_time_zone( $tz ); }
 298     }
 299
 300     my $pref =
 301       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 302
 303     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 304     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 305     my $date;
 306     if ( $pref =~ m/^iso/ ) {
 307         $date = $dateonly
 308           ? $dt->strftime("%Y-%m-%d")
 309           : $dt->strftime("%Y-%m-%d $time");
 310     }
 311     elsif ( $pref =~ m/^rfc3339/ ) {
 312         if (!$dateonly) {
 313             $date = $dt->strftime('%FT%T%z');
 314             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 315         }
 316         else {
 317             $date = $dt->strftime("%Y-%m-%d");
 318         }
 319     }
 320     elsif ( $pref =~ m/^metric/ ) {
 321         $date = $dateonly
 322           ? $dt->strftime("%d/%m/%Y")
 323           : $dt->strftime("%d/%m/%Y $time");
 324     }
 325     elsif ( $pref =~ m/^dmydot/ ) {
 326         $date = $dateonly
 327           ? $dt->strftime("%d.%m.%Y")
 328           : $dt->strftime("%d.%m.%Y $time");
 329     }
 330
 331     elsif ( $pref =~ m/^us/ ) {
 332         $date = $dateonly
 333           ? $dt->strftime("%m/%d/%Y")
 334           : $dt->strftime("%m/%d/%Y $time");
 335     }
 336     else {
 337         $date = $dateonly
 338           ? $dt->strftime("%Y-%m-%d")
 339           : $dt->strftime("%Y-%m-%d $time");
 340     }
 341
 342     if ( $as_due_date ) {
 343         $time_format eq '12hr'
 344             ? $date =~ s| 11:59 PM$||
 345             : $date =~ s| 23:59$||;
 346     }
 347
 348     return $date;
 349 }
 350
 351 =head2 format_sqldatetime
 352
 353 $string = format_sqldatetime( $string_as_returned_from_db );
 354
 355 a convenience routine for calling dt_from_string and formatting the result
 356 with output_pref as it is a frequent activity in scripts
 357
 358 =cut
 359
 360 sub format_sqldatetime {
 361     my $str        = shift;
 362     my $force_pref = shift;    # if testing we want to override Context
 363     my $force_time = shift;
 364     my $dateonly   = shift;
 365
 366     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 367         my $dt = dt_from_string( $str, 'sql' );
 368         return q{} unless $dt;
 369         $dt->truncate( to => 'minute' );
 370         return output_pref({
 371             dt => $dt,
 372             dateformat => $force_pref,
 373             timeformat => $force_time,
 374             dateonly => $dateonly
 375         });
 376     }
 377     return q{};
 378 }
 379
 380 =head2 flatpickr_date_format
 381
 382 $date_format = flatpickr_date_format( $koha_date_format );
 383
 384 Converts Koha's date format to Flatpickr's. E.g. 'us' returns 'm/d/Y'.
 385
 386 If no argument is given, the dateformat preference is assumed.
 387
 388 Returns undef if format is unknown.
 389
 390 =cut
 391
 392 sub flatpickr_date_format {
 393     my $arg = shift // C4::Context->preference('dateformat');
 394     return {
 395         us     => 'm/d/Y',
 396         metric => 'd/m/Y',
 397         dmydot => 'd.m.Y',
 398         iso    => 'Y-m-d',
 399     }->{$arg};
 400 }
 401
 402 1;