Koha/Patrons/Import.pm

   1 package Koha::Patrons::Import;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 3 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 use Modern::Perl;
  19 use Moo;
  20 use namespace::clean;
  21
  22 use Carp;
  23 use Text::CSV;
  24
  25 use C4::Members;
  26 use C4::Members::Attributes qw(:all);
  27 use C4::Members::AttributeTypes;
  28
  29 use Koha::Libraries;
  30 use Koha::Patrons;
  31 use Koha::Patron::Categories;
  32 use Koha::Patron::Debarments;
  33 use Koha::DateUtils;
  34
  35 =head1 NAME
  36
  37 Koha::Patrons::Import - Perl Module containing import_patrons method exported from import_borrowers script.
  38
  39 =head1 SYNOPSIS
  40
  41 use Koha::Patrons::Import;
  42
  43 =head1 DESCRIPTION
  44
  45 This module contains one method for importing patrons in bulk.
  46
  47 =head1 FUNCTIONS
  48
  49 =head2 import_patrons
  50
  51  my $return = Koha::Patrons::Import::import_patrons($params);
  52
  53 Applies various checks and imports patrons in bulk from a csv file.
  54
  55 Further pod documentation needed here.
  56
  57 =cut
  58
  59 has 'today_iso' => ( is => 'ro', lazy => 1,
  60     default => sub { output_pref( { dt => dt_from_string(), dateonly => 1, dateformat => 'iso' } ); }, );
  61
  62 has 'text_csv' => ( is => 'rw', lazy => 1,
  63     default => sub { Text::CSV->new( { binary => 1, } ); },  );
  64
  65 sub import_patrons {
  66     my ($self, $params) = @_;
  67
  68     my $handle = $params->{file};
  69     unless( $handle ) { carp('No file handle passed in!'); return; }
  70
  71     my $matchpoint           = $params->{matchpoint};
  72     my $defaults             = $params->{defaults};
  73     my $ext_preserve         = $params->{preserve_extended_attributes};
  74     my $overwrite_cardnumber = $params->{overwrite_cardnumber};
  75     my $extended             = C4::Context->preference('ExtendedPatronAttributes');
  76     my $set_messaging_prefs  = C4::Context->preference('EnhancedMessagingPreferences');
  77
  78     my @columnkeys = $self->set_column_keys($extended);
  79     my @feedback;
  80     my @errors;
  81
  82     my $imported    = 0;
  83     my $alreadyindb = 0;
  84     my $overwritten = 0;
  85     my $invalid     = 0;
  86     my @imported_borrowers;
  87     my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
  88
  89     # Use header line to construct key to column map
  90     my %csvkeycol;
  91     my $borrowerline = <$handle>;
  92     my @csvcolumns   = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
  93     push(@feedback, { feedback => 1, name => 'headerrow', value => join( ', ', @csvcolumns ) });
  94
  95     my @criticals = qw( surname );    # there probably should be others - rm branchcode && categorycode
  96   LINE: while ( my $borrowerline = <$handle> ) {
  97         my $line_number = $.;
  98         my %borrower;
  99         my @missing_criticals;
 100
 101         my $status  = $self->text_csv->parse($borrowerline);
 102         my @columns = $self->text_csv->fields();
 103         if ( !$status ) {
 104             push @missing_criticals, { badparse => 1, line => $line_number, lineraw => $borrowerline };
 105         }
 106         elsif ( @columns == @columnkeys ) {
 107             @borrower{@columnkeys} = @columns;
 108
 109             # MJR: try to fill blanks gracefully by using default values
 110             foreach my $key (@columnkeys) {
 111                 if ( $borrower{$key} !~ /\S/ ) {
 112                     $borrower{$key} = $defaults->{$key};
 113                 }
 114             }
 115         }
 116         else {
 117             # MJR: try to recover gracefully by using default values
 118             foreach my $key (@columnkeys) {
 119                 if ( defined( $csvkeycol{$key} ) and $columns[ $csvkeycol{$key} ] =~ /\S/ ) {
 120                     $borrower{$key} = $columns[ $csvkeycol{$key} ];
 121                 }
 122                 elsif ( $defaults->{$key} ) {
 123                     $borrower{$key} = $defaults->{$key};
 124                 }
 125                 elsif ( scalar grep { $key eq $_ } @criticals ) {
 126
 127                     # a critical field is undefined
 128                     push @missing_criticals, { key => $key, line => $., lineraw => $borrowerline };
 129                 }
 130                 else {
 131                     $borrower{$key} = '';
 132                 }
 133             }
 134         }
 135
 136         # Check if borrower category code exists and if it matches to a known category. Pushing error to missing_criticals otherwise.
 137         $self->check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 138
 139         # Check if branch code exists and if it matches to a branch name. Pushing error to missing_criticals otherwise.
 140         $self->check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 141
 142         # Popular spreadsheet applications make it difficult to force date outputs to be zero-padded, but we require it.
 143         $self->format_dates({borrower => \%borrower, lineraw => $borrowerline, line => $line_number, missing_criticals => \@missing_criticals, });
 144
 145         if (@missing_criticals) {
 146             foreach (@missing_criticals) {
 147                 $_->{borrowernumber} = $borrower{borrowernumber} || 'UNDEF';
 148                 $_->{surname}        = $borrower{surname}        || 'UNDEF';
 149             }
 150             $invalid++;
 151             ( 25 > scalar @errors ) and push @errors, { missing_criticals => \@missing_criticals };
 152
 153             # The first 25 errors are enough.  Keeping track of 30,000+ would destroy performance.
 154             next LINE;
 155         }
 156
 157         # Set patron attributes if extended.
 158         my $patron_attributes = $self->set_patron_attributes($extended, $borrower{patron_attributes}, \@feedback);
 159         if( $extended ) { delete $borrower{patron_attributes}; } # Not really a field in borrowers.
 160
 161         # Default date enrolled and date expiry if not already set.
 162         $borrower{dateenrolled} = $self->today_iso() unless $borrower{dateenrolled};
 163         $borrower{dateexpiry} = Koha::Patron::Categories->find( $borrower{categorycode} )->get_expiry_date( $borrower{dateenrolled} ) unless $borrower{dateexpiry};
 164
 165         my $borrowernumber;
 166         my ( $member, $patron );
 167         if ( defined($matchpoint) && ( $matchpoint eq 'cardnumber' ) && ( $borrower{'cardnumber'} ) ) {
 168             $patron = Koha::Patrons->find( { cardnumber => $borrower{'cardnumber'} } );
 169         }
 170         elsif ( defined($matchpoint) && ($matchpoint eq 'userid') && ($borrower{'userid'}) ) {
 171             $patron = Koha::Patrons->find( { userid => $borrower{userid} } );
 172         }
 173         elsif ($extended) {
 174             if ( defined($matchpoint_attr_type) ) {
 175                 foreach my $attr (@$patron_attributes) {
 176                     if ( $attr->{code} eq $matchpoint and $attr->{value} ne '' ) {
 177                         my @borrowernumbers = $matchpoint_attr_type->get_patrons( $attr->{value} );
 178                         $borrowernumber = $borrowernumbers[0] if scalar(@borrowernumbers) == 1;
 179                         last;
 180                     }
 181                 }
 182             }
 183         }
 184
 185         if ($patron) {
 186             $member = $patron->unblessed;
 187             $borrowernumber = $member->{'borrowernumber'};
 188         } else {
 189             $member = {};
 190         }
 191
 192         if ( C4::Members::checkcardnumber( $borrower{cardnumber}, $borrowernumber ) ) {
 193             push @errors,
 194               {
 195                 invalid_cardnumber => 1,
 196                 borrowernumber     => $borrowernumber,
 197                 cardnumber         => $borrower{cardnumber}
 198               };
 199             $invalid++;
 200             next;
 201         }
 202
 203
 204         # Check if the userid provided does not exist yet
 205         if (    defined($matchpoint)
 206             and $matchpoint ne 'userid'
 207             and exists $borrower{userid}
 208             and $borrower{userid}
 209             and not Koha::Patron->new( { userid => $borrower{userid} } )->has_valid_userid
 210         ) {
 211             push @errors, { duplicate_userid => 1, userid => $borrower{userid} };
 212             $invalid++;
 213             next LINE;
 214         }
 215
 216         if ($borrowernumber) {
 217
 218             # borrower exists
 219             unless ($overwrite_cardnumber) {
 220                 $alreadyindb++;
 221                 push(
 222                     @feedback,
 223                     {
 224                         already_in_db => 1,
 225                         value         => $borrower{'surname'} . ' / ' . $borrowernumber
 226                     }
 227                 );
 228                 next LINE;
 229             }
 230             $borrower{'borrowernumber'} = $borrowernumber;
 231             for my $col ( keys %borrower ) {
 232
 233                 # use values from extant patron unless our csv file includes this column or we provided a default.
 234                 # FIXME : You cannot update a field with a  perl-evaluated false value using the defaults.
 235
 236                 # The password is always encrypted, skip it!
 237                 next if $col eq 'password';
 238
 239                 unless ( exists( $csvkeycol{$col} ) || $defaults->{$col} ) {
 240                     $borrower{$col} = $member->{$col} if ( $member->{$col} );
 241                 }
 242             }
 243
 244             unless ( ModMember(%borrower) ) {
 245                 $invalid++;
 246
 247                 push(
 248                     @errors,
 249                     {
 250                         name  => 'lastinvalid',
 251                         value => $borrower{'surname'} . ' / ' . $borrowernumber
 252                     }
 253                 );
 254                 next LINE;
 255             }
 256             # Don't add a new restriction if the existing 'combined' restriction matches this one
 257             if ( $borrower{debarred} && ( ( $borrower{debarred} ne $member->{debarred} ) || ( $borrower{debarredcomment} ne $member->{debarredcomment} ) ) ) {
 258
 259                 # Check to see if this debarment already exists
 260                 my $debarrments = GetDebarments(
 261                     {
 262                         borrowernumber => $borrowernumber,
 263                         expiration     => $borrower{debarred},
 264                         comment        => $borrower{debarredcomment}
 265                     }
 266                 );
 267
 268                 # If it doesn't, then add it!
 269                 unless (@$debarrments) {
 270                     AddDebarment(
 271                         {
 272                             borrowernumber => $borrowernumber,
 273                             expiration     => $borrower{debarred},
 274                             comment        => $borrower{debarredcomment}
 275                         }
 276                     );
 277                 }
 278             }
 279             if ($extended) {
 280                 if ($ext_preserve) {
 281                     my $old_attributes = GetBorrowerAttributes($borrowernumber);
 282                     $patron_attributes = extended_attributes_merge( $old_attributes, $patron_attributes );
 283                 }
 284                 push @errors, { unknown_error => 1 }
 285                   unless SetBorrowerAttributes( $borrower{'borrowernumber'}, $patron_attributes, 'no_branch_limit' );
 286             }
 287             $overwritten++;
 288             push(
 289                 @feedback,
 290                 {
 291                     feedback => 1,
 292                     name     => 'lastoverwritten',
 293                     value    => $borrower{'surname'} . ' / ' . $borrowernumber
 294                 }
 295             );
 296         }
 297         else {
 298             my $patron = eval {
 299                 Koha::Patron->new(\%borrower)->store;
 300             };
 301             unless ( $@ ) {
 302
 303                 if ( $patron->is_debarred ) {
 304                     AddDebarment(
 305                         {
 306                             borrowernumber => $patron->borrowernumber,
 307                             expiration     => $patron->debarred,
 308                             comment        => $patron->debarredcomment,
 309                         }
 310                     );
 311                 }
 312
 313                 if ($extended) {
 314                     SetBorrowerAttributes( $patron->borrowernumber, $patron_attributes );
 315                 }
 316
 317                 if ($set_messaging_prefs) {
 318                     C4::Members::Messaging::SetMessagingPreferencesFromDefaults(
 319                         {
 320                             borrowernumber => $patron->borrowernumber,
 321                             categorycode   => $patron->categorycode,
 322                         }
 323                     );
 324                 }
 325
 326                 $imported++;
 327                 push @imported_borrowers, $patron->borrowernumber; #for patronlist
 328                 push(
 329                     @feedback,
 330                     {
 331                         feedback => 1,
 332                         name     => 'lastimported',
 333                         value    => $patron->surname . ' / ' . $patron->borrowernumber,
 334                     }
 335                 );
 336             }
 337             else {
 338                 $invalid++;
 339                 push @errors, { unknown_error => 1 };
 340                 push(
 341                     @errors,
 342                     {
 343                         name  => 'lastinvalid',
 344                         value => $borrower{'surname'} . ' / Create patron',
 345                     }
 346                 );
 347             }
 348         }
 349     }
 350
 351     return {
 352         feedback      => \@feedback,
 353         errors        => \@errors,
 354         imported      => $imported,
 355         overwritten   => $overwritten,
 356         already_in_db => $alreadyindb,
 357         invalid       => $invalid,
 358         imported_borrowers => \@imported_borrowers,
 359     };
 360 }
 361
 362 =head2 prepare_columns
 363
 364  my @csvcolumns = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
 365
 366 Returns an array of all column key and populates a hash of colunm key positions.
 367
 368 =cut
 369
 370 sub prepare_columns {
 371     my ($self, $params) = @_;
 372
 373     my $status = $self->text_csv->parse($params->{headerrow});
 374     unless( $status ) {
 375         push( @{$params->{errors}}, { badheader => 1, line => 1, lineraw => $params->{headerrow} });
 376         return;
 377     }
 378
 379     my @csvcolumns = $self->text_csv->fields();
 380     my $col = 0;
 381     foreach my $keycol (@csvcolumns) {
 382         # columnkeys don't contain whitespace, but some stupid tools add it
 383         $keycol =~ s/ +//g;
 384         $params->{keycol}->{$keycol} = $col++;
 385     }
 386
 387     return @csvcolumns;
 388 }
 389
 390 =head2 set_attribute_types
 391
 392  my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
 393
 394 Returns an attribute type based on matchpoint parameter.
 395
 396 =cut
 397
 398 sub set_attribute_types {
 399     my ($self, $params) = @_;
 400
 401     my $attribute_types;
 402     if( $params->{extended} ) {
 403         $attribute_types = C4::Members::AttributeTypes->fetch($params->{matchpoint});
 404     }
 405
 406     return $attribute_types;
 407 }
 408
 409 =head2 set_column_keys
 410
 411  my @columnkeys = set_column_keys($extended);
 412
 413 Returns an array of borrowers' table columns.
 414
 415 =cut
 416
 417 sub set_column_keys {
 418     my ($self, $extended) = @_;
 419
 420     my @columnkeys = map { $_ ne 'borrowernumber' ? $_ : () } Koha::Patrons->columns();
 421     push( @columnkeys, 'patron_attributes' ) if $extended;
 422
 423     return @columnkeys;
 424 }
 425
 426 =head2 set_patron_attributes
 427
 428  my $patron_attributes = set_patron_attributes($extended, $borrower{patron_attributes}, $feedback);
 429
 430 Returns a reference to array of hashrefs data structure as expected by SetBorrowerAttributes.
 431
 432 =cut
 433
 434 sub set_patron_attributes {
 435     my ($self, $extended, $patron_attributes, $feedback) = @_;
 436
 437     unless( $extended ) { return; }
 438     unless( defined($patron_attributes) ) { return; }
 439
 440     # Fixup double quotes in case we are passed smart quotes
 441     $patron_attributes =~ s/\xe2\x80\x9c/"/g;
 442     $patron_attributes =~ s/\xe2\x80\x9d/"/g;
 443
 444     push (@$feedback, { feedback => 1, name => 'attribute string', value => $patron_attributes });
 445
 446     my $result = extended_attributes_code_value_arrayref($patron_attributes);
 447
 448     return $result;
 449 }
 450
 451 =head2 check_branch_code
 452
 453  check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 454
 455 Pushes a 'missing_criticals' error entry if no branch code or branch code does not map to a branch name.
 456
 457 =cut
 458
 459 sub check_branch_code {
 460     my ($self, $branchcode, $borrowerline, $line_number, $missing_criticals) = @_;
 461
 462     # No branch code
 463     unless( $branchcode ) {
 464         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => $borrowerline, });
 465         return;
 466     }
 467
 468     # look for branch code
 469     my $library = Koha::Libraries->find( $branchcode );
 470     unless( $library ) {
 471         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => $borrowerline,
 472                                      value => $branchcode, branch_map => 1, });
 473     }
 474 }
 475
 476 =head2 check_borrower_category
 477
 478  check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 479
 480 Pushes a 'missing_criticals' error entry if no category code or category code does not map to a known category.
 481
 482 =cut
 483
 484 sub check_borrower_category {
 485     my ($self, $categorycode, $borrowerline, $line_number, $missing_criticals) = @_;
 486
 487     # No branch code
 488     unless( $categorycode ) {
 489         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => $borrowerline, });
 490         return;
 491     }
 492
 493     # Looking for borrower category
 494     my $category = Koha::Patron::Categories->find($categorycode);
 495     unless( $category ) {
 496         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => $borrowerline,
 497                                      value => $categorycode, category_map => 1, });
 498     }
 499 }
 500
 501 =head2 format_dates
 502
 503  format_dates({borrower => \%borrower, lineraw => $lineraw, line => $line_number, missing_criticals => \@missing_criticals, });
 504
 505 Pushes a 'missing_criticals' error entry for each of the 3 date types dateofbirth, dateenrolled and dateexpiry if it can not
 506 be formatted to the chosen date format. Populates the correctly formatted date otherwise.
 507
 508 =cut
 509
 510 sub format_dates {
 511     my ($self, $params) = @_;
 512
 513     foreach my $date_type (qw(dateofbirth dateenrolled dateexpiry)) {
 514         my $tempdate = $params->{borrower}->{$date_type} or next();
 515         my $formatted_date = eval { output_pref( { dt => dt_from_string( $tempdate ), dateonly => 1, dateformat => 'iso' } ); };
 516
 517         if ($formatted_date) {
 518             $params->{borrower}->{$date_type} = $formatted_date;
 519         } else {
 520             $params->{borrower}->{$date_type} = '';
 521             push (@{$params->{missing_criticals}}, { key => $date_type, line => $params->{line}, lineraw => $params->{lineraw}, bad_date => 1 });
 522         }
 523     }
 524 }
 525
 526 1;
 527
 528 =head1 AUTHOR
 529
 530 Koha Team
 531
 532 =cut