cataloguing/value_builder/stocknumberam123.pl

   1 #!/usr/bin/perl
   2
   3 # Converted to new plugin style (Bug 13437)
   4
   5 # Copyright 2010 BibLibre SARL
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth qw( get_template_and_user );
  26 use C4::Context;
  27 use C4::Output qw( output_html_with_http_headers );
  28
  29 =head1 DESCRIPTION
  30
  31 This plugin is specific to AM123 but could be used as a base for similar operations.
  32 It is used for stocknumber computation.
  33
  34 If the user send an empty string, we return a simple incremented stocknumber.
  35 If a prefix is submited, we look for the highest stocknumber with this prefix, and return it incremented.
  36 In this case, a stocknumber has this form : "PREFIX 0009678570".
  37  - PREFIX is an upercase word
  38  - a space separator
  39  - 10 digits, with leading 0s if needed
  40
  41 =cut
  42
  43 my $builder = sub {
  44     my ( $params ) = @_;
  45     my $res="
  46     <script>
  47         function Blur$params->{id}() {
  48                 var code = document.getElementById('$params->{id}');
  49                 var url = '../cataloguing/plugin_launcher.pl?plugin_name=stocknumberam123.pl&code=' + code.value;
  50                 var req = \$.get(url);
  51                 req.done(function(resp){
  52                     code.value = resp;
  53                     return 1;
  54                 });
  55                 return 1;
  56         }
  57     </script>
  58     ";
  59
  60     return $res;
  61 };
  62
  63 my $launcher = sub {
  64     my ( $params ) = @_;
  65     my $input = $params->{cgi};
  66     my $code = $input->param('code');
  67
  68     my ($template, $loggedinuser, $cookie) = get_template_and_user({
  69         template_name   => "cataloguing/value_builder/ajax.tt",
  70         query           => $input,
  71         type            => "intranet",
  72         flagsrequired   => {editcatalogue => '*'},
  73     });
  74
  75     my $dbh = C4::Context->dbh;
  76     # If the textbox is empty, we return a simple incremented stocknumber
  77     if ( $code eq "" ) {
  78         my $sth = $dbh->prepare("SELECT MAX(CAST(stocknumber AS SIGNED)) FROM items");
  79         $sth->execute;
  80
  81         if ( my $max = $sth->fetchrow ) {
  82             $template->param(
  83                 return => $max+1,
  84             );
  85         }
  86     # If a prefix is submited, we look for the highest stocknumber with this prefix, and return it incremented
  87     } elsif ( $code =~ m/^[a-zA-Z]+$/ ) {
  88         my $sth = $dbh->prepare("SELECT MAX(CAST(SUBSTRING_INDEX(stocknumber,' ',-1) AS SIGNED)) FROM items WHERE stocknumber LIKE ?");
  89         $sth->execute($code.' %');
  90
  91         if ( my $max = $sth->fetchrow ) {
  92             $template->param(
  93                 return => $code.' '.sprintf('%010s',($max+1)),
  94             );
  95         }
  96     # The user entered a custom value, we don't touch it, this could be handled in js
  97     } else {
  98         $template->param(
  99             return => $code,
 100         );
 101     }
 102     output_html_with_http_headers $input, $cookie, $template->output;
 103 };
 104
 105 return { builder => $builder, launcher => $launcher };