Koha/Virtualshelves.pm

   1 package Koha::Virtualshelves;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 3 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 use Modern::Perl;
  19
  20 use Carp;
  21
  22 use Koha::Database;
  23
  24 use Koha::Virtualshelf;
  25
  26 use base qw(Koha::Objects);
  27
  28 =head1 NAME
  29
  30 Koha::Virtualshelf - Koha Virtualshelf Object class
  31
  32 =head1 API
  33
  34 =head2 Class Methods
  35
  36 =cut
  37
  38 =head3 type
  39
  40 =cut
  41
  42 sub get_private_shelves {
  43     my ( $self, $params ) = @_;
  44     my $page = $params->{page};
  45     my $rows = $params->{rows};
  46     my $borrowernumber = $params->{borrowernumber} || 0;
  47
  48     $self->search(
  49         {
  50             category => 1,
  51             -or => {
  52                 'virtualshelfshares.borrowernumber' => $borrowernumber,
  53                 'me.owner' => $borrowernumber,
  54             }
  55         },
  56         {
  57             join => [ 'virtualshelfshares' ],
  58             group_by => 'shelfnumber',
  59             order_by => 'shelfname',
  60             ( ( $page and $rows ) ? ( page => $page, rows => $rows ) : () ),
  61         }
  62     );
  63 }
  64
  65
  66 sub get_public_shelves {
  67     my ( $self, $params ) = @_;
  68     my $page = $params->{page};
  69     my $rows = $params->{rows};
  70
  71     $self->search(
  72         {
  73             category => 2,
  74         },
  75         {
  76             group_by => 'shelfnumber',
  77             order_by => 'shelfname',
  78             ( ( $page and $rows ) ? ( page => $page, rows => $rows ) : () ),
  79         }
  80     );
  81 }
  82
  83 sub get_some_shelves {
  84     my ( $self, $params ) = @_;
  85     my $borrowernumber = $params->{borrowernumber} || 0;
  86     my $category = $params->{category} || 1;
  87     my $add_allowed = $params->{add_allowed};
  88
  89     my @conditions;
  90     if ( $add_allowed ) {
  91         push @conditions, {
  92             -or =>
  93             {
  94                 "me.allow_add" => 1,
  95                 "me.owner" => $borrowernumber,
  96             }
  97         };
  98     }
  99     if ( $category == 1 ) {
 100         push @conditions, {
 101             -or =>
 102             {
 103                 "virtualshelfshares.borrowernumber" => $borrowernumber,
 104                 "me.owner" => $borrowernumber,
 105             }
 106         };
 107     }
 108
 109     $self->search(
 110         {
 111             category => $category,
 112             ( @conditions ? ( -and => \@conditions ) : () ),
 113         },
 114         {
 115             join => [ 'virtualshelfshares' ],
 116             group_by => 'shelfnumber',
 117             order_by => { -desc => 'lastmodified' },
 118         }
 119     );
 120 }
 121
 122 sub get_shelves_containing_record {
 123     my ( $self, $params ) = @_;
 124     my $borrowernumber = $params->{borrowernumber};
 125     my $biblionumber   = $params->{biblionumber};
 126
 127     my @conditions = ( 'virtualshelfcontents.biblionumber' => $biblionumber );
 128     if ($borrowernumber) {
 129         push @conditions,
 130           {
 131               -or => [
 132                 {
 133                     category => 1,
 134                     -or      => {
 135                         'me.owner' => $borrowernumber,
 136                         -or        => {
 137                             'virtualshelfshares.borrowernumber' => $borrowernumber,
 138                             "me.allow_add"                      => 1,
 139                         },
 140                     }
 141                 },
 142                 { category => 2 },
 143             ]
 144           };
 145     } else {
 146         push @conditions, { category => 2 };
 147     }
 148
 149     return Koha::Virtualshelves->search(
 150         {
 151             -and => \@conditions
 152         },
 153         {
 154             join     => [ 'virtualshelfcontents', 'virtualshelfshares' ],
 155             group_by => 'shelfnumber',
 156             order_by => { -asc => 'shelfname' },
 157         }
 158     );
 159 }
 160
 161 sub _type {
 162     return 'Virtualshelve';
 163 }
 164
 165 sub object_class {
 166     return 'Koha::Virtualshelf';
 167 }
 168
 169 1;