Koha/Items.pm

   1 package Koha::Items;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Array::Utils qw( array_minus );
  22 use List::MoreUtils qw( uniq );
  23 use Try::Tiny;
  24
  25 use C4::Context;
  26 use C4::Biblio qw( GetMarcStructure GetMarcFromKohaField );
  27 use C4::Circulation;
  28
  29 use Koha::Database;
  30 use Koha::SearchEngine::Indexer;
  31
  32 use Koha::Item::Attributes;
  33 use Koha::Item;
  34 use Koha::CirculationRules;
  35
  36 use base qw(Koha::Objects);
  37
  38 use Koha::SearchEngine::Indexer;
  39
  40 =head1 NAME
  41
  42 Koha::Items - Koha Item object set class
  43
  44 =head1 API
  45
  46 =head2 Class methods
  47
  48 =cut
  49
  50 =head3 filter_by_for_hold
  51
  52     my $filtered_items = $items->filter_by_for_hold;
  53
  54 Return the items of the set that are *potentially* holdable.
  55
  56 Caller has the responsibility to call C4::Reserves::CanItemBeReserved before
  57 placing a hold on one of those items.
  58
  59 =cut
  60
  61 sub filter_by_for_hold {
  62     my ($self) = @_;
  63
  64     my @hold_not_allowed_itypes = Koha::CirculationRules->search(
  65         {
  66             rule_name    => 'holdallowed',
  67             branchcode   => undef,
  68             categorycode => undef,
  69             rule_value   => 'not_allowed',
  70         }
  71     )->get_column('itemtype');
  72     push @hold_not_allowed_itypes, Koha::ItemTypes->search({ notforloan => 1 })->get_column('itemtype');
  73
  74     my $params = {
  75         itemlost   => 0,
  76         withdrawn  => 0,
  77         notforloan => { '<=' => 0 },    # items with negative or zero notforloan value are holdable
  78         ( C4::Context->preference('AllowHoldsOnDamagedItems')? (): ( damaged => 0 ) ),
  79         ( C4::Context->only_my_library() ? ( homebranch => C4::Context::mybranch() ) : () ),
  80     };
  81
  82     if ( C4::Context->preference("item-level_itypes") ) {
  83         return $self->search(
  84             {
  85                 %$params,
  86                 itype        => { -not_in => \@hold_not_allowed_itypes },
  87             }
  88         );
  89     } else {
  90         return $self->search(
  91             {
  92                 %$params,
  93                 'biblioitem.itemtype' => { -not_in => \@hold_not_allowed_itypes },
  94             },
  95             {
  96                 join => 'biblioitem',
  97             }
  98         );
  99     }
 100 }
 101
 102 =head3 filter_by_visible_in_opac
 103
 104     my $filered_items = $items->filter_by_visible_in_opac(
 105         {
 106             [ patron => $patron ]
 107         }
 108     );
 109
 110 Returns a new resultset, containing those items that are not expected to be hidden in OPAC
 111 for the passed I<Koha::Patron> object that is passed.
 112
 113 The I<OpacHiddenItems>, I<hidelostitems> and I<OpacHiddenItemsExceptions> system preferences
 114 are honoured.
 115
 116 =cut
 117
 118 sub filter_by_visible_in_opac {
 119     my ($self, $params) = @_;
 120
 121     my $patron = $params->{patron};
 122
 123     my $result = $self;
 124
 125     # Filter out OpacHiddenItems unless disabled by OpacHiddenItemsExceptions
 126     unless ( $patron and $patron->category->override_hidden_items ) {
 127         my $rules = C4::Context->yaml_preference('OpacHiddenItems') // {};
 128
 129         my $rules_params;
 130         foreach my $field ( keys %$rules ) {
 131             $rules_params->{'me.'.$field} =
 132               [ { '-not_in' => $rules->{$field} }, undef ];
 133         }
 134
 135         $result = $result->search( $rules_params );
 136     }
 137
 138     if (C4::Context->preference('hidelostitems')) {
 139         $result = $result->filter_out_lost;
 140     }
 141
 142     return $result;
 143 }
 144
 145 =head3 filter_out_lost
 146
 147     my $filered_items = $items->filter_out_lost;
 148
 149 Returns a new resultset, containing those items that are not marked as lost.
 150
 151 =cut
 152
 153 sub filter_out_lost {
 154     my ($self) = @_;
 155
 156     my $params = { itemlost => 0 };
 157
 158     return $self->search( $params );
 159 }
 160
 161
 162 =head3 move_to_biblio
 163
 164  $items->move_to_biblio($to_biblio);
 165
 166 Move items to a given biblio.
 167
 168 =cut
 169
 170 sub move_to_biblio {
 171     my ( $self, $to_biblio ) = @_;
 172
 173     my $biblionumbers = { $to_biblio->biblionumber => 1 };
 174     while ( my $item = $self->next() ) {
 175         $biblionumbers->{ $item->biblionumber } = 1;
 176         $item->move_to_biblio( $to_biblio, { skip_record_index => 1 } );
 177     }
 178     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 179     for my $biblionumber ( keys %{$biblionumbers} ) {
 180         $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 181     }
 182 }
 183
 184 =head3 batch_update
 185
 186     Koha::Items->search->batch_update
 187         {
 188             new_values => {
 189                 itemnotes => $new_item_notes,
 190                 k         => $k,
 191             },
 192             regex_mod => {
 193                 itemnotes_nonpublic => {
 194                     search => 'foo',
 195                     replace => 'bar',
 196                     modifiers => 'gi',
 197                 },
 198             },
 199             exclude_from_local_holds_priority => 1|0,
 200             callback => sub {
 201                 # increment something here
 202             },
 203         }
 204     );
 205
 206 Batch update the items.
 207
 208 Returns ( $report, $self )
 209 Report has 2 keys:
 210   * modified_itemnumbers - list of the modified itemnumbers
 211   * modified_fields - number of fields modified
 212
 213 Parameters:
 214
 215 =over
 216
 217 =item new_values
 218
 219 Allows to set a new value for given fields.
 220 The key can be one of the item's column name, or one subfieldcode of a MARC subfields not linked with a Koha field
 221
 222 =item regex_mod
 223
 224 Allows to modify existing subfield's values using a regular expression
 225
 226 =item exclude_from_local_holds_priority
 227
 228 Set the passed boolean value to items.exclude_from_local_holds_priority
 229
 230 =item callback
 231
 232 Callback function to call after an item has been modified
 233
 234 =back
 235
 236 =cut
 237
 238 sub batch_update {
 239     my ( $self, $params ) = @_;
 240
 241     my $regex_mod = $params->{regex_mod} || {};
 242     my $new_values = $params->{new_values} || {};
 243     my $exclude_from_local_holds_priority = $params->{exclude_from_local_holds_priority};
 244     my $callback = $params->{callback};
 245
 246     my (@modified_itemnumbers, $modified_fields);
 247     my $i;
 248     my $schema = Koha::Database->new->schema;
 249     while ( my $item = $self->next ) {
 250
 251         try {$schema->txn_do(sub {
 252             my $modified_holds_priority = 0;
 253             if ( defined $exclude_from_local_holds_priority ) {
 254                 if(!defined $item->exclude_from_local_holds_priority || $item->exclude_from_local_holds_priority != $exclude_from_local_holds_priority) {
 255                     $item->exclude_from_local_holds_priority($exclude_from_local_holds_priority)->store;
 256                     $modified_holds_priority = 1;
 257                 }
 258             }
 259
 260             my $modified = 0;
 261             my $new_values = {%$new_values};    # Don't modify the original
 262
 263             my $old_values = $item->unblessed;
 264             if ( $item->more_subfields_xml ) {
 265                 $old_values = {
 266                     %$old_values,
 267                     %{$item->additional_attributes->to_hashref},
 268                 };
 269             }
 270
 271             for my $attr ( keys %$regex_mod ) {
 272                 my $old_value = $old_values->{$attr};
 273
 274                 next unless $old_value;
 275
 276                 my $value = apply_regex(
 277                     {
 278                         %{ $regex_mod->{$attr} },
 279                         value => $old_value,
 280                     }
 281                 );
 282
 283                 $new_values->{$attr} = $value;
 284             }
 285
 286             for my $attribute ( keys %$new_values ) {
 287                 next if $attribute eq 'more_subfields_xml'; # Already counted before
 288
 289                 my $old = $old_values->{$attribute};
 290                 my $new = $new_values->{$attribute};
 291                 $modified++
 292                   if ( defined $old xor defined $new )
 293                   || ( defined $old && defined $new && $new ne $old );
 294             }
 295
 296             { # Dealing with more_subfields_xml
 297
 298                 my $frameworkcode = $item->biblio->frameworkcode;
 299                 my $tagslib = C4::Biblio::GetMarcStructure( 1, $frameworkcode, { unsafe => 1 });
 300                 my ( $itemtag, $itemsubfield ) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
 301
 302                 my @more_subfield_tags = map {
 303                     (
 304                              ref($_)
 305                           && %$_
 306                           && !$_->{kohafield}    # Get subfields that are not mapped
 307                       )
 308                       ? $_->{tagsubfield}
 309                       : ()
 310                 } values %{ $tagslib->{$itemtag} };
 311
 312                 my $more_subfields_xml = Koha::Item::Attributes->new(
 313                     {
 314                         map {
 315                             exists $new_values->{$_} ? ( $_ => $new_values->{$_} )
 316                               : exists $old_values->{$_}
 317                               ? ( $_ => $old_values->{$_} )
 318                               : ()
 319                         } @more_subfield_tags
 320                     }
 321                 )->to_marcxml($frameworkcode);
 322
 323                 $new_values->{more_subfields_xml} = $more_subfields_xml;
 324
 325                 delete $new_values->{$_} for @more_subfield_tags; # Clean the hash
 326
 327             }
 328
 329             if ( $modified ) {
 330                 my $itemlost_pre = $item->itemlost;
 331                 $item->set($new_values)->store({skip_record_index => 1});
 332
 333                 C4::Circulation::LostItem(
 334                     $item->itemnumber, 'batchmod', undef,
 335                     { skip_record_index => 1 }
 336                 ) if $item->itemlost
 337                       and not $itemlost_pre;
 338             }
 339
 340             push @modified_itemnumbers, $item->itemnumber if $modified || $modified_holds_priority;
 341             $modified_fields += $modified + $modified_holds_priority;
 342         })}
 343         catch {
 344             warn $_
 345         };
 346
 347         if ( $callback ) {
 348             $callback->(++$i);
 349         }
 350     }
 351
 352     if (@modified_itemnumbers) {
 353         my @biblionumbers = uniq(
 354             Koha::Items->search( { itemnumber => \@modified_itemnumbers } )
 355                        ->get_column('biblionumber'));
 356
 357         if ( @biblionumbers ) {
 358             my $indexer = Koha::SearchEngine::Indexer->new(
 359                 { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 360
 361             $indexer->index_records( \@biblionumbers, 'specialUpdate',
 362                 "biblioserver", undef );
 363         }
 364     }
 365
 366     return ( { modified_itemnumbers => \@modified_itemnumbers, modified_fields => $modified_fields }, $self );
 367 }
 368
 369 sub apply_regex {
 370     # FIXME Should be moved outside of Koha::Items
 371     # FIXME This is nearly identical to Koha::SimpleMARC::_modify_values
 372     my ($params) = @_;
 373     my $search   = $params->{search};
 374     my $replace  = $params->{replace};
 375     my $modifiers = $params->{modifiers} || q{};
 376     my $value = $params->{value};
 377
 378     $replace =~ s/"/\\"/g;                    # Protection from embedded code
 379     $replace = '"' . $replace . '"'; # Put in a string for /ee
 380     my @available_modifiers = qw( i g );
 381     my $retained_modifiers  = q||;
 382     for my $modifier ( split //, $modifiers ) {
 383         $retained_modifiers .= $modifier
 384           if grep { /$modifier/ } @available_modifiers;
 385     }
 386     if ( $retained_modifiers =~ m/^(ig|gi)$/ ) {
 387         $value =~ s/$search/$replace/igee;
 388     }
 389     elsif ( $retained_modifiers eq 'i' ) {
 390         $value =~ s/$search/$replace/iee;
 391     }
 392     elsif ( $retained_modifiers eq 'g' ) {
 393         $value =~ s/$search/$replace/gee;
 394     }
 395     else {
 396         $value =~ s/$search/$replace/ee;
 397     }
 398
 399     return $value;
 400 }
 401
 402 =head3 search_ordered
 403
 404  $items->search_ordered;
 405
 406 Search and sort items in a specific order, depending if serials are present or not
 407
 408 =cut
 409
 410 sub search_ordered {
 411     my ($self, $params, $attributes) = @_;
 412
 413     $self = $self->search($params, $attributes);
 414
 415     my @biblionumbers = uniq $self->get_column('biblionumber');
 416
 417     if ( scalar ( @biblionumbers ) == 1
 418         && Koha::Biblios->find( $biblionumbers[0] )->serial )
 419     {
 420         return $self->search(
 421             {},
 422             {
 423                 order_by => [ 'serialid.publisheddate', 'me.enumchron' ],
 424                 join     => { serialitem => 'serialid' }
 425             }
 426         );
 427     } else {
 428         return $self->search(
 429             {},
 430             {
 431                 order_by => [
 432                     'homebranch.branchname',
 433                     'me.enumchron',
 434                     \"LPAD( me.copynumber, 8, '0' )",
 435                     {-desc => 'me.dateaccessioned'}
 436                 ],
 437                 join => ['homebranch']
 438             }
 439         );
 440     }
 441 }
 442
 443 =head2 Internal methods
 444
 445 =head3 _type
 446
 447 =cut
 448
 449 sub _type {
 450     return 'Item';
 451 }
 452
 453 =head3 object_class
 454
 455 =cut
 456
 457 sub object_class {
 458     return 'Koha::Item';
 459 }
 460
 461 =head1 AUTHOR
 462
 463 Kyle M Hall <kyle@bywatersolutions.com>
 464 Tomas Cohen Arazi <tomascohen@theke.io>
 465 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 466
 467 =cut
 468
 469 1;