members/memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2006 SAN OUEST PROVENCE et Paul POULAIN
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 # pragma
  21 use strict;
  22 use warnings;
  23
  24 # external modules
  25 use CGI;
  26 # use Digest::MD5 qw(md5_base64);
  27
  28 # internal modules
  29 use C4::Auth;
  30 use C4::Context;
  31 use C4::Output;
  32 use C4::Members;
  33 use C4::Members::Attributes;
  34 use C4::Members::AttributeTypes;
  35 use C4::Koha;
  36 use C4::Dates qw/format_date format_date_in_iso/;
  37 use C4::Input;
  38 use C4::Log;
  39 use C4::Letters;
  40 use C4::Branch; # GetBranches
  41 use C4::Form::MessagingPreferences;
  42
  43 use vars qw($debug);
  44
  45 BEGIN {
  46         $debug = $ENV{DEBUG} || 0;
  47 }
  48
  49 my $input = new CGI;
  50 ($debug) or $debug = $input->param('debug') || 0;
  51 my %data;
  52
  53 my $dbh = C4::Context->dbh;
  54
  55 my ($template, $loggedinuser, $cookie)
  56     = get_template_and_user({template_name => "members/memberentrygen.tmpl",
  57            query => $input,
  58            type => "intranet",
  59            authnotrequired => 0,
  60            flagsrequired => {borrowers => 1},
  61            debug => ($debug) ? 1 : 0,
  62        });
  63 my $guarantorid    = $input->param('guarantorid');
  64 my $borrowernumber = $input->param('borrowernumber');
  65 my $actionType     = $input->param('actionType') || '';
  66 my $modify         = $input->param('modify');
  67 my $delete         = $input->param('delete');
  68 my $op             = $input->param('op');
  69 my $destination    = $input->param('destination');
  70 my $cardnumber     = $input->param('cardnumber');
  71 my $check_member   = $input->param('check_member');
  72 my $nodouble       = $input->param('nodouble');
  73 $nodouble = 1 if $op eq 'modify'; # FIXME hack to represent fact that if we're
  74                                   # modifying an existing patron, it ipso facto
  75                                   # isn't a duplicate.  Marking FIXME because this
  76                                   # script needs to be refactored.
  77 my $select_city    = $input->param('select_city');
  78 my $nok            = $input->param('nok');
  79 my $guarantorinfo  = $input->param('guarantorinfo');
  80 my $step           = $input->param('step') || 0;
  81 my @errors;
  82 my $default_city;
  83 # $check_categorytype contains the value of duplicate borrowers category type to redirect in good template in step =2
  84 my $check_categorytype=$input->param('check_categorytype');
  85 # NOTE: Alert for ethnicity and ethnotes fields, they are invalid in all borrowers form
  86 my $borrower_data;
  87 my $NoUpdateLogin;
  88 my $userenv = C4::Context->userenv;
  89
  90 $template->param("uppercasesurnames" => C4::Context->preference('uppercasesurnames'));
  91
  92 my $minpw = C4::Context->preference('minPasswordLength');
  93 $template->param("minPasswordLength" => $minpw);
  94
  95 # function to designate mandatory fields (visually with css)
  96 my $check_BorrowerMandatoryField=C4::Context->preference("BorrowerMandatoryField");
  97 my @field_check=split(/\|/,$check_BorrowerMandatoryField);
  98 foreach (@field_check) {
  99         $template->param( "mandatory$_" => 1);
 100 }
 101 $template->param("add"=>1) if ($op eq 'add');
 102 $template->param("checked" => 1) if (defined($nodouble) && $nodouble eq 1);
 103 ($borrower_data = GetMember( 'borrowernumber'=>$borrowernumber )) if ($op eq 'modify' or $op eq 'save');
 104 my $categorycode  = $input->param('categorycode') || $borrower_data->{'categorycode'};
 105 my $category_type = $input->param('category_type');
 106 my $new_c_type = $category_type; #if we have input param, then we've already chosen the cat_type.
 107 unless ($category_type or !($categorycode)){
 108     my $borrowercategory = GetBorrowercategory($categorycode);
 109     $category_type    = $borrowercategory->{'category_type'};
 110     my $category_name = $borrowercategory->{'description'};
 111     $template->param("categoryname"=>$category_name);
 112 }
 113 $category_type="A" unless $category_type; # FIXME we should display a error message instead of a 500 error !
 114
 115 # if a add or modify is requested => check validity of data.
 116 %data = %$borrower_data if ($borrower_data);
 117
 118 # initialize %newdata
 119 my %newdata;    # comes from $input->param()
 120 if ($op eq 'insert' || $op eq 'modify' || $op eq 'save') {
 121     my @names= ($borrower_data && $op ne 'save') ? keys %$borrower_data : $input->param();
 122     foreach my $key (@names) {
 123         if (defined $input->param($key)) {
 124             $newdata{$key} = $input->param($key);
 125             $newdata{$key} =~ s/\"/&quot;/g unless $key eq 'borrowernotes' or $key eq 'opacnote';
 126         }
 127     }
 128     my $dateobject = C4::Dates->new();
 129     my $syspref = $dateobject->regexp();                # same syspref format for all 3 dates
 130     my $iso     = $dateobject->regexp('iso');   #
 131     foreach (qw(dateenrolled dateexpiry dateofbirth)) {
 132         next unless exists $newdata{$_};
 133         my $userdate = $newdata{$_} or next;
 134         if ($userdate =~ /$syspref/) {
 135             $newdata{$_} = format_date_in_iso($userdate);       # if they match syspref format, then convert to ISO
 136         } elsif ($userdate =~ /$iso/) {
 137             warn "Date $_ ($userdate) is already in ISO format";
 138         } else {
 139             ($userdate eq '0000-00-00') and warn "Data error: $_ is '0000-00-00'";
 140             $template->param( "ERROR_$_" => 1 );        # else ERROR!
 141             push(@errors,"ERROR_$_");
 142         }
 143     }
 144   # check permission to modify login info.
 145     if (ref($borrower_data) && ($borrower_data->{'category_type'} eq 'S') && ! (C4::Auth::haspermission($userenv->{'id'},{'staffaccess'=>1})) )  {
 146         $NoUpdateLogin = 1;
 147     }
 148 }
 149
 150 # remove keys from %newdata that ModMember() doesn't like
 151 {
 152     my @keys_to_delete = (
 153         qr/^BorrowerMandatoryField$/,
 154         qr/^category_type$/,
 155         qr/^check_member$/,
 156         qr/^destination$/,
 157         qr/^nodouble$/,
 158         qr/^op$/,
 159         qr/^save$/,
 160         qr/^select_roadtype$/,
 161         qr/^updtype$/,
 162         qr/^SMSnumber$/,
 163         qr/^setting_extended_patron_attributes$/,
 164         qr/^setting_messaging_prefs$/,
 165         qr/^digest$/,
 166         qr/^modify$/,
 167         qr/^step$/,
 168         qr/^\d+$/,
 169         qr/^\d+-DAYS/,
 170         qr/^patron_attr_/,
 171     );
 172     for my $regexp (@keys_to_delete) {
 173         for (keys %newdata) {
 174             delete($newdata{$_}) if /$regexp/;
 175         }
 176     }
 177 }
 178
 179 #############test for member being unique #############
 180 if (($op eq 'insert') and !$nodouble){
 181         my $category_type_send=$category_type if ($category_type eq 'I');
 182         my $check_category; # recover the category code of the doublon suspect borrowers
 183                         #   ($result,$categorycode) = checkuniquemember($collectivity,$surname,$firstname,$dateofbirth)
 184         ($check_member,$check_category) = checkuniquemember(
 185                         $category_type_send,
 186                         ($newdata{surname}     ? $newdata{surname}     : $data{surname}    ),
 187                         ($newdata{firstname}   ? $newdata{firstname}   : $data{firstname}  ),
 188                         ($newdata{dateofbirth} ? $newdata{dateofbirth} : $data{dateofbirth})
 189                 );
 190         if(!$check_member){
 191             $nodouble = 1;
 192         }
 193   #   recover the category type if the borrowers is a doublon
 194     if ($check_category) {
 195       my $tmpborrowercategory=GetBorrowercategory($check_category);
 196       $check_categorytype=$tmpborrowercategory->{'category_type'};
 197     }
 198 }
 199
 200   #recover all data from guarantor address phone ,fax...
 201 if ( defined($guarantorid) and
 202      ( $category_type eq 'C' || $category_type eq 'P' ) and
 203      $guarantorid ne ''  and
 204      $guarantorid ne '0' ) {
 205     if (my $guarantordata=GetMember(borrowernumber => $guarantorid)) {
 206         $guarantorinfo=$guarantordata->{'surname'}." , ".$guarantordata->{'firstname'};
 207         if ( !defined($data{'contactname'}) or $data{'contactname'} eq '' or
 208              $data{'contactname'} ne $guarantordata->{'surname'} ) {
 209             $newdata{'contactfirstname'}= $guarantordata->{'firstname'};
 210             $newdata{'contactname'}     = $guarantordata->{'surname'};
 211             $newdata{'contacttitle'}    = $guarantordata->{'title'};
 212                 foreach (qw(streetnumber address streettype address2
 213                         zipcode country city phone phonepro mobile fax email emailpro branchcode)) {
 214                         $newdata{$_} = $guarantordata->{$_};
 215                 }
 216         }
 217     }
 218 }
 219
 220 ###############test to take the right zipcode, country and city name ##############
 221 if (!defined($guarantorid) or $guarantorid eq '' or $guarantorid eq '0') {
 222     # set only if parameter was passed from the form
 223     $newdata{'city'}    = $input->param('city')    if defined($input->param('city'));
 224     $newdata{'zipcode'} = $input->param('zipcode') if defined($input->param('zipcode'));
 225     $newdata{'country'} = $input->param('country') if defined($input->param('country'));
 226 }
 227
 228 #builds default userid
 229 if ( (defined $newdata{'userid'}) && ($newdata{'userid'} eq '')){
 230     $newdata{'userid'} = Generate_Userid($borrowernumber, $newdata{'firstname'}, $newdata{'surname'});
 231 }
 232
 233 $debug and warn join "\t", map {"$_: $newdata{$_}"} qw(dateofbirth dateenrolled dateexpiry);
 234 my $extended_patron_attributes = ();
 235 if ($op eq 'save' || $op eq 'insert'){
 236   if (checkcardnumber($newdata{cardnumber},$newdata{borrowernumber})){
 237     push @errors, 'ERROR_cardnumber';
 238   }
 239   my $dateofbirthmandatory = (scalar grep {$_ eq "dateofbirth"} @field_check) ? 1 : 0;
 240   if ($newdata{dateofbirth} && $dateofbirthmandatory) {
 241     my $age = GetAge($newdata{dateofbirth});
 242     my $borrowercategory=GetBorrowercategory($newdata{'categorycode'});
 243         my ($low,$high) = ($borrowercategory->{'dateofbirthrequired'}, $borrowercategory->{'upperagelimit'});
 244     if (($high && ($age > $high)) or ($age < $low)) {
 245       push @errors, 'ERROR_age_limitations';
 246           $template->param('ERROR_age_limitations' => "$low to $high");
 247     }
 248   }
 249   if (C4::Context->preference("IndependantBranches")) {
 250     if ($userenv && $userenv->{flags} % 2 != 1){
 251       $debug and print STDERR "  $newdata{'branchcode'} : ".$userenv->{flags}.":".$userenv->{branch};
 252       unless (!$newdata{'branchcode'} || $userenv->{branch} eq $newdata{'branchcode'}){
 253         push @errors, "ERROR_branch";
 254       }
 255     }
 256   }
 257   # Check if the userid is unique
 258   unless (Check_Userid($newdata{'userid'},$borrowernumber)) {
 259     push @errors, "ERROR_login_exist";
 260   }
 261
 262   my $password = $input->param('password');
 263   push @errors, "ERROR_short_password" if( $password && $minpw && $password ne '****' && (length($password) < $minpw) );
 264
 265   if (C4::Context->preference('ExtendedPatronAttributes')) {
 266     $extended_patron_attributes = parse_extended_patron_attributes($input);
 267     foreach my $attr (@$extended_patron_attributes) {
 268         unless (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
 269             push @errors, "ERROR_extended_unique_id_failed";
 270             $template->param(ERROR_extended_unique_id_failed => "$attr->{code}/$attr->{value}");
 271         }
 272     }
 273   }
 274 }
 275
 276 if ($op eq 'modify' || $op eq 'insert' || $op eq 'save' ){
 277     if (exists ($newdata{'dateexpiry'}) && !($newdata{'dateexpiry'})){
 278         my $arg2 = $newdata{'dateenrolled'} || C4::Dates->today('iso');
 279         $newdata{'dateexpiry'} = GetExpiryDate($newdata{'categorycode'},$arg2);
 280     }
 281 }
 282
 283 if ( ( defined $input->param('SMSnumber') ) && ( $input->param('SMSnumber') ne $newdata{'mobile'} ) ) {
 284     $newdata{smsalertnumber} = $input->param('SMSnumber');
 285 }
 286
 287 ###  Error checks should happen before this line.
 288 $nok = $nok || scalar(@errors);
 289 if ((!$nok) and $nodouble and ($op eq 'insert' or $op eq 'save')){
 290         $debug and warn "$op dates: " . join "\t", map {"$_: $newdata{$_}"} qw(dateofbirth dateenrolled dateexpiry);
 291         if ($op eq 'insert'){
 292                 # we know it's not a duplicate borrowernumber or there would already be an error
 293         $borrowernumber = &AddMember(%newdata);
 294
 295         # If 'AutoEmailOpacUser' syspref is on, email user their account details from the 'notice' that matches the user's branchcode.
 296         if ( C4::Context->preference("AutoEmailOpacUser") == 1 && $newdata{'userid'}  && $newdata{'password'}) {
 297             #look for defined primary email address, if blank - attempt to use borr.email and borr.emailpro instead
 298             my $emailaddr;
 299             if  (C4::Context->preference("AutoEmailPrimaryAddress") ne 'OFF'  &&
 300                 $newdata{C4::Context->preference("AutoEmailPrimaryAddress")} =~  /\w\@\w/ ) {
 301                 $emailaddr =   $newdata{C4::Context->preference("AutoEmailPrimaryAddress")}
 302             }
 303             elsif ($newdata{email} =~ /\w\@\w/) {
 304                 $emailaddr = $newdata{email}
 305             }
 306             elsif ($newdata{emailpro} =~ /\w\@\w/) {
 307                 $emailaddr = $newdata{emailpro}
 308             }
 309             elsif ($newdata{B_email} =~ /\w\@\w/) {
 310                 $emailaddr = $newdata{B_email}
 311             }
 312             # if we manage to find a valid email address, send notice
 313             if ($emailaddr) {
 314                 $newdata{emailaddr} = $emailaddr;
 315                 my $letter = getletter ('members', "ACCTDETAILS:$newdata{'branchcode'}") ;
 316                 # if $branch notice fails, then email a default notice instead.
 317                 $letter = getletter ('members', "ACCTDETAILS")  if !$letter;
 318                 SendAlerts ( 'members' , \%newdata , $letter ) if $letter
 319             }
 320         }
 321
 322                 if ($data{'organisations'}){
 323                         # need to add the members organisations
 324                         my @orgs=split(/\|/,$data{'organisations'});
 325                         add_member_orgs($borrowernumber,\@orgs);
 326                 }
 327         if (C4::Context->preference('ExtendedPatronAttributes') and $input->param('setting_extended_patron_attributes')) {
 328             C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, $extended_patron_attributes);
 329         }
 330         if (C4::Context->preference('EnhancedMessagingPreferences') and $input->param('setting_messaging_prefs')) {
 331             C4::Form::MessagingPreferences::handle_form_action($input, { borrowernumber => $borrowernumber }, $template);
 332         }
 333         } elsif ($op eq 'save'){
 334                 if ($NoUpdateLogin) {
 335                         delete $newdata{'password'};
 336                         delete $newdata{'userid'};
 337                 }
 338                 &ModMember(%newdata);
 339         if (C4::Context->preference('ExtendedPatronAttributes') and $input->param('setting_extended_patron_attributes')) {
 340             C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, $extended_patron_attributes);
 341         }
 342         if (C4::Context->preference('EnhancedMessagingPreferences') and $input->param('setting_messaging_prefs')) {
 343             C4::Form::MessagingPreferences::handle_form_action($input, { borrowernumber => $borrowernumber }, $template);
 344         }
 345         }
 346         print scalar ($destination eq "circ") ?
 347                 $input->redirect("/cgi-bin/koha/circ/circulation.pl?borrowernumber=$borrowernumber") :
 348                 $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$borrowernumber") ;
 349         exit;           # You can only send 1 redirect!  After that, content or other headers don't matter.
 350 }
 351
 352 if ($delete){
 353         print $input->redirect("/cgi-bin/koha/deletemem.pl?member=$borrowernumber");
 354         exit;           # same as above
 355 }
 356
 357 if ($nok or !$nodouble){
 358     $op="add" if ($op eq "insert");
 359     $op="modify" if ($op eq "save");
 360     %data=%newdata;
 361     $template->param( updtype => ($op eq 'add' ?'I':'M'));      # used to check for $op eq "insert"... but we just changed $op!
 362     unless ($step){
 363         $template->param( step_1 => 1,step_2 => 1,step_3 => 1, step_4 => 1, step_5 => 1, step_6 => 1);
 364     }
 365 }
 366 if (C4::Context->preference("IndependantBranches")) {
 367     my $userenv = C4::Context->userenv;
 368     if ($userenv->{flags} % 2 != 1 && $data{branchcode}){
 369         unless ($userenv->{branch} eq $data{'branchcode'}){
 370             print $input->redirect("/cgi-bin/koha/members/members-home.pl");
 371             exit;
 372         }
 373     }
 374 }
 375 if ($op eq 'add'){
 376     $template->param( updtype => 'I', step_1=>1, step_2=>1, step_3=>1, step_4=>1, step_5 => 1, step_6 => 1);
 377 }
 378 if ($op eq "modify")  {
 379     $template->param( updtype => 'M',modify => 1 );
 380     $template->param( step_1=>1, step_2=>1, step_3=>1, step_4=>1, step_5 => 1, step_6 => 1) unless $step;
 381 }
 382 # my $cardnumber=$data{'cardnumber'};
 383 $data{'cardnumber'}=fixup_cardnumber($data{'cardnumber'}) if $op eq 'add';
 384 if(!defined($data{'sex'})){
 385     $template->param( none => 1);
 386 } elsif($data{'sex'} eq 'F'){
 387     $template->param( female => 1);
 388 } elsif ($data{'sex'} eq 'M'){
 389     $template->param(  male => 1);
 390 } else {
 391     $template->param(  none => 1);
 392 }
 393
 394 ##Now all the data to modify a member.
 395 my ($categories,$labels)=ethnicitycategories();
 396
 397 my $ethnicitycategoriescount=$#{$categories};
 398 my $ethcatpopup;
 399 if ($ethnicitycategoriescount>=0) {
 400   $ethcatpopup = CGI::popup_menu(-name=>'ethnicity',
 401         -id => 'ethnicity',
 402         -tabindex=>'',
 403         -values=>$categories,
 404         -default=>$data{'ethnicity'},
 405         -labels=>$labels);
 406   $template->param(ethcatpopup => $ethcatpopup); # bad style, has to be fixed
 407 }
 408
 409 my @typeloop;
 410 foreach (qw(C A S P I X)) {
 411     my $action="WHERE category_type=?";
 412         ($categories,$labels)=GetborCatFromCatType($_,$action);
 413         my @categoryloop;
 414         foreach my $cat (@$categories){
 415                 push @categoryloop,{'categorycode' => $cat,
 416                           'categoryname' => $labels->{$cat},
 417                           'categorycodeselected' => ((defined($borrower_data->{'categorycode'}) &&
 418                                                      $cat eq $borrower_data->{'categorycode'})
 419                                                      || (defined($categorycode) && $cat eq $categorycode)),
 420                 };
 421         }
 422         my %typehash;
 423         $typehash{'typename'}=$_;
 424         $typehash{'categoryloop'}=\@categoryloop;
 425         push @typeloop,{'typename' => $_,
 426           'categoryloop' => \@categoryloop};
 427 }
 428 $template->param('typeloop' => \@typeloop);
 429
 430 # test in city
 431 $select_city=getidcity($data{'city'}) if defined $guarantorid and ($guarantorid ne '0');
 432 ($default_city=$select_city) if ($step eq 0);
 433 if (!defined($select_city) or $select_city eq '' ){
 434         $default_city = &getidcity($data{'city'});
 435 }
 436
 437 my $city_arrayref = GetCities();
 438 if (@{$city_arrayref} ) {
 439     $template->param( city_cgipopup => 1);
 440
 441     if ($default_city) { # flag the current or default val
 442         for my $city ( @{$city_arrayref} ) {
 443             if ($default_city == $city->{cityid}) {
 444                 $city->{selected} = 1;
 445                 last;
 446             }
 447         }
 448     }
 449 }
 450
 451 my $default_roadtype;
 452 $default_roadtype=$data{'streettype'} ;
 453 my($roadtypeid,$road_type)=GetRoadTypes();
 454   $template->param( road_cgipopup => 1) if ($roadtypeid );
 455 my $roadpopup = CGI::popup_menu(-name=>'streettype',
 456         -id => 'streettype',
 457         -values=>$roadtypeid,
 458         -labels=>$road_type,
 459         -override => 1,
 460         -default=>$default_roadtype
 461         );
 462
 463 my $default_borrowertitle;
 464 $default_borrowertitle=$data{'title'} ;
 465 my($borrowertitle)=GetTitles();
 466 $template->param( title_cgipopup => 1) if ($borrowertitle);
 467 my $borrotitlepopup = CGI::popup_menu(-name=>'title',
 468         -id => 'btitle',
 469         -values=>$borrowertitle,
 470         -override => 1,
 471         -default=>$default_borrowertitle
 472         );
 473
 474 my @relationships = split /,|\|/, C4::Context->preference('BorrowerRelationship');
 475 my @relshipdata;
 476 while (@relationships) {
 477   my $relship = shift @relationships || '';
 478   my %row = ('relationship' => $relship);
 479   if (defined($data{'relationship'}) and $data{'relationship'} eq $relship) {
 480     $row{'selected'}=' selected';
 481   } else {
 482     $row{'selected'}='';
 483   }
 484   push(@relshipdata, \%row);
 485 }
 486
 487 my %flags = ( 'gonenoaddress' => ['gonenoaddress' ],
 488         'lost'          => ['lost'],
 489         'debarred'      => ['debarred']);
 490
 491
 492 my @flagdata;
 493 foreach (keys(%flags)) {
 494         my $key = $_;
 495         my %row =  ('key'   => $key,
 496                     'name'  => $flags{$key}[0]);
 497         if ($data{$key}) {
 498                 $row{'yes'}=' checked';
 499                 $row{'no'}='';
 500     }
 501         else {
 502                 $row{'yes'}='';
 503                 $row{'no'}=' checked';
 504         }
 505         push @flagdata,\%row;
 506 }
 507
 508 #get Branches
 509 my @branches;
 510 my @select_branch;
 511 my %select_branches;
 512
 513 my $onlymine=(C4::Context->preference('IndependantBranches') &&
 514               C4::Context->userenv &&
 515               C4::Context->userenv->{flags} % 2 !=1  &&
 516               C4::Context->userenv->{branch}?1:0);
 517
 518 my $branches=GetBranches($onlymine);
 519 my $default;
 520
 521 for my $branch (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 522     push @select_branch,$branch;
 523     $select_branches{$branch} = $branches->{$branch}->{'branchname'};
 524     $default = C4::Context->userenv->{'branch'} if (C4::Context->userenv && C4::Context->userenv->{'branch'});
 525 }
 526 # --------------------------------------------------------------------------------------------------------
 527   #in modify mod :default value from $CGIbranch comes from borrowers table
 528   #in add mod: default value come from branches table (ip correspendence)
 529 $default=$data{'branchcode'}  if ($op eq 'modify' || ($op eq 'add' && $category_type eq 'C'));
 530 my $CGIbranch = CGI::scrolling_list(-id    => 'branchcode',
 531             -name   => 'branchcode',
 532             -values => \@select_branch,
 533             -labels => \%select_branches,
 534             -size   => 1,
 535             -override => 1,
 536             -multiple =>0,
 537             -default => $default,
 538         );
 539 my $CGIorganisations;
 540 my $member_of_institution;
 541 if (C4::Context->preference("memberofinstitution")){
 542     my $organisations=get_institutions();
 543     my @orgs;
 544     my %org_labels;
 545     foreach my $organisation (keys %$organisations) {
 546         push @orgs,$organisation;
 547         $org_labels{$organisation}=$organisations->{$organisation}->{'surname'};
 548     }
 549     $member_of_institution=1;
 550
 551     $CGIorganisations = CGI::scrolling_list( -id => 'organisations',
 552         -name     => 'organisations',
 553         -labels   => \%org_labels,
 554         -values   => \@orgs,
 555         -size     => 5,
 556         -multiple => 'true'
 557
 558     );
 559 }
 560
 561 # --------------------------------------------------------------------------------------------------------
 562
 563 my $CGIsort = buildCGIsort("Bsort1","sort1",$data{'sort1'});
 564 if ($CGIsort) {
 565     $template->param(CGIsort1 => $CGIsort);
 566 }
 567 $template->param( sort1 => $data{'sort1'});             # shouldn't this be in an "else" statement like the 2nd one?
 568
 569 $CGIsort = buildCGIsort("Bsort2","sort2",$data{'sort2'});
 570 if ($CGIsort) {
 571     $template->param(CGIsort2 => $CGIsort);
 572 } else {
 573     $template->param( sort2 => $data{'sort2'});
 574 }
 575
 576 if ($nok) {
 577     foreach my $error (@errors) {
 578         $template->param($error) || $template->param( $error => 1);
 579     }
 580     $template->param(nok => 1);
 581 }
 582
 583   #Formatting data for display
 584
 585 if (!defined($data{'dateenrolled'}) or $data{'dateenrolled'} eq ''){
 586   $data{'dateenrolled'}=C4::Dates->today('iso');
 587 }
 588 if (C4::Context->preference('uppercasesurnames')) {
 589         $data{'surname'}    =uc($data{'surname'}    );
 590         $data{'contactname'}=uc($data{'contactname'});
 591 }
 592 foreach (qw(dateenrolled dateexpiry dateofbirth)) {
 593         $data{$_} = format_date($data{$_});     # back to syspref for display
 594         $template->param( $_ => $data{$_});
 595 }
 596
 597 if (C4::Context->preference('ExtendedPatronAttributes')) {
 598     $template->param(ExtendedPatronAttributes => 1);
 599     patron_attributes_form($template, $borrowernumber);
 600 }
 601
 602 if (C4::Context->preference('EnhancedMessagingPreferences')) {
 603     if ($op eq 'add') {
 604         C4::Form::MessagingPreferences::set_form_values({ categorycode => $categorycode }, $template);
 605     } else {
 606         C4::Form::MessagingPreferences::set_form_values({ borrowernumber => $borrowernumber }, $template);
 607     }
 608     $template->param(SMSSendDriver => C4::Context->preference("SMSSendDriver"));
 609     $template->param(SMSnumber     => defined $data{'smsalertnumber'} ? $data{'smsalertnumber'} : $data{'mobile'});
 610 }
 611
 612 $template->param( "showguarantor"  => ($category_type=~/A|I|S|X/) ? 0 : 1); # associate with step to know where you are
 613 $debug and warn "memberentry step: $step";
 614 $template->param(%data);
 615 $template->param( "step_$step"  => 1) if $step; # associate with step to know where u are
 616 $template->param(  step  => $step   ) if $step; # associate with step to know where u are
 617 $template->param( debug  => $debug  ) if $debug;
 618
 619 $template->param(
 620   BorrowerMandatoryField => C4::Context->preference("BorrowerMandatoryField"),#field to test with javascript
 621   category_type => $category_type,#to know the category type of the borrower
 622   DHTMLcalendar_dateformat => C4::Dates->DHTMLcalendar(),
 623   select_city => $select_city,
 624   "$category_type"  => 1,# associate with step to know where u are
 625   destination   => $destination,#to know wher u come from and wher u must go in redirect
 626   check_member    => $check_member,#to know if the borrower already exist(=>1) or not (=>0)
 627   "op$op"   => 1);
 628
 629 $template->param(
 630   nodouble  => $nodouble,
 631   borrowernumber  => $borrowernumber, #register number
 632   guarantorid => (defined($borrower_data->{'guarantorid'})) ? $borrower_data->{'guarantorid'} : $guarantorid,
 633   ethcatpopup => $ethcatpopup,
 634   relshiploop => \@relshipdata,
 635   city_loop => $city_arrayref,
 636   roadpopup => $roadpopup,
 637   borrotitlepopup => $borrotitlepopup,
 638   guarantorinfo   => $guarantorinfo,
 639   flagloop  => \@flagdata,
 640   dateformat      => C4::Dates->new()->visual(),
 641   C4::Context->preference('dateformat') => 1,
 642   check_categorytype =>$check_categorytype,#to recover the category type with checkcategorytype function
 643   modify          => $modify,
 644   nok     => $nok,#flag to konw if an error
 645   CGIbranch => $CGIbranch,
 646   memberofinstution => $member_of_institution,
 647   CGIorganisations => $CGIorganisations,
 648   NoUpdateLogin =>  $NoUpdateLogin
 649   );
 650
 651 if(defined($data{'flags'})){
 652   $template->param(flags=>$data{'flags'});
 653 }
 654 if(defined($data{'contacttitle'})){
 655   $template->param("contacttitle_" . $data{'contacttitle'} => "SELECTED");
 656 }
 657
 658
 659 output_html_with_http_headers $input, $cookie, $template->output;
 660
 661 sub  parse_extended_patron_attributes {
 662     my ($input) = @_;
 663     my @patron_attr = grep { /^patron_attr_\d+$/ } $input->param();
 664
 665     my @attr = ();
 666     my %dups = ();
 667     foreach my $key (@patron_attr) {
 668         my $value = $input->param($key);
 669         next unless defined($value) and $value ne '';
 670         my $password = $input->param("${key}_password");
 671         my $code     = $input->param("${key}_code");
 672         next if exists $dups{$code}->{$value};
 673         $dups{$code}->{$value} = 1;
 674         push @attr, { code => $code, value => $value, password => $password };
 675     }
 676     return \@attr;
 677 }
 678
 679 sub patron_attributes_form {
 680     my $template = shift;
 681     my $borrowernumber = shift;
 682
 683     my @types = C4::Members::AttributeTypes::GetAttributeTypes();
 684     if (scalar(@types) == 0) {
 685         $template->param(no_patron_attribute_types => 1);
 686         return;
 687     }
 688     my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
 689
 690     # map patron's attributes into a more convenient structure
 691     my %attr_hash = ();
 692     foreach my $attr (@$attributes) {
 693         push @{ $attr_hash{$attr->{code}} }, $attr;
 694     }
 695
 696     my @attribute_loop = ();
 697     my $i = 0;
 698     foreach my $type_code (map { $_->{code} } @types) {
 699         my $attr_type = C4::Members::AttributeTypes->fetch($type_code);
 700         my $entry = {
 701             code              => $attr_type->code(),
 702             description       => $attr_type->description(),
 703             repeatable        => $attr_type->repeatable(),
 704             password_allowed  => $attr_type->password_allowed(),
 705             category          => $attr_type->authorised_value_category(),
 706             password          => '',
 707         };
 708         if (exists $attr_hash{$attr_type->code()}) {
 709             foreach my $attr (@{ $attr_hash{$attr_type->code()} }) {
 710                 my $newentry = { map { $_ => $entry->{$_} } %$entry };
 711                 $newentry->{value} = $attr->{value};
 712                 $newentry->{password} = $attr->{password};
 713                 $newentry->{use_dropdown} = 0;
 714                 if ($attr_type->authorised_value_category()) {
 715                     $newentry->{use_dropdown} = 1;
 716                     $newentry->{auth_val_loop} = GetAuthorisedValues($attr_type->authorised_value_category(), $attr->{value});
 717                 }
 718                 $i++;
 719                 $newentry->{form_id} = "patron_attr_$i";
 720                 #use Data::Dumper; die Dumper($entry) if  $entry->{use_dropdown};
 721                 push @attribute_loop, $newentry;
 722             }
 723         } else {
 724             $i++;
 725             my $newentry = { map { $_ => $entry->{$_} } %$entry };
 726             if ($attr_type->authorised_value_category()) {
 727                 $newentry->{use_dropdown} = 1;
 728                 $newentry->{auth_val_loop} = GetAuthorisedValues($attr_type->authorised_value_category());
 729             }
 730             $newentry->{form_id} = "patron_attr_$i";
 731             push @attribute_loop, $newentry;
 732         }
 733     }
 734     $template->param(patron_attributes => \@attribute_loop);
 735
 736 }
 737
 738 # Local Variables:
 739 # tab-width: 8
 740 # End: