Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Context;
  29 use C4::Auth qw( checkpw_hash );
  30 use C4::Log qw( logaction );
  31 use Koha::Account;
  32 use Koha::ArticleRequests;
  33 use C4::Letters qw( GetPreparedLetter EnqueueLetter SendQueuedMessages );
  34 use Koha::AuthUtils;
  35 use Koha::Checkouts;
  36 use Koha::CirculationRules;
  37 use Koha::Club::Enrollments;
  38 use Koha::Database;
  39 use Koha::DateUtils qw( dt_from_string );
  40 use Koha::Encryption;
  41 use Koha::Exceptions::Password;
  42 use Koha::Holds;
  43 use Koha::CurbsidePickups;
  44 use Koha::Old::Checkouts;
  45 use Koha::Patron::Attributes;
  46 use Koha::Patron::Categories;
  47 use Koha::Patron::Debarments;
  48 use Koha::Patron::HouseboundProfile;
  49 use Koha::Patron::HouseboundRole;
  50 use Koha::Patron::Images;
  51 use Koha::Patron::Messages;
  52 use Koha::Patron::Modifications;
  53 use Koha::Patron::Relationships;
  54 use Koha::Patron::Restrictions;
  55 use Koha::Patrons;
  56 use Koha::Plugins;
  57 use Koha::Recalls;
  58 use Koha::Result::Boolean;
  59 use Koha::Subscription::Routinglists;
  60 use Koha::Token;
  61 use Koha::Virtualshelves;
  62
  63 use base qw(Koha::Object);
  64
  65 use constant ADMINISTRATIVE_LOCKOUT => -1;
  66
  67 our $RESULTSET_PATRON_ID_MAPPING = {
  68     Accountline          => 'borrowernumber',
  69     Aqbasketuser         => 'borrowernumber',
  70     Aqbudget             => 'budget_owner_id',
  71     Aqbudgetborrower     => 'borrowernumber',
  72     ArticleRequest       => 'borrowernumber',
  73     BorrowerDebarment    => 'borrowernumber',
  74     BorrowerFile         => 'borrowernumber',
  75     BorrowerModification => 'borrowernumber',
  76     ClubEnrollment       => 'borrowernumber',
  77     Issue                => 'borrowernumber',
  78     ItemsLastBorrower    => 'borrowernumber',
  79     Linktracker          => 'borrowernumber',
  80     Message              => 'borrowernumber',
  81     MessageQueue         => 'borrowernumber',
  82     OldIssue             => 'borrowernumber',
  83     OldReserve           => 'borrowernumber',
  84     Rating               => 'borrowernumber',
  85     Reserve              => 'borrowernumber',
  86     Review               => 'borrowernumber',
  87     SearchHistory        => 'userid',
  88     Statistic            => 'borrowernumber',
  89     Suggestion           => 'suggestedby',
  90     TagAll               => 'borrowernumber',
  91     Virtualshelfcontent  => 'borrowernumber',
  92     Virtualshelfshare    => 'borrowernumber',
  93     Virtualshelve        => 'owner',
  94 };
  95
  96 =head1 NAME
  97
  98 Koha::Patron - Koha Patron Object class
  99
 100 =head1 API
 101
 102 =head2 Class Methods
 103
 104 =head3 new
 105
 106 =cut
 107
 108 sub new {
 109     my ( $class, $params ) = @_;
 110
 111     return $class->SUPER::new($params);
 112 }
 113
 114 =head3 fixup_cardnumber
 115
 116 Autogenerate next cardnumber from highest value found in database
 117
 118 =cut
 119
 120 sub fixup_cardnumber {
 121     my ( $self ) = @_;
 122
 123     my $max = $self->cardnumber;
 124     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 125
 126     $max ||= Koha::Patrons->search({
 127         cardnumber => {-regexp => '^-?[0-9]+$'}
 128     }, {
 129         select => \'CAST(cardnumber AS SIGNED)',
 130         as => ['cast_cardnumber']
 131     })->_resultset->get_column('cast_cardnumber')->max;
 132     $self->cardnumber(($max || 0) +1);
 133 }
 134
 135 =head3 trim_whitespace
 136
 137 trim whitespace from data which has some non-whitespace in it.
 138 Could be moved to Koha::Object if need to be reused
 139
 140 =cut
 141
 142 sub trim_whitespaces {
 143     my( $self ) = @_;
 144
 145     my $schema  = Koha::Database->new->schema;
 146     my @columns = $schema->source($self->_type)->columns;
 147
 148     for my $column( @columns ) {
 149         my $value = $self->$column;
 150         if ( defined $value ) {
 151             $value =~ s/^\s*|\s*$//g;
 152             $self->$column($value);
 153         }
 154     }
 155     return $self;
 156 }
 157
 158 =head3 plain_text_password
 159
 160 $patron->plain_text_password( $password );
 161
 162 stores a copy of the unencrypted password in the object
 163 for use in code before encrypting for db
 164
 165 =cut
 166
 167 sub plain_text_password {
 168     my ( $self, $password ) = @_;
 169     if ( $password ) {
 170         $self->{_plain_text_password} = $password;
 171         return $self;
 172     }
 173     return $self->{_plain_text_password}
 174         if $self->{_plain_text_password};
 175
 176     return;
 177 }
 178
 179 =head3 store
 180
 181 Patron specific store method to cleanup record
 182 and do other necessary things before saving
 183 to db
 184
 185 =cut
 186
 187 sub store {
 188     my ($self) = @_;
 189
 190     $self->_result->result_source->schema->txn_do(
 191         sub {
 192             if (
 193                 C4::Context->preference("autoMemberNum")
 194                 and ( not defined $self->cardnumber
 195                     or $self->cardnumber eq '' )
 196               )
 197             {
 198                 # Warning: The caller is responsible for locking the members table in write
 199                 # mode, to avoid database corruption.
 200                 # We are in a transaction but the table is not locked
 201                 $self->fixup_cardnumber;
 202             }
 203
 204             unless( $self->category->in_storage ) {
 205                 Koha::Exceptions::Object::FKConstraint->throw(
 206                     broken_fk => 'categorycode',
 207                     value     => $self->categorycode,
 208                 );
 209             }
 210
 211             $self->trim_whitespaces;
 212
 213             my $new_cardnumber = $self->cardnumber;
 214             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 215             $self->cardnumber( $new_cardnumber );
 216
 217             # Set surname to uppercase if uppercasesurname is true
 218             $self->surname( uc($self->surname) )
 219                 if C4::Context->preference("uppercasesurnames");
 220
 221             $self->relationship(undef) # We do not want to store an empty string in this field
 222               if defined $self->relationship
 223                      and $self->relationship eq "";
 224
 225             unless ( $self->in_storage ) {    #AddMember
 226
 227                 # Generate a valid userid/login if needed
 228                 $self->generate_userid
 229                   if not $self->userid or not $self->has_valid_userid;
 230
 231                 # Add expiration date if it isn't already there
 232                 unless ( $self->dateexpiry ) {
 233                     $self->dateexpiry( $self->category->get_expiry_date );
 234                 }
 235
 236                 # Add enrollment date if it isn't already there
 237                 unless ( $self->dateenrolled ) {
 238                     $self->dateenrolled(dt_from_string);
 239                 }
 240
 241                 # Set the privacy depending on the patron's category
 242                 my $default_privacy = $self->category->default_privacy || q{};
 243                 $default_privacy =
 244                     $default_privacy eq 'default' ? 1
 245                   : $default_privacy eq 'never'   ? 2
 246                   : $default_privacy eq 'forever' ? 0
 247                   :                                                   undef;
 248                 $self->privacy($default_privacy);
 249
 250                 # Call any check_password plugins if password is passed
 251                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 252                     my @plugins = Koha::Plugins->new()->GetPlugins({
 253                         method => 'check_password',
 254                     });
 255                     foreach my $plugin ( @plugins ) {
 256                         # This plugin hook will also be used by a plugin for the Norwegian national
 257                         # patron database. This is why we need to pass both the password and the
 258                         # borrowernumber to the plugin.
 259                         my $ret = $plugin->check_password(
 260                             {
 261                                 password       => $self->password,
 262                                 borrowernumber => $self->borrowernumber
 263                             }
 264                         );
 265                         if ( $ret->{'error'} == 1 ) {
 266                             Koha::Exceptions::Password::Plugin->throw();
 267                         }
 268                     }
 269                 }
 270
 271                 # Make a copy of the plain text password for later use
 272                 $self->plain_text_password( $self->password );
 273
 274                 $self->password_expiration_date( $self->password
 275                     ? $self->category->get_password_expiry_date || undef
 276                     : undef );
 277                 # Create a disabled account if no password provided
 278                 $self->password( $self->password
 279                     ? Koha::AuthUtils::hash_password( $self->password )
 280                     : '!' );
 281
 282                 $self->borrowernumber(undef);
 283
 284                 $self = $self->SUPER::store;
 285
 286                 $self->add_enrolment_fee_if_needed(0);
 287
 288                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 289                   if C4::Context->preference("BorrowersLog");
 290             }
 291             else {    #ModMember
 292
 293                 my $self_from_storage = $self->get_from_storage;
 294                 # FIXME We should not deal with that here, callers have to do this job
 295                 # Moved from ModMember to prevent regressions
 296                 unless ( $self->userid ) {
 297                     my $stored_userid = $self_from_storage->userid;
 298                     $self->userid($stored_userid);
 299                 }
 300
 301                 # Password must be updated using $self->set_password
 302                 $self->password($self_from_storage->password);
 303
 304                 if ( $self->category->categorycode ne
 305                     $self_from_storage->category->categorycode )
 306                 {
 307                     # Add enrolement fee on category change if required
 308                     $self->add_enrolment_fee_if_needed(1)
 309                       if C4::Context->preference('FeeOnChangePatronCategory');
 310
 311                     # Clean up guarantors on category change if required
 312                     $self->guarantor_relationships->delete
 313                       unless ( $self->category->can_be_guarantee );
 314
 315                 }
 316
 317                 # Actionlogs
 318                 if ( C4::Context->preference("BorrowersLog") ) {
 319                     my $info;
 320                     my $from_storage = $self_from_storage->unblessed;
 321                     my $from_object  = $self->unblessed;
 322                     my @skip_fields  = (qw/lastseen updated_on/);
 323                     for my $key ( keys %{$from_storage} ) {
 324                         next if any { /$key/ } @skip_fields;
 325                         if (
 326                             (
 327                                   !defined( $from_storage->{$key} )
 328                                 && defined( $from_object->{$key} )
 329                             )
 330                             || ( defined( $from_storage->{$key} )
 331                                 && !defined( $from_object->{$key} ) )
 332                             || (
 333                                    defined( $from_storage->{$key} )
 334                                 && defined( $from_object->{$key} )
 335                                 && ( $from_storage->{$key} ne
 336                                     $from_object->{$key} )
 337                             )
 338                           )
 339                         {
 340                             $info->{$key} = {
 341                                 before => $from_storage->{$key},
 342                                 after  => $from_object->{$key}
 343                             };
 344                         }
 345                     }
 346
 347                     if ( defined($info) ) {
 348                         logaction(
 349                             "MEMBERS",
 350                             "MODIFY",
 351                             $self->borrowernumber,
 352                             to_json(
 353                                 $info,
 354                                 { utf8 => 1, pretty => 1, canonical => 1 }
 355                             )
 356                         );
 357                     }
 358                 }
 359
 360                 # Final store
 361                 $self = $self->SUPER::store;
 362             }
 363         }
 364     );
 365     return $self;
 366 }
 367
 368 =head3 delete
 369
 370 $patron->delete
 371
 372 Delete patron's holds, lists and finally the patron.
 373
 374 Lists owned by the borrower are deleted or ownership is transferred depending on the
 375 ListOwnershipUponPatronDeletion pref, but entries from the borrower to other lists are kept.
 376
 377 =cut
 378
 379 sub delete {
 380     my ($self) = @_;
 381
 382     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 383     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 384
 385     $self->_result->result_source->schema->txn_do(
 386         sub {
 387             # Cancel Patron's holds
 388             my $holds = $self->holds;
 389             while( my $hold = $holds->next ){
 390                 $hold->cancel;
 391             }
 392
 393             # Handle lists (virtualshelves)
 394             $self->virtualshelves->disown_or_delete;
 395
 396             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 397             # for patron selfreg
 398             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 399
 400             $self->SUPER::delete;
 401
 402             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 403         }
 404     );
 405     return $self;
 406 }
 407
 408 =head3 category
 409
 410 my $patron_category = $patron->category
 411
 412 Return the patron category for this patron
 413
 414 =cut
 415
 416 sub category {
 417     my ( $self ) = @_;
 418     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 419 }
 420
 421 =head3 image
 422
 423 =cut
 424
 425 sub image {
 426     my ( $self ) = @_;
 427
 428     return Koha::Patron::Images->find( $self->borrowernumber );
 429 }
 430
 431 =head3 library
 432
 433 Returns a Koha::Library object representing the patron's home library.
 434
 435 =cut
 436
 437 sub library {
 438     my ( $self ) = @_;
 439     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 440 }
 441
 442 =head3 sms_provider
 443
 444 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 445
 446 =cut
 447
 448 sub sms_provider {
 449     my ( $self ) = @_;
 450     my $sms_provider_rs = $self->_result->sms_provider;
 451     return unless $sms_provider_rs;
 452     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 453 }
 454
 455 =head3 guarantor_relationships
 456
 457 Returns Koha::Patron::Relationships object for this patron's guarantors
 458
 459 Returns the set of relationships for the patrons that are guarantors for this patron.
 460
 461 This is returned instead of a Koha::Patron object because the guarantor
 462 may not exist as a patron in Koha. If this is true, the guarantors name
 463 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 464
 465 =cut
 466
 467 sub guarantor_relationships {
 468     my ($self) = @_;
 469
 470     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 471 }
 472
 473 =head3 guarantee_relationships
 474
 475 Returns Koha::Patron::Relationships object for this patron's guarantors
 476
 477 Returns the set of relationships for the patrons that are guarantees for this patron.
 478
 479 The method returns Koha::Patron::Relationship objects for the sake
 480 of consistency with the guantors method.
 481 A guarantee by definition must exist as a patron in Koha.
 482
 483 =cut
 484
 485 sub guarantee_relationships {
 486     my ($self) = @_;
 487
 488     return Koha::Patron::Relationships->search(
 489         { guarantor_id => $self->id },
 490         {
 491             prefetch => 'guarantee',
 492             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 493         }
 494     );
 495 }
 496
 497 =head3 relationships_debt
 498
 499 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 500
 501 =cut
 502
 503 sub relationships_debt {
 504     my ($self, $params) = @_;
 505
 506     my $include_guarantors  = $params->{include_guarantors};
 507     my $only_this_guarantor = $params->{only_this_guarantor};
 508     my $include_this_patron = $params->{include_this_patron};
 509
 510     my @guarantors;
 511     if ( $only_this_guarantor ) {
 512         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 513         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 514     } elsif ( $self->guarantor_relationships->count ) {
 515         # I am a guarantee, just get all my guarantors
 516         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 517     } else {
 518         # I am a guarantor, I need to get all the guarantors of all my guarantees
 519         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 520     }
 521
 522     my $non_issues_charges = 0;
 523     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 524     foreach my $guarantor (@guarantors) {
 525         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 526
 527         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 528         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 529         my $guarantees_non_issues_charges = 0;
 530         foreach my $guarantee (@guarantees) {
 531             next if $seen->{ $guarantee->id };
 532             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 533             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 534             $seen->{ $guarantee->id } = 1;
 535         }
 536
 537         $non_issues_charges += $guarantees_non_issues_charges;
 538         $seen->{ $guarantor->id } = 1;
 539     }
 540
 541     return $non_issues_charges;
 542 }
 543
 544 =head3 housebound_profile
 545
 546 Returns the HouseboundProfile associated with this patron.
 547
 548 =cut
 549
 550 sub housebound_profile {
 551     my ( $self ) = @_;
 552     my $profile = $self->_result->housebound_profile;
 553     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 554         if ( $profile );
 555     return;
 556 }
 557
 558 =head3 housebound_role
 559
 560 Returns the HouseboundRole associated with this patron.
 561
 562 =cut
 563
 564 sub housebound_role {
 565     my ( $self ) = @_;
 566
 567     my $role = $self->_result->housebound_role;
 568     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 569     return;
 570 }
 571
 572 =head3 siblings
 573
 574 Returns the siblings of this patron.
 575
 576 =cut
 577
 578 sub siblings {
 579     my ($self) = @_;
 580
 581     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 582
 583     return unless @guarantors;
 584
 585     my @siblings =
 586       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 587
 588     return unless @siblings;
 589
 590     my %seen;
 591     @siblings =
 592       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 593
 594     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 595 }
 596
 597 =head3 merge_with
 598
 599     my $patron = Koha::Patrons->find($id);
 600     $patron->merge_with( \@patron_ids );
 601
 602     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 603     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 604     of the keeper patron.
 605
 606 =cut
 607
 608 sub merge_with {
 609     my ( $self, $patron_ids ) = @_;
 610
 611     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 612     return if $anonymous_patron && $self->id eq $anonymous_patron;
 613
 614     my @patron_ids = @{ $patron_ids };
 615
 616     # Ensure the keeper isn't in the list of patrons to merge
 617     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 618
 619     my $schema = Koha::Database->new()->schema();
 620
 621     my $results;
 622
 623     $self->_result->result_source->schema->txn_do( sub {
 624         foreach my $patron_id (@patron_ids) {
 625
 626             next if $patron_id eq $anonymous_patron;
 627
 628             my $patron = Koha::Patrons->find( $patron_id );
 629
 630             next unless $patron;
 631
 632             # Unbless for safety, the patron will end up being deleted
 633             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 634
 635             my $attributes = $patron->extended_attributes;
 636             my $new_attributes = [
 637                 map { { code => $_->code, attribute => $_->attribute } }
 638                     $attributes->as_list
 639             ];
 640             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 641             for my $attribute ( @$new_attributes ) {
 642                 try {
 643                     $self->add_extended_attribute($attribute);
 644                 } catch {
 645                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 646                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 647                         $_->rethrow;
 648                     }
 649                 };
 650             }
 651
 652             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 653                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 654                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 655                 $rs->update({ $field => $self->id });
 656                 if ( $r eq 'BorrowerDebarment' ) {
 657                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 658                 }
 659             }
 660
 661             $patron->move_to_deleted();
 662             $patron->delete();
 663         }
 664     });
 665
 666     return $results;
 667 }
 668
 669
 670
 671 =head3 wants_check_for_previous_checkout
 672
 673     $wants_check = $patron->wants_check_for_previous_checkout;
 674
 675 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 676
 677 =cut
 678
 679 sub wants_check_for_previous_checkout {
 680     my ( $self ) = @_;
 681     my $syspref = C4::Context->preference("checkPrevCheckout");
 682
 683     # Simple cases
 684     ## Hard syspref trumps all
 685     return 1 if ($syspref eq 'hardyes');
 686     return 0 if ($syspref eq 'hardno');
 687     ## Now, patron pref trumps all
 688     return 1 if ($self->checkprevcheckout eq 'yes');
 689     return 0 if ($self->checkprevcheckout eq 'no');
 690
 691     # More complex: patron inherits -> determine category preference
 692     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 693     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 694     return 0 if ($checkPrevCheckoutByCat eq 'no');
 695
 696     # Finally: category preference is inherit, default to 0
 697     if ($syspref eq 'softyes') {
 698         return 1;
 699     } else {
 700         return 0;
 701     }
 702 }
 703
 704 =head3 do_check_for_previous_checkout
 705
 706     $do_check = $patron->do_check_for_previous_checkout($item);
 707
 708 Return 1 if the bib associated with $ITEM has previously been checked out to
 709 $PATRON, 0 otherwise.
 710
 711 =cut
 712
 713 sub do_check_for_previous_checkout {
 714     my ( $self, $item ) = @_;
 715
 716     my @item_nos;
 717     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 718     if ( $biblio->is_serial ) {
 719         push @item_nos, $item->{itemnumber};
 720     } else {
 721         # Get all itemnumbers for given bibliographic record.
 722         @item_nos = $biblio->items->get_column( 'itemnumber' );
 723     }
 724
 725     # Create (old)issues search criteria
 726     my $criteria = {
 727         borrowernumber => $self->borrowernumber,
 728         itemnumber => \@item_nos,
 729     };
 730
 731     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 732     if ($delay) {
 733         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 734         my $newer_than = dt_from_string()->subtract( days => $delay );
 735         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 736     }
 737
 738     # Check current issues table
 739     my $issues = Koha::Checkouts->search($criteria);
 740     return 1 if $issues->count; # 0 || N
 741
 742     # Check old issues table
 743     my $old_issues = Koha::Old::Checkouts->search($criteria);
 744     return $old_issues->count;  # 0 || N
 745 }
 746
 747 =head3 is_debarred
 748
 749 my $debarment_expiration = $patron->is_debarred;
 750
 751 Returns the date a patron debarment will expire, or undef if the patron is not
 752 debarred
 753
 754 =cut
 755
 756 sub is_debarred {
 757     my ($self) = @_;
 758
 759     return unless $self->debarred;
 760     return $self->debarred
 761       if $self->debarred =~ '^9999'
 762       or dt_from_string( $self->debarred ) > dt_from_string;
 763     return;
 764 }
 765
 766 =head3 is_expired
 767
 768 my $is_expired = $patron->is_expired;
 769
 770 Returns 1 if the patron is expired or 0;
 771
 772 =cut
 773
 774 sub is_expired {
 775     my ($self) = @_;
 776     return 0 unless $self->dateexpiry;
 777     return 0 if $self->dateexpiry =~ '^9999';
 778     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 779     return 0;
 780 }
 781
 782 =head3 password_expired
 783
 784 my $password_expired = $patron->password_expired;
 785
 786 Returns 1 if the patron's password is expired or 0;
 787
 788 =cut
 789
 790 sub password_expired {
 791     my ($self) = @_;
 792     return 0 unless $self->password_expiration_date;
 793     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 794     return 0;
 795 }
 796
 797 =head3 is_going_to_expire
 798
 799 my $is_going_to_expire = $patron->is_going_to_expire;
 800
 801 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 802
 803 =cut
 804
 805 sub is_going_to_expire {
 806     my ($self) = @_;
 807
 808     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 809
 810     return 0 unless $delay;
 811     return 0 unless $self->dateexpiry;
 812     return 0 if $self->dateexpiry =~ '^9999';
 813     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 814     return 0;
 815 }
 816
 817 =head3 set_password
 818
 819     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 820
 821 Set the patron's password.
 822
 823 =head4 Exceptions
 824
 825 The passed string is validated against the current password enforcement policy.
 826 Validation can be skipped by passing the I<skip_validation> parameter.
 827
 828 Exceptions are thrown if the password is not good enough.
 829
 830 =over 4
 831
 832 =item Koha::Exceptions::Password::TooShort
 833
 834 =item Koha::Exceptions::Password::WhitespaceCharacters
 835
 836 =item Koha::Exceptions::Password::TooWeak
 837
 838 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 839
 840 =back
 841
 842 =cut
 843
 844 sub set_password {
 845     my ( $self, $args ) = @_;
 846
 847     my $password = $args->{password};
 848
 849     unless ( $args->{skip_validation} ) {
 850         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 851
 852         if ( !$is_valid ) {
 853             if ( $error eq 'too_short' ) {
 854                 my $min_length = $self->category->effective_min_password_length;
 855                 $min_length = 3 if not $min_length or $min_length < 3;
 856
 857                 my $password_length = length($password);
 858                 Koha::Exceptions::Password::TooShort->throw(
 859                     length => $password_length, min_length => $min_length );
 860             }
 861             elsif ( $error eq 'has_whitespaces' ) {
 862                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 863             }
 864             elsif ( $error eq 'too_weak' ) {
 865                 Koha::Exceptions::Password::TooWeak->throw();
 866             }
 867         }
 868     }
 869
 870     if ( C4::Context->config("enable_plugins") ) {
 871         # Call any check_password plugins
 872         my @plugins = Koha::Plugins->new()->GetPlugins({
 873             method => 'check_password',
 874         });
 875         foreach my $plugin ( @plugins ) {
 876             # This plugin hook will also be used by a plugin for the Norwegian national
 877             # patron database. This is why we need to pass both the password and the
 878             # borrowernumber to the plugin.
 879             my $ret = $plugin->check_password(
 880                 {
 881                     password       => $password,
 882                     borrowernumber => $self->borrowernumber
 883                 }
 884             );
 885             # This plugin hook will also be used by a plugin for the Norwegian national
 886             # patron database. This is why we need to call the actual plugins and then
 887             # check skip_validation afterwards.
 888             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 889                 Koha::Exceptions::Password::Plugin->throw();
 890             }
 891         }
 892     }
 893
 894     if ( C4::Context->preference('NotifyPasswordChange') ) {
 895         my $self_from_storage = $self->get_from_storage;
 896         if ( !C4::Auth::checkpw_hash( $password, $self_from_storage->password ) ) {
 897             my $emailaddr = $self_from_storage->notice_email_address;
 898
 899             # if we manage to find a valid email address, send notice
 900             if ($emailaddr) {
 901                 my $letter = C4::Letters::GetPreparedLetter(
 902                     module      => 'members',
 903                     letter_code => 'PASSWORD_CHANGE',
 904                     branchcode  => $self_from_storage->branchcode,
 905                     ,
 906                     lang   => $self_from_storage->lang || 'default',
 907                     tables => {
 908                         'branches'  => $self_from_storage->branchcode,
 909                         'borrowers' => $self_from_storage->borrowernumber,
 910                     },
 911                     want_librarian => 1,
 912                 ) or return;
 913
 914                 my $message_id = C4::Letters::EnqueueLetter(
 915                     {
 916                         letter                 => $letter,
 917                         borrowernumber         => $self_from_storage->id,
 918                         to_address             => $emailaddr,
 919                         message_transport_type => 'email'
 920                     }
 921                 );
 922                 C4::Letters::SendQueuedMessages( { message_id => $message_id } );
 923             }
 924         }
 925     }
 926
 927     my $digest = Koha::AuthUtils::hash_password($password);
 928
 929     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 930
 931     # We do not want to call $self->store and retrieve password from DB
 932     $self->password($digest);
 933     $self->login_attempts(0);
 934     $self->SUPER::store;
 935
 936     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 937         if C4::Context->preference("BorrowersLog");
 938
 939     return $self;
 940 }
 941
 942
 943 =head3 renew_account
 944
 945 my $new_expiry_date = $patron->renew_account
 946
 947 Extending the subscription to the expiry date.
 948
 949 =cut
 950
 951 sub renew_account {
 952     my ($self) = @_;
 953     my $date;
 954     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 955         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 956     } else {
 957         $date =
 958             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 959             ? dt_from_string( $self->dateexpiry )
 960             : dt_from_string;
 961     }
 962     my $expiry_date = $self->category->get_expiry_date($date);
 963
 964     $self->dateexpiry($expiry_date);
 965     $self->date_renewed( dt_from_string() );
 966     $self->store();
 967
 968     $self->add_enrolment_fee_if_needed(1);
 969
 970     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 971     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 972 }
 973
 974 =head3 has_overdues
 975
 976 my $has_overdues = $patron->has_overdues;
 977
 978 Returns the number of patron's overdues
 979
 980 =cut
 981
 982 sub has_overdues {
 983     my ($self) = @_;
 984     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 985     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 986 }
 987
 988 =head3 track_login
 989
 990     $patron->track_login;
 991     $patron->track_login({ force => 1 });
 992
 993     Tracks a (successful) login attempt.
 994     The preference TrackLastPatronActivity must be enabled. Or you
 995     should pass the force parameter.
 996
 997 =cut
 998
 999 sub track_login {
1000     my ( $self, $params ) = @_;
1001     return if
1002         !$params->{force} &&
1003         !C4::Context->preference('TrackLastPatronActivity');
1004     $self->lastseen( dt_from_string() )->store;
1005 }
1006
1007 =head3 move_to_deleted
1008
1009 my $is_moved = $patron->move_to_deleted;
1010
1011 Move a patron to the deletedborrowers table.
1012 This can be done before deleting a patron, to make sure the data are not completely deleted.
1013
1014 =cut
1015
1016 sub move_to_deleted {
1017     my ($self) = @_;
1018     my $patron_infos = $self->unblessed;
1019     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
1020     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
1021 }
1022
1023 =head3 can_request_article
1024
1025     if ( $patron->can_request_article( $library->id ) ) { ... }
1026
1027 Returns true if the patron can request articles. As limits apply for the patron
1028 on the same day, those completed the same day are considered as current.
1029
1030 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1031
1032 =cut
1033
1034 sub can_request_article {
1035     my ($self, $library_id) = @_;
1036
1037     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1038
1039     my $rule = Koha::CirculationRules->get_effective_rule(
1040         {
1041             branchcode   => $library_id,
1042             categorycode => $self->categorycode,
1043             rule_name    => 'open_article_requests_limit'
1044         }
1045     );
1046
1047     my $limit = ($rule) ? $rule->rule_value : undef;
1048
1049     return 1 unless defined $limit;
1050
1051     my $count = Koha::ArticleRequests->search(
1052         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1053             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1054         ]
1055     )->count;
1056     return $count < $limit ? 1 : 0;
1057 }
1058
1059 =head3 article_request_fee
1060
1061     my $fee = $patron->article_request_fee(
1062         {
1063           [ library_id => $library->id, ]
1064         }
1065     );
1066
1067 Returns the fee to be charged to the patron when it places an article request.
1068
1069 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1070
1071 =cut
1072
1073 sub article_request_fee {
1074     my ($self, $params) = @_;
1075
1076     my $library_id = $params->{library_id};
1077
1078     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1079
1080     my $rule = Koha::CirculationRules->get_effective_rule(
1081         {
1082             branchcode   => $library_id,
1083             categorycode => $self->categorycode,
1084             rule_name    => 'article_request_fee'
1085         }
1086     );
1087
1088     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1089
1090     return $fee;
1091 }
1092
1093 =head3 add_article_request_fee_if_needed
1094
1095     my $fee = $patron->add_article_request_fee_if_needed(
1096         {
1097           [ item_id    => $item->id,
1098             library_id => $library->id, ]
1099         }
1100     );
1101
1102 If an article request fee needs to be charged, it adds a debit to the patron's
1103 account.
1104
1105 Returns the fee line.
1106
1107 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1108
1109 =cut
1110
1111 sub add_article_request_fee_if_needed {
1112     my ($self, $params) = @_;
1113
1114     my $library_id = $params->{library_id};
1115     my $item_id    = $params->{item_id};
1116
1117     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1118
1119     my $amount = $self->article_request_fee(
1120         {
1121             library_id => $library_id,
1122         }
1123     );
1124
1125     my $debit_line;
1126
1127     if ( $amount > 0 ) {
1128         $debit_line = $self->account->add_debit(
1129             {
1130                 amount     => $amount,
1131                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1132                 interface  => C4::Context->interface,
1133                 library_id => $library_id,
1134                 type       => 'ARTICLE_REQUEST',
1135                 item_id    => $item_id,
1136             }
1137         );
1138     }
1139
1140     return $debit_line;
1141 }
1142
1143 =head3 article_requests
1144
1145     my $article_requests = $patron->article_requests;
1146
1147 Returns the patron article requests.
1148
1149 =cut
1150
1151 sub article_requests {
1152     my ($self) = @_;
1153
1154     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1155 }
1156
1157 =head3 add_enrolment_fee_if_needed
1158
1159 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1160
1161 Add enrolment fee for a patron if needed.
1162
1163 $renewal - boolean denoting whether this is an account renewal or not
1164
1165 =cut
1166
1167 sub add_enrolment_fee_if_needed {
1168     my ($self, $renewal) = @_;
1169     my $enrolment_fee = $self->category->enrolmentfee;
1170     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1171         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1172         $self->account->add_debit(
1173             {
1174                 amount     => $enrolment_fee,
1175                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1176                 interface  => C4::Context->interface,
1177                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1178                 type       => $type
1179             }
1180         );
1181     }
1182     return $enrolment_fee || 0;
1183 }
1184
1185 =head3 checkouts
1186
1187 my $checkouts = $patron->checkouts
1188
1189 =cut
1190
1191 sub checkouts {
1192     my ($self) = @_;
1193     my $checkouts = $self->_result->issues;
1194     return Koha::Checkouts->_new_from_dbic( $checkouts );
1195 }
1196
1197 =head3 pending_checkouts
1198
1199 my $pending_checkouts = $patron->pending_checkouts
1200
1201 This method will return the same as $self->checkouts, but with a prefetch on
1202 items, biblio and biblioitems.
1203
1204 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1205
1206 It should not be used directly, prefer to access fields you need instead of
1207 retrieving all these fields in one go.
1208
1209 =cut
1210
1211 sub pending_checkouts {
1212     my( $self ) = @_;
1213     my $checkouts = $self->_result->issues->search(
1214         {},
1215         {
1216             order_by => [
1217                 { -desc => 'me.timestamp' },
1218                 { -desc => 'issuedate' },
1219                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1220             ],
1221             prefetch => { item => { biblio => 'biblioitems' } },
1222         }
1223     );
1224     return Koha::Checkouts->_new_from_dbic( $checkouts );
1225 }
1226
1227 =head3 old_checkouts
1228
1229 my $old_checkouts = $patron->old_checkouts
1230
1231 =cut
1232
1233 sub old_checkouts {
1234     my ($self) = @_;
1235     my $old_checkouts = $self->_result->old_issues;
1236     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1237 }
1238
1239 =head3 overdues
1240
1241 my $overdue_items = $patron->overdues
1242
1243 Return the overdue items
1244
1245 =cut
1246
1247 sub overdues {
1248     my ($self) = @_;
1249     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1250     return $self->checkouts->search(
1251         {
1252             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1253         },
1254         {
1255             prefetch => { item => { biblio => 'biblioitems' } },
1256         }
1257     );
1258 }
1259
1260
1261 =head3 restrictions
1262
1263   my $restrictions = $patron->restrictions;
1264
1265 Returns the patron restrictions.
1266
1267 =cut
1268
1269 sub restrictions {
1270     my ($self) = @_;
1271     my $restrictions_rs = $self->_result->restrictions;
1272     return Koha::Patron::Restrictions->_new_from_dbic($restrictions_rs);
1273 }
1274
1275 =head3 get_routing_lists
1276
1277 my $routinglists = $patron->get_routing_lists
1278
1279 Returns the routing lists a patron is subscribed to.
1280
1281 =cut
1282
1283 sub get_routing_lists {
1284     my ($self) = @_;
1285     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1286     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1287 }
1288
1289 =head3 get_age
1290
1291     my $age = $patron->get_age
1292
1293 Return the age of the patron
1294
1295 =cut
1296
1297 sub get_age {
1298     my ($self)    = @_;
1299
1300     return unless $self->dateofbirth;
1301
1302     my $date_of_birth = dt_from_string( $self->dateofbirth );
1303     my $today         = dt_from_string->truncate( to => 'day' );
1304
1305     return $today->subtract_datetime( $date_of_birth )->years;
1306 }
1307
1308 =head3 is_valid_age
1309
1310 my $is_valid = $patron->is_valid_age
1311
1312 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1313
1314 =cut
1315
1316 sub is_valid_age {
1317     my ($self) = @_;
1318     my $age = $self->get_age;
1319
1320     my $patroncategory = $self->category;
1321     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1322
1323     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1324 }
1325
1326 =head3 account
1327
1328 my $account = $patron->account
1329
1330 =cut
1331
1332 sub account {
1333     my ($self) = @_;
1334     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1335 }
1336
1337 =head3 holds
1338
1339 my $holds = $patron->holds
1340
1341 Return all the holds placed by this patron
1342
1343 =cut
1344
1345 sub holds {
1346     my ($self) = @_;
1347     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1348     return Koha::Holds->_new_from_dbic($holds_rs);
1349 }
1350
1351 =head3 old_holds
1352
1353 my $old_holds = $patron->old_holds
1354
1355 Return all the historical holds for this patron
1356
1357 =cut
1358
1359 sub old_holds {
1360     my ($self) = @_;
1361     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1362     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1363 }
1364
1365 =head3 curbside_pickups
1366
1367 my $curbside_pickups = $patron->curbside_pickups;
1368
1369 Return all the curbside pickups for this patron
1370
1371 =cut
1372
1373 sub curbside_pickups {
1374     my ($self) = @_;
1375     my $curbside_pickups_rs = $self->_result->curbside_pickups_borrowernumbers->search;
1376     return Koha::CurbsidePickups->_new_from_dbic($curbside_pickups_rs);
1377 }
1378
1379 =head3 return_claims
1380
1381 my $return_claims = $patron->return_claims
1382
1383 =cut
1384
1385 sub return_claims {
1386     my ($self) = @_;
1387     my $return_claims = $self->_result->return_claims_borrowernumbers;
1388     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1389 }
1390
1391 =head3 notice_email_address
1392
1393   my $email = $patron->notice_email_address;
1394
1395 Return the email address of patron used for notices.
1396 Returns the empty string if no email address.
1397
1398 =cut
1399
1400 sub notice_email_address{
1401     my ( $self ) = @_;
1402
1403     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1404     # if syspref is set to 'first valid' (value == OFF), look up email address
1405     if ( $which_address eq 'OFF' ) {
1406         return $self->first_valid_email_address;
1407     }
1408
1409     return $self->$which_address || '';
1410 }
1411
1412 =head3 first_valid_email_address
1413
1414 my $first_valid_email_address = $patron->first_valid_email_address
1415
1416 Return the first valid email address for a patron.
1417 For now, the order  is defined as email, emailpro, B_email.
1418 Returns the empty string if the borrower has no email addresses.
1419
1420 =cut
1421
1422 sub first_valid_email_address {
1423     my ($self) = @_;
1424
1425     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1426 }
1427
1428 =head3 get_club_enrollments
1429
1430 =cut
1431
1432 sub get_club_enrollments {
1433     my ( $self ) = @_;
1434
1435     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1436 }
1437
1438 =head3 get_enrollable_clubs
1439
1440 =cut
1441
1442 sub get_enrollable_clubs {
1443     my ( $self, $is_enrollable_from_opac ) = @_;
1444
1445     my $params;
1446     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1447       if $is_enrollable_from_opac;
1448     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1449
1450     $params->{borrower} = $self;
1451
1452     return Koha::Clubs->get_enrollable($params);
1453 }
1454
1455 =head3 account_locked
1456
1457 my $is_locked = $patron->account_locked
1458
1459 Return true if the patron has reached the maximum number of login attempts
1460 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1461 as an administrative lockout (independent of FailedLoginAttempts; see also
1462 Koha::Patron->lock).
1463 Otherwise return false.
1464 If the pref is not set (empty string, null or 0), the feature is considered as
1465 disabled.
1466
1467 =cut
1468
1469 sub account_locked {
1470     my ($self) = @_;
1471     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1472     return 1 if $FailedLoginAttempts
1473           and $self->login_attempts
1474           and $self->login_attempts >= $FailedLoginAttempts;
1475     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1476     return 0;
1477 }
1478
1479 =head3 can_see_patron_infos
1480
1481 my $can_see = $patron->can_see_patron_infos( $patron );
1482
1483 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1484
1485 =cut
1486
1487 sub can_see_patron_infos {
1488     my ( $self, $patron ) = @_;
1489     return unless $patron;
1490     return $self->can_see_patrons_from( $patron->branchcode );
1491 }
1492
1493 =head3 can_see_patrons_from
1494
1495 my $can_see = $patron->can_see_patrons_from( $branchcode );
1496
1497 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1498
1499 =cut
1500
1501 sub can_see_patrons_from {
1502     my ( $self, $branchcode ) = @_;
1503     my $can = 0;
1504     if ( $self->branchcode eq $branchcode ) {
1505         $can = 1;
1506     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1507         $can = 1;
1508     } elsif ( my $library_groups = $self->library->library_groups ) {
1509         while ( my $library_group = $library_groups->next ) {
1510             if ( $library_group->parent->has_child( $branchcode ) ) {
1511                 $can = 1;
1512                 last;
1513             }
1514         }
1515     }
1516     return $can;
1517 }
1518
1519 =head3 can_log_into
1520
1521 my $can_log_into = $patron->can_log_into( $library );
1522
1523 Given a I<Koha::Library> object, it returns a boolean representing
1524 the fact the patron can log into a the library.
1525
1526 =cut
1527
1528 sub can_log_into {
1529     my ( $self, $library ) = @_;
1530
1531     my $can = 0;
1532
1533     if ( C4::Context->preference('IndependentBranches') ) {
1534         $can = 1
1535           if $self->is_superlibrarian
1536           or $self->branchcode eq $library->id;
1537     }
1538     else {
1539         # no restrictions
1540         $can = 1;
1541     }
1542
1543    return $can;
1544 }
1545
1546 =head3 libraries_where_can_see_patrons
1547
1548 my $libraries = $patron-libraries_where_can_see_patrons;
1549
1550 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1551 The branchcodes are arbitrarily returned sorted.
1552 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1553
1554 An empty array means no restriction, the patron can see patron's infos from any libraries.
1555
1556 =cut
1557
1558 sub libraries_where_can_see_patrons {
1559     my ( $self ) = @_;
1560     my $userenv = C4::Context->userenv;
1561
1562     return () unless $userenv; # For tests, but userenv should be defined in tests...
1563
1564     my @restricted_branchcodes;
1565     if (C4::Context::only_my_library) {
1566         push @restricted_branchcodes, $self->branchcode;
1567     }
1568     else {
1569         unless (
1570             $self->has_permission(
1571                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1572             )
1573           )
1574         {
1575             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1576             if ( $library_groups->count )
1577             {
1578                 while ( my $library_group = $library_groups->next ) {
1579                     my $parent = $library_group->parent;
1580                     if ( $parent->has_child( $self->branchcode ) ) {
1581                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1582                     }
1583                 }
1584             }
1585
1586             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1587         }
1588     }
1589
1590     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1591     @restricted_branchcodes = uniq(@restricted_branchcodes);
1592     @restricted_branchcodes = sort(@restricted_branchcodes);
1593     return @restricted_branchcodes;
1594 }
1595
1596 =head3 has_permission
1597
1598 my $permission = $patron->has_permission($required);
1599
1600 See C4::Auth::haspermission for details of syntax for $required
1601
1602 =cut
1603
1604 sub has_permission {
1605     my ( $self, $flagsrequired ) = @_;
1606     return unless $self->userid;
1607     # TODO code from haspermission needs to be moved here!
1608     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1609 }
1610
1611 =head3 is_superlibrarian
1612
1613   my $is_superlibrarian = $patron->is_superlibrarian;
1614
1615 Return true if the patron is a superlibrarian.
1616
1617 =cut
1618
1619 sub is_superlibrarian {
1620     my ($self) = @_;
1621     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1622 }
1623
1624 =head3 is_adult
1625
1626 my $is_adult = $patron->is_adult
1627
1628 Return true if the patron has a category with a type Adult (A) or Organization (I)
1629
1630 =cut
1631
1632 sub is_adult {
1633     my ( $self ) = @_;
1634     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1635 }
1636
1637 =head3 is_child
1638
1639 my $is_child = $patron->is_child
1640
1641 Return true if the patron has a category with a type Child (C)
1642
1643 =cut
1644
1645 sub is_child {
1646     my( $self ) = @_;
1647     return $self->category->category_type eq 'C' ? 1 : 0;
1648 }
1649
1650 =head3 has_valid_userid
1651
1652 my $patron = Koha::Patrons->find(42);
1653 $patron->userid( $new_userid );
1654 my $has_a_valid_userid = $patron->has_valid_userid
1655
1656 my $patron = Koha::Patron->new( $params );
1657 my $has_a_valid_userid = $patron->has_valid_userid
1658
1659 Return true if the current userid of this patron is valid/unique, otherwise false.
1660
1661 Note that this should be done in $self->store instead and raise an exception if needed.
1662
1663 =cut
1664
1665 sub has_valid_userid {
1666     my ($self) = @_;
1667
1668     return 0 unless $self->userid;
1669
1670     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1671
1672     my $already_exists = Koha::Patrons->search(
1673         {
1674             userid => $self->userid,
1675             (
1676                 $self->in_storage
1677                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1678                 : ()
1679             ),
1680         }
1681     )->count;
1682     return $already_exists ? 0 : 1;
1683 }
1684
1685 =head3 generate_userid
1686
1687 my $patron = Koha::Patron->new( $params );
1688 $patron->generate_userid
1689
1690 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1691
1692 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1693
1694 =cut
1695
1696 sub generate_userid {
1697     my ($self) = @_;
1698     my $offset = 0;
1699     my $firstname = $self->firstname // q{};
1700     my $surname = $self->surname // q{};
1701     #The script will "do" the following code and increment the $offset until the generated userid is unique
1702     do {
1703       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1704       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1705       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1706       $userid = NFKD( $userid );
1707       $userid =~ s/\p{NonspacingMark}//g;
1708       $userid .= $offset unless $offset == 0;
1709       $self->userid( $userid );
1710       $offset++;
1711      } while (! $self->has_valid_userid );
1712
1713      return $self;
1714 }
1715
1716 =head3 add_extended_attribute
1717
1718 =cut
1719
1720 sub add_extended_attribute {
1721     my ($self, $attribute) = @_;
1722
1723     return Koha::Patron::Attribute->new(
1724         {
1725             %$attribute,
1726             ( borrowernumber => $self->borrowernumber ),
1727         }
1728     )->store;
1729
1730 }
1731
1732 =head3 extended_attributes
1733
1734 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1735
1736 Or setter FIXME
1737
1738 =cut
1739
1740 sub extended_attributes {
1741     my ( $self, $attributes ) = @_;
1742     if ($attributes) {    # setter
1743         my $schema = $self->_result->result_source->schema;
1744         $schema->txn_do(
1745             sub {
1746                 # Remove the existing one
1747                 $self->extended_attributes->filter_by_branch_limitations->delete;
1748
1749                 # Insert the new ones
1750                 my $new_types = {};
1751                 for my $attribute (@$attributes) {
1752                     $self->add_extended_attribute($attribute);
1753                     $new_types->{$attribute->{code}} = 1;
1754                 }
1755
1756                 # Check globally mandatory types
1757                 my @required_attribute_types =
1758                     Koha::Patron::Attribute::Types->search(
1759                         {
1760                             mandatory => 1,
1761                             category_code => [ undef, $self->categorycode ],
1762                             'borrower_attribute_types_branches.b_branchcode' =>
1763                               undef,
1764                         },
1765                         { join => 'borrower_attribute_types_branches' }
1766                     )->get_column('code');
1767                 for my $type ( @required_attribute_types ) {
1768                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
1769                         type => $type,
1770                     ) if !$new_types->{$type};
1771                 }
1772             }
1773         );
1774     }
1775
1776     my $rs = $self->_result->borrower_attributes;
1777     # We call search to use the filters in Koha::Patron::Attributes->search
1778     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1779 }
1780
1781 =head3 messages
1782
1783     my $messages = $patron->messages;
1784
1785 Return the message attached to the patron.
1786
1787 =cut
1788
1789 sub messages {
1790     my ( $self ) = @_;
1791     my $messages_rs = $self->_result->messages_borrowernumbers->search;
1792     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
1793 }
1794
1795 =head3 lock
1796
1797     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1798
1799     Lock and optionally expire a patron account.
1800     Remove holds and article requests if remove flag set.
1801     In order to distinguish from locking by entering a wrong password, let's
1802     call this an administrative lockout.
1803
1804 =cut
1805
1806 sub lock {
1807     my ( $self, $params ) = @_;
1808     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1809     if( $params->{expire} ) {
1810         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1811     }
1812     $self->store;
1813     if( $params->{remove} ) {
1814         $self->holds->delete;
1815         $self->article_requests->delete;
1816     }
1817     return $self;
1818 }
1819
1820 =head3 anonymize
1821
1822     Koha::Patrons->find($id)->anonymize;
1823
1824     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1825     are randomized, other personal data is cleared too.
1826     Patrons with issues are skipped.
1827
1828 =cut
1829
1830 sub anonymize {
1831     my ( $self ) = @_;
1832     if( $self->_result->issues->count ) {
1833         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1834         return;
1835     }
1836     # Mandatory fields come from the corresponding pref, but email fields
1837     # are removed since scrambled email addresses only generate errors
1838     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1839         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1840     $mandatory->{userid} = 1; # needed since sub store does not clear field
1841     my @columns = $self->_result->result_source->columns;
1842     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
1843     push @columns, 'dateofbirth'; # add this date back in
1844     foreach my $col (@columns) {
1845         $self->_anonymize_column($col, $mandatory->{lc $col} );
1846     }
1847     $self->anonymized(1)->store;
1848 }
1849
1850 sub _anonymize_column {
1851     my ( $self, $col, $mandatory ) = @_;
1852     my $col_info = $self->_result->result_source->column_info($col);
1853     my $type = $col_info->{data_type};
1854     my $nullable = $col_info->{is_nullable};
1855     my $val;
1856     if( $type =~ /char|text/ ) {
1857         $val = $mandatory
1858             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1859             : $nullable
1860             ? undef
1861             : q{};
1862     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1863         $val = $nullable ? undef : 0;
1864     } elsif( $type =~ /date|time/ ) {
1865         $val = $nullable ? undef : dt_from_string;
1866     }
1867     $self->$col($val);
1868 }
1869
1870 =head3 add_guarantor
1871
1872     my $relationship = $patron->add_guarantor(
1873         {
1874             borrowernumber => $borrowernumber,
1875             relationships  => $relationship,
1876         }
1877     );
1878
1879     Adds a new guarantor to a patron.
1880
1881 =cut
1882
1883 sub add_guarantor {
1884     my ( $self, $params ) = @_;
1885
1886     my $guarantor_id = $params->{guarantor_id};
1887     my $relationship = $params->{relationship};
1888
1889     return Koha::Patron::Relationship->new(
1890         {
1891             guarantee_id => $self->id,
1892             guarantor_id => $guarantor_id,
1893             relationship => $relationship
1894         }
1895     )->store();
1896 }
1897
1898 =head3 get_extended_attribute
1899
1900 my $attribute_value = $patron->get_extended_attribute( $code );
1901
1902 Return the attribute for the code passed in parameter.
1903
1904 It not exist it returns undef
1905
1906 Note that this will not work for repeatable attribute types.
1907
1908 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1909 (which should be a real patron's attribute (not extended)
1910
1911 =cut
1912
1913 sub get_extended_attribute {
1914     my ( $self, $code, $value ) = @_;
1915     my $rs = $self->_result->borrower_attributes;
1916     return unless $rs;
1917     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1918     return unless $attribute->count;
1919     return $attribute->next;
1920 }
1921
1922 =head3 to_api
1923
1924     my $json = $patron->to_api;
1925
1926 Overloaded method that returns a JSON representation of the Koha::Patron object,
1927 suitable for API output.
1928
1929 =cut
1930
1931 sub to_api {
1932     my ( $self, $params ) = @_;
1933
1934     my $json_patron = $self->SUPER::to_api( $params );
1935
1936     $json_patron->{restricted} = ( $self->is_debarred )
1937                                     ? Mojo::JSON->true
1938                                     : Mojo::JSON->false;
1939
1940     return $json_patron;
1941 }
1942
1943 =head3 to_api_mapping
1944
1945 This method returns the mapping for representing a Koha::Patron object
1946 on the API.
1947
1948 =cut
1949
1950 sub to_api_mapping {
1951     return {
1952         borrowernotes       => 'staff_notes',
1953         borrowernumber      => 'patron_id',
1954         branchcode          => 'library_id',
1955         categorycode        => 'category_id',
1956         checkprevcheckout   => 'check_previous_checkout',
1957         contactfirstname    => undef,                     # Unused
1958         contactname         => undef,                     # Unused
1959         contactnote         => 'altaddress_notes',
1960         contacttitle        => undef,                     # Unused
1961         dateenrolled        => 'date_enrolled',
1962         dateexpiry          => 'expiry_date',
1963         dateofbirth         => 'date_of_birth',
1964         debarred            => undef,                     # replaced by 'restricted'
1965         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1966         emailpro            => 'secondary_email',
1967         flags               => undef,    # permissions manipulation handled in /permissions
1968         gonenoaddress       => 'incorrect_address',
1969         lastseen            => 'last_seen',
1970         lost                => 'patron_card_lost',
1971         opacnote            => 'opac_notes',
1972         othernames          => 'other_name',
1973         password            => undef,            # password manipulation handled in /password
1974         phonepro            => 'secondary_phone',
1975         relationship        => 'relationship_type',
1976         sex                 => 'gender',
1977         smsalertnumber      => 'sms_number',
1978         sort1               => 'statistics_1',
1979         sort2               => 'statistics_2',
1980         autorenew_checkouts => 'autorenew_checkouts',
1981         streetnumber        => 'street_number',
1982         streettype          => 'street_type',
1983         zipcode             => 'postal_code',
1984         B_address           => 'altaddress_address',
1985         B_address2          => 'altaddress_address2',
1986         B_city              => 'altaddress_city',
1987         B_country           => 'altaddress_country',
1988         B_email             => 'altaddress_email',
1989         B_phone             => 'altaddress_phone',
1990         B_state             => 'altaddress_state',
1991         B_streetnumber      => 'altaddress_street_number',
1992         B_streettype        => 'altaddress_street_type',
1993         B_zipcode           => 'altaddress_postal_code',
1994         altcontactaddress1  => 'altcontact_address',
1995         altcontactaddress2  => 'altcontact_address2',
1996         altcontactaddress3  => 'altcontact_city',
1997         altcontactcountry   => 'altcontact_country',
1998         altcontactfirstname => 'altcontact_firstname',
1999         altcontactphone     => 'altcontact_phone',
2000         altcontactsurname   => 'altcontact_surname',
2001         altcontactstate     => 'altcontact_state',
2002         altcontactzipcode   => 'altcontact_postal_code',
2003         password_expiration_date => undef,
2004         primary_contact_method => undef,
2005         secret              => undef,
2006         auth_method         => undef,
2007     };
2008 }
2009
2010 =head3 queue_notice
2011
2012     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
2013     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
2014     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
2015
2016     Queue messages to a patron. Can pass a message that is part of the message_attributes
2017     table or supply the transport to use.
2018
2019     If passed a message name we retrieve the patrons preferences for transports
2020     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
2021     we have no address/number for sending
2022
2023     $letter_params is a hashref of the values to be passed to GetPreparedLetter
2024
2025     test_mode will only report which notices would be sent, but nothing will be queued
2026
2027 =cut
2028
2029 sub queue_notice {
2030     my ( $self, $params ) = @_;
2031     my $letter_params = $params->{letter_params};
2032     my $test_mode = $params->{test_mode};
2033
2034     return unless $letter_params;
2035     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
2036
2037     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
2038     my $from_email_address = $library->from_email_address;
2039
2040     my @message_transports;
2041     my $letter_code;
2042     $letter_code = $letter_params->{letter_code};
2043     if( $params->{message_name} ){
2044         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
2045                 borrowernumber => $letter_params->{borrowernumber},
2046                 message_name => $params->{message_name}
2047         } );
2048         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
2049         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
2050     } else {
2051         @message_transports = @{$params->{message_transports}};
2052     }
2053     return unless defined $letter_code;
2054     $letter_params->{letter_code} = $letter_code;
2055     my $print_sent = 0;
2056     my %return;
2057     foreach my $mtt (@message_transports){
2058         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2059         # Notice is handled by TalkingTech_itiva_outbound.pl
2060         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2061             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2062             or ( $mtt eq 'phone' and not $self->phone ) )
2063         {
2064             push @{ $return{fallback} }, $mtt;
2065             $mtt = 'print';
2066         }
2067         next if $mtt eq 'print' && $print_sent;
2068         $letter_params->{message_transport_type} = $mtt;
2069         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2070         C4::Letters::EnqueueLetter({
2071             letter => $letter,
2072             borrowernumber => $self->borrowernumber,
2073             from_address   => $from_email_address,
2074             message_transport_type => $mtt
2075         }) unless $test_mode;
2076         push @{$return{sent}}, $mtt;
2077         $print_sent = 1 if $mtt eq 'print';
2078     }
2079     return \%return;
2080 }
2081
2082 =head3 safe_to_delete
2083
2084     my $result = $patron->safe_to_delete;
2085     if ( $result eq 'has_guarantees' ) { ... }
2086     elsif ( $result ) { ... }
2087     else { # cannot delete }
2088
2089 This method tells if the Koha:Patron object can be deleted. Possible return values
2090
2091 =over 4
2092
2093 =item 'ok'
2094
2095 =item 'has_checkouts'
2096
2097 =item 'has_debt'
2098
2099 =item 'has_guarantees'
2100
2101 =item 'is_anonymous_patron'
2102
2103 =back
2104
2105 =cut
2106
2107 sub safe_to_delete {
2108     my ($self) = @_;
2109
2110     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2111
2112     my $error;
2113
2114     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2115         $error = 'is_anonymous_patron';
2116     }
2117     elsif ( $self->checkouts->count ) {
2118         $error = 'has_checkouts';
2119     }
2120     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2121         $error = 'has_debt';
2122     }
2123     elsif ( $self->guarantee_relationships->count ) {
2124         $error = 'has_guarantees';
2125     }
2126
2127     if ( $error ) {
2128         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2129     }
2130
2131     return Koha::Result::Boolean->new(1);
2132 }
2133
2134 =head3 recalls
2135
2136     my $recalls = $patron->recalls;
2137
2138 Return the patron's recalls.
2139
2140 =cut
2141
2142 sub recalls {
2143     my ( $self ) = @_;
2144
2145     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2146 }
2147
2148 =head3 account_balance
2149
2150     my $balance = $patron->account_balance
2151
2152 Return the patron's account balance
2153
2154 =cut
2155
2156 sub account_balance {
2157     my ($self) = @_;
2158     return $self->account->balance;
2159 }
2160
2161 =head3 notify_library_of_registration
2162
2163 $patron->notify_library_of_registration( $email_patron_registrations );
2164
2165 Send patron registration email to library if EmailPatronRegistrations system preference is enabled.
2166
2167 =cut
2168
2169 sub notify_library_of_registration {
2170     my ( $self, $email_patron_registrations ) = @_;
2171
2172     if (
2173         my $letter = C4::Letters::GetPreparedLetter(
2174             module      => 'members',
2175             letter_code => 'OPAC_REG',
2176             branchcode  => $self->branchcode,
2177             lang        => $self->lang || 'default',
2178             tables      => {
2179                 'borrowers' => $self->borrowernumber
2180             },
2181         )
2182     ) {
2183         my $to_address;
2184         if ( $email_patron_registrations eq "BranchEmailAddress" ) {
2185             my $library = Koha::Libraries->find( $self->branchcode );
2186             $to_address = $library->inbound_email_address;
2187         }
2188         elsif ( $email_patron_registrations eq "KohaAdminEmailAddress" ) {
2189             $to_address = C4::Context->preference('ReplytoDefault')
2190             || C4::Context->preference('KohaAdminEmailAddress');
2191         }
2192         else {
2193             $to_address =
2194                 C4::Context->preference('EmailAddressForPatronRegistrations')
2195                 || C4::Context->preference('ReplytoDefault')
2196                 || C4::Context->preference('KohaAdminEmailAddress');
2197         }
2198
2199         my $message_id = C4::Letters::EnqueueLetter(
2200             {
2201                 letter                 => $letter,
2202                 borrowernumber         => $self->borrowernumber,
2203                 to_address             => $to_address,
2204                 message_transport_type => 'email'
2205             }
2206         ) or warn "can't enqueue letter $letter";
2207         if ( $message_id ) {
2208             return 1;
2209         }
2210     }
2211 }
2212
2213 =head3 has_messaging_preference
2214
2215 my $bool = $patron->has_messaging_preference({
2216     message_name => $message_name, # A value from message_attributes.message_name
2217     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2218     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2219 });
2220
2221 =cut
2222
2223 sub has_messaging_preference {
2224     my ( $self, $params ) = @_;
2225
2226     my $message_name           = $params->{message_name};
2227     my $message_transport_type = $params->{message_transport_type};
2228     my $wants_digest           = $params->{wants_digest};
2229
2230     return $self->_result->search_related_rs(
2231         'borrower_message_preferences',
2232         $params,
2233         {
2234             prefetch =>
2235               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2236         }
2237     )->count;
2238 }
2239
2240 =head3 can_patron_change_staff_only_lists
2241
2242 $patron->can_patron_change_staff_only_lists;
2243
2244 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2245 Otherwise, return 0.
2246
2247 =cut
2248
2249 sub can_patron_change_staff_only_lists {
2250     my ( $self, $params ) = @_;
2251     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2252     return 0;
2253 }
2254
2255 =head3 encode_secret
2256
2257   $patron->encode_secret($secret32);
2258
2259 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2260 You still need to call ->store.
2261
2262 =cut
2263
2264 sub encode_secret {
2265     my ( $self, $secret ) = @_;
2266     if( $secret ) {
2267         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2268     }
2269     return $self->secret($secret);
2270 }
2271
2272 =head3 decoded_secret
2273
2274   my $secret32 = $patron->decoded_secret;
2275
2276 Decode the patron secret. We expect to get back a base32 string, but this
2277 is not checked here. Caller of encode_secret is responsible for that.
2278
2279 =cut
2280
2281 sub decoded_secret {
2282     my ( $self ) = @_;
2283     if( $self->secret ) {
2284         return Koha::Encryption->new->decrypt_hex( $self->secret );
2285     }
2286     return $self->secret;
2287 }
2288
2289 =head3 virtualshelves
2290
2291     my $shelves = $patron->virtualshelves;
2292
2293 =cut
2294
2295 sub virtualshelves {
2296     my $self = shift;
2297     return Koha::Virtualshelves->_new_from_dbic( scalar $self->_result->virtualshelves );
2298 }
2299
2300 =head2 Internal methods
2301
2302 =head3 _type
2303
2304 =cut
2305
2306 sub _type {
2307     return 'Borrower';
2308 }
2309
2310 =head1 AUTHORS
2311
2312 Kyle M Hall <kyle@bywatersolutions.com>
2313 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2314 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2315
2316 =cut
2317
2318 1;