members/maninvoice.pl

   1 #!/usr/bin/perl
   2
   3 #written 11/1/2000 by chris@katipo.oc.nz
   4 #script to display borrowers account details
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 # Copyright 2010 BibLibre
   8 # Copyright 2019 PTFS Europe
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 use Modern::Perl;
  26 use Try::Tiny qw( catch try );
  27 use URI::Escape qw( uri_escape_utf8 );
  28
  29 use C4::Auth qw( get_template_and_user );
  30 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  31 use CGI qw ( -utf8 );
  32 use C4::Members;
  33 use C4::Accounts;
  34 use Koha::Token;
  35
  36 use Koha::Patrons;
  37 use Koha::Items;
  38 use Koha::Old::Items;
  39 use Koha::Checkouts;
  40 use Koha::Old::Checkouts;
  41
  42 use Koha::Patron::Categories;
  43 use Koha::Account::DebitTypes;
  44
  45 my $input = CGI->new;
  46 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  47     {
  48         template_name   => "members/maninvoice.tt",
  49         query           => $input,
  50         type            => "intranet",
  51         flagsrequired   => {
  52             borrowers     => 'edit_borrowers',
  53             updatecharges => 'remaining_permissions'
  54         }
  55     }
  56 );
  57
  58 my $borrowernumber = $input->param('borrowernumber');
  59 my $patron         = Koha::Patrons->find($borrowernumber);
  60 unless ($patron) {
  61     print $input->redirect(
  62         "/cgi-bin/koha/circ/circulation.pl?borrowernumber=$borrowernumber");
  63     exit;
  64 }
  65
  66 my $logged_in_user = Koha::Patrons->find($loggedinuser);
  67 output_and_exit_if_error(
  68     $input, $cookie,
  69     $template,
  70     {
  71         module         => 'members',
  72         logged_in_user => $logged_in_user,
  73         current_patron => $patron
  74     }
  75 );
  76
  77 my $library_id = C4::Context->userenv->{'branch'};
  78 my $desc       = $input->param('desc');
  79 my $amount     = $input->param('amount');
  80 my $note       = $input->param('note');
  81 my $debit_type = $input->param('type');
  82 my $barcode    = $input->param('barcode');
  83 $template->param(
  84     desc    => $desc,
  85     amount  => $amount,
  86     note    => $note,
  87     type    => $debit_type,
  88     barcode => $barcode
  89 );
  90
  91 my $add = $input->param('add');
  92 if ($add) {
  93     output_and_exit( $input, $cookie, $template, 'wrong_csrf_token' )
  94       unless Koha::Token->new->check_csrf(
  95         {
  96             session_id => scalar $input->cookie('CGISESSID'),
  97             token      => scalar $input->param('csrf_token'),
  98         }
  99       );
 100
 101     # Note: If the logged in user is not allowed to see this patron an invoice can be forced
 102     # Here we are trusting librarians not to hack the system
 103     my $desc       = $input->param('desc');
 104     my $amount     = $input->param('amount');
 105     my $note       = $input->param('note');
 106     my $debit_type = $input->param('type');
 107
 108     # If barcode is passed, attempt to find the associated item
 109     my $failed;
 110     my $item_id;
 111     my $olditem; # FIXME: When items and deleted_items are merged, we can remove this
 112     my $issue_id;
 113     if ($barcode) {
 114         my $item = Koha::Items->find( { barcode => $barcode } );
 115         if ($item) {
 116             $item_id = $item->itemnumber;
 117         }
 118         else {
 119             $item = Koha::Old::Items->search( { barcode => $barcode },
 120                 { order_by => { -desc => 'timestamp' }, rows => 1 } );
 121             if ($item->count) {
 122                 $item_id = $item->next->itemnumber;
 123                 $olditem = 1;
 124             }
 125             else {
 126                 $template->param( error => 'itemnumber' );
 127                 $failed = 1;
 128             }
 129         }
 130
 131         if ( ( $debit_type eq 'LOST' ) && $item_id ) {
 132             my $checkouts = Koha::Checkouts->search(
 133                 {
 134                     itemnumber     => $item_id,
 135                     borrowernumber => $borrowernumber
 136                 }
 137             );
 138             my $checkout =
 139                 $checkouts->count
 140               ? $checkouts->next
 141               : Koha::Old::Checkouts->search(
 142                 {
 143                     itemnumber     => $item_id,
 144                     borrowernumber => $borrowernumber
 145                 },
 146                 { order_by => { -desc => 'returndate' }, rows => 1 }
 147             )->next;
 148             $issue_id = $checkout ? $checkout->issue_id : undef;
 149         }
 150     }
 151
 152     unless ($failed) {
 153         try {
 154             my $line = $patron->account->add_debit(
 155                 {
 156                     amount      => $amount,
 157                     description => $desc,
 158                     note        => $note,
 159                     user_id     => $logged_in_user->borrowernumber,
 160                     interface   => 'intranet',
 161                     library_id  => $library_id,
 162                     type        => $debit_type,
 163                     ( $olditem ? () : ( item_id => $item_id ) ),
 164                     issue_id    => $issue_id
 165                 }
 166             );
 167
 168             if ( C4::Context->preference('AccountAutoReconcile') ) {
 169                 $patron->account->reconcile_balance;
 170             }
 171
 172             if ( $add eq 'save and pay' ) {
 173                 my $url = sprintf(
 174                     '/cgi-bin/koha/members/paycollect.pl?borrowernumber=%s&pay_individual=1&debit_type_code=%s&amount=%s&amountoutstanding=%s&description=%s&itemnumber=%s&accountlines_id=%s',
 175                     map { uri_escape_utf8($_) } (
 176                         $borrowernumber,
 177                         $line->debit_type_code,
 178                         $line->amount,
 179                         $line->amountoutstanding,
 180                         $line->description,
 181                         $line->itemnumber,
 182                         $line->id
 183                     )
 184                 );
 185
 186                 print $input->redirect($url);
 187             }
 188             else {
 189                 print $input->redirect(
 190                     "/cgi-bin/koha/members/boraccount.pl?borrowernumber=$borrowernumber"
 191                 );
 192             }
 193
 194             exit;
 195         }
 196         catch {
 197             my $error = $_;
 198             if ( ref($error) eq 'Koha::Exceptions::Object::FKConstraint' ) {
 199                 $template->param( error => $error->broken_fk );
 200             }
 201             else {
 202                 $template->param( error => $error );
 203             }
 204         }
 205     }
 206 }
 207
 208 my $debit_types = Koha::Account::DebitTypes->search_with_library_limits(
 209   { can_be_invoiced => 1, archived => 0 },
 210   {}, $library_id );
 211
 212 $template->param(
 213   debit_types => $debit_types,
 214   csrf_token  => Koha::Token->new->generate_csrf(
 215       { session_id => scalar $input->cookie('CGISESSID') }
 216   ),
 217   patron    => $patron,
 218   finesview => 1,
 219   );
 220 output_html_with_http_headers $input, $cookie, $template->output;