koha-tmpl/intranet-tmpl/prog/en/xslt/MARC21slim2SRWDC.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2
   3 <!DOCTYPE stylesheet [<!ENTITY nbsp "&#160;" >]>
   4
   5 <xsl:stylesheet version="1.0" xmlns:marc="http://www.loc.gov/MARC21/slim" xmlns:srw_dc="info:srw/schema/1/dc-schema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://purl.org/dc/elements/1.1/" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="marc">
   6         <xsl:import href="MARC21slimUtils.xsl"/>
   7         <xsl:output method="xml" indent="yes" encoding="UTF-8"/>
   8         <!-- modification log
   9         NT 01/04:  added collection level element
  10         and removed attributes
  11
  12         JR 06/04:  Added ISBN identifier
  13
  14    JR 09/05:  Added additional <subject> subfields and 651 for <coverage>
  15    RG 10/07/05: Corrected subject subfields; 10/12/05: added if statement for <language>
  16 -->
  17         <xsl:template match="/">
  18                 <xsl:if test="marc:collection">
  19                         <srw_dc:dcCollection xmlns:srw_dc="info:srw/schema/1/dc-schema" xsi:schemaLocation="info:srw/schema/1/dc-schema http://www.loc.gov/z3950/agency/zing/srw/dc-schema.xsd">
  20                                 <xsl:for-each select="marc:collection">
  21                                         <xsl:for-each select="marc:record">
  22                                                 <srw_dc:dc>
  23                                                         <xsl:apply-templates select="."/>
  24                                                 </srw_dc:dc>
  25                                         </xsl:for-each>
  26                                 </xsl:for-each>
  27                         </srw_dc:dcCollection>
  28                 </xsl:if>
  29                 <xsl:if test="marc:record">
  30                         <srw_dc:dc xmlns:srw_dc="info:srw/schema/1/dc-schema" xsi:schemaLocation="info:srw/schema/1/dc-schema http://www.loc.gov/z3950/agency/zing/srw/dc-schema.xsd">
  31                                 <xsl:apply-templates select="marc:record"/>
  32                         </srw_dc:dc>
  33                 </xsl:if>
  34         </xsl:template>
  35         <xsl:template match="marc:record">
  36                 <xsl:variable name="leader" select="marc:leader"/>
  37                 <xsl:variable name="leader6" select="substring($leader,7,1)"/>
  38                 <xsl:variable name="leader7" select="substring($leader,8,1)"/>
  39                 <xsl:variable name="controlField008" select="marc:controlfield[@tag=008]"/>
  40                 <xsl:for-each select="marc:datafield[@tag=245]">
  41                         <title>
  42                                 <xsl:call-template name="subfieldSelect">
  43                                         <xsl:with-param name="codes">abfghk</xsl:with-param>
  44                                 </xsl:call-template>
  45                         </title>
  46                 </xsl:for-each>
  47                 <xsl:for-each select="marc:datafield[@tag=100]|marc:datafield[@tag=110]|marc:datafield[@tag=111]|marc:datafield[@tag=700]|marc:datafield[@tag=710]|marc:datafield[@tag=711]|marc:datafield[@tag=720]">
  48                         <creator>
  49                                 <xsl:value-of select="normalize-space(.)"/>
  50                         </creator>
  51                 </xsl:for-each>
  52                 <type>
  53                         <xsl:if test="$leader7='c'">
  54                                 <!-- nt fix 1/04 -->
  55                                 <!--<xsl:attribute name="collection">yes</xsl:attribute>-->
  56                                 <xsl:text>collection</xsl:text>
  57                         </xsl:if>
  58                         <xsl:if test="$leader6='d' or $leader6='f' or $leader6='p' or $leader6='t'">
  59                                 <!-- nt fix 1/04 -->
  60                                 <!--<xsl:attribute name="manuscript">yes</xsl:attribute> -->
  61                                 <xsl:text>manuscript</xsl:text>
  62                         </xsl:if>
  63                         <xsl:choose>
  64                                 <xsl:when test="$leader6='a' or $leader6='t'">text</xsl:when>
  65                                 <xsl:when test="$leader6='e' or $leader6='f'">cartographic</xsl:when>
  66                                 <xsl:when test="$leader6='c' or $leader6='d'">notated music</xsl:when>
  67                                 <xsl:when test="$leader6='i' or $leader6='j'">sound recording</xsl:when>
  68                                 <xsl:when test="$leader6='k'">still image</xsl:when>
  69                                 <xsl:when test="$leader6='g'">moving image</xsl:when>
  70                                 <xsl:when test="$leader6='r'">three dimensional object</xsl:when>
  71                                 <xsl:when test="$leader6='m'">software, multimedia</xsl:when>
  72                                 <xsl:when test="$leader6='p'">mixed material</xsl:when>
  73                         </xsl:choose>
  74                 </type>
  75                 <xsl:for-each select="marc:datafield[@tag=655]">
  76                         <type>
  77                                 <xsl:value-of select="normalize-space(.)"/>
  78                         </type>
  79                 </xsl:for-each>
  80                 <xsl:for-each select="marc:datafield[@tag=260]">
  81                         <publisher>
  82                                 <xsl:call-template name="subfieldSelect">
  83                                         <xsl:with-param name="codes">ab</xsl:with-param>
  84                                 </xsl:call-template>
  85                         </publisher>
  86                 </xsl:for-each>
  87                 <xsl:for-each select="marc:datafield[@tag=260]/marc:subfield[@code='c']">
  88                         <date>
  89                                 <xsl:value-of select="."/>
  90                         </date>
  91                 </xsl:for-each>
  92                 <xsl:if test="substring($controlField008,36,3)">
  93                         <language>
  94                                 <xsl:value-of select="substring($controlField008,36,3)"/>
  95                         </language>
  96                 </xsl:if>
  97                 <xsl:for-each select="marc:datafield[@tag=856]/marc:subfield[@code='q']">
  98                         <format>
  99                                 <xsl:value-of select="."/>
 100                         </format>
 101                 </xsl:for-each>
 102                 <xsl:for-each select="marc:datafield[@tag=520]">
 103                         <description>
 104                                 <!-- nt fix 01/04 -->
 105                                 <xsl:value-of select="normalize-space(marc:subfield[@code='a'])"/>
 106                         </description>
 107                 </xsl:for-each>
 108                 <xsl:for-each select="marc:datafield[@tag=521]">
 109                         <description>
 110                                 <xsl:value-of select="marc:subfield[@code='a']"/>
 111                         </description>
 112                 </xsl:for-each>
 113                 <xsl:for-each select="marc:datafield[500&lt;@tag][@tag&lt;=599][not(@tag=506 or @tag=530 or @tag=540 or @tag=546)]">
 114                         <description>
 115                                 <xsl:value-of select="marc:subfield[@code='a']"/>
 116                         </description>
 117                 </xsl:for-each>
 118                 <xsl:for-each select="marc:datafield[@tag=600]">
 119                         <subject>
 120                                 <xsl:call-template name="subfieldSelect">
 121                                         <xsl:with-param name="codes">abcdefghjklmnopqrstu4</xsl:with-param>
 122                                 </xsl:call-template>
 123                                 <xsl:if test="marc:subfield[@code='v' or @code='x' or @code='y' or @code='z']">
 124                                 <xsl:text>--</xsl:text>
 125                                 <xsl:call-template name="subfieldSelect">
 126                                         <xsl:with-param name="codes">vxyz</xsl:with-param>
 127                                         <xsl:with-param name="delimeter">--</xsl:with-param>
 128                                 </xsl:call-template>
 129                                 </xsl:if>
 130                         </subject>
 131                 </xsl:for-each>
 132                 <xsl:for-each select="marc:datafield[@tag=610]">
 133                         <subject>
 134                                 <xsl:call-template name="subfieldSelect">
 135                                         <xsl:with-param name="codes">abcdefghklmnoprstu4</xsl:with-param>
 136                                 </xsl:call-template>
 137                                 <xsl:if test="marc:subfield[@code='v' or @code='x' or @code='y' or
 138                                         @code='z']">
 139                                         <xsl:text>--</xsl:text>
 140                                         <xsl:call-template name="subfieldSelect">
 141                                                 <xsl:with-param name="codes">vxyz</xsl:with-param>
 142                                                 <xsl:with-param name="delimeter">--</xsl:with-param>
 143                                         </xsl:call-template>
 144                                 </xsl:if>
 145                         </subject>
 146                 </xsl:for-each>
 147                 <xsl:for-each select="marc:datafield[@tag=611]">
 148                         <subject>
 149                                 <xsl:call-template name="subfieldSelect">
 150                                         <xsl:with-param name="codes">acdefghklnpqstu4</xsl:with-param>
 151                                 </xsl:call-template>
 152                                 <xsl:if test="marc:subfield[@code='v' or @code='x' or @code='y' or
 153                                         @code='z']">
 154                                         <xsl:text>--</xsl:text>
 155                                         <xsl:call-template name="subfieldSelect">
 156                                                 <xsl:with-param name="codes">vxyz</xsl:with-param>
 157                                                 <xsl:with-param name="delimeter">--</xsl:with-param>
 158                                         </xsl:call-template>
 159                                 </xsl:if>
 160                         </subject>
 161                 </xsl:for-each>
 162                 <xsl:for-each select="marc:datafield[@tag=630]">
 163                         <subject>
 164                                 <xsl:call-template name="subfieldSelect">
 165                                         <xsl:with-param name="codes">adfghklmnoprst</xsl:with-param>
 166                                 </xsl:call-template>
 167                                 <xsl:if test="marc:subfield[@code='v' or @code='x' or @code='y' or
 168                                         @code='z']">
 169                                         <xsl:text>--</xsl:text>
 170                                         <xsl:call-template name="subfieldSelect">
 171                                                 <xsl:with-param name="codes">vxyz</xsl:with-param>
 172                                                 <xsl:with-param name="delimeter">--</xsl:with-param>
 173                                         </xsl:call-template>
 174                                 </xsl:if>
 175                         </subject>
 176                 </xsl:for-each>
 177                 <xsl:for-each select="marc:datafield[@tag=650]">
 178                         <subject>
 179                                 <xsl:call-template name="subfieldSelect">
 180                                         <xsl:with-param name="codes">ae</xsl:with-param></xsl:call-template>
 181                                 <xsl:if test="marc:subfield[@code='v' or @code='x' or @code='y' or
 182                                         @code='z']">
 183                                         <xsl:text>--</xsl:text>
 184                                         <xsl:call-template name="subfieldSelect">
 185                                                 <xsl:with-param name="codes">vxyz</xsl:with-param>
 186                                                 <xsl:with-param name="delimeter">--</xsl:with-param>
 187                                         </xsl:call-template>
 188                                 </xsl:if>
 189                         </subject>
 190                 </xsl:for-each>
 191                 <xsl:for-each select="marc:datafield[@tag=653]">
 192                         <subject>
 193                                 <xsl:call-template name="subfieldSelect">
 194                                         <xsl:with-param name="codes">a</xsl:with-param>
 195                                 </xsl:call-template>
 196                         </subject>
 197                 </xsl:for-each>
 198                 <xsl:for-each select="marc:datafield[@tag=651]">
 199                         <coverage>
 200                                 <xsl:call-template name="subfieldSelect">
 201                                         <xsl:with-param name="codes">a</xsl:with-param>
 202                                 </xsl:call-template>
 203                                 <xsl:if test="marc:subfield[@code='v' or @code='x' or @code='y' or
 204                                         @code='z']">
 205                                         <xsl:text>--</xsl:text>
 206                                         <xsl:call-template name="subfieldSelect">
 207                                                 <xsl:with-param name="codes">vxyz</xsl:with-param>
 208                                                 <xsl:with-param name="delimeter">--</xsl:with-param>
 209                                         </xsl:call-template>
 210                                 </xsl:if>
 211                         </coverage>
 212                 </xsl:for-each>
 213                 <xsl:for-each select="marc:datafield[@tag=752]">
 214                         <coverage>
 215                                 <xsl:call-template name="subfieldSelect">
 216                                         <xsl:with-param name="codes">abcd</xsl:with-param>
 217                                 </xsl:call-template>
 218                         </coverage>
 219                 </xsl:for-each>
 220                 <xsl:for-each select="marc:datafield[@tag=530]">
 221                         <!-- nt 01/04 attribute fix -->
 222                         <relation>
 223                                 <!--<xsl:attribute name="type">original</xsl:attribute>-->
 224                                 <xsl:call-template name="subfieldSelect">
 225                                         <xsl:with-param name="codes">abcdu</xsl:with-param>
 226                                 </xsl:call-template>
 227                         </relation>
 228                 </xsl:for-each>
 229                 <xsl:for-each select="marc:datafield[@tag=760]|marc:datafield[@tag=762]|marc:datafield[@tag=765]|marc:datafield[@tag=767]|marc:datafield[@tag=770]|marc:datafield[@tag=772]|marc:datafield[@tag=773]|marc:datafield[@tag=774]|marc:datafield[@tag=775]|marc:datafield[@tag=776]|marc:datafield[@tag=777]|marc:datafield[@tag=780]|marc:datafield[@tag=785]|marc:datafield[@tag=786]|marc:datafield[@tag=787]">
 230                         <relation>
 231                                 <xsl:call-template name="subfieldSelect">
 232                                         <xsl:with-param name="codes">ot</xsl:with-param>
 233                                 </xsl:call-template>
 234                         </relation>
 235                 </xsl:for-each>
 236                 <xsl:for-each select="marc:datafield[@tag=856]">
 237                         <identifier>
 238                                 <xsl:value-of select="marc:subfield[@code='u']"/>
 239                         </identifier>
 240                 </xsl:for-each>
 241                 <xsl:for-each select="marc:datafield[@tag=020]">
 242                         <identifier>
 243                                 <xsl:text>URN:ISBN:</xsl:text>
 244                                 <xsl:value-of select="marc:subfield[@code='a']"/>
 245                         </identifier>
 246                 </xsl:for-each>
 247                 <xsl:for-each select="marc:datafield[@tag=506]">
 248                         <rights>
 249                                 <xsl:value-of select="marc:subfield[@code='a']"/>
 250                         </rights>
 251                 </xsl:for-each>
 252                 <xsl:for-each select="marc:datafield[@tag=540]">
 253                         <rights>
 254                                 <xsl:value-of select="marc:subfield[@code='a']"/>
 255                         </rights>
 256                 </xsl:for-each>
 257         </xsl:template>
 258 </xsl:stylesheet>
 259 <!-- Stylus Studio meta-information - (c)1998-2003 Copyright Sonic Software Corporation. All rights reserved.
 260 <metaInformation>
 261 <scenarios/><MapperInfo srcSchemaPath="" srcSchemaRoot="" srcSchemaPathIsRelative="yes" srcSchemaInterpretAsXML="no" destSchemaPath="" destSchemaRoot="" destSchemaPathIsRelative="yes" destSchemaInterpretAsXML="no"/>
 262 </metaInformation>
 263 -->