admin/z3950servers.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2002 paul.poulain@free.fr
   4 # Copyright 2014 Rijksmuseum
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 # This script is used to maintain the Z3950 servers table.
  23 # Parameter $op is operation: list, new, edit, add_validated, delete_confirmed.
  24 # add_validated saves a validated record and goes to list view.
  25 # delete_confirmed deletes a record and goes to list view.
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use C4::Context;
  30 use C4::Auth qw( get_template_and_user );
  31 use C4::Output qw( output_html_with_http_headers );
  32 use Koha::Database;
  33 use Koha::Z3950Servers;
  34
  35 # Initialize CGI, template, database
  36
  37 my $input = CGI->new;
  38 my $op = $input->param('op') || 'list';
  39 my $id = $input->param('id') || 0;
  40 my $type = $input->param('type') || '';
  41 my $searchfield = '';
  42
  43 my ( $template, $loggedinuser, $cookie ) = get_template_and_user( {
  44     template_name => "admin/z3950servers.tt",
  45     query => $input,
  46     type => "intranet",
  47     flagsrequired => { parameters => 'manage_search_targets' },
  48 });
  49 my $script_name = "/cgi-bin/koha/admin/z3950servers.pl";
  50 $template->param( script_name => $script_name );
  51
  52 my $schema = Koha::Database->new()->schema();
  53
  54 # Main code
  55 # First process a confirmed delete, or save a validated record
  56
  57 if( $op eq 'delete_confirmed' && $id ) {
  58     my $server = Koha::Z3950Servers->find($id);
  59     if ( $server ) {
  60         $server->delete;
  61         $template->param( msg_deleted => 1, msg_add => $server->servername );
  62     } else {
  63         $template->param( msg_notfound => 1, msg_add => $id );
  64     }
  65     $id = 0;
  66 } elsif ( $op eq 'add_validated' ) {
  67     my @fields=qw/host port db userid password rank syntax encoding timeout
  68         recordtype checked servername servertype sru_options sru_fields attributes
  69         add_xslt/;
  70     my $formdata = _form_data_hashref( $input, \@fields );
  71     if( $id ) {
  72         my $server = Koha::Z3950Servers->find($id);
  73         if ( $server ) {
  74             $server->set( $formdata )->store;
  75             $template->param( msg_updated => 1, msg_add => $formdata->{servername} );
  76         } else {
  77             $template->param( msg_notfound => 1, msg_add => $id );
  78         }
  79         $id = 0;
  80     } else {
  81         Koha::Z3950Server->new( $formdata )->store;
  82         $template->param( msg_added => 1, msg_add => $formdata->{servername} );
  83     }
  84 } else {
  85     #use searchfield only in remaining operations
  86     $searchfield = $input->param('searchfield') || '';
  87 }
  88
  89 # Now list multiple records, or edit one record
  90
  91 my $data = [];
  92 if ( $op eq 'add' || $op eq 'edit' ) {
  93     $data = ServerSearch( $schema, $id, $searchfield ) if $searchfield || $id;
  94     delete $data->[0]->{id} if @$data && $op eq 'add'; #cloning record
  95     $template->param( add_form => 1, server => @$data? $data->[0]: undef,
  96         op => $op, type => $op eq 'add'? lc $type: '' );
  97 } else {
  98     $data = ServerSearch( $schema, $id, $searchfield );
  99     $template->param( loop => \@$data, searchfield => $searchfield, id => $id,
 100         op => 'list' );
 101 }
 102 output_html_with_http_headers $input, $cookie, $template->output;
 103
 104 # End of main code
 105
 106 sub ServerSearch  { #find server(s) by id or name
 107     my ( $schema, $id, $searchstring )= @_;
 108
 109     return Koha::Z3950Servers->search(
 110         $id ? { id => $id } : { servername => { like => $searchstring . '%' } },
 111     )->unblessed;
 112 }
 113
 114 sub _form_data_hashref {
 115     my ( $input, $fieldref ) = @_;
 116     return { map { ( $_ => scalar $input->param($_)//'' ) } @$fieldref };
 117 }