Koha/Plugins.pm

   1 package Koha::Plugins;
   2
   3 # Copyright 2012 Kyle Hall
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Array::Utils qw( array_minus );
  23 use Class::Inspector;
  24 use List::MoreUtils qw( any );
  25 use Module::Load::Conditional qw( can_load );
  26 use Module::Load;
  27 use Module::Pluggable search_path => ['Koha::Plugin'], except => qr/::Edifact(|::Line|::Message|::Order|::Segment|::Transport)$/;
  28 use Try::Tiny;
  29
  30 use C4::Context;
  31 use C4::Output;
  32
  33 use Koha::Cache::Memory::Lite;
  34 use Koha::Exceptions::Plugin;
  35 use Koha::Plugins::Methods;
  36
  37 use constant ENABLED_PLUGINS_CACHE_KEY => 'enabled_plugins';
  38
  39 BEGIN {
  40     my $pluginsdir = C4::Context->config("pluginsdir");
  41     my @pluginsdir = ref($pluginsdir) eq 'ARRAY' ? @$pluginsdir : $pluginsdir;
  42     push @INC, array_minus(@pluginsdir, @INC) ;
  43     pop @INC if $INC[-1] eq '.';
  44 }
  45
  46 =head1 NAME
  47
  48 Koha::Plugins - Module for loading and managing plugins.
  49
  50 =head2 new
  51
  52 Constructor
  53
  54 =cut
  55
  56 sub new {
  57     my ( $class, $args ) = @_;
  58
  59     return unless ( C4::Context->config("enable_plugins") || $args->{'enable_plugins'} );
  60
  61     $args->{'pluginsdir'} = C4::Context->config("pluginsdir");
  62
  63     return bless( $args, $class );
  64 }
  65
  66 =head2 call
  67
  68 Calls a plugin method for all enabled plugins
  69
  70     @responses = Koha::Plugins->call($method, @args)
  71
  72 Note: Pass your arguments as refs, when you want subsequent plugins to use the value
  73 updated by preceding plugins, provided that these plugins support that.
  74
  75 =cut
  76
  77 sub call {
  78     my ($class, $method, @args) = @_;
  79
  80     return unless C4::Context->config('enable_plugins');
  81
  82     my @responses;
  83     my @plugins = $class->get_enabled_plugins();
  84     @plugins = grep { $_->can($method) } @plugins;
  85
  86     # TODO: Remove warn when after_hold_create is removed from the codebase
  87     warn "after_hold_create is deprecated and will be removed soon. Contact the following plugin's authors: " . join( ', ', map {$_->{metadata}->{name}} @plugins)
  88         if $method eq 'after_hold_create' and @plugins;
  89
  90     foreach my $plugin (@plugins) {
  91         my $response = eval { $plugin->$method(@args) };
  92         if ($@) {
  93             warn sprintf("Plugin error (%s): %s", $plugin->get_metadata->{name}, $@);
  94             next;
  95         }
  96
  97         push @responses, $response;
  98     }
  99
 100     return @responses;
 101 }
 102
 103 =head2 get_enabled_plugins
 104
 105 Returns a list of enabled plugins.
 106
 107     @plugins = Koha::Plugins->get_enabled_plugins();
 108
 109 =cut
 110
 111 sub get_enabled_plugins {
 112     my ($class) = @_;
 113
 114     return unless C4::Context->config('enable_plugins');
 115
 116     my $enabled_plugins = Koha::Cache::Memory::Lite->get_from_cache(ENABLED_PLUGINS_CACHE_KEY);
 117     unless ($enabled_plugins) {
 118         $enabled_plugins = [];
 119         my $rs = Koha::Database->schema->resultset('PluginData');
 120         $rs = $rs->search({ plugin_key => '__ENABLED__', plugin_value => 1 });
 121         my @plugin_classes = $rs->get_column('plugin_class')->all();
 122         foreach my $plugin_class (@plugin_classes) {
 123             unless (can_load(modules => { $plugin_class => undef }, nocache => 1)) {
 124                 warn "Failed to load $plugin_class: $Module::Load::Conditional::ERROR";
 125                 next;
 126             }
 127
 128             my $plugin = eval { $plugin_class->new() };
 129             if ($@ || !$plugin) {
 130                 warn "Failed to instantiate plugin $plugin_class: $@";
 131                 next;
 132             }
 133
 134             push @$enabled_plugins, $plugin;
 135         }
 136         Koha::Cache::Memory::Lite->set_in_cache(ENABLED_PLUGINS_CACHE_KEY, $enabled_plugins);
 137     }
 138
 139     return @$enabled_plugins;
 140 }
 141
 142 =head2 GetPlugins
 143
 144 This will return a list of all available plugins, optionally limited by
 145 method or metadata value.
 146
 147     my @plugins = Koha::Plugins::GetPlugins({
 148         method => 'some_method',
 149         metadata => { some_key => 'some_value' },
 150     });
 151
 152 The method and metadata parameters are optional.
 153 If you pass multiple keys in the metadata hash, all keys must match.
 154
 155 =cut
 156
 157 sub GetPlugins {
 158     my ( $self, $params ) = @_;
 159
 160     my $method       = $params->{method};
 161     my $req_metadata = $params->{metadata} // {};
 162
 163     my $filter = ( $method ) ? { plugin_method => $method } : undef;
 164
 165     my $plugin_classes = Koha::Plugins::Methods->search(
 166         $filter,
 167         {   columns  => 'plugin_class',
 168             distinct => 1
 169         }
 170     )->_resultset->get_column('plugin_class');
 171
 172     my @plugins;
 173
 174     # Loop through all plugins that implement at least a method
 175     while ( my $plugin_class = $plugin_classes->next ) {
 176
 177         if ( can_load( modules => { $plugin_class => undef }, nocache => 1 ) ) {
 178
 179             my $plugin;
 180             my $failed_instantiation;
 181
 182             try {
 183                 $plugin = $plugin_class->new({
 184                     enable_plugins => $self->{'enable_plugins'}
 185                         # loads even if plugins are disabled
 186                         # FIXME: is this for testing without bothering to mock config?
 187                 });
 188             }
 189             catch {
 190                 warn "$_";
 191                 $failed_instantiation = 1;
 192             };
 193
 194             next if $failed_instantiation;
 195
 196             next unless $plugin->is_enabled or
 197                         defined($params->{all}) && $params->{all};
 198
 199             # filter the plugin out by metadata
 200             my $plugin_metadata = $plugin->get_metadata;
 201             next
 202                 if $plugin_metadata
 203                 and %$req_metadata
 204                 and any { !$plugin_metadata->{$_} || $plugin_metadata->{$_} ne $req_metadata->{$_} } keys %$req_metadata;
 205
 206             push @plugins, $plugin;
 207         } elsif ( defined($params->{errors}) && $params->{errors} ){
 208             push @plugins, { error => 'cannot_load', name => $plugin_class };
 209         }
 210
 211     }
 212
 213     return @plugins;
 214 }
 215
 216 =head2 InstallPlugins
 217
 218 Koha::Plugins::InstallPlugins()
 219
 220 This method iterates through all plugins physically present on a system.
 221 For each plugin module found, it will test that the plugin can be loaded,
 222 and if it can, will store its available methods in the plugin_methods table.
 223
 224 NOTE: We reload all plugins here as a protective measure in case someone
 225 has removed a plugin directly from the system without using the UI
 226
 227 =cut
 228
 229 sub InstallPlugins {
 230     my ( $self, $params ) = @_;
 231
 232     my @plugin_classes = $self->plugins();
 233     my @plugins;
 234
 235     foreach my $plugin_class (@plugin_classes) {
 236         if ( can_load( modules => { $plugin_class => undef }, nocache => 1 ) ) {
 237             next unless $plugin_class->isa('Koha::Plugins::Base');
 238
 239             my $plugin;
 240             my $failed_instantiation;
 241
 242             try {
 243                 $plugin = $plugin_class->new({ enable_plugins => $self->{'enable_plugins'} });
 244             }
 245             catch {
 246                 warn "$_";
 247                 $failed_instantiation = 1;
 248             };
 249
 250             next if $failed_instantiation;
 251
 252             Koha::Plugins::Methods->search({ plugin_class => $plugin_class })->delete();
 253
 254             foreach my $method ( @{ Class::Inspector->methods( $plugin_class, 'public' ) } ) {
 255                 Koha::Plugins::Method->new(
 256                     {
 257                         plugin_class  => $plugin_class,
 258                         plugin_method => $method,
 259                     }
 260                 )->store();
 261             }
 262
 263             push @plugins, $plugin;
 264         } else {
 265             my $error = $Module::Load::Conditional::ERROR;
 266             # Do not warn the error if the plugin has been uninstalled
 267             warn $error unless $error =~ m|^Could not find or check module '$plugin_class'|;
 268         }
 269     }
 270
 271     Koha::Cache::Memory::Lite->clear_from_cache(ENABLED_PLUGINS_CACHE_KEY);
 272
 273     return @plugins;
 274 }
 275
 276 1;
 277 __END__
 278
 279 =head1 AUTHOR
 280
 281 Kyle M Hall <kyle.m.hall@gmail.com>
 282
 283 =cut