catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 #
   7 # This file is part of Koha
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it under the
  10 # terms of the GNU General Public License as published by the Free Software
  11 # Foundation; either version 2 of the License, or (at your option) any later
  12 # version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  15 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  16 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License along
  19 # with Koha; if not, write to the Free Software Foundation, Inc.,
  20 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  21
  22 =head1 NAME
  23
  24 search - a search script for finding records in a Koha system (Version 3)
  25
  26 =head1 OVERVIEW
  27
  28 This script utilizes a new search API for Koha 3. It is designed to be
  29 simple to use and configure, yet capable of performing feats like stemming,
  30 field weighting, relevance ranking, support for multiple  query language
  31 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  32 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  33 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  34
  35 The API as represented in this script is mostly sound, even if the individual
  36 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  37 free to disagree :-)
  38
  39 I will attempt to describe what is happening at each part of this script.
  40 -- Joshua Ferraro <jmf AT liblime DOT com>
  41
  42 =head2 INTRO
  43
  44 This script performs two functions:
  45
  46 =over
  47
  48 =item 1. interacts with Koha to retrieve and display the results of a search
  49
  50 =item 2. loads the advanced search page
  51
  52 =back
  53
  54 These two functions share many of the same variables and modules, so the first
  55 task is to load what they have in common and determine which template to use.
  56 Once determined, proceed to only load the variables and procedures necessary
  57 for that function.
  58
  59 =head2 LOADING ADVANCED SEARCH PAGE
  60
  61 This is fairly straightforward, and I won't go into detail ;-)
  62
  63 =head2 PERFORMING A SEARCH
  64
  65 If we're performing a search, this script  performs three primary
  66 operations:
  67
  68 =over
  69
  70 =item 1. builds query strings (yes, plural)
  71
  72 =item 2. perform the search and return the results array
  73
  74 =item 3. build the HTML for output to the template
  75
  76 =back
  77
  78 There are several additional secondary functions performed that I will
  79 not cover in detail.
  80
  81 =head3 1. Building Query Strings
  82
  83 There are several types of queries needed in the process of search and retrieve:
  84
  85 =over
  86
  87 =item 1 $query - the fully-built query passed to zebra
  88
  89 This is the most complex query that needs to be built. The original design goal
  90 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  91 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  92 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  93 I'll try to flesh out this section to better explain.
  94
  95 This query incorporates query profiles that aren't compatible with most non-Zebra
  96 Z39.50 targets to acomplish the field weighting and relevance ranking.
  97
  98 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
  99 stemming, etc., suitable to pass off to other search targets
 100
 101 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 102 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 103
 104 =item 3 $query_cgi - passed to the template / saved for future refinements of
 105 the query (by user)
 106
 107 This is a simple string that completely expresses the query as a CGI string that
 108 can be used for future refinements of the query or as a part of a history feature.
 109
 110 =item 4 $query_desc - Human search description - what the user sees in search
 111 feedback area
 112
 113 This is a simple string that is human readable. It will contain '=', ',', etc.
 114
 115 =back
 116
 117 =head3 2. Perform the Search
 118
 119 This section takes the query strings and performs searches on the named servers,
 120 including the Koha Zebra server, stores the results in a deeply nested object,
 121 builds 'faceted results', and returns these objects.
 122
 123 =head3 3. Build HTML
 124
 125 The final major section of this script takes the objects collected thusfar and
 126 builds the HTML for output to the template and user.
 127
 128 =head3 Additional Notes
 129
 130 Not yet completed...
 131
 132 =cut
 133
 134 use strict;            # always use
 135 #use warnings; FIXME - Bug 2505
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getAllLanguages);
 147 use C4::Koha;
 148 use C4::VirtualShelves qw(GetRecentShelves);
 149 use POSIX qw(ceil floor);
 150 use C4::Branch; # GetBranches
 151
 152 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 153 # create a new CGI object
 154 # FIXME: no_undef_params needs to be tested
 155 use CGI qw('-no_undef_params');
 156 my $cgi = new CGI;
 157
 158 my ($template,$borrowernumber,$cookie);
 159
 160 # decide which template to use
 161 my $template_name;
 162 my $template_type;
 163 my @params = $cgi->param("limit");
 164 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 165     $template_name = 'catalogue/results.tmpl';
 166 }
 167 else {
 168     $template_name = 'catalogue/advsearch.tmpl';
 169     $template_type = 'advsearch';
 170 }
 171 # load the template
 172 ($template, $borrowernumber, $cookie) = get_template_and_user({
 173     template_name => $template_name,
 174     query => $cgi,
 175     type => "intranet",
 176     authnotrequired => 0,
 177     flagsrequired   => { catalogue => 1 },
 178     }
 179 );
 180 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 181     $template->param('UNIMARC' => 1);
 182 }
 183
 184 ## URI Re-Writing
 185 # Deprecated, but preserved because it's interesting :-)
 186 # The same thing can be accomplished with mod_rewrite in
 187 # a more elegant way
 188 #
 189 #my $rewrite_flag;
 190 #my $uri = $cgi->url(-base => 1);
 191 #my $relative_url = $cgi->url(-relative=>1);
 192 #$uri.="/".$relative_url."?";
 193 #warn "URI:$uri";
 194 #my @cgi_params_list = $cgi->param();
 195 #my $url_params = $cgi->Vars;
 196 #
 197 #for my $each_param_set (@cgi_params_list) {
 198 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 199 #}
 200 #warn "New URI:$uri";
 201 # Only re-write a URI if there are params or if it already hasn't been re-written
 202 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 203 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 204 #                            -cookie => $cookie);
 205 #    exit;
 206 #}
 207
 208 # load the branches
 209 my $branches = GetBranches();
 210 my @branch_loop;
 211
 212 # we need to know the borrower branch code to set a default branch
 213 my $borrowerbranchcode = C4::Context->userenv->{'branch'};
 214
 215 for my $branch_hash (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 216     # if independantbranches is activated, set the default branch to the borrower branch
 217     my $selected = (C4::Context->preference("independantbranches") and ($borrowerbranchcode eq $branch_hash)) ? 1 : undef;
 218     push @branch_loop, {value => "$branch_hash" , branchname => $branches->{$branch_hash}->{'branchname'}, selected => $selected};
 219 }
 220
 221 my $categories = GetBranchCategories(undef,'searchdomain');
 222
 223 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 224
 225 # load the Type stuff
 226 # load the Type stuff
 227 my $itemtypes = GetItemTypes;
 228 # the index parameter is different for item-level itemtypes
 229 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 230 my @itemtypesloop;
 231 my $selected=1;
 232 my $cnt;
 233 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes");
 234
 235 if (!$advanced_search_types or $advanced_search_types eq 'itemtypes') {                                                                 foreach my $thisitemtype ( sort {$itemtypes->{$a}->{'description'} cmp $itemtypes->{$b}->{'description'} } keys %$itemtypes ) {
 236     my %row =(  number=>$cnt++,
 237                 ccl => $itype_or_itemtype,
 238                 code => $thisitemtype,
 239                 selected => $selected,
 240                 description => $itemtypes->{$thisitemtype}->{'description'},
 241                 count5 => $cnt % 4,
 242                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 243             );
 244         $selected = 0 if ($selected) ;
 245         push @itemtypesloop, \%row;
 246     }
 247     $template->param(itemtypeloop => \@itemtypesloop);
 248 } else {
 249     my $advsearchtypes = GetAuthorisedValues($advanced_search_types);
 250     for my $thisitemtype (sort {$a->{'lib'} cmp $b->{'lib'}} @$advsearchtypes) {
 251         my %row =(
 252                 number=>$cnt++,
 253                 ccl => $advanced_search_types,
 254                 code => $thisitemtype->{authorised_value},
 255                 selected => $selected,
 256                 description => $thisitemtype->{'lib'},
 257                 count5 => $cnt % 4,
 258                 imageurl=> getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 259             );
 260         push @itemtypesloop, \%row;
 261     }
 262     $template->param(itemtypeloop => \@itemtypesloop);
 263 }
 264
 265 # The following should only be loaded if we're bringing up the advanced search template
 266 if ( $template_type eq 'advsearch' ) {
 267
 268     # load the servers (used for searching -- to do federated searching, etc.)
 269     my $primary_servers_loop;# = displayPrimaryServers();
 270     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 271
 272     my $secondary_servers_loop;
 273     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 274
 275     # set the default sorting
 276     my $default_sort_by = C4::Context->preference('defaultSortField')."_".C4::Context->preference('defaultSortOrder')
 277         if (C4::Context->preference('OPACdefaultSortField') && C4::Context->preference('OPACdefaultSortOrder'));
 278     $template->param($default_sort_by => 1);
 279
 280     # determine what to display next to the search boxes (ie, boolean option
 281     # shouldn't appear on the first one, scan indexes should, adding a new
 282     # box should only appear on the last, etc.
 283     my @search_boxes_array;
 284     my $search_boxes_count = C4::Context->preference("OPACAdvSearchInputCount") || 3; # FIXME: using OPAC sysprefs?
 285     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 286     for (my $i=1;$i<=$search_boxes_count;$i++) {
 287         # if it's the first one, don't display boolean option, but show scan indexes
 288         if ($i==1) {
 289             push @search_boxes_array, {scan_index => 1};
 290         }
 291         # if it's the last one, show the 'add field' box
 292         elsif ($i==$search_boxes_count) {
 293             push @search_boxes_array,
 294                 {
 295                 boolean => 1,
 296                 add_field => 1,
 297                 };
 298         }
 299         else {
 300             push @search_boxes_array,
 301                 {
 302                 boolean => 1,
 303                 };
 304         }
 305
 306     }
 307     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 308                       search_boxes_loop => \@search_boxes_array);
 309
 310     # load the language limits (for search)
 311     my $languages_limit_loop = getAllLanguages();
 312     $template->param(search_languages_loop => $languages_limit_loop,);
 313
 314     # use the global setting by default
 315     if ( C4::Context->preference("expandedSearchOption") == 1) {
 316         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 317     }
 318     # but let the user override it
 319     if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 320         $template->param( expanded_options => $cgi->param('expanded_options'));
 321     }
 322
 323     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 324
 325     output_html_with_http_headers $cgi, $cookie, $template->output;
 326     exit;
 327 }
 328
 329 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 330
 331 # Fetch the paramater list as a hash in scalar context:
 332 #  * returns paramater list as tied hash ref
 333 #  * we can edit the values by changing the key
 334 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 335 my $params = $cgi->Vars;
 336
 337 # Params that can have more than one value
 338 # sort by is used to sort the query
 339 # in theory can have more than one but generally there's just one
 340 my @sort_by;
 341 my $default_sort_by = C4::Context->preference('defaultSortField')."_".C4::Context->preference('defaultSortOrder')
 342     if (C4::Context->preference('defaultSortField') && C4::Context->preference('defaultSortOrder'));
 343
 344 @sort_by = split("\0",$params->{'sort_by'}) if $params->{'sort_by'};
 345 $sort_by[0] = $default_sort_by unless $sort_by[0];
 346 foreach my $sort (@sort_by) {
 347     $template->param($sort => 1);
 348 }
 349 $template->param('sort_by' => $sort_by[0]);
 350
 351 # Use the servers defined, or just search our local catalog(default)
 352 my @servers;
 353 @servers = split("\0",$params->{'server'}) if $params->{'server'};
 354 unless (@servers) {
 355     #FIXME: this should be handled using Context.pm
 356     @servers = ("biblioserver");
 357     # @servers = C4::Context->config("biblioserver");
 358 }
 359 # operators include boolean and proximity operators and are used
 360 # to evaluate multiple operands
 361 my @operators;
 362 @operators = split("\0",$params->{'op'}) if $params->{'op'};
 363
 364 # indexes are query qualifiers, like 'title', 'author', etc. They
 365 # can be single or multiple parameters separated by comma: kw,right-Truncation
 366 my @indexes;
 367 @indexes = split("\0",$params->{'idx'});
 368
 369 # if a simple index (only one)  display the index used in the top search box
 370 if ($indexes[0] && !$indexes[1]) {
 371     $template->param("ms_".$indexes[0] => 1);}
 372
 373
 374 # an operand can be a single term, a phrase, or a complete ccl query
 375 my @operands;
 376 @operands = split("\0",$params->{'q'}) if $params->{'q'};
 377
 378 # limits are use to limit to results to a pre-defined category such as branch or language
 379 my @limits;
 380 @limits = split("\0",$params->{'limit'}) if $params->{'limit'};
 381
 382 if($params->{'multibranchlimit'}) {
 383 push @limits, join(" or ", map { "branch: $_ "}  @{GetBranchesInCategory($params->{'multibranchlimit'})}) ;
 384 }
 385
 386 my $available;
 387 foreach my $limit(@limits) {
 388     if ($limit =~/available/) {
 389         $available = 1;
 390     }
 391 }
 392 $template->param(available => $available);
 393
 394 # append year limits if they exist
 395 my $limit_yr;
 396 my $limit_yr_value;
 397 if ($params->{'limit-yr'}) {
 398     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 399         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 400         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 401         $limit_yr_value = "$yr1-$yr2";
 402     }
 403     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 404         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 405         $limit_yr_value = $params->{'limit-yr'};
 406     }
 407     push @limits,$limit_yr;
 408     #FIXME: Should return a error to the user, incorect date format specified
 409 }
 410
 411 # convert indexes and operands to corresponding parameter names for the z3950 search
 412 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 413 my $z3950par;
 414 my $indexes2z3950 = {
 415         kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 416         'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 417         ti=>'title', 'ti,phr'=>'title', se=>'title'
 418 };
 419 for (my $ii = 0; $ii < @operands; ++$ii)
 420 {
 421         my $name = $indexes2z3950->{$indexes[$ii]};
 422         if (defined $name && defined $operands[$ii])
 423         {
 424                 $z3950par ||= {};
 425                 $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 426         }
 427 }
 428
 429
 430 # Params that can only have one value
 431 my $scan = $params->{'scan'};
 432 my $count = C4::Context->preference('numSearchResults') || 20;
 433 my $results_per_page = $params->{'count'} || $count;
 434 my $offset = $params->{'offset'} || 0;
 435 my $page = $cgi->param('page') || 1;
 436 #my $offset = ($page-1)*$results_per_page;
 437 my $hits;
 438 my $expanded_facet = $params->{'expand'};
 439
 440 # Define some global variables
 441 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 442
 443 my @results;
 444
 445 ## I. BUILD THE QUERY
 446 my $lang = C4::Output::getlanguagecookie($cgi);
 447 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by,$scan,$lang);
 448
 449 ## parse the query_cgi string and put it into a form suitable for <input>s
 450 my @query_inputs;
 451 my $scan_index_to_use;
 452
 453 for my $this_cgi ( split('&',$query_cgi) ) {
 454     next unless $this_cgi;
 455     $this_cgi =~ m/(.*=)(.*)/;
 456     my $input_name = $1;
 457     my $input_value = $2;
 458     $input_name =~ s/=$//;
 459     push @query_inputs, { input_name => $input_name, input_value => $input_value };
 460         if ($input_name eq 'idx') {
 461         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 462         }
 463 }
 464 $template->param ( QUERY_INPUTS => \@query_inputs,
 465                    scan_index_to_use => $scan_index_to_use );
 466
 467 ## parse the limit_cgi string and put it into a form suitable for <input>s
 468 my @limit_inputs;
 469 for my $this_cgi ( split('&',$limit_cgi) ) {
 470     next unless $this_cgi;
 471     # handle special case limit-yr
 472     if ($this_cgi =~ /yr,st-numeric/) {
 473         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 474         next;
 475     }
 476     $this_cgi =~ m/(.*=)(.*)/;
 477     my $input_name = $1;
 478     my $input_value = $2;
 479     $input_name =~ s/=$//;
 480     push @limit_inputs, { input_name => $input_name, input_value => $input_value };
 481 }
 482 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 483
 484 ## II. DO THE SEARCH AND GET THE RESULTS
 485 my $total; # the total results for the whole set
 486 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 487 my @results_array;
 488 my $results_hashref;
 489
 490 if (C4::Context->preference('NoZebra')) {
 491     $query=~s/yr(:|=)\s*([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 492     $simple_query=~s/yr\s*(:|=)([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 493     # warn $query;
 494     eval {
 495         ($error, $results_hashref, $facets) = NZgetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 496     };
 497 } else {
 498     eval {
 499         ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 500     };
 501 }
 502 # This sorts the facets into alphabetical order
 503 if ($facets) {
 504     foreach my $f (@$facets) {
 505         $f->{facets} = [ sort { uc($a->{facet_title_value}) cmp uc($b->{facet_title_value}) } @{ $f->{facets} } ];
 506     }
 507 }
 508 if ($@ || $error) {
 509     $template->param(query_error => $error.$@);
 510     output_html_with_http_headers $cgi, $cookie, $template->output;
 511     exit;
 512 }
 513
 514 # At this point, each server has given us a result set
 515 # now we build that set for template display
 516 my @sup_results_array;
 517 for (my $i=0;$i<@servers;$i++) {
 518     my $server = $servers[$i];
 519     if ($server =~/biblioserver/) { # this is the local bibliographic server
 520         $hits = $results_hashref->{$server}->{"hits"};
 521         my $page = $cgi->param('page') || 0;
 522         my @newresults = searchResults('intranet', $query_desc, $hits, $results_per_page, $offset, $scan,
 523                                        @{$results_hashref->{$server}->{"RECORDS"}});
 524         $total = $total + $results_hashref->{$server}->{"hits"};
 525         ## If there's just one result, redirect to the detail page
 526         if ($total == 1) {
 527             my $biblionumber = $newresults[0]->{biblionumber};
 528                         my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 529                         my $views = { C4::Search::enabled_staff_search_views };
 530             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 531                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 532             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 533                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 534             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 535                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 536             } else {
 537                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 538             }
 539             exit;
 540         }
 541
 542
 543         if ($hits) {
 544             $template->param(total => $hits);
 545             my $limit_cgi_not_availablity = $limit_cgi;
 546             $limit_cgi_not_availablity =~ s/&limit=available//g;
 547             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 548             $template->param(limit_cgi => $limit_cgi);
 549             $template->param(query_cgi => $query_cgi);
 550             $template->param(query_desc => $query_desc);
 551             $template->param(limit_desc => $limit_desc);
 552             $template->param(offset     => $offset);
 553             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 554                         $template->param (z3950_search_params => C4::Search::z3950_search_args($query_desc));
 555             if ($query_desc || $limit_desc) {
 556                 $template->param(searchdesc => 1);
 557             }
 558             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 559             $template->param(results_per_page =>  $results_per_page);
 560             $template->param(SEARCH_RESULTS => \@newresults);
 561
 562             ## FIXME: add a global function for this, it's better than the current global one
 563             ## Build the page numbers on the bottom of the page
 564             my @page_numbers;
 565             # total number of pages there will be
 566             my $pages = ceil($hits / $results_per_page);
 567             # default page number
 568             my $current_page_number = 1;
 569             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 570             my $previous_page_offset = $offset - $results_per_page unless ($offset - $results_per_page <0);
 571             my $next_page_offset = $offset + $results_per_page;
 572             # If we're within the first 10 pages, keep it simple
 573             #warn "current page:".$current_page_number;
 574             if ($current_page_number < 10) {
 575                 # just show the first 10 pages
 576                 # Loop through the pages
 577                 my $pages_to_show = 10;
 578                 $pages_to_show = $pages if $pages<10;
 579                 for (my $i=1; $i<=$pages_to_show;$i++) {
 580                     # the offset for this page
 581                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 582                     # the page number for this page
 583                     my $this_page_number = $i;
 584                     # it should only be highlighted if it's the current page
 585                     my $highlight = 1 if ($this_page_number == $current_page_number);
 586                     # put it in the array
 587                     push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 588
 589                 }
 590
 591             }
 592
 593             # now, show twenty pages, with the current one smack in the middle
 594             else {
 595                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 596                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 597                     my $this_page_number = $i-9;
 598                     my $highlight = 1 if ($this_page_number == $current_page_number);
 599                     if ($this_page_number <= $pages) {
 600                         push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 601                     }
 602                 }
 603             }
 604             # FIXME: no previous_page_offset when pages < 2
 605             $template->param(   PAGE_NUMBERS => \@page_numbers,
 606                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 607             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 608         }
 609
 610
 611         # no hits
 612         else {
 613             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 614                         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 615         }
 616
 617     } # end of the if local
 618
 619     # asynchronously search the authority server
 620     elsif ($server =~/authorityserver/) { # this is the local authority server
 621         my @inner_sup_results_array;
 622         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 623             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 624             # warn "Authority Found: ".$marc_record_object->as_formatted();
 625             push @inner_sup_results_array, {
 626                 'title' => $marc_record_object->field(100)->subfield('a'),
 627                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 628             };
 629         }
 630         push @sup_results_array, {  servername => $server,
 631                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 632     }
 633     # FIXME: can add support for other targets as needed here
 634     $template->param(           outer_sup_results_loop => \@sup_results_array);
 635 } #/end of the for loop
 636 #$template->param(FEDERATED_RESULTS => \@results_array);
 637
 638
 639 $template->param(
 640             #classlist => $classlist,
 641             total => $total,
 642             opacfacets => 1,
 643             facets_loop => $facets,
 644             scan => $scan,
 645             search_error => $error,
 646 );
 647
 648 if ($query_desc || $limit_desc) {
 649     $template->param(searchdesc => 1);
 650 }
 651
 652 # VI. BUILD THE TEMPLATE
 653
 654 # Build drop-down list for 'Add To:' menu...
 655
 656 my $row_count = 10; # FIXME:This probably should be a syspref
 657 my ($pubshelves, $total) = GetRecentShelves(2, $row_count, undef);
 658 my ($barshelves, $total) = GetRecentShelves(1, $row_count, $borrowernumber);
 659
 660 my @pubshelves = @{$pubshelves};
 661 my @barshelves = @{$barshelves};
 662
 663 if (@pubshelves) {
 664         $template->param( addpubshelves     => scalar (@pubshelves));
 665         $template->param( addpubshelvesloop => @pubshelves);
 666 }
 667
 668 if (@barshelves) {
 669         $template->param( addbarshelves     => scalar (@barshelves));
 670         $template->param( addbarshelvesloop => @barshelves);
 671 }
 672
 673
 674
 675 output_html_with_http_headers $cgi, $cookie, $template->output;