Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use DateTime::Format::DateParse;
  24 use C4::Context;
  25
  26 use base 'Exporter';
  27 use version; our $VERSION = qv('1.0.0');
  28
  29 our @EXPORT = (
  30     qw( dt_from_string output_pref format_sqldatetime output_pref_due format_sqlduedatetime)
  31 );
  32
  33 =head1 DateUtils
  34
  35 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  36
  37 =head1 DESCRIPTION
  38
  39 Koha has historically only used dates not datetimes and been content to
  40 handle these as strings. It also has confused formatting with actual dates
  41 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  42
  43 =cut
  44
  45 =head2 dt_ftom_string
  46
  47 $dt = dt_from_string($date_string, [$format, $timezone ]);
  48
  49 Passed a date string returns a DateTime object format and timezone default
  50 to the system preferences. If the date string is empty DateTime->now is returned
  51
  52 =cut
  53
  54 sub dt_from_string {
  55     my ( $date_string, $date_format, $tz ) = @_;
  56     if ( !$tz ) {
  57         $tz = C4::Context->tz;
  58     }
  59     if ( !$date_format ) {
  60         $date_format = C4::Context->preference('dateformat');
  61     }
  62     if ($date_string) {
  63         if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  64             return $date_string;
  65         }
  66
  67         if ( $date_format eq 'metric' ) {
  68             $date_string =~ s#-#/#g;
  69             $date_string =~ s/^00/01/;    # system allows the 0th of the month
  70             $date_string =~ s#^(\d{1,2})/(\d{1,2})#$2/$1#;
  71         } else {
  72             if ( $date_format eq 'iso' ) {
  73                 $date_string =~ s/-00/-01/;
  74                 if ( $date_string =~ m/^0000-0/ ) {
  75                     return;               # invalid date in db
  76                 }
  77             } elsif ( $date_format eq 'us' ) {
  78                 $date_string =~ s#-#/#g;
  79                 $date_string =~ s[/00/][/01/];
  80             } elsif ( $date_format eq 'sql' ) {
  81                 $date_string =~
  82 s/(\d{4})(\d{2})(\d{2})\s+(\d{2})(\d{2})(\d{2})/$1-$2-$3T$4:$5:$6/;
  83                 return if ($date_string =~ /^0000-00-00/);
  84                 $date_string =~ s/00T/01T/;
  85             }
  86         }
  87         return DateTime::Format::DateParse->parse_datetime( $date_string,
  88             $tz->name() );
  89     }
  90     return DateTime->now( time_zone => $tz );
  91
  92 }
  93
  94 =head2 output_pref
  95
  96 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1 ] });
  97 $date_string = output_pref( $dt );
  98
  99 Returns a string containing the time & date formatted as per the C4::Context setting,
 100 or C<undef> if C<undef> was provided.
 101
 102 This routine can either be passed a DateTime object or or a hashref.  If it is
 103 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 104 an optional 'dateformat' to override the dateformat system preference, an
 105 optional 'timeformat' to override the TimeFormat system preference value,
 106 and an optional 'dateonly' to specify that only the formatted date string
 107 should be returned without the time.
 108
 109 =cut
 110
 111 sub output_pref {
 112     my $params = shift;
 113     my ( $dt, $force_pref, $force_time, $dateonly );
 114     if ( ref $params eq 'HASH' ) {
 115         $dt         = $params->{dt};
 116         $force_pref = $params->{dateformat};         # if testing we want to override Context
 117         $force_time = $params->{timeformat};
 118         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 119     } else {
 120         $dt = $params;
 121     }
 122
 123     return unless defined $dt;
 124
 125     $dt->set_time_zone( C4::Context->tz );
 126
 127     my $pref =
 128       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 129
 130     my $time_format = $force_time || C4::Context->preference('TimeFormat');
 131     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 132
 133     given ($pref) {
 134         when (/^iso/) {
 135             return $dateonly
 136                 ? $dt->strftime("%Y-%m-%d")
 137                 : $dt->strftime("%Y-%m-%d $time");
 138         }
 139         when (/^metric/) {
 140             return $dateonly
 141                 ? $dt->strftime("%d/%m/%Y")
 142                 : $dt->strftime("%d/%m/%Y $time");
 143         }
 144         when (/^us/) {
 145
 146             return $dateonly
 147                 ? $dt->strftime("%m/%d/%Y")
 148                 : $dt->strftime("%m/%d/%Y $time");
 149         }
 150         default {
 151             return $dateonly
 152                 ? $dt->strftime("%Y-%m-%d")
 153                 : $dt->strftime("%Y-%m-%d $time");
 154         }
 155
 156     }
 157     return;
 158 }
 159
 160 =head2 output_pref_due
 161
 162 $date_string = output_pref_due({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1 ] });
 163 $date_string = output_pref_due($dt);
 164
 165 Returns a string containing the time & date formatted as per the C4::Context setting
 166
 167 This routine can either be passed a DateTime object or or a hashref.  If it is
 168 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 169 an optional 'dateformat' to override the dateformat system preference, an
 170 optional 'timeformat' to override the TimeFormat system preference value,
 171 and an optional 'dateonly' to specify that only the formatted date string
 172 should be returned without the time.
 173
 174 This is effectively a wrapper around output_pref for due dates;
 175 the time portion is stripped if it is '23:59'
 176
 177 =cut
 178
 179 sub output_pref_due {
 180     my $disp_str = output_pref(@_);
 181     $disp_str =~ s/ 23:59//;
 182     return $disp_str;
 183 }
 184
 185 =head2 format_sqldatetime
 186
 187 $string = format_sqldatetime( $string_as_returned_from_db );
 188
 189 a convenience routine for calling dt_from_string and formatting the result
 190 with output_pref as it is a frequent activity in scripts
 191
 192 =cut
 193
 194 sub format_sqldatetime {
 195     my $str        = shift;
 196     my $force_pref = shift;    # if testing we want to override Context
 197     my $force_time = shift;
 198     my $dateonly   = shift;
 199
 200     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 201         my $dt = dt_from_string( $str, 'sql' );
 202         return q{} unless $dt;
 203         $dt->truncate( to => 'minute' );
 204         return output_pref({
 205             dt => $dt,
 206             dateformat => $force_pref,
 207             timeformat => $force_time,
 208             dateonly => $dateonly
 209         });
 210     }
 211     return q{};
 212 }
 213
 214 =head2 format_sqlduedatetime
 215
 216 $string = format_sqldatetime( $string_as_returned_from_db );
 217
 218 a convenience routine for calling dt_from_string and formatting the result
 219 with output_pref_due as it is a frequent activity in scripts
 220
 221 =cut
 222
 223 sub format_sqlduedatetime {
 224     my $str        = shift;
 225     my $force_pref = shift;    # if testing we want to override Context
 226     my $force_time = shift;
 227     my $dateonly   = shift;
 228
 229     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 230         my $dt = dt_from_string( $str, 'sql' );
 231         $dt->truncate( to => 'minute' );
 232         return output_pref_due({
 233             dt => $dt,
 234             dateformat => $force_pref,
 235             timeformat => $force_time,
 236             dateonly => $dateonly
 237         });
 238     }
 239     return q{};
 240 }
 241
 242 1;