members/pay.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2010 BibLibre
   5 # Copyright 2010,2011 PTFS-Europe Ltd
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 =head1 pay.pl
  23
  24  written 11/1/2000 by chris@katipo.oc.nz
  25  part of the koha library system, script to facilitate paying off fines
  26
  27 =cut
  28
  29 use strict;
  30 use warnings;
  31
  32 use URI::Escape;
  33 use C4::Context;
  34 use C4::Auth;
  35 use C4::Output;
  36 use CGI qw ( -utf8 );
  37 use C4::Members;
  38 use C4::Accounts;
  39 use C4::Stats;
  40 use C4::Koha;
  41 use C4::Overdues;
  42 use C4::Branch;
  43 use C4::Members::Attributes qw(GetBorrowerAttributes);
  44
  45 our $input = CGI->new;
  46
  47 my $updatecharges_permissions = $input->param('woall') ? 'writeoff' : 'remaining_permissions';
  48 our ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  49     {   template_name   => 'members/pay.tt',
  50         query           => $input,
  51         type            => 'intranet',
  52         authnotrequired => 0,
  53         flagsrequired   => { borrowers => 1, updatecharges => $updatecharges_permissions },
  54         debug           => 1,
  55     }
  56 );
  57
  58 my @names = $input->param;
  59
  60 our $borrowernumber = $input->param('borrowernumber');
  61 if ( !$borrowernumber ) {
  62     $borrowernumber = $input->param('borrowernumber0');
  63 }
  64
  65 # get borrower details
  66 our $borrower = GetMember( borrowernumber => $borrowernumber );
  67 our $user = $input->remote_user;
  68 $user ||= q{};
  69
  70 my $branches = GetBranches();
  71 our $branch = GetBranch( $input, $branches );
  72
  73 my $writeoff_item = $input->param('confirm_writeoff');
  74 my $paycollect    = $input->param('paycollect');
  75 if ($paycollect) {
  76     print $input->redirect(
  77         "/cgi-bin/koha/members/paycollect.pl?borrowernumber=$borrowernumber");
  78 }
  79 my $payselected = $input->param('payselected');
  80 if ($payselected) {
  81     payselected(@names);
  82 }
  83
  84 my $writeoff_all = $input->param('woall');    # writeoff all fines
  85 if ($writeoff_all) {
  86     writeoff_all(@names);
  87 } elsif ($writeoff_item) {
  88     my $accountlines_id = $input->param('accountlines_id');
  89     my $itemno       = $input->param('itemnumber');
  90     my $account_type = $input->param('accounttype');
  91     my $amount       = $input->param('amountoutstanding');
  92     my $payment_note = $input->param("payment_note");
  93     WriteOffFee( $borrowernumber, $accountlines_id, $itemno, $account_type, $amount, $branch, $payment_note );
  94 }
  95
  96 for (@names) {
  97     if (/^pay_indiv_(\d+)$/) {
  98         my $line_no = $1;
  99         redirect_to_paycollect( 'pay_individual', $line_no );
 100     } elsif (/^wo_indiv_(\d+)$/) {
 101         my $line_no = $1;
 102         redirect_to_paycollect( 'writeoff_individual', $line_no );
 103     }
 104 }
 105
 106 $template->param(
 107     finesview => 1,
 108     activeBorrowerRelationship => (C4::Context->preference('borrowerRelationship') ne ''),
 109     RoutingSerials => C4::Context->preference('RoutingSerials'),
 110 );
 111
 112 add_accounts_to_template();
 113
 114 output_html_with_http_headers $input, $cookie, $template->output;
 115
 116 sub add_accounts_to_template {
 117
 118     my ( $total, undef, undef ) = GetMemberAccountRecords($borrowernumber);
 119     my $accounts = [];
 120     my @notify   = NumberNotifyId($borrowernumber);
 121
 122     my $notify_groups = [];
 123     for my $notify_id (@notify) {
 124         my ( $acct_total, $accountlines, undef ) =
 125           GetBorNotifyAcctRecord( $borrowernumber, $notify_id );
 126         if ( @{$accountlines} ) {
 127             my $totalnotify = AmountNotify( $notify_id, $borrowernumber );
 128             push @{$accounts},
 129               { accountlines => $accountlines,
 130                 notify       => $notify_id,
 131                 total        => $totalnotify,
 132               };
 133         }
 134     }
 135     borrower_add_additional_fields($borrower);
 136
 137     $template->param(%$borrower);
 138
 139     $template->param(
 140         accounts => $accounts,
 141         borrower => $borrower,
 142         categoryname => $borrower->{'description'},
 143         total    => $total,
 144     );
 145     return;
 146
 147 }
 148
 149 sub get_for_redirect {
 150     my ( $name, $name_in, $money ) = @_;
 151     my $s     = q{&} . $name . q{=};
 152     my $value = $input->param($name_in);
 153     if ( !defined $value ) {
 154         $value = ( $money == 1 ) ? 0 : q{};
 155     }
 156     if ($money) {
 157         $s .= sprintf '%.2f', $value;
 158     } else {
 159         $s .= $value;
 160     }
 161     return $s;
 162 }
 163
 164 sub redirect_to_paycollect {
 165     my ( $action, $line_no ) = @_;
 166     my $redirect =
 167       "/cgi-bin/koha/members/paycollect.pl?borrowernumber=$borrowernumber";
 168     $redirect .= q{&};
 169     $redirect .= "$action=1";
 170     $redirect .= get_for_redirect( 'accounttype', "accounttype$line_no", 0 );
 171     $redirect .= get_for_redirect( 'amount', "amount$line_no", 1 );
 172     $redirect .=
 173       get_for_redirect( 'amountoutstanding', "amountoutstanding$line_no", 1 );
 174     $redirect .= get_for_redirect( 'title',        "title$line_no",        0 );
 175     $redirect .= get_for_redirect( 'itemnumber',   "itemnumber$line_no",   0 );
 176     $redirect .= get_for_redirect( 'notify_id',    "notify_id$line_no",    0 );
 177     $redirect .= get_for_redirect( 'notify_level', "notify_level$line_no", 0 );
 178     $redirect .= get_for_redirect( 'accountlines_id', "accountlines_id$line_no", 0 );
 179     $redirect .= q{&} . 'payment_note' . q{=} . uri_escape_utf8( $input->param("payment_note_$line_no") );
 180     $redirect .= '&remote_user=';
 181     $redirect .= $user;
 182     return print $input->redirect($redirect);
 183 }
 184
 185 sub writeoff_all {
 186     my @params = @_;
 187     my @wo_lines = grep { /^accountlines_id\d+$/ } @params;
 188     for (@wo_lines) {
 189         if (/(\d+)/) {
 190             my $value       = $1;
 191             my $accounttype = $input->param("accounttype$value");
 192
 193             #    my $borrowernum    = $input->param("borrowernumber$value");
 194             my $itemno    = $input->param("itemnumber$value");
 195             my $amount    = $input->param("amountoutstanding$value");
 196             my $accountlines_id = $input->param("accountlines_id$value");
 197             my $payment_note = $input->param("payment_note_$value");
 198             WriteOffFee( $borrowernumber, $accountlines_id, $itemno, $accounttype, $amount, $branch, $payment_note );
 199         }
 200     }
 201
 202     $borrowernumber = $input->param('borrowernumber');
 203     print $input->redirect(
 204         "/cgi-bin/koha/members/boraccount.pl?borrowernumber=$borrowernumber");
 205     return;
 206 }
 207
 208 sub borrower_add_additional_fields {
 209     my $b_ref = shift;
 210
 211 # some borrower info is not returned in the standard call despite being assumed
 212 # in a number of templates. It should not be the business of this script but in lieu of
 213 # a revised api here it is ...
 214     if ( $b_ref->{category_type} eq 'C' ) {
 215         my ( $catcodes, $labels ) =
 216           GetborCatFromCatType( 'A', 'WHERE category_type = ?' );
 217         if ( @{$catcodes} ) {
 218             if ( @{$catcodes} > 1 ) {
 219                 $b_ref->{CATCODE_MULTI} = 1;
 220             } elsif ( @{$catcodes} == 1 ) {
 221                 $b_ref->{catcode} = $catcodes->[0];
 222             }
 223         }
 224     } elsif ( $b_ref->{category_type} eq 'A' ) {
 225         $b_ref->{adultborrower} = 1;
 226     }
 227     my ( $picture, $dberror ) = GetPatronImage( $b_ref->{borrowernumber} );
 228     if ($picture) {
 229         $b_ref->{has_picture} = 1;
 230     }
 231
 232     if (C4::Context->preference('ExtendedPatronAttributes')) {
 233         $b_ref->{extendedattributes} = GetBorrowerAttributes($borrowernumber);
 234         $template->param(
 235             ExtendedPatronAttributes => 1,
 236         );
 237     }
 238
 239     $b_ref->{branchname} = GetBranchName( $b_ref->{branchcode} );
 240     return;
 241 }
 242
 243 sub payselected {
 244     my @params = @_;
 245     my $amt    = 0;
 246     my @lines_to_pay;
 247     foreach (@params) {
 248         if (/^incl_par_(\d+)$/) {
 249             my $index = $1;
 250             push @lines_to_pay, $input->param("accountlines_id$index");
 251             $amt += $input->param("amountoutstanding$index");
 252         }
 253     }
 254     $amt = '&amt=' . $amt;
 255     my $sel = '&selected=' . join ',', @lines_to_pay;
 256     my $notes = '&notes=' . join("%0A", map { $input->param("payment_note_$_") } @lines_to_pay );
 257     my $redirect =
 258         "/cgi-bin/koha/members/paycollect.pl?borrowernumber=$borrowernumber"
 259       . $amt
 260       . $sel
 261       . $notes;
 262
 263     print $input->redirect($redirect);
 264     return;
 265 }