Koha/MetadataRecord.pm

   1 package Koha::MetadataRecord;
   2
   3 # Copyright 2013 C & P Bibliography Services
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 =head1 NAME
  21
  22 Koha::MetadataRecord - base class for metadata records
  23
  24 =head1 SYNOPSIS
  25
  26     my $record = new Koha::MetadataRecord({ 'record' => $record });
  27
  28 =head1 DESCRIPTION
  29
  30 Object-oriented class that encapsulates all metadata (i.e. bibliographic
  31 and authority) records in Koha.
  32
  33 =cut
  34
  35 use Modern::Perl;
  36
  37 use Carp;
  38 use Koha::Util::MARC;
  39
  40 use base qw(Class::Accessor);
  41
  42 __PACKAGE__->mk_accessors(qw( record schema format id ));
  43
  44
  45 =head2 new
  46
  47     my $metadata_record = new Koha::MetadataRecord({
  48                                 record => $record,
  49                                 schema => $schema,
  50                                 format => $format,
  51                                 id     => $id
  52                           });
  53
  54 Returns a Koha::MetadataRecord object encapsulating record metadata.
  55
  56 C<$record> is expected to be a deserialized object (for example
  57 a MARC::Record or XML::LibXML::Document object or JSON).
  58
  59 C<$schema> is used to describe the metadata schema (for example
  60 marc21, unimarc, dc, mods, etc).
  61
  62 C<$format> is used to specify the serialization format. It is important
  63 for Koha::RecordProcessor because it will pick the right Koha::Filter
  64 implementation based on this parameter. Valid values are:
  65
  66    MARC (for MARC::Record objects)
  67    XML  (for XML::LibXML::Document objects)
  68    JSON (for JSON objects)
  69
  70 (optional) C<$id> is used so the record carries its own id and Koha doesn't
  71 need to look for it inside the record.
  72
  73 =cut
  74
  75 sub new {
  76
  77     my $class  = shift;
  78     my $params = shift;
  79
  80     if (!defined $params->{ record }) {
  81         carp 'No record passed';
  82         return;
  83     }
  84
  85     if (!defined $params->{ schema }) {
  86         carp 'No schema passed';
  87         return;
  88     }
  89
  90     my $record = $params->{ record };
  91     my $schema = $params->{ schema };
  92     my $format = $params->{ format } // 'MARC';
  93     my $id     = $params->{ id };
  94
  95     my $self = $class->SUPER::new({
  96         record => $record,
  97         schema => $schema,
  98         format => $format,
  99         id     => $id
 100     });
 101
 102     bless $self, $class;
 103     return $self;
 104 }
 105
 106 =head2 createMergeHash
 107
 108 Create a hash for use when merging records. At the moment the only
 109 metadata schema supported is MARC.
 110
 111 =cut
 112
 113 sub createMergeHash {
 114     my ($self, $tagslib) = @_;
 115     if ($self->schema =~ m/marc/) {
 116         return Koha::Util::MARC::createMergeHash($self->record, $tagslib);
 117     }
 118 }
 119
 120 sub getKohaField {
 121     my ($self, $kohafield) = @_;
 122
 123     if ($self->schema =~ m/marc/) {
 124         my $relations = C4::Context->marcfromkohafield->{''};
 125         my $tagfield = $relations->{$kohafield};
 126
 127         return '' if ref($tagfield) ne 'ARRAY';
 128
 129         my ($tag, $subfield) = @$tagfield;
 130         my @kohafield;
 131         foreach my $field ( $self->record->field($tag) ) {
 132             if ( $field->tag() < 10 ) {
 133                 push @kohafield, $field->data();
 134             } else {
 135                 foreach my $contents ( $field->subfield($subfield) ) {
 136                     push @kohafield, $contents;
 137                 }
 138             }
 139         }
 140
 141         return join ' | ', @kohafield;
 142     }
 143 }
 144
 145 1;