cataloguing/value_builder/stocknumberam123.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2010 BibLibre SARL
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22 use C4::Auth;
  23 use CGI qw ( -utf8 );
  24 use C4::Context;
  25
  26 =head1 DESCRIPTION
  27
  28 This plugin is specific to AM123 but could be used as a base for similar operations.
  29 It is used for stocknumber computation.
  30
  31 If the user send an empty string, we return a simple incremented stocknumber.
  32 If a prefix is submited, we look for the highest stocknumber with this prefix, and return it incremented.
  33 In this case, a stocknumber has this form : "PREFIX 0009678570".
  34  - PREFIX is an upercase word
  35  - a space separator
  36  - 10 digits, with leading 0s if needed
  37
  38 =cut
  39
  40 sub plugin_javascript {
  41     my ($dbh,$record,$tagslib,$field_number,$tabloop) = @_;
  42     my $res="
  43     <script type='text/javascript'>
  44         function Blur$field_number() {
  45                 var code = document.getElementById('$field_number');
  46                 var url = '../cataloguing/plugin_launcher.pl?plugin_name=stocknumberam123.pl&code=' + code.value;
  47                 var req = \$.get(url);
  48                 req.done(function(resp){
  49                     code.value = resp;
  50                     return 1;
  51                 });
  52                 return 1;
  53         }
  54
  55     </script>
  56     ";
  57
  58     return ($field_number,$res);
  59 }
  60
  61 sub plugin {
  62     my ($input) = @_;
  63     my $code = $input->param('code');
  64
  65     my ($template, $loggedinuser, $cookie) = get_template_and_user({
  66         template_name   => "cataloguing/value_builder/ajax.tt",
  67         query           => $input,
  68         type            => "intranet",
  69         authnotrequired => 0,
  70         flagsrequired   => {editcatalogue => '*'},
  71         debug           => 1,
  72     });
  73
  74     my $dbh = C4::Context->dbh;
  75     # If the textbox is empty, we return a simple incremented stocknumber
  76     if ( $code eq "" ) {
  77         my $sth = $dbh->prepare("SELECT MAX(CAST(stocknumber AS SIGNED)) FROM items");
  78         $sth->execute;
  79
  80         if ( my $max = $sth->fetchrow ) {
  81             $template->param(
  82                 return => $max+1,
  83             );
  84         }
  85     # If a prefix is submited, we look for the highest stocknumber with this prefix, and return it incremented
  86     } elsif ( $code =~ m/^[A-Z]+$/ ) {
  87         my $sth = $dbh->prepare("SELECT MAX(CAST(SUBSTRING_INDEX(stocknumber,' ',-1) AS SIGNED)) FROM items WHERE stocknumber LIKE ?");
  88         $sth->execute($code.' %');
  89
  90         if ( my $max = $sth->fetchrow ) {
  91             $template->param(
  92                 return => $code.' '.sprintf('%010s',($max+1)),
  93             );
  94         }
  95     # The user entered a custom value, we don't touch it, this could be handled in js
  96     } else {
  97         $template->param(
  98             return => $code,
  99         );
 100     }
 101     output_html_with_http_headers $input, $cookie, $template->output;
 102 }