Koha/RecordProcessor.pm

   1 package Koha::RecordProcessor;
   2
   3 # Copyright 2012 C & P Bibliography Services
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 Koha::RecordProcessor - Dispatcher class for record normalization
  23
  24 =head1 SYNOPSIS
  25
  26   use Koha::RecordProcessor;
  27   my $normalizer = Koha::RecordProcessor(%params);
  28   $normalizer->process($record)
  29
  30 =head1 DESCRIPTION
  31
  32 Dispatcher class for record normalization. RecordProcessors must
  33 extend Koha::RecordProcessor::Base, be in the Koha::Filter namespace,
  34 and provide the following methods:
  35
  36 B<filter ($record)> - apply the filter and return the result. $record
  37 may be either a scalar or an arrayref, and the return result will be
  38 the same type.
  39
  40 These methods may be overriden:
  41
  42 B<initialize (%params)> - initialize the filter
  43
  44 B<destroy ()> - destroy the filter
  45
  46 These methods should not be overridden unless you are very sure of what
  47 you are doing:
  48
  49 B<new ()> - create a new filter object
  50
  51 Note that the RecordProcessor will not clone the record that is
  52 passed in. If you do not want to change the original MARC::Record
  53 object (or whatever type of object you are passing in), you must
  54 clone it I<prior> to passing it off to the RecordProcessor.
  55
  56 =head1 FUNCTIONS
  57
  58 =cut
  59
  60 use Modern::Perl;
  61
  62 use Module::Load::Conditional qw(can_load);
  63 use Module::Pluggable::Object;
  64
  65 use base qw(Class::Accessor);
  66
  67 __PACKAGE__->mk_accessors(qw( schema filters options record ));
  68
  69 =head2 new
  70
  71     my $normalizer = Koha::RecordProcessor->new(%params);
  72
  73 Create a new normalizer. Available parameters are:
  74
  75 =over 8
  76
  77 =item B<schema>
  78
  79 Which metadata schema is in use. At the moment the only supported schema
  80 is 'MARC'.
  81
  82 =item B<filters>
  83
  84 What filter(s) to use. This must be an arrayref to a list of filters. Filters
  85 can be specified either with a complete class path, or, if they are in the
  86 Koha::Filter::${schema} namespace, as only the filter name, and
  87 "Koha::Filter::${schema}" will be prepended to it before the filter is loaded.
  88
  89 =back
  90
  91 =cut
  92 sub new {
  93
  94     my $class = shift;
  95     my $param = shift;
  96
  97
  98     my $schema  = $param->{schema}  || 'MARC';
  99     my $options = $param->{options} || '';
 100
 101     my $req_filters = ( ref($param->{filters}) ne 'ARRAY' )
 102                         ? [ $param->{filters} ]
 103                         :   $param->{filters};
 104     my @filters = ( );
 105
 106     foreach my $filter_name (@{ $req_filters }) {
 107         next unless $filter_name;
 108         # Fully qualify the module name.
 109         my $filter_module = $filter_name =~ m/:/ ? $filter_name : "Koha::Filter::${schema}::${filter_name}";
 110         if (can_load( modules => { $filter_module => undef } )) {
 111             my $filter = $filter_module->new();
 112             $filter->initialize($param);
 113             push @filters, $filter;
 114         }
 115     }
 116
 117     my $self = $class->SUPER::new( { schema => $schema,
 118                                      filters => \@filters,
 119                                      options => $options });
 120     bless $self, $class;
 121     return $self;
 122 }
 123
 124 =head2 bind
 125
 126     $normalizer->bind($record)
 127
 128 Bind a normalizer to a particular record.
 129
 130 =cut
 131 sub bind {
 132     my $self = shift;
 133     my $record = shift;
 134
 135     $self->{record} = $record;
 136     return;
 137 }
 138
 139 =head2 process
 140
 141     my $newrecord = $normalizer->process([$record])
 142
 143 Run the record(s) through the normalization pipeline. If $record is
 144 not specified, process the record the normalizer is bound to.
 145 Note that $record may be either a scalar or an arrayref, and the
 146 return value will be of the same type.
 147
 148 =cut
 149 sub process {
 150     my $self = shift;
 151     my $record = shift || $self->record;
 152
 153     return unless defined $record;
 154
 155     foreach my $filterobj (@{$self->filters}) {
 156         next unless $filterobj;
 157         $filterobj->filter($record);
 158     }
 159
 160     return $record;
 161 }
 162
 163 sub DESTROY {
 164     my $self = shift;
 165
 166     foreach my $filterobj (@{$self->filters}) {
 167         $filterobj->destroy();
 168     }
 169 }
 170
 171 =head2 AvailableFilters
 172
 173     my @available_filters = Koha::RecordProcessor::AvailableFilters([$schema]);
 174
 175 Get a list of available filters. Optionally specify the metadata schema.
 176 At present only MARC is supported as a schema.
 177
 178 =cut
 179 sub AvailableFilters {
 180     my $schema = pop || '';
 181     my $path = 'Koha::Filter';
 182     $path .= "::$schema" if ($schema eq 'MARC');
 183     my $finder = Module::Pluggable::Object->new(search_path => $path);
 184     return $finder->plugins;
 185 }
 186
 187 1;