Koha/Object.pm

   1 package Koha::Object;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2016 Koha Development Team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp qw( croak );
  24 use Mojo::JSON;
  25 use Scalar::Util qw( blessed looks_like_number );
  26 use Try::Tiny qw( catch try );
  27 use List::MoreUtils qw( any );
  28
  29 use Koha::Database;
  30 use Koha::Exceptions::Object;
  31 use Koha::DateUtils qw( dt_from_string output_pref );
  32 use Koha::Object::Message;
  33
  34 =head1 NAME
  35
  36 Koha::Object - Koha Object base class
  37
  38 =head1 SYNOPSIS
  39
  40     use Koha::Object;
  41     my $object = Koha::Object->new({ property1 => $property1, property2 => $property2, etc... } );
  42
  43 =head1 DESCRIPTION
  44
  45 This class must always be subclassed.
  46
  47 =head1 API
  48
  49 =head2 Class Methods
  50
  51 =cut
  52
  53 =head3 Koha::Object->new();
  54
  55 my $object = Koha::Object->new();
  56 my $object = Koha::Object->new($attributes);
  57
  58 Note that this cannot be used to retrieve record from the DB.
  59
  60 =cut
  61
  62 sub new {
  63     my ( $class, $attributes ) = @_;
  64     my $self = {};
  65
  66     if ($attributes) {
  67         my $schema = Koha::Database->new->schema;
  68
  69         # Remove the arguments which exist, are not defined but NOT NULL to use the default value
  70         my $columns_info = $schema->resultset( $class->_type )->result_source->columns_info;
  71         for my $column_name ( keys %$attributes ) {
  72             my $c_info = $columns_info->{$column_name};
  73             next if $c_info->{is_nullable};
  74             next if not exists $attributes->{$column_name} or defined $attributes->{$column_name};
  75             delete $attributes->{$column_name};
  76         }
  77
  78         $self->{_result} =
  79           $schema->resultset( $class->_type() )->new($attributes);
  80     }
  81
  82     $self->{_messages} = [];
  83
  84     croak("No _type found! Koha::Object must be subclassed!")
  85       unless $class->_type();
  86
  87     bless( $self, $class );
  88
  89 }
  90
  91 =head3 Koha::Object->_new_from_dbic();
  92
  93 my $object = Koha::Object->_new_from_dbic($dbic_row);
  94
  95 =cut
  96
  97 sub _new_from_dbic {
  98     my ( $class, $dbic_row ) = @_;
  99     my $self = {};
 100
 101     # DBIC result row
 102     $self->{_result} = $dbic_row;
 103
 104     croak("No _type found! Koha::Object must be subclassed!")
 105       unless $class->_type();
 106
 107     croak( "DBIC result _type " . ref( $self->{_result} ) . " isn't of the _type " . $class->_type() )
 108       unless ref( $self->{_result} ) eq "Koha::Schema::Result::" . $class->_type();
 109
 110     bless( $self, $class );
 111
 112 }
 113
 114 =head3 $object->store();
 115
 116 Saves the object in storage.
 117 If the object is new, it will be created.
 118 If the object previously existed, it will be updated.
 119
 120 Returns:
 121     $self  if the store was a success
 122     undef  if the store failed
 123
 124 =cut
 125
 126 sub store {
 127     my ($self) = @_;
 128
 129     my $columns_info = $self->_result->result_source->columns_info;
 130
 131     # Handle not null and default values for integers and dates
 132     foreach my $col ( keys %{$columns_info} ) {
 133         # Integers
 134         if (   _numeric_column_type( $columns_info->{$col}->{data_type} )
 135             or _decimal_column_type( $columns_info->{$col}->{data_type} )
 136         ) {
 137             # Has been passed but not a number, usually an empty string
 138             my $value = $self->_result()->get_column($col);
 139             if ( defined $value and not looks_like_number( $value ) ) {
 140                 if ( $columns_info->{$col}->{is_nullable} ) {
 141                     # If nullable, default to null
 142                     $self->_result()->set_column($col => undef);
 143                 } else {
 144                     # If cannot be null, get the default value
 145                     # What if cannot be null and does not have a default value? Possible?
 146                     $self->_result()->set_column($col => $columns_info->{$col}->{default_value});
 147                 }
 148             }
 149         }
 150         elsif ( _date_or_datetime_column_type( $columns_info->{$col}->{data_type} ) ) {
 151             # Set to null if an empty string (or == 0 but should not happen)
 152             my $value = $self->_result()->get_column($col);
 153             if ( defined $value and not $value ) {
 154                 if ( $columns_info->{$col}->{is_nullable} ) {
 155                     $self->_result()->set_column($col => undef);
 156                 } else {
 157                     $self->_result()->set_column($col => $columns_info->{$col}->{default_value});
 158                 }
 159             }
 160             elsif ( not defined $self->$col
 161                   && $columns_info->{$col}->{datetime_undef_if_invalid} )
 162               {
 163                   # timestamp
 164                   $self->_result()->set_column($col => $columns_info->{$col}->{default_value});
 165               }
 166         }
 167     }
 168
 169     try {
 170         return $self->_result()->update_or_insert() ? $self : undef;
 171     }
 172     catch {
 173         # Catch problems and raise relevant exceptions
 174         if (ref($_) eq 'DBIx::Class::Exception') {
 175             warn $_->{msg};
 176             if ( $_->{msg} =~ /Cannot add or update a child row: a foreign key constraint fails/ ) {
 177                 # FK constraints
 178                 # FIXME: MySQL error, if we support more DB engines we should implement this for each
 179                 if ( $_->{msg} =~ /FOREIGN KEY \(`(?<column>.*?)`\)/ ) {
 180                     Koha::Exceptions::Object::FKConstraint->throw(
 181                         error     => 'Broken FK constraint',
 182                         broken_fk => $+{column}
 183                     );
 184                 }
 185             }
 186             elsif( $_->{msg} =~ /Duplicate entry '(.*?)' for key '(?<key>.*?)'/ ) {
 187                 Koha::Exceptions::Object::DuplicateID->throw(
 188                     error => 'Duplicate ID',
 189                     duplicate_id => $+{key}
 190                 );
 191             }
 192             elsif( $_->{msg} =~ /Incorrect (?<type>\w+) value: '(?<value>.*)' for column \W?(?<property>\S+)/ ) { # The optional \W in the regex might be a quote or backtick
 193                 my $type = $+{type};
 194                 my $value = $+{value};
 195                 my $property = $+{property};
 196                 $property =~ s/['`]//g;
 197                 Koha::Exceptions::Object::BadValue->throw(
 198                     type     => $type,
 199                     value    => $value,
 200                     property => $property =~ /(\w+\.\w+)$/ ? $1 : $property, # results in table.column without quotes or backtics
 201                 );
 202             }
 203         }
 204         # Catch-all for foreign key breakages. It will help find other use cases
 205         $_->rethrow();
 206     }
 207 }
 208
 209 =head3 $object->update();
 210
 211 A shortcut for set + store in one call.
 212
 213 =cut
 214
 215 sub update {
 216     my ($self, $values) = @_;
 217     Koha::Exceptions::Object::NotInStorage->throw unless $self->in_storage;
 218     $self->set($values)->store();
 219 }
 220
 221 =head3 $object->delete();
 222
 223 Removes the object from storage.
 224
 225 Returns:
 226     The item object if deletion was a success
 227     The DBIX::Class error if deletion failed
 228
 229 =cut
 230
 231 sub delete {
 232     my ($self) = @_;
 233
 234     my $deleted = $self->_result()->delete;
 235     if ( ref $deleted ) {
 236         my $object_class  = Koha::Object::_get_object_class( $self->_result->result_class );
 237         $deleted = $object_class->_new_from_dbic($deleted);
 238     }
 239     return $deleted;
 240 }
 241
 242 =head3 $object->set( $properties_hashref )
 243
 244 $object->set(
 245     {
 246         property1 => $property1,
 247         property2 => $property2,
 248         property3 => $propery3,
 249     }
 250 );
 251
 252 Enables multiple properties to be set at once
 253
 254 Returns:
 255     1      if all properties were set.
 256     0      if one or more properties do not exist.
 257     undef  if all properties exist but a different error
 258            prevents one or more properties from being set.
 259
 260 If one or more of the properties do not exist,
 261 no properties will be set.
 262
 263 =cut
 264
 265 sub set {
 266     my ( $self, $properties ) = @_;
 267
 268     my @columns = @{$self->_columns()};
 269
 270     foreach my $p ( keys %$properties ) {
 271         unless ( grep { $_ eq $p } @columns ) {
 272             Koha::Exceptions::Object::PropertyNotFound->throw( "No property $p for " . ref($self) );
 273         }
 274     }
 275
 276     return $self->_result()->set_columns($properties) ? $self : undef;
 277 }
 278
 279 =head3 $object->set_or_blank( $properties_hashref )
 280
 281 $object->set_or_blank(
 282     {
 283         property1 => $property1,
 284         property2 => $property2,
 285         property3 => $propery3,
 286     }
 287 );
 288
 289 If not listed in $properties_hashref, the property will be set to the default
 290 value defined at DB level, or nulled.
 291
 292 =cut
 293
 294
 295 sub set_or_blank {
 296     my ( $self, $properties ) = @_;
 297
 298     my $columns_info = $self->_result->result_source->columns_info;
 299
 300     foreach my $col ( keys %{$columns_info} ) {
 301
 302         next if exists $properties->{$col};
 303
 304         if ( $columns_info->{$col}->{is_nullable} ) {
 305             $properties->{$col} = undef;
 306         } else {
 307             $properties->{$col} = $columns_info->{$col}->{default_value};
 308         }
 309     }
 310
 311     return $self->set($properties);
 312 }
 313
 314 =head3 $object->unblessed();
 315
 316 Returns an unblessed representation of object.
 317
 318 =cut
 319
 320 sub unblessed {
 321     my ($self) = @_;
 322
 323     return { $self->_result->get_columns };
 324 }
 325
 326 =head3 $object->get_from_storage;
 327
 328 =cut
 329
 330 sub get_from_storage {
 331     my ( $self, $attrs ) = @_;
 332     my $stored_object = $self->_result->get_from_storage($attrs);
 333     return unless $stored_object;
 334     my $object_class  = Koha::Object::_get_object_class( $self->_result->result_class );
 335     return $object_class->_new_from_dbic($stored_object);
 336 }
 337
 338 =head3 $object->messages
 339
 340     my @messages = @{ $object->messages };
 341
 342 Returns the (probably non-fatal) messages that were recorded on the object.
 343
 344 =cut
 345
 346 sub messages {
 347     my ( $self ) = @_;
 348
 349     $self->{_messages} = []
 350         unless defined $self->{_messages};
 351
 352     return $self->{_messages};
 353 }
 354
 355 =head3 $object->add_message
 356
 357     try {
 358         <some action that might fail>
 359     }
 360     catch {
 361         if ( <fatal condition> ) {
 362             Koha::Exception->throw...
 363         }
 364
 365         # This is a non fatal error, notify the caller
 366         $self->add_message({ message => $error, type => 'error' });
 367     }
 368     return $self;
 369
 370 Adds a message.
 371
 372 =cut
 373
 374 sub add_message {
 375     my ( $self, $params ) = @_;
 376
 377     push @{ $self->{_messages} }, Koha::Object::Message->new($params);
 378
 379     return $self;
 380 }
 381
 382 =head3 $object->TO_JSON
 383
 384 Returns an unblessed representation of the object, suitable for JSON output.
 385
 386 =cut
 387
 388 sub TO_JSON {
 389
 390     my ($self) = @_;
 391
 392     my $unblessed    = $self->unblessed;
 393     my $columns_info = Koha::Database->new->schema->resultset( $self->_type )
 394         ->result_source->{_columns};
 395
 396     foreach my $col ( keys %{$columns_info} ) {
 397
 398         if ( $columns_info->{$col}->{is_boolean} )
 399         {    # Handle booleans gracefully
 400             $unblessed->{$col}
 401                 = ( $unblessed->{$col} )
 402                 ? Mojo::JSON->true
 403                 : Mojo::JSON->false;
 404         }
 405         elsif ( _numeric_column_type( $columns_info->{$col}->{data_type} )
 406             and looks_like_number( $unblessed->{$col} )
 407         ) {
 408
 409             # TODO: Remove once the solution for
 410             # https://github.com/perl5-dbi/DBD-mysql/issues/212
 411             # is ported to whatever distro we support by that time
 412             # or we move to DBD::MariaDB
 413             $unblessed->{$col} += 0;
 414         }
 415         elsif ( _decimal_column_type( $columns_info->{$col}->{data_type} )
 416             and looks_like_number( $unblessed->{$col} )
 417         ) {
 418
 419             # TODO: Remove once the solution for
 420             # https://github.com/perl5-dbi/DBD-mysql/issues/212
 421             # is ported to whatever distro we support by that time
 422             # or we move to DBD::MariaDB
 423             $unblessed->{$col} += 0.00;
 424         }
 425         elsif ( _datetime_column_type( $columns_info->{$col}->{data_type} ) ) {
 426             eval {
 427                 return unless $unblessed->{$col};
 428                 $unblessed->{$col} = output_pref({
 429                     dateformat => 'rfc3339',
 430                     dt         => dt_from_string($unblessed->{$col}, 'sql'),
 431                 });
 432             };
 433         }
 434     }
 435     return $unblessed;
 436 }
 437
 438 sub _date_or_datetime_column_type {
 439     my ($column_type) = @_;
 440
 441     my @dt_types = (
 442         'timestamp',
 443         'date',
 444         'datetime'
 445     );
 446
 447     return ( grep { $column_type eq $_ } @dt_types) ? 1 : 0;
 448 }
 449 sub _datetime_column_type {
 450     my ($column_type) = @_;
 451
 452     my @dt_types = (
 453         'timestamp',
 454         'datetime'
 455     );
 456
 457     return ( grep { $column_type eq $_ } @dt_types) ? 1 : 0;
 458 }
 459
 460 sub _numeric_column_type {
 461     # TODO: Remove once the solution for
 462     # https://github.com/perl5-dbi/DBD-mysql/issues/212
 463     # is ported to whatever distro we support by that time
 464     # or we move to DBD::MariaDB
 465     my ($column_type) = @_;
 466
 467     my @numeric_types = (
 468         'bigint',
 469         'integer',
 470         'int',
 471         'mediumint',
 472         'smallint',
 473         'tinyint',
 474     );
 475
 476     return ( grep { $column_type eq $_ } @numeric_types) ? 1 : 0;
 477 }
 478
 479 sub _decimal_column_type {
 480     # TODO: Remove once the solution for
 481     # https://github.com/perl5-dbi/DBD-mysql/issues/212
 482     # is ported to whatever distro we support by that time
 483     # or we move to DBD::MariaDB
 484     my ($column_type) = @_;
 485
 486     my @decimal_types = (
 487         'decimal',
 488         'double precision',
 489         'float'
 490     );
 491
 492     return ( grep { $column_type eq $_ } @decimal_types) ? 1 : 0;
 493 }
 494
 495 =head3 prefetch_whitelist
 496
 497     my $whitelist = $object->prefetch_whitelist()
 498
 499 Returns a hash of prefetchable subs and the type they return.
 500
 501 =cut
 502
 503 sub prefetch_whitelist {
 504     my ( $self ) = @_;
 505
 506     my $whitelist = {};
 507     my $relations = $self->_result->result_source->_relationships;
 508
 509     foreach my $key (keys %{$relations}) {
 510         if($self->can($key)) {
 511             my $result_class = $relations->{$key}->{class};
 512             my $obj = $result_class->new;
 513             try {
 514                 $whitelist->{$key} = Koha::Object::_get_object_class( $obj->result_class );
 515             } catch {
 516                 $whitelist->{$key} = undef;
 517             }
 518         }
 519     }
 520
 521     return $whitelist;
 522 }
 523
 524 =head3 to_api
 525
 526     my $object_for_api = $object->to_api(
 527         {
 528           [ embed => {
 529                 items => {
 530                     children => {
 531                         holds => {,
 532                             children => {
 533                               ...
 534                             }
 535                         }
 536                     }
 537                 },
 538                 library => {
 539                     ...
 540                 }
 541             },
 542             public => 0|1,
 543             ...
 544          ]
 545         }
 546     );
 547
 548 Returns a representation of the object, suitable for API output.
 549
 550 =cut
 551
 552 sub to_api {
 553     my ( $self, $params ) = @_;
 554     my $json_object = $self->TO_JSON;
 555
 556     # Remove forbidden attributes if required
 557     if ( $params->{public} ) {
 558         for my $field ( keys %{$json_object} ) {
 559             delete $json_object->{$field} unless any { $_ eq $field } @{ $self->public_read_list };
 560         }
 561     }
 562
 563     my $to_api_mapping = $self->to_api_mapping;
 564
 565     # Rename attributes if there's a mapping
 566     if ( $self->can('to_api_mapping') ) {
 567         foreach my $column ( keys %{ $self->to_api_mapping } ) {
 568             my $mapped_column = $self->to_api_mapping->{$column};
 569             if ( exists $json_object->{$column}
 570                 && defined $mapped_column )
 571             {
 572                 # key != undef
 573                 $json_object->{$mapped_column} = delete $json_object->{$column};
 574             }
 575             elsif ( exists $json_object->{$column}
 576                 && !defined $mapped_column )
 577             {
 578                 # key == undef
 579                 delete $json_object->{$column};
 580             }
 581         }
 582     }
 583
 584     # Make sure we duplicate the $params variable to avoid
 585     # breaking calls in a loop (Koha::Objects->to_api)
 586     $params    = {%$params};
 587     my $embeds = delete $params->{embed};
 588
 589     if ($embeds) {
 590         foreach my $embed ( keys %{$embeds} ) {
 591             if ( $embed =~ m/^(?<relation>.*)_count$/
 592                 and $embeds->{$embed}->{is_count} ) {
 593
 594                 my $relation = $+{relation};
 595                 $json_object->{$embed} = $self->$relation->count;
 596             }
 597             else {
 598                 my $curr = $embed;
 599                 my $next = $embeds->{$curr}->{children};
 600
 601                 my $children = $self->$curr;
 602
 603                 if ( defined $children and ref($children) eq 'ARRAY' ) {
 604                     my @list = map {
 605                         $self->_handle_to_api_child(
 606                             {
 607                                 child  => $_,
 608                                 next   => $next,
 609                                 curr   => $curr,
 610                                 params => $params
 611                             }
 612                         )
 613                     } @{$children};
 614                     $json_object->{$curr} = \@list;
 615                 }
 616                 else {
 617                     $json_object->{$curr} = $self->_handle_to_api_child(
 618                         {
 619                             child  => $children,
 620                             next   => $next,
 621                             curr   => $curr,
 622                             params => $params
 623                         }
 624                     );
 625                 }
 626             }
 627         }
 628     }
 629
 630     return $json_object;
 631 }
 632
 633 =head3 to_api_mapping
 634
 635     my $mapping = $object->to_api_mapping;
 636
 637 Generic method that returns the attribute name mappings required to
 638 render the object on the API.
 639
 640 Note: this only returns an empty I<hashref>. Each class should have its
 641 own mapping returned.
 642
 643 =cut
 644
 645 sub to_api_mapping {
 646     return {};
 647 }
 648
 649 =head3 public_read_list
 650
 651
 652     my @public_read_list = @{$object->public_read_list};
 653
 654 Generic method that returns the list of database columns that are allowed to
 655 be passed to render objects on the public API.
 656
 657 Note: this only returns an empty I<arrayref>. Each class should have its
 658 own implementation.
 659
 660 =cut
 661
 662 sub public_read_list
 663  {
 664     return [];
 665 }
 666
 667 =head3 from_api_mapping
 668
 669     my $mapping = $object->from_api_mapping;
 670
 671 Generic method that returns the attribute name mappings so the data that
 672 comes from the API is correctly renamed to match what is required for the DB.
 673
 674 =cut
 675
 676 sub from_api_mapping {
 677     my ( $self ) = @_;
 678
 679     my $to_api_mapping = $self->to_api_mapping;
 680
 681     unless ( defined $self->{_from_api_mapping} ) {
 682         $self->{_from_api_mapping} = {};
 683         while (my ($key, $value) = each %{ $to_api_mapping } ) {
 684             $self->{_from_api_mapping}->{$value} = $key
 685                 if defined $value;
 686         }
 687     }
 688
 689     return $self->{_from_api_mapping};
 690 }
 691
 692 =head3 new_from_api
 693
 694     my $object = Koha::Object->new_from_api;
 695     my $object = Koha::Object->new_from_api( $attrs );
 696
 697 Creates a new object, mapping the API attribute names to the ones on the DB schema.
 698
 699 =cut
 700
 701 sub new_from_api {
 702     my ( $class, $params ) = @_;
 703
 704     my $self = $class->new;
 705     return $self->set_from_api( $params );
 706 }
 707
 708 =head3 set_from_api
 709
 710     my $object = Koha::Object->new(...);
 711     $object->set_from_api( $attrs )
 712
 713 Sets the object's attributes mapping API attribute names to the ones on the DB schema.
 714
 715 =cut
 716
 717 sub set_from_api {
 718     my ( $self, $from_api_params ) = @_;
 719
 720     return $self->set( $self->attributes_from_api( $from_api_params ) );
 721 }
 722
 723 =head3 attributes_from_api
 724
 725     my $attributes = attributes_from_api( $params );
 726
 727 Returns the passed params, converted from API naming into the model.
 728
 729 =cut
 730
 731 sub attributes_from_api {
 732     my ( $self, $from_api_params ) = @_;
 733
 734     my $from_api_mapping = $self->from_api_mapping;
 735
 736     my $params;
 737     my $columns_info = $self->_result->result_source->columns_info;
 738     my $dtf          = $self->_result->result_source->storage->datetime_parser;
 739
 740     while (my ($key, $value) = each %{ $from_api_params } ) {
 741         my $koha_field_name =
 742           exists $from_api_mapping->{$key}
 743           ? $from_api_mapping->{$key}
 744           : $key;
 745
 746         if ( $columns_info->{$koha_field_name}->{is_boolean} ) {
 747             # TODO: Remove when D8 is formally deprecated
 748             # Handle booleans gracefully
 749             $value = ( $value ) ? 1 : 0;
 750         }
 751         elsif ( _date_or_datetime_column_type( $columns_info->{$koha_field_name}->{data_type} ) ) {
 752             try {
 753                 if ( $columns_info->{$koha_field_name}->{data_type} eq 'date' ) {
 754                     $value = $dtf->format_date(dt_from_string($value, 'rfc3339'))
 755                         if defined $value;
 756                 }
 757                 else {
 758                     $value = $dtf->format_datetime(dt_from_string($value, 'rfc3339'))
 759                         if defined $value;
 760                 }
 761             }
 762             catch {
 763                 Koha::Exceptions::BadParameter->throw( parameter => $key );
 764             };
 765         }
 766
 767         $params->{$koha_field_name} = $value;
 768     }
 769
 770     return $params;
 771 }
 772
 773 =head3 $object->unblessed_all_relateds
 774
 775 my $everything_into_one_hashref = $object->unblessed_all_relateds
 776
 777 The unblessed method only retrieves column' values for the column of the object.
 778 In a *few* cases we want to retrieve the information of all the prefetched data.
 779
 780 =cut
 781
 782 sub unblessed_all_relateds {
 783     my ($self) = @_;
 784
 785     my %data;
 786     my $related_resultsets = $self->_result->{related_resultsets} || {};
 787     my $rs = $self->_result;
 788     while ( $related_resultsets and %$related_resultsets ) {
 789         my @relations = keys %{ $related_resultsets };
 790         if ( @relations ) {
 791             my $relation = $relations[0];
 792             $rs = $rs->related_resultset($relation)->get_cache;
 793             $rs = $rs->[0]; # Does it makes sense to have several values here?
 794             my $object_class = Koha::Object::_get_object_class( $rs->result_class );
 795             my $koha_object = $object_class->_new_from_dbic( $rs );
 796             $related_resultsets = $rs->{related_resultsets};
 797             %data = ( %data, %{ $koha_object->unblessed } );
 798         }
 799     }
 800     %data = ( %data, %{ $self->unblessed } );
 801     return \%data;
 802 }
 803
 804 =head3 $object->_result();
 805
 806 Returns the internal DBIC Row object
 807
 808 =cut
 809
 810 sub _result {
 811     my ($self) = @_;
 812
 813     # If we don't have a dbic row at this point, we need to create an empty one
 814     $self->{_result} ||=
 815       Koha::Database->new()->schema()->resultset( $self->_type() )->new({});
 816
 817     return $self->{_result};
 818 }
 819
 820 =head3 $object->_columns();
 821
 822 Returns an arrayref of the table columns
 823
 824 =cut
 825
 826 sub _columns {
 827     my ($self) = @_;
 828
 829     # If we don't have a dbic row at this point, we need to create an empty one
 830     $self->{_columns} ||= [ $self->_result()->result_source()->columns() ];
 831
 832     return $self->{_columns};
 833 }
 834
 835 sub _get_object_class {
 836     my ( $type ) = @_;
 837     return unless $type;
 838
 839     if( $type->can('koha_object_class') ) {
 840         return $type->koha_object_class;
 841     }
 842     $type =~ s|Schema::Result::||;
 843     return ${type};
 844 }
 845
 846 =head3 AUTOLOAD
 847
 848 The autoload method is used only to get and set values for an objects properties.
 849
 850 =cut
 851
 852 sub AUTOLOAD {
 853     my $self = shift;
 854
 855     my $method = our $AUTOLOAD;
 856     $method =~ s/.*://;
 857
 858     my @columns = @{$self->_columns()};
 859     # Using direct setter/getter like $item->barcode() or $item->barcode($barcode);
 860     if ( grep { $_ eq $method } @columns ) {
 861         if ( @_ ) {
 862             $self->_result()->set_column( $method, @_ );
 863             return $self;
 864         } else {
 865             my $value = $self->_result()->get_column( $method );
 866             return $value;
 867         }
 868     }
 869
 870     my @known_methods = qw( is_changed id in_storage get_column discard_changes make_column_dirty );
 871
 872     Koha::Exceptions::Object::MethodNotCoveredByTests->throw(
 873         error      => sprintf("The method %s->%s is not covered by tests!", ref($self), $method),
 874         show_trace => 1
 875     ) unless grep { $_ eq $method } @known_methods;
 876
 877
 878     my $r = eval { $self->_result->$method(@_) };
 879     if ( $@ ) {
 880         Koha::Exceptions::Object->throw( ref($self) . "::$method generated this error: " . $@ );
 881     }
 882     return $r;
 883 }
 884
 885 =head3 _type
 886
 887 This method must be defined in the child class. The value is the name of the DBIC resultset.
 888 For example, for borrowers, the _type method will return "Borrower".
 889
 890 =cut
 891
 892 sub _type { }
 893
 894 =head3 _handle_to_api_child
 895
 896 =cut
 897
 898 sub _handle_to_api_child {
 899     my ($self, $args ) = @_;
 900
 901     my $child  = $args->{child};
 902     my $next   = $args->{next};
 903     my $curr   = $args->{curr};
 904     my $params = $args->{params};
 905
 906     my $res;
 907
 908     if ( defined $child ) {
 909
 910         Koha::Exceptions::Exception->throw( "Asked to embed $curr but its return value doesn't implement to_api" )
 911             if defined $next and blessed $child and !$child->can('to_api');
 912
 913         if ( blessed $child ) {
 914             $params->{embed} = $next;
 915             $res = $child->to_api($params);
 916         }
 917         else {
 918             $res = $child;
 919         }
 920     }
 921
 922     return $res;
 923 }
 924
 925 sub DESTROY { }
 926
 927 =head1 AUTHOR
 928
 929 Kyle M Hall <kyle@bywatersolutions.com>
 930
 931 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 932
 933 =cut
 934
 935 1;