acqui/lateorders.pl

   1 #!/usr/bin/perl
   2
   3
   4 # Copyright 2005 Biblibre
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 lateorders.pl
  23
  24 =head1 DESCRIPTION
  25
  26 this script shows late orders for a specific supplier, branch and delay
  27 given on input arg.
  28
  29 =head1 CGI PARAMETERS
  30
  31 =over 4
  32
  33 =item booksellerid
  34 To know on which supplier this script have to display late order.
  35
  36 =item delay
  37 To know the time boundary. Default value is 30 days.
  38
  39 =item branch
  40 To know on which branch this script have to display late order.
  41
  42 =back
  43
  44 =cut
  45
  46 use Modern::Perl;
  47 use CGI qw ( -utf8 );
  48 use C4::Auth;
  49 use C4::Koha;
  50 use C4::Output;
  51 use C4::Context;
  52 use C4::Acquisition;
  53 use C4::Letters;
  54 use Koha::DateUtils;
  55 use Koha::Acquisition::Orders;
  56 use Koha::CsvProfiles;
  57
  58 my $input = CGI->new;
  59 my ($template, $loggedinuser, $cookie) = get_template_and_user(
  60     {
  61         template_name   => "acqui/lateorders.tt",
  62         query           => $input,
  63         type            => "intranet",
  64         flagsrequired   => { acquisition => 'order_receive' },
  65     }
  66 );
  67
  68 my $booksellerid = $input->param('booksellerid');
  69 my $delay        = $input->param('delay') // 0;
  70
  71 # Get the "date from" param if !defined is today
  72 my $estimateddeliverydatefrom = $input->param('estimateddeliverydatefrom');
  73 my $estimateddeliverydateto   = $input->param('estimateddeliverydateto');
  74
  75 my $estimateddeliverydatefrom_dt =
  76   $estimateddeliverydatefrom
  77   ? dt_from_string($estimateddeliverydatefrom)
  78   : undef;
  79
  80 # Get the "date to" param. If it is not defined and $delay is not defined too, it is the today's date.
  81 my $estimateddeliverydateto_dt = $estimateddeliverydateto
  82     ? dt_from_string($estimateddeliverydateto)
  83     : ( not defined $delay and not defined $estimateddeliverydatefrom)
  84         ? dt_from_string()
  85         : undef;
  86
  87 # Format the output of "date from" and "date to"
  88 if ($estimateddeliverydatefrom_dt) {
  89     $estimateddeliverydatefrom = output_pref({dt => $estimateddeliverydatefrom_dt, dateonly => 1});
  90 }
  91 if ($estimateddeliverydateto_dt) {
  92     $estimateddeliverydateto = output_pref({dt => $estimateddeliverydateto_dt, dateonly => 1});
  93 }
  94
  95 my $branch     = $input->param('branch');
  96 my $op         = $input->param('op');
  97
  98 my @errors = ();
  99 if ( $delay and not $delay =~ /^\d{1,3}$/ ) {
 100     push @errors, {delay_digits => 1, bad_delay => $delay};
 101 }
 102
 103 if ($op and $op eq "send_alert"){
 104     my @ordernums = $input->multi_param("ordernumber");
 105     my $err;
 106     eval {
 107         $err = SendAlerts( 'claimacquisition', \@ordernums, $input->param("letter_code") );
 108         if ( not ref $err or not exists $err->{error} ) {
 109             Koha::Acquisition::Orders->find($_)->claim() for @ordernums;
 110         }
 111     };
 112
 113     if ( ref $err and exists $err->{error} and $err->{error} eq "no_email" ) {
 114         $template->{VARS}->{'error_claim'} = "no_email";
 115     } elsif ( ref $err and exists $err->{error} and $err->{error} eq "no_order_selected"){
 116         $template->{VARS}->{'error_claim'} = "no_order_selected";
 117     } elsif ( $@ or ref $err and exists $err->{error} ) {
 118         $template->param(error_claim => $@ || $err->{error});
 119     } else {
 120         $template->{VARS}->{'info_claim'} = 1;
 121     }
 122 }
 123
 124 my @lateorders = Koha::Acquisition::Orders->filter_by_lates(
 125     {
 126         delay        => $delay,
 127         (
 128             $estimateddeliverydatefrom_dt
 129             ? ( estimated_from => $estimateddeliverydatefrom_dt )
 130             : ()
 131         ),
 132         (
 133             $estimateddeliverydateto_dt
 134             ? ( estimated_to => $estimateddeliverydateto_dt )
 135             : ()
 136         )
 137     },
 138 )->as_list;
 139
 140 my $booksellers = Koha::Acquisition::Booksellers->search(
 141     {
 142         id => {
 143             -in => [ map { $_->basket->booksellerid } @lateorders ]
 144         },
 145     }
 146 );
 147
 148 @lateorders = grep { $_->basket->booksellerid eq $booksellerid } @lateorders if $booksellerid;
 149
 150 my $letters = GetLetters({ module => "claimacquisition" });
 151
 152 $template->param(ERROR_LOOP => \@errors) if (@errors);
 153 $template->param(
 154     lateorders => \@lateorders,
 155     booksellers => $booksellers,
 156     bookseller_filter => ( $booksellerid ? $booksellers->find($booksellerid) : undef),
 157         delay => $delay,
 158     letters => $letters,
 159     estimateddeliverydatefrom => $estimateddeliverydatefrom,
 160     estimateddeliverydateto   => $estimateddeliverydateto,
 161         intranetcolorstylesheet => C4::Context->preference("intranetcolorstylesheet"),
 162     csv_profiles         => [ Koha::CsvProfiles->search({ type => 'sql', used_for => 'late_orders' }) ],
 163 );
 164 output_html_with_http_headers $input, $cookie, $template->output;