catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to acomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use strict;            # always use
 136 #use warnings; FIXME - Bug 2505
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth qw(:DEFAULT get_session);
 146 use C4::Search;
 147 use C4::Languages qw(getLanguages);
 148 use C4::Koha;
 149 use C4::Members qw(GetMember);
 150 use URI::Escape;
 151 use POSIX qw(ceil floor);
 152 use C4::Branch; # GetBranches
 153 use C4::Search::History;
 154
 155 use Koha::LibraryCategories;
 156 use Koha::Virtualshelves;
 157 use Koha::SearchEngine::Search;
 158 use Koha::SearchEngine::QueryBuilder;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = new CGI;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174 }
 175 else {
 176     $template_name = 'catalogue/advsearch.tt';
 177     $template_type = 'advsearch';
 178 }
 179 # load the template
 180 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 181     template_name => $template_name,
 182     query => $cgi,
 183     type => "intranet",
 184     authnotrequired => 0,
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194 if (C4::Context->preference("IntranetNumbersPreferPhrase")) {
 195     $template->param('numbersphr' => 1);
 196 }
 197
 198 if($cgi->cookie("holdfor")){
 199     my $holdfor_patron = GetMember('borrowernumber' => $cgi->cookie("holdfor"));
 200     $template->param(
 201         holdfor => $cgi->cookie("holdfor"),
 202         holdfor_surname => $holdfor_patron->{'surname'},
 203         holdfor_firstname => $holdfor_patron->{'firstname'},
 204         holdfor_cardnumber => $holdfor_patron->{'cardnumber'},
 205     );
 206 }
 207
 208 # get biblionumbers stored in the cart
 209 my @cart_list;
 210
 211 if($cgi->cookie("intranet_bib_list")){
 212     my $cart_list = $cgi->cookie("intranet_bib_list");
 213     @cart_list = split(/\//, $cart_list);
 214 }
 215
 216 # load the branches
 217 my $categories = Koha::LibraryCategories->search( { categorytype => 'searchdomain' }, { order_by => [ 'categorytype', 'categorycode' ] } );
 218
 219 $template->param(searchdomainloop => $categories);
 220
 221 # load the Type stuff
 222 my $itemtypes = GetItemTypes;
 223 # the index parameter is different for item-level itemtypes
 224 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 225 my @advancedsearchesloop;
 226 my $cnt;
 227 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 228 my @advanced_search_types = split(/\|/, $advanced_search_types);
 229
 230 foreach my $advanced_srch_type (@advanced_search_types) {
 231     $advanced_srch_type =~ s/^\s*//;
 232     $advanced_srch_type =~ s/\s*$//;
 233    if ($advanced_srch_type eq 'itemtypes') {
 234    # itemtype is a special case, since it's not defined in authorized values
 235         my @itypesloop;
 236         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes ) {
 237             my %row =(  number=>$cnt++,
 238                 ccl => "$itype_or_itemtype,phr",
 239                 code => $thisitemtype,
 240                 description => $itemtypes->{$thisitemtype}->{translated_description},
 241                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 242             );
 243             push @itypesloop, \%row;
 244         }
 245         my %search_code = (  advanced_search_type => $advanced_srch_type,
 246                              code_loop => \@itypesloop );
 247         push @advancedsearchesloop, \%search_code;
 248     } else {
 249     # covers all the other cases: non-itemtype authorized values
 250        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 251         my @authvalueloop;
 252         for my $thisitemtype (@$advsearchtypes) {
 253                 my %row =(
 254                                 number=>$cnt++,
 255                                 ccl => $advanced_srch_type,
 256                 code => $thisitemtype->{authorised_value},
 257                 description => $thisitemtype->{'lib'},
 258                 imageurl => getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 259                 );
 260                 push @authvalueloop, \%row;
 261         }
 262         my %search_code = (  advanced_search_type => $advanced_srch_type,
 263                              code_loop => \@authvalueloop );
 264         push @advancedsearchesloop, \%search_code;
 265     }
 266 }
 267 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 268 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 269 my $advancedsearchesloop = prepare_adv_search_types($types);
 270 $template->param(advancedsearchesloop => $advancedsearchesloop);
 271
 272 # The following should only be loaded if we're bringing up the advanced search template
 273 if ( $template_type eq 'advsearch' ) {
 274
 275     # load the servers (used for searching -- to do federated searching, etc.)
 276     my $primary_servers_loop;# = displayPrimaryServers();
 277     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 278
 279     my $secondary_servers_loop;
 280     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 281
 282     # set the default sorting
 283     if (   C4::Context->preference('OPACdefaultSortField')
 284         && C4::Context->preference('OPACdefaultSortOrder') ) {
 285         my $default_sort_by =
 286             C4::Context->preference('defaultSortField') . '_'
 287           . C4::Context->preference('defaultSortOrder');
 288         $template->param( sort_by => $default_sort_by  );
 289     }
 290
 291     # determine what to display next to the search boxes (ie, boolean option
 292     # shouldn't appear on the first one, scan indexes should, adding a new
 293     # box should only appear on the last, etc.
 294     my @search_boxes_array;
 295     my $search_boxes_count = 3; # begin whith 3 boxes
 296     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 297     for (my $i=1;$i<=$search_boxes_count;$i++) {
 298         # if it's the first one, don't display boolean option, but show scan indexes
 299         if ($i==1) {
 300             push @search_boxes_array, {scan_index => 1};
 301         }
 302         # if it's the last one, show the 'add field' box
 303         elsif ($i==$search_boxes_count) {
 304             push @search_boxes_array,
 305                 {
 306                 boolean => 1,
 307                 add_field => 1,
 308                 };
 309         }
 310         else {
 311             push @search_boxes_array,
 312                 {
 313                 boolean => 1,
 314                 };
 315         }
 316
 317     }
 318     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 319                       search_boxes_loop => \@search_boxes_array);
 320
 321     # load the language limits (for search)
 322     my $languages_limit_loop = getLanguages($lang, 1);
 323     $template->param(search_languages_loop => $languages_limit_loop,);
 324
 325     # Expanded search options in advanced search:
 326     # use the global setting by default, but let the user override it
 327     {
 328         my $expanded = $cgi->param('expanded_options');
 329         $expanded = C4::Context->preference("expandedSearchOption") || 0
 330             if !defined($expanded) || $expanded !~ /^0|1$/;
 331         $template->param( expanded_options => $expanded );
 332     }
 333
 334     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 335
 336     output_html_with_http_headers $cgi, $cookie, $template->output;
 337     exit;
 338 }
 339
 340 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 341
 342 # Fetch the paramater list as a hash in scalar context:
 343 #  * returns paramater list as tied hash ref
 344 #  * we can edit the values by changing the key
 345 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 346 my $params = $cgi->Vars;
 347
 348 # Params that can have more than one value
 349 # sort by is used to sort the query
 350 # in theory can have more than one but generally there's just one
 351 my @sort_by;
 352 my $default_sort_by;
 353 if (   C4::Context->preference('defaultSortField')
 354     && C4::Context->preference('defaultSortOrder') ) {
 355     $default_sort_by =
 356         C4::Context->preference('defaultSortField') . '_'
 357       . C4::Context->preference('defaultSortOrder');
 358 }
 359
 360 @sort_by = $cgi->multi_param('sort_by');
 361 $sort_by[0] = $default_sort_by unless $sort_by[0];
 362 foreach my $sort (@sort_by) {
 363     $template->param($sort => 1) if $sort;
 364 }
 365 $template->param('sort_by' => $sort_by[0]);
 366
 367 # Use the servers defined, or just search our local catalog(default)
 368 my @servers = $cgi->multi_param('server');
 369 unless (@servers) {
 370     #FIXME: this should be handled using Context.pm
 371     @servers = ("biblioserver");
 372     # @servers = C4::Context->config("biblioserver");
 373 }
 374 # operators include boolean and proximity operators and are used
 375 # to evaluate multiple operands
 376 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 377
 378 # indexes are query qualifiers, like 'title', 'author', etc. They
 379 # can be single or multiple parameters separated by comma: kw,right-Truncation
 380 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 381
 382 # if a simple index (only one)  display the index used in the top search box
 383 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 384     my $idx = "ms_".$indexes[0];
 385     $idx =~ s/\,/comma/g;  # template toolkit doesnt like variables with a , in it
 386     $template->param($idx => 1);
 387 }
 388
 389 # an operand can be a single term, a phrase, or a complete ccl query
 390 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 391
 392 # limits are use to limit to results to a pre-defined category such as branch or language
 393 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 394 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 395 my %is_nolimit = map { $_ => 1 } @nolimits;
 396 @limits = grep { not $is_nolimit{$_} } @limits;
 397
 398 if($params->{'multibranchlimit'}) {
 399     my $library_category = Koha::LibraryCategories->find( $params->{multibranchlimit} );
 400     my @libraries = $library_category->libraries;
 401     my $multibranch = '('.join( " or ", map { 'branch: ' . $_->id } @libraries ) .')';
 402     push @limits, $multibranch if ($multibranch ne  '()');
 403 }
 404
 405 my $available;
 406 foreach my $limit(@limits) {
 407     if ($limit =~/available/) {
 408         $available = 1;
 409     }
 410 }
 411 $template->param(available => $available);
 412
 413 # append year limits if they exist
 414 my $limit_yr;
 415 my $limit_yr_value;
 416 if ($params->{'limit-yr'}) {
 417     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 418         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 419         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 420         $limit_yr_value = "$yr1-$yr2";
 421     }
 422     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 423         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 424         $limit_yr_value = $params->{'limit-yr'};
 425     }
 426     push @limits,$limit_yr;
 427     #FIXME: Should return a error to the user, incorect date format specified
 428 }
 429
 430 # convert indexes and operands to corresponding parameter names for the z3950 search
 431 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 432 my $z3950par;
 433 my $indexes2z3950 = {
 434     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 435     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 436     ti=>'title', 'ti,phr'=>'title', se=>'title'
 437 };
 438 for (my $ii = 0; $ii < @operands; ++$ii)
 439 {
 440     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 441     if (defined $name && defined $operands[$ii])
 442     {
 443         $z3950par ||= {};
 444         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 445     }
 446 }
 447
 448
 449 # Params that can only have one value
 450 my $scan = $params->{'scan'};
 451 my $count = C4::Context->preference('numSearchResults') || 20;
 452 my $results_per_page = $params->{'count'} || $count;
 453 my $offset = $params->{'offset'} || 0;
 454 my $page = $cgi->param('page') || 1;
 455 #my $offset = ($page-1)*$results_per_page;
 456 my $hits;
 457 my $expanded_facet = $params->{'expand'};
 458
 459 # Define some global variables
 460 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 461
 462 my $builder = Koha::SearchEngine::QueryBuilder->new(
 463     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 464 my $searcher = Koha::SearchEngine::Search->new(
 465     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 466
 467 ## I. BUILD THE QUERY
 468 (
 469     $error,             $query, $simple_query, $query_cgi,
 470     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 471     $query_type
 472   )
 473   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 474     \@sort_by, $scan, $lang );
 475
 476 ## parse the query_cgi string and put it into a form suitable for <input>s
 477 my @query_inputs;
 478 my $scan_index_to_use;
 479 my $scan_search_term_to_use;
 480
 481 for my $this_cgi ( split('&',$query_cgi) ) {
 482     next unless $this_cgi;
 483     $this_cgi =~ m/(.*?)=(.*)/;
 484     my $input_name = $1;
 485     my $input_value = $2;
 486     push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 487     if ($input_name eq 'idx') {
 488         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 489     }
 490     if ($input_name eq 'q') {
 491         $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 492     }
 493 }
 494 $template->param ( QUERY_INPUTS => \@query_inputs,
 495                    scan_index_to_use => $scan_index_to_use,
 496                    scan_search_term_to_use => $scan_search_term_to_use );
 497
 498 ## parse the limit_cgi string and put it into a form suitable for <input>s
 499 my @limit_inputs;
 500 for my $this_cgi ( split('&',$limit_cgi) ) {
 501     next unless $this_cgi;
 502     # handle special case limit-yr
 503     if ($this_cgi =~ /yr,st-numeric/) {
 504         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 505         next;
 506     }
 507     $this_cgi =~ m/(.*=)(.*)/;
 508     my $input_name = $1;
 509     my $input_value = $2;
 510     $input_name =~ s/=$//;
 511     push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 512 }
 513 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 514
 515 ## II. DO THE SEARCH AND GET THE RESULTS
 516 my $total; # the total results for the whole set
 517 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 518 my $results_hashref;
 519
 520 eval {
 521     my $itemtypes = GetItemTypes;
 522     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 523         $query,            $simple_query, \@sort_by,       \@servers,
 524         $results_per_page, $offset,       $expanded_facet, undef,
 525         $itemtypes,        $query_type,   $scan
 526     );
 527 };
 528
 529 if ($@ || $error) {
 530     $template->param(query_error => $error.$@);
 531     output_html_with_http_headers $cgi, $cookie, $template->output;
 532     exit;
 533 }
 534
 535 # At this point, each server has given us a result set
 536 # now we build that set for template display
 537 my @sup_results_array;
 538 for (my $i=0;$i<@servers;$i++) {
 539     my $server = $servers[$i];
 540     if ($server =~/biblioserver/) { # this is the local bibliographic server
 541         $hits = $results_hashref->{$server}->{"hits"};
 542         my $page = $cgi->param('page') || 0;
 543         my @newresults = searchResults('intranet', $query_desc, $hits, $results_per_page, $offset, $scan,
 544                                        $results_hashref->{$server}->{"RECORDS"});
 545         $total = $total + $results_hashref->{$server}->{"hits"};
 546
 547         # Search history
 548         if (C4::Context->preference('EnableSearchHistory')) {
 549             unless ( $offset ) {
 550                 my $path_info = $cgi->url(-path_info=>1);
 551                 my $query_cgi_history = $cgi->url(-query=>1);
 552                 $query_cgi_history =~ s/^$path_info\?//;
 553                 $query_cgi_history =~ s/;/&/g;
 554                 my $query_desc_history = $query_desc;
 555                 $query_desc_history .= ", $limit_desc"
 556                     if $limit_desc;
 557
 558                 C4::Search::History::add({
 559                     userid => $borrowernumber,
 560                     sessionid => $cgi->cookie("CGISESSID"),
 561                     query_desc => $query_desc_history,
 562                     query_cgi => $query_cgi_history,
 563                     total => $total,
 564                     type => "biblio",
 565                 });
 566             }
 567             $template->param( EnableSearchHistory => 1 );
 568         }
 569
 570         ## If there's just one result, redirect to the detail page
 571         if ($total == 1) {
 572             my $biblionumber = $newresults[0]->{biblionumber};
 573             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 574             my $views = { C4::Search::enabled_staff_search_views };
 575             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 576                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 577             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 578                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 579             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 580                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 581             } else {
 582                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 583             }
 584             exit;
 585         }
 586
 587         # set up parameters if user wishes to re-run the search
 588         # as a Z39.50 search
 589         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 590
 591         if ($hits) {
 592             $template->param(total => $hits);
 593             my $limit_cgi_not_availablity = $limit_cgi;
 594             $limit_cgi_not_availablity =~ s/&limit=available//g;
 595             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 596             $template->param(limit_cgi => $limit_cgi);
 597             $template->param(query_cgi => $query_cgi);
 598             $template->param(query_desc => $query_desc);
 599             $template->param(limit_desc => $limit_desc);
 600             $template->param(offset     => $offset);
 601             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 602             if ($query_desc || $limit_desc) {
 603                 $template->param(searchdesc => 1);
 604             }
 605             $template->param(results_per_page =>  $results_per_page);
 606             # must define a value for size if not present in DB
 607             # in order to avoid problems generated by the default size value in TT
 608             foreach my $line (@newresults) {
 609                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 610                 # while we're checking each line, see if item is in the cart
 611                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 612                     $line->{'incart'} = 1;
 613                 }
 614             }
 615             $template->param(SEARCH_RESULTS => \@newresults);
 616             ## FIXME: add a global function for this, it's better than the current global one
 617             ## Build the page numbers on the bottom of the page
 618             my @page_numbers;
 619             # total number of pages there will be
 620             my $pages = ceil($hits / $results_per_page);
 621             # default page number
 622             my $current_page_number = 1;
 623             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 624             my $previous_page_offset;
 625             if ( $offset >= $results_per_page ) {
 626                 $previous_page_offset = $offset - $results_per_page;
 627             }
 628             my $next_page_offset = $offset + $results_per_page;
 629             # If we're within the first 10 pages, keep it simple
 630             #warn "current page:".$current_page_number;
 631             if ($current_page_number < 10) {
 632                 # just show the first 10 pages
 633                 # Loop through the pages
 634                 my $pages_to_show = 10;
 635                 $pages_to_show = $pages if $pages<10;
 636                 for (my $i=1; $i<=$pages_to_show;$i++) {
 637                     # the offset for this page
 638                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 639                     # the page number for this page
 640                     my $this_page_number = $i;
 641                     # put it in the array
 642                     push @page_numbers,
 643                       { offset    => $this_offset,
 644                         pg        => $this_page_number,
 645                         # it should only be highlighted if it's the current page
 646                         highlight => $this_page_number == $current_page_number,
 647                         sort_by   => join ' ', @sort_by
 648                       };
 649
 650                 }
 651
 652             }
 653
 654             # now, show twenty pages, with the current one smack in the middle
 655             else {
 656                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 657                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 658                     my $this_page_number = $i-9;
 659                     if ( $this_page_number <= $pages ) {
 660                         push @page_numbers,
 661                           { offset    => $this_offset,
 662                             pg        => $this_page_number,
 663                             highlight => $this_page_number == $current_page_number,
 664                             sort_by   => join ' ', @sort_by
 665                           };
 666                     }
 667                 }
 668             }
 669             # FIXME: no previous_page_offset when pages < 2
 670             $template->param(   PAGE_NUMBERS => \@page_numbers,
 671                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 672             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 673         }
 674
 675
 676         # no hits
 677         else {
 678             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 679         }
 680
 681     } # end of the if local
 682
 683     # asynchronously search the authority server
 684     elsif ($server =~/authorityserver/) { # this is the local authority server
 685         my @inner_sup_results_array;
 686         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 687             my $marc_record_object = C4::Search::new_record_from_zebra(
 688                 'authorityserver',
 689                 $sup_record
 690             );
 691             # warn "Authority Found: ".$marc_record_object->as_formatted();
 692             push @inner_sup_results_array, {
 693                 'title' => $marc_record_object->field(100)->subfield('a'),
 694                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 695             };
 696         }
 697         push @sup_results_array, {  servername => $server,
 698                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 699     }
 700     # FIXME: can add support for other targets as needed here
 701     $template->param(           outer_sup_results_loop => \@sup_results_array);
 702 } #/end of the for loop
 703 #$template->param(FEDERATED_RESULTS => \@results_array);
 704
 705 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 706
 707 my $gotonumber = $cgi->param('gotoNumber');
 708 if ($gotonumber eq 'last' || $gotonumber eq 'first') {
 709     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 710 }
 711 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 712 my $gotopage = $cgi->param('gotoPage');
 713 $template->{'VARS'}->{'gotoPage'} = $gotopage
 714   if $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 715
 716 for my $facet ( @$facets ) {
 717     for my $entry ( @{ $facet->{facets} } ) {
 718         my $index = $entry->{type_link_value};
 719         my $value = $entry->{facet_link_value};
 720         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 721     }
 722 }
 723
 724 $template->param(
 725             #classlist => $classlist,
 726             total => $total,
 727             opacfacets => 1,
 728             facets_loop => $facets,
 729             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 730             scan => $scan,
 731             search_error => $error,
 732 );
 733
 734 if ($query_desc || $limit_desc) {
 735     $template->param(searchdesc => 1);
 736 }
 737
 738 # VI. BUILD THE TEMPLATE
 739
 740 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 741     {
 742         borrowernumber => $borrowernumber,
 743         add_allowed    => 1,
 744         category       => 1,
 745     }
 746 );
 747 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 748     {
 749         borrowernumber => $borrowernumber,
 750         add_allowed    => 1,
 751         category       => 2,
 752     }
 753 );
 754
 755
 756 $template->param(
 757     add_to_some_private_shelves => $some_private_shelves,
 758     add_to_some_public_shelves  => $some_public_shelves,
 759 );
 760
 761 output_html_with_http_headers $cgi, $cookie, $template->output;
 762
 763
 764 =head2 prepare_adv_search_types
 765
 766     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 767     my @advanced_search_types = prepare_adv_search_types($type);
 768
 769 Different types can be searched for in the advanced search. This takes the
 770 system preference that defines these types and parses it into an arrayref for
 771 the template.
 772
 773 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 774 It also accounts for the "item-level_itypes" system preference.
 775
 776 =cut
 777
 778 sub prepare_adv_search_types {
 779     my ($types) = @_;
 780
 781     my @advanced_search_types = split( /\|/, $types );
 782
 783     # the index parameter is different for item-level itemtypes
 784     my $itype_or_itemtype =
 785       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 786     my $itemtypes = GetItemTypes;
 787
 788     my ( $cnt, @result );
 789     foreach my $advanced_srch_type (@advanced_search_types) {
 790         $advanced_srch_type =~ s/^\s*//;
 791         $advanced_srch_type =~ s/\s*$//;
 792         if ( $advanced_srch_type eq 'itemtypes' ) {
 793
 794        # itemtype is a special case, since it's not defined in authorized values
 795             my @itypesloop;
 796             foreach my $thisitemtype (
 797                 sort {
 798                     $itemtypes->{$a}->{'translated_description'}
 799                       cmp $itemtypes->{$b}->{'translated_description'}
 800                 } keys %$itemtypes
 801               )
 802             {
 803                 my %row = (
 804                     number      => $cnt++,
 805                     ccl         => "$itype_or_itemtype,phr",
 806                     code        => $thisitemtype,
 807                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 808                     imageurl    => getitemtypeimagelocation(
 809                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 810                     ),
 811                 );
 812                 push @itypesloop, \%row;
 813             }
 814             my %search_code = (
 815                 advanced_search_type => $advanced_srch_type,
 816                 code_loop            => \@itypesloop
 817             );
 818             push @result, \%search_code;
 819         }
 820         else {
 821             # covers all the other cases: non-itemtype authorized values
 822             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 823             my @authvalueloop;
 824             for my $thisitemtype (@$advsearchtypes) {
 825                 my %row = (
 826                     number      => $cnt++,
 827                     ccl         => $advanced_srch_type,
 828                     code        => $thisitemtype->{authorised_value},
 829                     description => $thisitemtype->{'lib'},
 830                     imageurl    => getitemtypeimagelocation(
 831                         'intranet', $thisitemtype->{'imageurl'}
 832                     ),
 833                 );
 834                 push @authvalueloop, \%row;
 835             }
 836             my %search_code = (
 837                 advanced_search_type => $advanced_srch_type,
 838                 code_loop            => \@authvalueloop
 839             );
 840             push @result, \%search_code;
 841         }
 842     }
 843     return \@result;
 844 }