acqui/addorderiso2709.pl

   1 #!/usr/bin/perl
   2
   3 #A script that lets the user populate a basket from an iso2709 file
   4 #the script first displays a list of import batches, then when a batch is selected displays all the biblios in it.
   5 #The user can then pick which biblios he wants to order
   6
   7 # Copyright 2008 - 2011 BibLibre SARL
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 use Modern::Perl;
  25 use CGI qw ( -utf8 );
  26 use Carp;
  27 use YAML qw/Load/;
  28
  29 use C4::Context;
  30 use C4::Auth;
  31 use C4::Output;
  32 use C4::ImportBatch;
  33 use C4::Matcher;
  34 use C4::Search qw/FindDuplicate/;
  35 use C4::Acquisition;
  36 use C4::Biblio;
  37 use C4::Items;
  38 use C4::Koha;
  39 use C4::Budgets;
  40 use C4::Acquisition;
  41 use C4::Suggestions;    # GetSuggestion
  42 use C4::Members;
  43
  44 use Koha::Number::Price;
  45 use Koha::Acquisition::Currencies;
  46 use Koha::Acquisition::Order;
  47 use Koha::Acquisition::Bookseller;
  48
  49 my $input = new CGI;
  50 my ($template, $loggedinuser, $cookie, $userflags) = get_template_and_user({
  51     template_name => "acqui/addorderiso2709.tt",
  52     query => $input,
  53     type => "intranet",
  54     authnotrequired => 0,
  55     flagsrequired   => { acquisition => 'order_manage' },
  56     debug => 1,
  57 });
  58
  59 my $cgiparams = $input->Vars;
  60 my $op = $cgiparams->{'op'} || '';
  61 my $booksellerid  = $input->param('booksellerid');
  62 my $allmatch = $input->param('allmatch');
  63 my $bookseller = Koha::Acquisition::Bookseller->fetch({ id => $booksellerid });
  64
  65 $template->param(scriptname => "/cgi-bin/koha/acqui/addorderiso2709.pl",
  66                 booksellerid => $booksellerid,
  67                 booksellername => $bookseller->{name},
  68                 );
  69
  70 if ($cgiparams->{'import_batch_id'} && $op eq ""){
  71     $op = "batch_details";
  72 }
  73
  74 #Needed parameters:
  75 if (! $cgiparams->{'basketno'}){
  76     die "Basketnumber required to order from iso2709 file import";
  77 }
  78
  79 #
  80 # 1st step = choose the file to import into acquisition
  81 #
  82 if ($op eq ""){
  83     $template->param("basketno" => $cgiparams->{'basketno'});
  84 #display batches
  85     import_batches_list($template);
  86 #
  87 # 2nd step = display the content of the chosen file
  88 #
  89 } elsif ($op eq "batch_details"){
  90 #display lines inside the selected batch
  91     # get currencies (for change rates calcs if needed)
  92     my @currencies = Koha::Acquisition::Currencies->search;
  93
  94     $template->param("batch_details" => 1,
  95                      "basketno"      => $cgiparams->{'basketno'},
  96                      currencies => \@currencies,
  97                      bookseller => $bookseller,
  98                      "allmatch" => $allmatch,
  99                      );
 100     import_biblios_list($template, $cgiparams->{'import_batch_id'});
 101     my $basket = GetBasket($cgiparams->{basketno});
 102     if ( C4::Context->preference('AcqCreateItem') eq 'ordering' && !$basket->{is_standing} ) {
 103         # prepare empty item form
 104         my $cell = PrepareItemrecordDisplay( '', '', '', 'ACQ' );
 105
 106         #     warn "==> ".Data::Dumper::Dumper($cell);
 107         unless ($cell) {
 108             $cell = PrepareItemrecordDisplay( '', '', '', '' );
 109             $template->param( 'NoACQframework' => 1 );
 110         }
 111         my @itemloop;
 112         push @itemloop, $cell;
 113
 114         $template->param( items => \@itemloop );
 115     }
 116 #
 117 # 3rd step = import the records
 118 #
 119 } elsif ( $op eq 'import_records' ) {
 120 #import selected lines
 121     $template->param('basketno' => $cgiparams->{'basketno'});
 122 # Budget_id is mandatory for adding an order, we just add a default, the user needs to modify this aftewards
 123     my $budgets = GetBudgets();
 124     if (scalar @$budgets == 0){
 125         die "No budgets defined, can't continue";
 126     }
 127     my $budget_id = @$budgets[0]->{'budget_id'};
 128 #get all records from a batch, and check their import status to see if they are checked.
 129 #(default values: quantity 1, uncertainprice yes, first budget)
 130
 131     # retrieve the file you want to import
 132     my $import_batch_id = $cgiparams->{'import_batch_id'};
 133     my $biblios = GetImportRecordsRange($import_batch_id);
 134     my $duplinbatch;
 135     my $imported = 0;
 136     my @import_record_id_selected = $input->multi_param("import_record_id");
 137     my @quantities = $input->multi_param('quantity');
 138     my @prices = $input->multi_param('price');
 139     my @budgets_id = $input->multi_param('budget_id');
 140     my @discount = $input->multi_param('discount');
 141     my @sort1 = $input->multi_param('sort1');
 142     my @sort2 = $input->multi_param('sort2');
 143     my $active_currency = Koha::Acquisition::Currencies->get_active;
 144     for my $biblio (@$biblios){
 145         # Check if this import_record_id was selected
 146         next if not grep { $_ eq $$biblio{import_record_id} } @import_record_id_selected;
 147         my ( $marcblob, $encoding ) = GetImportRecordMarc( $biblio->{'import_record_id'} );
 148         my $marcrecord = MARC::Record->new_from_usmarc($marcblob) || die "couldn't translate marc information";
 149         my $match = GetImportRecordMatches( $biblio->{'import_record_id'}, 1 );
 150         my $biblionumber=$#$match > -1?$match->[0]->{'biblionumber'}:0;
 151         my $c_quantity = shift( @quantities ) || GetMarcQuantity($marcrecord, C4::Context->preference('marcflavour') ) || 1;
 152         my $c_budget_id = shift( @budgets_id ) || $input->param('all_budget_id') || $budget_id;
 153         my $c_discount = shift ( @discount);
 154         $c_discount = $c_discount / 100 if $c_discount > 1;
 155         my $c_sort1 = shift( @sort1 ) || $input->param('all_sort1') || '';
 156         my $c_sort2 = shift( @sort2 ) || $input->param('all_sort2') || '';
 157
 158         # 1st insert the biblio, or find it through matcher
 159         unless ( $biblionumber ) {
 160             $duplinbatch=$import_batch_id and next if FindDuplicate($marcrecord);
 161             # add the biblio
 162             my $bibitemnum;
 163
 164             # remove ISBN -
 165             my ( $isbnfield, $isbnsubfield ) = GetMarcFromKohaField( 'biblioitems.isbn', '' );
 166             if ( $marcrecord->field($isbnfield) ) {
 167                 foreach my $field ( $marcrecord->field($isbnfield) ) {
 168                     foreach my $subfield ( $field->subfield($isbnsubfield) ) {
 169                         my $newisbn = $field->subfield($isbnsubfield);
 170                         $newisbn =~ s/-//g;
 171                         $field->update( $isbnsubfield => $newisbn );
 172                     }
 173                 }
 174             }
 175             ( $biblionumber, $bibitemnum ) = AddBiblio( $marcrecord, $cgiparams->{'frameworkcode'} || '' );
 176             SetImportRecordStatus( $biblio->{'import_record_id'}, 'imported' );
 177             # 2nd add authorities if applicable
 178             if (C4::Context->preference("BiblioAddsAuthorities")){
 179                 my $headings_linked =BiblioAutoLink($marcrecord, $cgiparams->{'frameworkcode'});
 180             }
 181         } else {
 182             SetImportRecordStatus( $biblio->{'import_record_id'}, 'imported' );
 183         }
 184         # 3rd add order
 185         my $patron = C4::Members::GetMember( borrowernumber => $loggedinuser );
 186         # get quantity in the MARC record (1 if none)
 187         my $quantity = GetMarcQuantity($marcrecord, C4::Context->preference('marcflavour')) || 1;
 188         my %orderinfo = (
 189             biblionumber       => $biblionumber,
 190             basketno           => $cgiparams->{'basketno'},
 191             quantity           => $c_quantity,
 192             branchcode         => $patron->{branchcode},
 193             budget_id          => $c_budget_id,
 194             uncertainprice     => 1,
 195             sort1              => $c_sort1,
 196             sort2              => $c_sort2,
 197             order_internalnote => $cgiparams->{'all_order_internalnote'},
 198             order_vendornote   => $cgiparams->{'all_order_vendornote'},
 199             currency           => $cgiparams->{'all_currency'},
 200         );
 201         # get the price if there is one.
 202         my $price= shift( @prices ) || GetMarcPrice($marcrecord, C4::Context->preference('marcflavour'));
 203         if ($price){
 204             # in France, the cents separator is the , but sometimes, ppl use a .
 205             # in this case, the price will be x100 when unformatted ! Replace the . by a , to get a proper price calculation
 206             $price =~ s/\./,/ if C4::Context->preference("CurrencyFormat") eq "FR";
 207             $price = Koha::Number::Price->new($price)->unformat;
 208             $orderinfo{gstrate} = $bookseller->{gstrate};
 209             my $c = $c_discount ? $c_discount : $bookseller->{discount} / 100;
 210             if ( $bookseller->{listincgst} ) {
 211                 if ( $c_discount ) {
 212                     $orderinfo{ecost} = $price;
 213                     $orderinfo{rrp}   = $orderinfo{ecost} / ( 1 - $c );
 214                 } else {
 215                     $orderinfo{ecost} = $price * ( 1 - $c );
 216                     $orderinfo{rrp}   = $price;
 217                 }
 218             } else {
 219                 if ( $c_discount ) {
 220                     $orderinfo{ecost} = $price / ( 1 + $orderinfo{gstrate} );
 221                     $orderinfo{rrp}   = $orderinfo{ecost} / ( 1 - $c );
 222                 } else {
 223                     $orderinfo{rrp}   = $price / ( 1 + $orderinfo{gstrate} );
 224                     $orderinfo{ecost} = $orderinfo{rrp} * ( 1 - $c );
 225                 }
 226             }
 227             $orderinfo{listprice} = $orderinfo{rrp} / $active_currency->rate;
 228             $orderinfo{unitprice} = $orderinfo{ecost};
 229             $orderinfo{total} = $orderinfo{ecost} * $c_quantity;
 230         } else {
 231             $orderinfo{listprice} = 0;
 232         }
 233
 234         # remove uncertainprice flag if we have found a price in the MARC record
 235         $orderinfo{uncertainprice} = 0 if $orderinfo{listprice};
 236         my $order = Koha::Acquisition::Order->new( \%orderinfo )->insert;
 237
 238         # 4th, add items if applicable
 239         # parse the item sent by the form, and create an item just for the import_record_id we are dealing with
 240         # this is not optimised, but it's working !
 241         my $basket = GetBasket($cgiparams->{basketno});
 242         if ( C4::Context->preference('AcqCreateItem') eq 'ordering' && !$basket->{is_standing} ) {
 243             my @tags         = $input->multi_param('tag');
 244             my @subfields    = $input->multi_param('subfield');
 245             my @field_values = $input->multi_param('field_value');
 246             my @serials      = $input->multi_param('serial');
 247             my @ind_tag   = $input->multi_param('ind_tag');
 248             my @indicator = $input->multi_param('indicator');
 249             my $item;
 250             push @{ $item->{tags} },         $tags[0];
 251             push @{ $item->{subfields} },    $subfields[0];
 252             push @{ $item->{field_values} }, $field_values[0];
 253             push @{ $item->{ind_tag} },      $ind_tag[0];
 254             push @{ $item->{indicator} },    $indicator[0];
 255             my $xml = TransformHtmlToXml( \@tags, \@subfields, \@field_values, \@indicator, \@ind_tag );
 256             my $record = MARC::Record::new_from_xml( $xml, 'UTF-8' );
 257             for (my $qtyloop=1;$qtyloop <= $c_quantity;$qtyloop++) {
 258                 my ( $biblionumber, $bibitemnum, $itemnumber ) = AddItemFromMarc( $record, $biblionumber );
 259                 $order->add_item( $itemnumber );
 260             }
 261         } else {
 262             SetImportRecordStatus( $biblio->{'import_record_id'}, 'imported' );
 263         }
 264         $imported++;
 265     }
 266     # go to basket page
 267     if ( $imported ) {
 268         print $input->redirect("/cgi-bin/koha/acqui/basket.pl?basketno=".$cgiparams->{'basketno'}."&amp;duplinbatch=$duplinbatch");
 269     } else {
 270         print $input->redirect("/cgi-bin/koha/acqui/addorderiso2709.pl?import_batch_id=$import_batch_id&amp;basketno=".$cgiparams->{'basketno'}."&amp;booksellerid=$booksellerid&amp;allmatch=1");
 271     }
 272     exit;
 273 }
 274
 275 my $budgets = GetBudgets();
 276 my $budget_id = @$budgets[0]->{'budget_id'};
 277 # build bookfund list
 278 my $borrower = GetMember( 'borrowernumber' => $loggedinuser );
 279 my ( $flags, $homebranch ) = ( $borrower->{'flags'}, $borrower->{'branchcode'} );
 280 my $budget = GetBudget($budget_id);
 281
 282 # build budget list
 283 my $budget_loop = [];
 284 my $budgets_hierarchy = GetBudgetHierarchy;
 285 foreach my $r ( @{$budgets_hierarchy} ) {
 286     next unless (CanUserUseBudget($borrower, $r, $userflags));
 287     if ( !defined $r->{budget_amount} || $r->{budget_amount} == 0 ) {
 288         next;
 289     }
 290     push @{$budget_loop},
 291       { b_id  => $r->{budget_id},
 292         b_txt => $r->{budget_name},
 293         b_sort1_authcat => $r->{'sort1_authcat'},
 294         b_sort2_authcat => $r->{'sort2_authcat'},
 295         b_active => $r->{budget_period_active},
 296         b_sel => ( $r->{budget_id} == $budget_id ) ? 1 : 0,
 297       };
 298 }
 299
 300 @{$budget_loop} =
 301   sort { uc( $a->{b_txt}) cmp uc( $b->{b_txt}) } @{$budget_loop};
 302
 303 $template->param( budget_loop    => $budget_loop,);
 304
 305 output_html_with_http_headers $input, $cookie, $template->output;
 306
 307
 308 sub import_batches_list {
 309     my ($template) = @_;
 310     my $batches = GetImportBatchRangeDesc();
 311
 312     my @list = ();
 313     foreach my $batch (@$batches) {
 314         if ( $batch->{'import_status'} =~ /^staged$|^reverted$/ && $batch->{'record_type'} eq 'biblio') {
 315             # check if there is at least 1 line still staged
 316             my $stagedList=GetImportRecordsRange($batch->{'import_batch_id'}, undef, 1, $batch->{import_status}, { order_by_direction => 'ASC' });
 317             if (scalar @$stagedList) {
 318                 push @list, {
 319                         import_batch_id => $batch->{'import_batch_id'},
 320                         num_records => $batch->{'num_records'},
 321                         num_items => $batch->{'num_items'},
 322                         staged_date => $batch->{'upload_timestamp'},
 323                         import_status => $batch->{'import_status'},
 324                         file_name => $batch->{'file_name'},
 325                         comments => $batch->{'comments'},
 326                 };
 327             } else {
 328                 # if there are no more line to includes, set the status to imported
 329                 SetImportBatchStatus( $batch->{'import_batch_id'}, 'imported' );
 330             }
 331         }
 332     }
 333     $template->param(batch_list => \@list);
 334     my $num_batches = GetNumberOfNonZ3950ImportBatches();
 335     $template->param(num_results => $num_batches);
 336 }
 337
 338 sub import_biblios_list {
 339     my ($template, $import_batch_id) = @_;
 340     my $batch = GetImportBatch($import_batch_id,'staged');
 341     return () unless $batch and $batch->{import_status} =~ /^staged$|^reverted$/;
 342     my $biblios = GetImportRecordsRange($import_batch_id,'','',$batch->{import_status});
 343     my @list = ();
 344
 345     foreach my $biblio (@$biblios) {
 346         my $citation = $biblio->{'title'};
 347         $citation .= " $biblio->{'author'}" if $biblio->{'author'};
 348         $citation .= " (" if $biblio->{'issn'} or $biblio->{'isbn'};
 349         $citation .= $biblio->{'isbn'} if $biblio->{'isbn'};
 350         $citation .= ", " if $biblio->{'issn'} and $biblio->{'isbn'};
 351         $citation .= $biblio->{'issn'} if $biblio->{'issn'};
 352         $citation .= ")" if $biblio->{'issn'} or $biblio->{'isbn'};
 353         my $match = GetImportRecordMatches($biblio->{'import_record_id'}, 1);
 354         my %cellrecord = (
 355             import_record_id => $biblio->{'import_record_id'},
 356             citation => $citation,
 357             import  => 1,
 358             status => $biblio->{'status'},
 359             record_sequence => $biblio->{'record_sequence'},
 360             overlay_status => $biblio->{'overlay_status'},
 361             match_biblionumber => $#$match > -1 ? $match->[0]->{'biblionumber'} : 0,
 362             match_citation     => $#$match > -1 ? $match->[0]->{'title'} || '' . ' ' . $match->[0]->{'author'} || '': '',
 363             match_score => $#$match > -1 ? $match->[0]->{'score'} : 0,
 364         );
 365         my ( $marcblob, $encoding ) = GetImportRecordMarc( $biblio->{'import_record_id'} );
 366         my $marcrecord = MARC::Record->new_from_usmarc($marcblob) || die "couldn't translate marc information";
 367         my $infos = get_infos_syspref($marcrecord, ['price', 'quantity', 'budget_code', 'discount', 'sort1', 'sort2']);
 368         my $price = $infos->{price};
 369         my $quantity = $infos->{quantity};
 370         my $budget_code = $infos->{budget_code};
 371         my $discount = $infos->{discount};
 372         my $sort1 = $infos->{sort1};
 373         my $sort2 = $infos->{sort2};
 374         my $budget_id;
 375         if($budget_code) {
 376             my $biblio_budget = GetBudgetByCode($budget_code);
 377             if($biblio_budget) {
 378                 $budget_id = $biblio_budget->{budget_id};
 379             }
 380         }
 381         $cellrecord{price} = $price || '';
 382         $cellrecord{quantity} = $quantity || '';
 383         $cellrecord{budget_id} = $budget_id || '';
 384         $cellrecord{discount} = $discount || '';
 385         $cellrecord{sort1} = $sort1 || '';
 386         $cellrecord{sort2} = $sort2 || '';
 387
 388         push @list, \%cellrecord;
 389     }
 390     my $num_records = $batch->{'num_records'};
 391     my $overlay_action = GetImportBatchOverlayAction($import_batch_id);
 392     my $nomatch_action = GetImportBatchNoMatchAction($import_batch_id);
 393     my $item_action = GetImportBatchItemAction($import_batch_id);
 394     $template->param(biblio_list => \@list,
 395                         num_results => $num_records,
 396                         import_batch_id => $import_batch_id,
 397                         "overlay_action_${overlay_action}" => 1,
 398                         overlay_action => $overlay_action,
 399                         "nomatch_action_${nomatch_action}" => 1,
 400                         nomatch_action => $nomatch_action,
 401                         "item_action_${item_action}" => 1,
 402                         item_action => $item_action
 403                     );
 404     batch_info($template, $batch);
 405 }
 406
 407 sub batch_info {
 408     my ($template, $batch) = @_;
 409     $template->param(batch_info => 1,
 410                                       file_name => $batch->{'file_name'},
 411                                           comments => $batch->{'comments'},
 412                                           import_status => $batch->{'import_status'},
 413                                           upload_timestamp => $batch->{'upload_timestamp'},
 414                                           num_records => $batch->{'num_records'},
 415                                           num_items => $batch->{'num_items'});
 416     if ($batch->{'num_records'} > 0) {
 417         if ($batch->{'import_status'} eq 'staged' or $batch->{'import_status'} eq 'reverted') {
 418             $template->param(can_commit => 1);
 419         }
 420         if ($batch->{'import_status'} eq 'imported') {
 421             $template->param(can_revert => 1);
 422         }
 423     }
 424     if (defined $batch->{'matcher_id'}) {
 425         my $matcher = C4::Matcher->fetch($batch->{'matcher_id'});
 426         if (defined $matcher) {
 427             $template->param('current_matcher_id' => $batch->{'matcher_id'},
 428                                               'current_matcher_code' => $matcher->code(),
 429                                               'current_matcher_description' => $matcher->description());
 430         }
 431     }
 432     add_matcher_list($batch->{'matcher_id'}, $template);
 433 }
 434
 435 sub add_matcher_list {
 436     my ($current_matcher_id, $template) = @_;
 437     my @matchers = C4::Matcher::GetMatcherList();
 438     if (defined $current_matcher_id) {
 439         for (my $i = 0; $i <= $#matchers; $i++) {
 440             if ($matchers[$i]->{'matcher_id'} == $current_matcher_id) {
 441                 $matchers[$i]->{'selected'} = 1;
 442             }
 443         }
 444     }
 445     $template->param(available_matchers => \@matchers);
 446 }
 447
 448 sub get_infos_syspref {
 449     my ($record, $field_list) = @_;
 450     my $syspref = C4::Context->preference('MarcFieldsToOrder');
 451     $syspref = "$syspref\n\n"; # YAML is anal on ending \n. Surplus does not hurt
 452     my $yaml = eval {
 453         YAML::Load($syspref);
 454     };
 455     if ( $@ ) {
 456         warn "Unable to parse MarcFieldsToOrder syspref : $@";
 457         return ();
 458     }
 459     my $r;
 460     for my $field_name ( @$field_list ) {
 461         next unless exists $yaml->{$field_name};
 462         my @fields = split /\|/, $yaml->{$field_name};
 463         for my $field ( @fields ) {
 464             my ( $f, $sf ) = split /\$/, $field;
 465             next unless $f and $sf;
 466             if ( my $v = $record->subfield( $f, $sf ) ) {
 467                 $r->{$field_name} = $v;
 468             }
 469             last if $yaml->{$field};
 470         }
 471     }
 472     return $r;
 473 }