Koha/Hold.pm

   1 package Koha::Hold;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2017 Koha Development team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any );
  24
  25 use C4::Context qw(preference);
  26 use C4::Letters qw( GetPreparedLetter EnqueueLetter );
  27 use C4::Log qw( logaction );
  28 use C4::Reserves;
  29
  30 use Koha::AuthorisedValues;
  31 use Koha::DateUtils qw( dt_from_string );
  32 use Koha::Patrons;
  33 use Koha::Biblios;
  34 use Koha::Hold::CancellationRequests;
  35 use Koha::Items;
  36 use Koha::Libraries;
  37 use Koha::Old::Holds;
  38 use Koha::Calendar;
  39 use Koha::Plugins;
  40
  41 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  42
  43 use Koha::Exceptions;
  44 use Koha::Exceptions::Hold;
  45
  46 use base qw(Koha::Object);
  47
  48 =head1 NAME
  49
  50 Koha::Hold - Koha Hold object class
  51
  52 =head1 API
  53
  54 =head2 Class methods
  55
  56 =cut
  57
  58 =head3 age
  59
  60 returns the number of days since a hold was placed, optionally
  61 using the calendar
  62
  63 my $age = $hold->age( $use_calendar );
  64
  65 =cut
  66
  67 sub age {
  68     my ( $self, $use_calendar ) = @_;
  69
  70     my $today = dt_from_string;
  71     my $age;
  72
  73     if ( $use_calendar ) {
  74         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
  75         $age = $calendar->days_between( dt_from_string( $self->reservedate ), $today );
  76     }
  77     else {
  78         $age = $today->delta_days( dt_from_string( $self->reservedate ) );
  79     }
  80
  81     $age = $age->in_units( 'days' );
  82
  83     return $age;
  84 }
  85
  86 =head3 suspend_hold
  87
  88 my $hold = $hold->suspend_hold( $suspend_until );
  89
  90 =cut
  91
  92 sub suspend_hold {
  93     my ( $self, $date ) = @_;
  94
  95     $date &&= dt_from_string($date)->truncate( to => 'day' )->datetime;
  96
  97     if ( $self->is_found ) {    # We can't suspend found holds
  98         if ( $self->is_waiting ) {
  99             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'W' );
 100         }
 101         elsif ( $self->is_in_transit ) {
 102             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'T' );
 103         }
 104         elsif ( $self->is_in_processing ) {
 105             Koha::Exceptions::Hold::CannotSuspendFound->throw( status => 'P' );
 106         }
 107         else {
 108             Koha::Exceptions::Hold::CannotSuspendFound->throw(
 109                       'Unhandled data exception on found hold (id='
 110                     . $self->id
 111                     . ', found='
 112                     . $self->found
 113                     . ')' );
 114         }
 115     }
 116
 117     $self->suspend(1);
 118     $self->suspend_until($date);
 119     $self->store();
 120
 121     Koha::Plugins->call(
 122         'after_hold_action',
 123         {
 124             action  => 'suspend',
 125             payload => { hold => $self->get_from_storage }
 126         }
 127     );
 128
 129     logaction( 'HOLDS', 'SUSPEND', $self->reserve_id, $self )
 130         if C4::Context->preference('HoldsLog');
 131
 132     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 133         {
 134             biblio_ids => [ $self->biblionumber ]
 135         }
 136     ) if C4::Context->preference('RealTimeHoldsQueue');
 137
 138     return $self;
 139 }
 140
 141 =head3 resume
 142
 143 my $hold = $hold->resume();
 144
 145 =cut
 146
 147 sub resume {
 148     my ( $self ) = @_;
 149
 150     $self->suspend(0);
 151     $self->suspend_until( undef );
 152
 153     $self->store();
 154
 155     Koha::Plugins->call(
 156         'after_hold_action',
 157         {
 158             action  => 'resume',
 159             payload => { hold => $self->get_from_storage }
 160         }
 161     );
 162
 163     logaction( 'HOLDS', 'RESUME', $self->reserve_id, $self )
 164         if C4::Context->preference('HoldsLog');
 165
 166     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 167         {
 168             biblio_ids => [ $self->biblionumber ]
 169         }
 170     ) if C4::Context->preference('RealTimeHoldsQueue');
 171
 172     return $self;
 173 }
 174
 175 =head3 delete
 176
 177 $hold->delete();
 178
 179 =cut
 180
 181 sub delete {
 182     my ( $self ) = @_;
 183
 184     my $deleted = $self->SUPER::delete($self);
 185
 186     logaction( 'HOLDS', 'DELETE', $self->reserve_id, $self )
 187         if C4::Context->preference('HoldsLog');
 188
 189     return $deleted;
 190 }
 191
 192 =head3 set_transfer
 193
 194 =cut
 195
 196 sub set_transfer {
 197     my ( $self ) = @_;
 198
 199     $self->priority(0);
 200     $self->found('T');
 201     $self->store();
 202
 203     Koha::Plugins->call(
 204         'after_hold_action',
 205         {
 206             action  => 'transfer',
 207             payload => { hold => $self->get_from_storage }
 208         }
 209     );
 210
 211     return $self;
 212 }
 213
 214 =head3 set_waiting
 215
 216 =cut
 217
 218 sub set_waiting {
 219     my ( $self, $desk_id ) = @_;
 220
 221     $self->priority(0);
 222
 223     my $today = dt_from_string();
 224
 225     my $values = {
 226         found => 'W',
 227         ( !$self->waitingdate ? ( waitingdate => $today->ymd ) : () ),
 228         desk_id => $desk_id,
 229     };
 230
 231     my $max_pickup_delay = C4::Context->preference("ReservesMaxPickUpDelay");
 232     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 233
 234     my $new_expiration_date = $today->clone->add(days => $max_pickup_delay);
 235
 236     if ( C4::Context->preference("ExcludeHolidaysFromMaxPickUpDelay") ) {
 237         my $itemtype = $self->item ? $self->item->effective_itemtype : $self->biblio->itemtype;
 238         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
 239             {
 240                 categorycode => $self->borrower->categorycode,
 241                 itemtype     => $itemtype,
 242                 branchcode   => $self->branchcode,
 243             }
 244         );
 245         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode, days_mode => $daysmode );
 246
 247         $new_expiration_date = $calendar->days_forward( dt_from_string(), $max_pickup_delay );
 248     }
 249
 250     # If patron's requested expiration date is prior to the
 251     # calculated one, we keep the patron's one.
 252     if ( $self->patron_expiration_date ) {
 253         my $requested_expiration = dt_from_string( $self->patron_expiration_date );
 254
 255         my $cmp =
 256           $requested_expiration
 257           ? DateTime->compare( $requested_expiration, $new_expiration_date )
 258           : 0;
 259
 260         $new_expiration_date =
 261           $cmp == -1 ? $requested_expiration : $new_expiration_date;
 262     }
 263
 264     $values->{expirationdate} = $new_expiration_date->ymd;
 265
 266     $self->set($values)->store();
 267
 268     Koha::Plugins->call(
 269         'after_hold_action',
 270         {
 271             action  => 'waiting',
 272             payload => { hold => $self->get_from_storage }
 273         }
 274     );
 275
 276     return $self;
 277 }
 278
 279 =head3 is_pickup_location_valid
 280
 281     if ($hold->is_pickup_location_valid({ library_id => $library->id }) ) {
 282         ...
 283     }
 284
 285 Returns a I<boolean> representing if the passed pickup location is valid for the hold.
 286 It throws a I<Koha::Exceptions::_MissingParameter> if the library_id parameter is not
 287 passed.
 288
 289 =cut
 290
 291 sub is_pickup_location_valid {
 292     my ( $self, $params ) = @_;
 293
 294     Koha::Exceptions::MissingParameter->throw('The library_id parameter is mandatory')
 295         unless $params->{library_id};
 296
 297     my $pickup_locations;
 298
 299     if ( $self->itemnumber ) { # item-level
 300         $pickup_locations = $self->item->pickup_locations({ patron => $self->patron });
 301     }
 302     else { # biblio-level
 303         $pickup_locations = $self->biblio->pickup_locations({ patron => $self->patron });
 304     }
 305
 306     return any { $_->branchcode eq $params->{library_id} } $pickup_locations->as_list;
 307 }
 308
 309 =head3 set_pickup_location
 310
 311     $hold->set_pickup_location(
 312         {
 313             library_id => $library->id,
 314           [ force   => 0|1 ]
 315         }
 316     );
 317
 318 Updates the hold pickup location. It throws a I<Koha::Exceptions::Hold::InvalidPickupLocation> if
 319 the passed pickup location is not valid.
 320
 321 Note: It is up to the caller to verify if I<AllowHoldPolicyOverride> is set when setting the
 322 B<force> parameter.
 323
 324 =cut
 325
 326 sub set_pickup_location {
 327     my ( $self, $params ) = @_;
 328
 329     Koha::Exceptions::MissingParameter->throw('The library_id parameter is mandatory')
 330         unless $params->{library_id};
 331
 332     if (
 333         $params->{force}
 334         || $self->is_pickup_location_valid(
 335             { library_id => $params->{library_id} }
 336         )
 337       )
 338     {
 339         # all good, set the new pickup location
 340         $self->branchcode( $params->{library_id} )->store;
 341     }
 342     else {
 343         Koha::Exceptions::Hold::InvalidPickupLocation->throw;
 344     }
 345
 346     return $self;
 347 }
 348
 349 =head3 set_processing
 350
 351 $hold->set_processing;
 352
 353 Mark the hold as in processing.
 354
 355 =cut
 356
 357 sub set_processing {
 358     my ( $self ) = @_;
 359
 360     $self->priority(0);
 361     $self->found('P');
 362     $self->store();
 363
 364     Koha::Plugins->call(
 365         'after_hold_action',
 366         {
 367             action  => 'processing',
 368             payload => { hold => $self->get_from_storage }
 369         }
 370     );
 371
 372     return $self;
 373 }
 374
 375 =head3 is_found
 376
 377 Returns true if hold is waiting, in transit or in processing
 378
 379 =cut
 380
 381 sub is_found {
 382     my ($self) = @_;
 383
 384     return 0 unless $self->found();
 385     return 1 if $self->found() eq 'W';
 386     return 1 if $self->found() eq 'T';
 387     return 1 if $self->found() eq 'P';
 388 }
 389
 390 =head3 is_waiting
 391
 392 Returns true if hold is a waiting hold
 393
 394 =cut
 395
 396 sub is_waiting {
 397     my ($self) = @_;
 398
 399     my $found = $self->found;
 400     return $found && $found eq 'W';
 401 }
 402
 403 =head3 is_in_transit
 404
 405 Returns true if hold is a in_transit hold
 406
 407 =cut
 408
 409 sub is_in_transit {
 410     my ($self) = @_;
 411
 412     return 0 unless $self->found();
 413     return $self->found() eq 'T';
 414 }
 415
 416 =head3 is_in_processing
 417
 418 Returns true if hold is a in_processing hold
 419
 420 =cut
 421
 422 sub is_in_processing {
 423     my ($self) = @_;
 424
 425     return 0 unless $self->found();
 426     return $self->found() eq 'P';
 427 }
 428
 429 =head3 is_cancelable_from_opac
 430
 431 Returns true if hold is a cancelable hold
 432
 433 Holds may be only canceled if they are not found.
 434
 435 This is used from the OPAC.
 436
 437 =cut
 438
 439 sub is_cancelable_from_opac {
 440     my ($self) = @_;
 441
 442     return 1 unless $self->is_found();
 443     return 0; # if ->is_in_transit or if ->is_waiting or ->is_in_processing
 444 }
 445
 446 =head3 cancellation_requestable_from_opac
 447
 448     if ( $hold->cancellation_requestable_from_opac ) { ... }
 449
 450 Returns a I<boolean> representing if a cancellation request can be placed on the hold
 451 from the OPAC. It targets holds that cannot be cancelled from the OPAC (see the
 452 B<is_cancelable_from_opac> method above), but for which circulation rules allow
 453 requesting cancellation.
 454
 455 Throws a B<Koha::Exceptions::InvalidStatus> exception with the following I<invalid_status>
 456 values:
 457
 458 =over 4
 459
 460 =item B<'hold_not_waiting'>: the hold is expected to be waiting and it is not.
 461
 462 =item B<'no_item_linked'>: the waiting hold doesn't have an item properly linked.
 463
 464 =back
 465
 466 =cut
 467
 468 sub cancellation_requestable_from_opac {
 469     my ( $self ) = @_;
 470
 471     Koha::Exceptions::InvalidStatus->throw( invalid_status => 'hold_not_waiting' )
 472       unless $self->is_waiting;
 473
 474     my $item = $self->item;
 475
 476     Koha::Exceptions::InvalidStatus->throw( invalid_status => 'no_item_linked' )
 477       unless $item;
 478
 479     my $patron = $self->patron;
 480
 481     my $controlbranch = $patron->branchcode;
 482
 483     if ( C4::Context->preference('ReservesControlBranch') eq 'ItemHomeLibrary' ) {
 484         $controlbranch = $item->homebranch;
 485     }
 486
 487     return Koha::CirculationRules->get_effective_rule_value(
 488         {
 489             categorycode => $patron->categorycode,
 490             itemtype     => $item->itype,
 491             branchcode   => $controlbranch,
 492             rule_name    => 'waiting_hold_cancellation',
 493         }
 494     ) ? 1 : 0;
 495 }
 496
 497 =head3 is_at_destination
 498
 499 Returns true if hold is waiting
 500 and the hold's pickup branch matches
 501 the hold item's holding branch
 502
 503 =cut
 504
 505 sub is_at_destination {
 506     my ($self) = @_;
 507
 508     return $self->is_waiting() && ( $self->branchcode() eq $self->item()->holdingbranch() );
 509 }
 510
 511 =head3 biblio
 512
 513 Returns the related Koha::Biblio object for this hold
 514
 515 =cut
 516
 517 sub biblio {
 518     my ($self) = @_;
 519
 520     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 521
 522     return $self->{_biblio};
 523 }
 524
 525 =head3 patron
 526
 527 Returns the related Koha::Patron object for this hold
 528
 529 =cut
 530
 531 sub patron {
 532     my ($self) = @_;
 533
 534     my $patron_rs = $self->_result->patron;
 535     return Koha::Patron->_new_from_dbic($patron_rs);
 536 }
 537
 538 =head3 item
 539
 540 Returns the related Koha::Item object for this Hold
 541
 542 =cut
 543
 544 sub item {
 545     my ($self) = @_;
 546
 547     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 548
 549     return $self->{_item};
 550 }
 551
 552 =head3 item_group
 553
 554 Returns the related Koha::Biblio::ItemGroup object for this Hold
 555
 556 =cut
 557
 558 sub item_group {
 559     my ($self) = @_;
 560
 561     my $item_group_rs = $self->_result->item_group;
 562     return unless $item_group_rs;
 563     return Koha::Biblio::ItemGroup->_new_from_dbic($item_group_rs);
 564 }
 565
 566 =head3 branch
 567
 568 Returns the related Koha::Library object for this Hold
 569
 570 =cut
 571
 572 sub branch {
 573     my ($self) = @_;
 574
 575     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 576
 577     return $self->{_branch};
 578 }
 579
 580 =head3 desk
 581
 582 Returns the related Koha::Desk object for this Hold
 583
 584 =cut
 585
 586 sub desk {
 587     my $self = shift;
 588     my $desk_rs = $self->_result->desk;
 589     return unless $desk_rs;
 590     return Koha::Desk->_new_from_dbic($desk_rs);
 591 }
 592
 593 =head3 borrower
 594
 595 Returns the related Koha::Patron object for this Hold
 596
 597 =cut
 598
 599 # FIXME Should be renamed with ->patron
 600 sub borrower {
 601     my ($self) = @_;
 602
 603     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 604
 605     return $self->{_borrower};
 606 }
 607
 608 =head3 is_suspended
 609
 610 my $bool = $hold->is_suspended();
 611
 612 =cut
 613
 614 sub is_suspended {
 615     my ( $self ) = @_;
 616
 617     return $self->suspend();
 618 }
 619
 620 =head3 add_cancellation_request
 621
 622     my $cancellation_request = $hold->add_cancellation_request({ [ creation_date => $creation_date ] });
 623
 624 Adds a cancellation request to the hold. Returns the generated
 625 I<Koha::Hold::CancellationRequest> object.
 626
 627 =cut
 628
 629 sub add_cancellation_request {
 630     my ( $self, $params ) = @_;
 631
 632     my $request = Koha::Hold::CancellationRequest->new(
 633         {   hold_id      => $self->id,
 634             ( $params->{creation_date} ? ( creation_date => $params->{creation_date} ) : () ),
 635         }
 636     )->store;
 637
 638     $request->discard_changes;
 639
 640     return $request;
 641 }
 642
 643 =head3 cancellation_requests
 644
 645     my $cancellation_requests = $hold->cancellation_requests;
 646
 647 Returns related a I<Koha::Hold::CancellationRequests> resultset.
 648
 649 =cut
 650
 651 sub cancellation_requests {
 652     my ($self) = @_;
 653
 654     return Koha::Hold::CancellationRequests->search( { hold_id => $self->id } );
 655 }
 656
 657 =head3 cancel
 658
 659 my $cancel_hold = $hold->cancel(
 660     {
 661         [ charge_cancel_fee   => 1||0, ]
 662         [ cancellation_reason => $cancellation_reason, ]
 663         [ skip_holds_queue    => 1||0 ]
 664     }
 665 );
 666
 667 Cancel a hold:
 668 - The hold will be moved to the old_reserves table with a priority=0
 669 - The priority of other holds will be updated
 670 - The patron will be charge (see ExpireReservesMaxPickUpDelayCharge) if the charge_cancel_fee parameter is set
 671 - The canceled hold will have the cancellation reason added to old_reserves.cancellation_reason if one is passed in
 672 - a CANCEL HOLDS log will be done if the pref HoldsLog is on
 673
 674 =cut
 675
 676 sub cancel {
 677     my ( $self, $params ) = @_;
 678
 679     my $autofill_next = $params->{autofill} && $self->itemnumber && $self->found && $self->found eq 'W';
 680
 681     $self->_result->result_source->schema->txn_do(
 682         sub {
 683             my $patron = $self->patron;
 684
 685             $self->cancellationdate( dt_from_string->strftime( '%Y-%m-%d %H:%M:%S' ) );
 686             $self->priority(0);
 687             $self->cancellation_reason( $params->{cancellation_reason} );
 688             $self->store();
 689
 690             if ( $params->{cancellation_reason} ) {
 691                 my $letter = C4::Letters::GetPreparedLetter(
 692                     module                 => 'reserves',
 693                     letter_code            => 'HOLD_CANCELLATION',
 694                     message_transport_type => 'email',
 695                     branchcode             => $self->borrower->branchcode,
 696                     lang                   => $self->borrower->lang,
 697                     tables => {
 698                         branches    => $self->borrower->branchcode,
 699                         borrowers   => $self->borrowernumber,
 700                         items       => $self->itemnumber,
 701                         biblio      => $self->biblionumber,
 702                         biblioitems => $self->biblionumber,
 703                         reserves    => $self->unblessed,
 704                     }
 705                 );
 706
 707                 if ($letter) {
 708                     C4::Letters::EnqueueLetter(
 709                         {
 710                             letter                   => $letter,
 711                             borrowernumber         => $self->borrowernumber,
 712                             message_transport_type => 'email',
 713                         }
 714                     );
 715                 }
 716             }
 717
 718             my $old_me = $self->_move_to_old;
 719
 720             Koha::Plugins->call(
 721                 'after_hold_action',
 722                 {
 723                     action  => 'cancel',
 724                     payload => { hold => $old_me->get_from_storage }
 725                 }
 726             );
 727
 728             # anonymize if required
 729             $old_me->anonymize
 730                 if $patron->privacy == 2;
 731
 732             $self->SUPER::delete(); # Do not add a DELETE log
 733             # now fix the priority on the others....
 734             C4::Reserves::_FixPriority({ biblionumber => $self->biblionumber });
 735
 736             # and, if desired, charge a cancel fee
 737             my $charge = C4::Context->preference("ExpireReservesMaxPickUpDelayCharge");
 738             if ( $charge && $params->{'charge_cancel_fee'} ) {
 739                 my $account =
 740                   Koha::Account->new( { patron_id => $self->borrowernumber } );
 741                 $account->add_debit(
 742                     {
 743                         amount     => $charge,
 744                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 745                         interface  => C4::Context->interface,
 746                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 747                         type       => 'RESERVE_EXPIRED',
 748                         item_id    => $self->itemnumber
 749                     }
 750                 );
 751             }
 752
 753             C4::Log::logaction( 'HOLDS', 'CANCEL', $self->reserve_id, $self )
 754                 if C4::Context->preference('HoldsLog');
 755
 756             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 757                 {
 758                     biblio_ids => [ $old_me->biblionumber ]
 759                 }
 760             ) unless $params->{skip_holds_queue} or !C4::Context->preference('RealTimeHoldsQueue');
 761         }
 762     );
 763
 764     if ($autofill_next) {
 765         my ( undef, $next_hold ) = C4::Reserves::CheckReserves( $self->itemnumber );
 766         if ($next_hold) {
 767             my $is_transfer = $self->branchcode ne $next_hold->{branchcode};
 768
 769             C4::Reserves::ModReserveAffect( $self->itemnumber, $self->borrowernumber, $is_transfer, $next_hold->{reserve_id}, $self->desk_id, $autofill_next );
 770             C4::Items::ModItemTransfer( $self->itemnumber, $self->branchcode, $next_hold->{branchcode}, "Reserve" ) if $is_transfer;
 771         }
 772     }
 773
 774     return $self;
 775 }
 776
 777 =head3 fill
 778
 779     $hold->fill;
 780
 781 This method marks the hold as filled. It effectively moves it to old_reserves.
 782
 783 =cut
 784
 785 sub fill {
 786     my ( $self ) = @_;
 787     $self->_result->result_source->schema->txn_do(
 788         sub {
 789             my $patron = $self->patron;
 790
 791             $self->set(
 792                 {
 793                     found    => 'F',
 794                     priority => 0,
 795                 }
 796             );
 797
 798             my $old_me = $self->_move_to_old;
 799
 800             Koha::Plugins->call(
 801                 'after_hold_action',
 802                 {
 803                     action  => 'fill',
 804                     payload => { hold => $old_me->get_from_storage }
 805                 }
 806             );
 807
 808             # anonymize if required
 809             $old_me->anonymize
 810                 if $patron->privacy == 2;
 811
 812             $self->SUPER::delete(); # Do not add a DELETE log
 813
 814             # now fix the priority on the others....
 815             C4::Reserves::_FixPriority({ biblionumber => $self->biblionumber });
 816
 817             if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
 818                 my $fee = $patron->category->reservefee // 0;
 819                 if ( $fee > 0 ) {
 820                     $patron->account->add_debit(
 821                         {
 822                             amount       => $fee,
 823                             description  => $self->biblio->title,
 824                             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 825                             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 826                             interface    => C4::Context->interface,
 827                             type         => 'RESERVE',
 828                             item_id      => $self->itemnumber
 829                         }
 830                     );
 831                 }
 832             }
 833
 834             C4::Log::logaction( 'HOLDS', 'FILL', $self->id, $self )
 835                 if C4::Context->preference('HoldsLog');
 836
 837             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 838                 {
 839                     biblio_ids => [ $old_me->biblionumber ]
 840                 }
 841             ) if C4::Context->preference('RealTimeHoldsQueue');
 842         }
 843     );
 844     return $self;
 845 }
 846
 847 =head3 store
 848
 849 Override base store method to set default
 850 expirationdate for holds.
 851
 852 =cut
 853
 854 sub store {
 855     my ($self) = @_;
 856
 857     Koha::Exceptions::Hold::MissingPickupLocation->throw() unless $self->branchcode;
 858
 859     if ( !$self->in_storage ) {
 860         if ( ! $self->expirationdate && $self->patron_expiration_date ) {
 861             $self->expirationdate($self->patron_expiration_date);
 862         }
 863
 864         if (
 865             C4::Context->preference('DefaultHoldExpirationdate')
 866                 && !$self->expirationdate
 867           )
 868         {
 869             $self->_set_default_expirationdate;
 870         }
 871     }
 872     else {
 873
 874         my %updated_columns = $self->_result->get_dirty_columns;
 875         return $self->SUPER::store unless %updated_columns;
 876
 877         if ( exists $updated_columns{reservedate} ) {
 878             if (
 879                 C4::Context->preference('DefaultHoldExpirationdate')
 880                 && ! exists $updated_columns{expirationdate}
 881               )
 882             {
 883                 $self->_set_default_expirationdate;
 884             }
 885         }
 886     }
 887
 888     $self = $self->SUPER::store;
 889 }
 890
 891 sub _set_default_expirationdate {
 892     my $self = shift;
 893
 894     my $period = C4::Context->preference('DefaultHoldExpirationdatePeriod') || 0;
 895     my $timeunit =
 896       C4::Context->preference('DefaultHoldExpirationdateUnitOfTime') || 'days';
 897
 898     $self->expirationdate(
 899         dt_from_string( $self->reservedate )->add( $timeunit => $period ) );
 900 }
 901
 902 =head3 _move_to_old
 903
 904 my $is_moved = $hold->_move_to_old;
 905
 906 Move a hold to the old_reserve table following the same pattern as Koha::Patron->move_to_deleted
 907
 908 =cut
 909
 910 sub _move_to_old {
 911     my ($self) = @_;
 912     my $hold_infos = $self->unblessed;
 913     return Koha::Old::Hold->new( $hold_infos )->store;
 914 }
 915
 916 =head3 to_api_mapping
 917
 918 This method returns the mapping for representing a Koha::Hold object
 919 on the API.
 920
 921 =cut
 922
 923 sub to_api_mapping {
 924     return {
 925         reserve_id       => 'hold_id',
 926         borrowernumber   => 'patron_id',
 927         reservedate      => 'hold_date',
 928         biblionumber     => 'biblio_id',
 929         branchcode       => 'pickup_library_id',
 930         notificationdate => undef,
 931         reminderdate     => undef,
 932         cancellationdate => 'cancellation_date',
 933         reservenotes     => 'notes',
 934         found            => 'status',
 935         itemnumber       => 'item_id',
 936         waitingdate      => 'waiting_date',
 937         expirationdate   => 'expiration_date',
 938         patron_expiration_date => undef,
 939         lowestPriority   => 'lowest_priority',
 940         suspend          => 'suspended',
 941         suspend_until    => 'suspended_until',
 942         itemtype         => 'item_type',
 943         item_level_hold  => 'item_level',
 944     };
 945 }
 946
 947 =head3 can_update_pickup_location_opac
 948
 949     my $can_update_pickup_location_opac = $hold->can_update_pickup_location_opac;
 950
 951 Returns if a hold can change pickup location from opac
 952
 953 =cut
 954
 955 sub can_update_pickup_location_opac {
 956     my ($self) = @_;
 957
 958     my @statuses = split /,/, C4::Context->preference("OPACAllowUserToChangeBranch");
 959     foreach my $status ( @statuses ){
 960         return 1 if ($status eq 'pending' && !$self->is_found && !$self->is_suspended );
 961         return 1 if ($status eq 'intransit' && $self->is_in_transit);
 962         return 1 if ($status eq 'suspended' && $self->is_suspended);
 963     }
 964     return 0;
 965 }
 966
 967 =head2 Internal methods
 968
 969 =head3 _type
 970
 971 =cut
 972
 973 sub _type {
 974     return 'Reserve';
 975 }
 976
 977 =head1 AUTHORS
 978
 979 Kyle M Hall <kyle@bywatersolutions.com>
 980 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 981 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 982
 983 =cut
 984
 985 1;