catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Circulation qw( barcodedecode );
 145 use C4::Auth qw( get_template_and_user );
 146 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 147 use C4::Languages qw( getlanguage getLanguages );
 148 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 149 use URI::Escape;
 150 use POSIX qw(ceil floor);
 151 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 152
 153 use Koha::ItemTypes;
 154 use Koha::Library::Groups;
 155 use Koha::Patrons;
 156 use Koha::SearchEngine::Search;
 157 use Koha::SearchEngine::QueryBuilder;
 158 use Koha::Virtualshelves;
 159 use Koha::SearchFields;
 160 use Koha::SearchFilters;
 161
 162 use URI::Escape;
 163 use JSON qw( decode_json encode_json );
 164
 165 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 166 # create a new CGI object
 167 # FIXME: no_undef_params needs to be tested
 168 use CGI qw('-no_undef_params' -utf8 );
 169 my $cgi = CGI->new;
 170
 171 # decide which template to use
 172 my $template_name;
 173 my $template_type;
 174 # limits are used to limit to results to a pre-defined category such as branch or language
 175 my @limits = map uri_unescape($_), $cgi->multi_param("limit");
 176 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 177 my %is_nolimit = map { $_ => 1 } @nolimits;
 178 @limits = grep { not $is_nolimit{$_} } @limits;
 179 if  (
 180         !$cgi->param('edit_search') && !$cgi->param('edit_filter') &&
 181         ( (@limits>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('limit-yr')) )
 182     ) {
 183     $template_name = 'catalogue/results.tt';
 184     $template_type = 'results';
 185 }
 186 else {
 187     $template_name = 'catalogue/advsearch.tt';
 188     $template_type = 'advsearch';
 189 }
 190 # load the template
 191 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 192     template_name => $template_name,
 193     query => $cgi,
 194     type => "intranet",
 195     flagsrequired   => { catalogue => 1 },
 196     }
 197 );
 198
 199 my $lang = C4::Languages::getlanguage($cgi);
 200
 201 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 202     $template->param('UNIMARC' => 1);
 203 }
 204
 205 if($cgi->cookie("holdfor")){
 206     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 207     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 208         $template->param(
 209             holdfor        => $cgi->cookie("holdfor"),
 210             holdfor_patron => $holdfor_patron,
 211         );
 212     }
 213 }
 214
 215 if($cgi->cookie("holdforclub")){
 216     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 217     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 218         $template->param(
 219             holdforclub => $cgi->cookie("holdforclub"),
 220             holdforclub_name => $holdfor_club->name,
 221         );
 222     }
 223 }
 224
 225 if($cgi->cookie("searchToOrder")){
 226     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 227     $template->param(
 228         searchtoorder_basketno => $basketno,
 229         searchtoorder_vendorid => $vendorid
 230     );
 231 }
 232
 233 # get biblionumbers stored in the cart
 234 my @cart_list;
 235
 236 if($cgi->cookie("intranet_bib_list")){
 237     my $cart_list = $cgi->cookie("intranet_bib_list");
 238     @cart_list = split(/\//, $cart_list);
 239 }
 240
 241 my @search_groups =
 242   Koha::Library::Groups->get_search_groups( { interface => 'staff' } )->as_list;
 243
 244 my $branch_limit = '';
 245 my $limit_param = $cgi->param('limit');
 246 if ( $limit_param and $limit_param =~ /branch:([\w-]+)/ ) {
 247     $branch_limit = $1;
 248 }
 249
 250 $template->param(
 251     search_groups    => \@search_groups,
 252     branch_limit     => $branch_limit
 253 );
 254
 255 # load the Type stuff
 256 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 257 my $advancedsearchesloop = prepare_adv_search_types($types);
 258 $template->param(advancedsearchesloop => $advancedsearchesloop);
 259
 260 $template->param( searchid => scalar $cgi->param('searchid'), );
 261
 262 # The following should only be loaded if we're bringing up the advanced search template
 263 if ( $template_type eq 'advsearch' ) {
 264
 265     my @operands;
 266     my @operators;
 267     my @indexes;
 268     my $expanded = $cgi->param('expanded_options');
 269     if( $cgi->param('edit_search') ){
 270         @operands = $cgi->multi_param('q');
 271         @operators = $cgi->multi_param('op');
 272         @indexes   = $cgi->multi_param('idx');
 273         $template->param(
 274            sort      => $cgi->param('sort_by'),
 275         );
 276         # determine what to display next to the search boxes
 277     } elsif ( $cgi->param('edit_filter') ){
 278         my $search_filter = Koha::SearchFilters->find( $cgi->param('edit_filter') );
 279         if( $search_filter ){
 280             my $query = decode_json( $search_filter->query );
 281             my $limits = decode_json( $search_filter->limits );
 282             @operands  = @{ $query->{operands} };
 283             @indexes   = @{ $query->{indexes} };
 284             @operators = @{ $query->{operators} };
 285             @limits    = @{ $limits->{limits} };
 286             $template->param( edit_filter => $search_filter );
 287         } else {
 288             $template->param( unknown_filter => 1 );
 289         }
 290     }
 291
 292     while( scalar @operands < 3 ){
 293         push @operands, "";
 294     }
 295     $template->param( operands  => \@operands );
 296     $template->param( operators => \@operators );
 297     $template->param( indexes   => \@indexes );
 298
 299     my %limit_hash;
 300     foreach my $limit (@limits){
 301         if ( $limit eq 'available' ){
 302             $template->param( limit_available => 1 );
 303         } else {
 304             my ($index,$value) = split(':',$limit);
 305             $value =~ s/"//g;
 306             if ( $index =~ /mc-/ ){
 307                 $limit_hash{$index . "_" . $value} = 1;
 308             } else {
 309                 push @{$limit_hash{$index}}, $value;
 310             }
 311         }
 312     };
 313     $template->param( limits => \%limit_hash );
 314
 315     $expanded = 1 if scalar @operators || scalar @limits;
 316
 317     # load the servers (used for searching -- to do federated searching, etc.)
 318     my $primary_servers_loop;# = displayPrimaryServers();
 319     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 320
 321     my $secondary_servers_loop;
 322     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 323
 324     # set the default sorting
 325     if (   C4::Context->preference('defaultSortField')
 326         && C4::Context->preference('defaultSortOrder') ) {
 327         my $default_sort_by =
 328             C4::Context->preference('defaultSortField') . '_'
 329           . C4::Context->preference('defaultSortOrder');
 330         $template->param( sort_by => $default_sort_by  );
 331     }
 332
 333     $template->param(uc(C4::Context->preference("marcflavour")) =>1 );
 334
 335     # load the language limits (for search)
 336     my $languages_limit_loop = getLanguages($lang, 1);
 337     $template->param(search_languages_loop => $languages_limit_loop,);
 338
 339     # Expanded search options in advanced search:
 340     # use the global setting by default, but let the user override it
 341     {
 342         $expanded = C4::Context->preference("expandedSearchOption") || 0
 343             if !defined($expanded) || $expanded !~ /^0|1$/;
 344         $template->param( expanded_options => $expanded );
 345     }
 346
 347     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 348
 349     output_html_with_http_headers $cgi, $cookie, $template->output;
 350     exit;
 351 }
 352
 353 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 354
 355 # Fetch the paramater list as a hash in scalar context:
 356 #  * returns paramater list as tied hash ref
 357 #  * we can edit the values by changing the key
 358 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 359 my $params = $cgi->Vars;
 360 # Params that can have more than one value
 361 # sort by is used to sort the query
 362 # in theory can have more than one but generally there's just one
 363 my @sort_by;
 364 my $default_sort_by;
 365 if (   C4::Context->preference('defaultSortField')
 366     && C4::Context->preference('defaultSortOrder') ) {
 367     $default_sort_by =
 368         C4::Context->preference('defaultSortField') . '_'
 369       . C4::Context->preference('defaultSortOrder');
 370 }
 371
 372 @sort_by = $cgi->multi_param('sort_by');
 373 $sort_by[0] = $default_sort_by unless $sort_by[0];
 374 foreach my $sort (@sort_by) {
 375     $template->param($sort => 1) if $sort;
 376 }
 377 $template->param('sort_by' => $sort_by[0]);
 378
 379 # Use the servers defined, or just search our local catalog(default)
 380 my @servers = $cgi->multi_param('server');
 381 unless (@servers) {
 382     #FIXME: this should be handled using Context.pm
 383     @servers = ("biblioserver");
 384     # @servers = C4::Context->config("biblioserver");
 385 }
 386 # operators include boolean and proximity operators and are used
 387 # to evaluate multiple operands
 388 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 389
 390 # indexes are query qualifiers, like 'title', 'author', etc. They
 391 # can be single or multiple parameters separated by comma: kw,right-Truncation
 392 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 393
 394 # if a simple index (only one)  display the index used in the top search box
 395 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 396     my $idx = "ms_".$indexes[0];
 397     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 398     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 399     $template->param(header_pulldown => $idx);
 400 }
 401
 402 # an operand can be a single term, a phrase, or a complete ccl query
 403 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 404
 405 # if a simple search, display the value in the search box
 406 my $basic_search = 0;
 407 if ($operands[0] && !$operands[1]) {
 408     my $ms_query = $operands[0];
 409     $ms_query =~ s/ #\S+//;
 410     $template->param(ms_value => $ms_query);
 411     $basic_search=1;
 412 }
 413
 414 my $available;
 415 foreach my $limit(@limits) {
 416     if ($limit =~/available/) {
 417         $available = 1;
 418     }
 419 }
 420 $template->param(available => $available);
 421
 422 # append year limits if they exist
 423 my $limit_yr;
 424 my $limit_yr_value;
 425 if ($params->{'limit-yr'}) {
 426     if ($params->{'limit-yr'} =~ /\d{4}/) {
 427         $limit_yr = "yr,st-numeric:$params->{'limit-yr'}";
 428         $limit_yr_value = $params->{'limit-yr'};
 429     }
 430     push @limits,$limit_yr;
 431     #FIXME: Should return a error to the user, incorect date format specified
 432 }
 433
 434 # convert indexes and operands to corresponding parameter names for the z3950 search
 435 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 436 my $z3950par;
 437 my $indexes2z3950 = {
 438     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 439     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 440     ti=>'title', 'ti,phr'=>'title', se=>'title'
 441 };
 442 for (my $ii = 0; $ii < @operands; ++$ii)
 443 {
 444     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 445     if (defined $name && defined $operands[$ii])
 446     {
 447         $z3950par ||= {};
 448         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 449     }
 450 }
 451
 452
 453 # Params that can only have one value
 454 my $scan = $params->{'scan'};
 455 my $count = C4::Context->preference('numSearchResults') || 20;
 456 my $results_per_page = $params->{'count'} || $count;
 457 my $offset = $params->{'offset'} || 0;
 458 my $whole_record = $params->{'whole_record'} || 0;
 459 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 460 $offset = 0 if $offset < 0;
 461 my $page = $cgi->param('page') || 1;
 462 #my $offset = ($page-1)*$results_per_page;
 463
 464 # Define some global variables
 465 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 466
 467 my $builder = Koha::SearchEngine::QueryBuilder->new(
 468     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 469 my $searcher = Koha::SearchEngine::Search->new(
 470     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 471
 472 # If index indicates the value is a barocode, we need to preproccess it before searching
 473 for ( my $i = 0; $i < @operands; $i++ ) {
 474     $operands[$i] = barcodedecode($operands[$i]) if $indexes[$i] eq 'bc';
 475 }
 476
 477 ## I. BUILD THE QUERY
 478 (
 479     $error,             $query, $simple_query, $query_cgi,
 480     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 481     $query_type
 482   )
 483   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 484     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 485
 486 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 487
 488 ## parse the query_cgi string and put it into a form suitable for <input>s
 489 my @query_inputs;
 490 my $scan_index_to_use;
 491 my $scan_search_term_to_use;
 492
 493 if ($query_cgi) {
 494     for my $this_cgi ( split('&', $query_cgi) ) {
 495         next unless $this_cgi;
 496         $this_cgi =~ m/(.*?)=(.*)/;
 497         my $input_name = $1;
 498         my $input_value = $2;
 499         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 500         if ($input_name eq 'idx') {
 501             # The form contains multiple fields, so take the first value as the scan index
 502             $scan_index_to_use = $input_value unless $scan_index_to_use;
 503         }
 504         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 505             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 506         }
 507     }
 508 }
 509
 510 $template->param ( QUERY_INPUTS => \@query_inputs,
 511                    scan_index_to_use => $scan_index_to_use,
 512                    scan_search_term_to_use => $scan_search_term_to_use );
 513
 514 ## parse the limit_cgi string and put it into a form suitable for <input>s
 515 my @limit_inputs;
 516 my %active_filters;
 517 if ($limit_cgi) {
 518     for my $this_cgi ( split('&', $limit_cgi) ) {
 519         next unless $this_cgi;
 520         # handle special case limit-yr
 521         if ($this_cgi =~ /yr,st-numeric/) {
 522             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 523             next;
 524         }
 525         $this_cgi =~ m/(.*=)(.*)/;
 526         my $input_name = $1;
 527         my $input_value = $2;
 528         $input_name =~ s/=$//;
 529         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 530         if( $input_value =~ /search_filter/ ){
 531             my ($filter_id) = ( uri_unescape($input_value) =~ /^search_filter:(.*)$/ );
 532             $active_filters{$filter_id} = 1;
 533         }
 534
 535     }
 536 }
 537 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 538
 539 ## II. DO THE SEARCH AND GET THE RESULTS
 540 my $total = 0; # the total results for the whole set
 541 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 542 my $results_hashref;
 543
 544 eval {
 545     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 546     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 547         $query,            $simple_query, \@sort_by,       \@servers,
 548         $results_per_page, $offset,       undef,           $itemtypes,
 549         $query_type,       $scan
 550     );
 551 };
 552
 553 if ($@ || $error) {
 554     my $query_error = q{};
 555     $query_error .= $error if $error;
 556     $query_error .= $@ if $@;
 557     $template->param(query_error => $query_error);
 558     output_html_with_http_headers $cgi, $cookie, $template->output;
 559     exit;
 560 }
 561
 562 # At this point, each server has given us a result set
 563 # now we build that set for template display
 564 my @sup_results_array;
 565 for (my $i=0;$i<@servers;$i++) {
 566     my $server = $servers[$i];
 567     if ($server =~/biblioserver/) { # this is the local bibliographic server
 568         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 569         if ( $hits == 0 && $basic_search ){
 570             $operands[0] = '"'.$operands[0].'"'; #quote it
 571             ## I. BUILD THE QUERY
 572             (
 573                 $error,             $query, $simple_query, $query_cgi,
 574                 $query_desc,        $limit, $limit_cgi,    $limit_desc,
 575                 $query_type
 576               )
 577               = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 578                 \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 579             my $quoted_results_hashref;
 580             eval {
 581                 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 582                 ( $error, $quoted_results_hashref, $facets ) = $searcher->search_compat(
 583                     $query,            $simple_query, \@sort_by,       ['biblioserver'],
 584                     $results_per_page, $offset,       undef,           $itemtypes,
 585                     $query_type,       $scan
 586                 );
 587             };
 588             my $quoted_hits = $quoted_results_hashref->{$server}->{"hits"} // 0;
 589             if ( $quoted_hits ){
 590                 $results_hashref->{'biblioserver'} = $quoted_results_hashref->{'biblioserver'};
 591                 $hits = $quoted_hits;
 592             }
 593         }
 594         my $page = $cgi->param('page') || 0;
 595         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 596                                        $results_hashref->{$server}->{"RECORDS"});
 597         $total = $total + $hits;
 598
 599         # Search history
 600         if (C4::Context->preference('EnableSearchHistory')) {
 601             unless ( $offset ) {
 602                 my $path_info = $cgi->url(-path_info=>1);
 603                 my $query_cgi_history = $cgi->url(-query=>1);
 604                 $query_cgi_history =~ s/^$path_info\?//;
 605                 $query_cgi_history =~ s/;/&/g;
 606                 my $query_desc_history = $query_desc;
 607                 $query_desc_history .= ", $limit_desc"
 608                     if $limit_desc;
 609
 610                 C4::Search::History::add({
 611                     userid => $borrowernumber,
 612                     sessionid => $cgi->cookie("CGISESSID"),
 613                     query_desc => $query_desc_history,
 614                     query_cgi => $query_cgi_history,
 615                     total => $total,
 616                     type => "biblio",
 617                 });
 618             }
 619             $template->param( EnableSearchHistory => 1 );
 620         }
 621
 622         ## If there's just one result, redirect to the detail page unless doing an index scan
 623         if ($total == 1 && !$scan) {
 624             my $biblionumber = $newresults[0]->{biblionumber};
 625             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 626             my $views = { C4::Search::enabled_staff_search_views };
 627             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 628                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 629             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 630                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 631             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 632                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 633             } else {
 634                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 635             }
 636             exit;
 637         }
 638
 639         # set up parameters if user wishes to re-run the search
 640         # as a Z39.50 search
 641         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 642         $template->param(limit_cgi => $limit_cgi);
 643         $template->param(query_cgi => $query_cgi);
 644         $template->param(query_json => encode_json({
 645             operators => \@operators,
 646             operands => \@operands,
 647             indexes => \@indexes
 648         }));
 649         $template->param(limit_json => encode_json({
 650             limits => \@limits
 651         }));
 652         $template->param(query_desc => $query_desc);
 653         $template->param(limit_desc => $limit_desc);
 654         $template->param(offset     => $offset);
 655         $template->param(offset     => $offset);
 656
 657
 658         if ($hits) {
 659             $template->param(total => $hits);
 660             if ($limit_cgi) {
 661                 my $limit_cgi_not_availablity = $limit_cgi;
 662                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 663                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 664             }
 665             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 666             if ($query_desc || $limit_desc) {
 667                 $template->param(searchdesc => 1);
 668             }
 669             $template->param(results_per_page =>  $results_per_page);
 670             # must define a value for size if not present in DB
 671             # in order to avoid problems generated by the default size value in TT
 672             foreach my $line (@newresults) {
 673                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 674                 # while we're checking each line, see if item is in the cart
 675                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 676                     $line->{'incart'} = 1;
 677                 }
 678             }
 679             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 680                 Koha::SearchEngine::Search->pagination_bar(
 681                     {
 682                         hits              => $hits,
 683                         max_result_window => $searcher->max_result_window,
 684                         results_per_page  => $results_per_page,
 685                         offset            => $offset,
 686                         sort_by           => \@sort_by
 687                     }
 688                 );
 689             $template->param( hits_to_paginate => $hits_to_paginate );
 690             $template->param(SEARCH_RESULTS => \@newresults);
 691             # FIXME: no previous_page_offset when pages < 2
 692             $template->param(   PAGE_NUMBERS => $page_numbers,
 693                                 last_page_offset => $last_page_offset,
 694                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 695             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 696         }
 697
 698
 699         # no hits
 700         else {
 701             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 702         }
 703
 704     } # end of the if local
 705
 706     # asynchronously search the authority server
 707     elsif ($server =~/authorityserver/) { # this is the local authority server
 708         my @inner_sup_results_array;
 709         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 710             my $marc_record_object = C4::Search::new_record_from_zebra(
 711                 'authorityserver',
 712                 $sup_record
 713             );
 714             # warn "Authority Found: ".$marc_record_object->as_formatted();
 715             push @inner_sup_results_array, {
 716                 'title' => $marc_record_object->field(100)->subfield('a'),
 717                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 718             };
 719         }
 720         push @sup_results_array, {  servername => $server,
 721                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 722     }
 723     # FIXME: can add support for other targets as needed here
 724     $template->param(           outer_sup_results_loop => \@sup_results_array);
 725 } #/end of the for loop
 726 #$template->param(FEDERATED_RESULTS => \@results_array);
 727
 728 my $gotonumber = $cgi->param('gotoNumber');
 729 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 730     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 731 }
 732 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 733 my $gotopage = $cgi->param('gotoPage');
 734 $template->{'VARS'}->{'gotoPage'} = $gotopage
 735   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 736
 737 for my $facet ( @$facets ) {
 738     for my $entry ( @{ $facet->{facets} } ) {
 739         my $index = $entry->{type_link_value};
 740         my $value = $entry->{facet_link_value};
 741         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 742     }
 743 }
 744
 745
 746 $template->param(
 747     search_filters => Koha::SearchFilters->search({ staff_client => 1 }, { order_by => "name" }),
 748     active_filters => \%active_filters,
 749 ) if C4::Context->preference('SavedSearchFilters');
 750
 751 $template->param(
 752             #classlist => $classlist,
 753             total => $total,
 754             opacfacets => 1,
 755             facets_loop => $facets,
 756             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 757             scan => $scan,
 758             search_error => $error,
 759 );
 760
 761 if ($query_desc || $limit_desc) {
 762     $template->param(searchdesc => 1);
 763 }
 764
 765 # VI. BUILD THE TEMPLATE
 766
 767 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 768     {
 769         borrowernumber => $borrowernumber,
 770         add_allowed    => 1,
 771         public         => 0,
 772     }
 773 );
 774 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 775     {
 776         borrowernumber => $borrowernumber,
 777         add_allowed    => 1,
 778         public         => 1,
 779     }
 780 );
 781
 782
 783 $template->param(
 784     add_to_some_private_shelves => $some_private_shelves,
 785     add_to_some_public_shelves  => $some_public_shelves,
 786 );
 787
 788 output_html_with_http_headers $cgi, $cookie, $template->output;
 789
 790
 791 =head2 prepare_adv_search_types
 792
 793     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 794     my @advanced_search_types = prepare_adv_search_types($type);
 795
 796 Different types can be searched for in the advanced search. This takes the
 797 system preference that defines these types and parses it into an arrayref for
 798 the template.
 799
 800 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 801 It also accounts for the "item-level_itypes" system preference.
 802
 803 =cut
 804
 805 sub prepare_adv_search_types {
 806     my ($types) = @_;
 807
 808     my @advanced_search_types = split( /\|/, $types );
 809
 810     # the index parameter is different for item-level itemtypes
 811     my $itype_or_itemtype =
 812       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 813     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 814
 815     my ( $cnt, @result );
 816     foreach my $advanced_srch_type (@advanced_search_types) {
 817         $advanced_srch_type =~ s/^\s*//;
 818         $advanced_srch_type =~ s/\s*$//;
 819         if ( $advanced_srch_type eq 'itemtypes' ) {
 820
 821        # itemtype is a special case, since it's not defined in authorized values
 822             my @itypesloop;
 823             foreach my $thisitemtype (
 824                 sort {
 825                     $itemtypes->{$a}->{'translated_description'}
 826                       cmp $itemtypes->{$b}->{'translated_description'}
 827                 } keys %$itemtypes
 828               )
 829             {
 830                 my %row = (
 831                     number      => $cnt++,
 832                     ccl         => "$itype_or_itemtype,phr",
 833                     code        => $thisitemtype,
 834                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 835                     imageurl    => getitemtypeimagelocation(
 836                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 837                     ),
 838                 );
 839                 push @itypesloop, \%row;
 840             }
 841             my %search_code = (
 842                 advanced_search_type => $advanced_srch_type,
 843                 code_loop            => \@itypesloop
 844             );
 845             push @result, \%search_code;
 846         }
 847         else {
 848             # covers all the other cases: non-itemtype authorized values
 849             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 850             my @authvalueloop;
 851             for my $thisitemtype (@$advsearchtypes) {
 852                 my %row = (
 853                     number      => $cnt++,
 854                     ccl         => $advanced_srch_type,
 855                     code        => $thisitemtype->{authorised_value},
 856                     description => $thisitemtype->{'lib'},
 857                     imageurl    => getitemtypeimagelocation(
 858                         'intranet', $thisitemtype->{'imageurl'}
 859                     ),
 860                 );
 861                 push @authvalueloop, \%row;
 862             }
 863             my %search_code = (
 864                 advanced_search_type => $advanced_srch_type,
 865                 code_loop            => \@authvalueloop
 866             );
 867             push @result, \%search_code;
 868         }
 869     }
 870     return \@result;
 871 }