misc/cronjobs/cleanup_database.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 PTFS, Inc.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use constant DEFAULT_ZEBRAQ_PURGEDAYS             => 30;
  23 use constant DEFAULT_MAIL_PURGEDAYS               => 30;
  24 use constant DEFAULT_IMPORT_PURGEDAYS             => 60;
  25 use constant DEFAULT_LOGS_PURGEDAYS               => 180;
  26 use constant DEFAULT_SEARCHHISTORY_PURGEDAYS      => 30;
  27 use constant DEFAULT_SHARE_INVITATION_EXPIRY_DAYS => 14;
  28 use constant DEFAULT_DEBARMENTS_PURGEDAYS         => 30;
  29
  30 BEGIN {
  31     # find Koha's Perl modules
  32     # test carefully before changing this
  33     use FindBin;
  34     eval { require "$FindBin::Bin/../kohalib.pl" };
  35 }
  36
  37 use C4::Context;
  38 use C4::Search;
  39 use C4::Search::History;
  40 use Getopt::Long;
  41 use C4::Log;
  42 use C4::Accounts;
  43 use Koha::UploadedFiles;
  44
  45 sub usage {
  46     print STDERR <<USAGE;
  47 Usage: $0 [-h|--help] [--sessions] [--sessdays DAYS] [-v|--verbose] [--zebraqueue DAYS] [-m|--mail] [--merged] [--import DAYS] [--logs DAYS] [--searchhistory DAYS] [--restrictions DAYS] [--all-restrictions] [--fees DAYS] [--temp-uploads] [--temp-uploads-days DAYS] [--uploads-missing 0|1 ]
  48
  49    -h --help          prints this help message, and exits, ignoring all
  50                       other options
  51    --sessions         purge the sessions table.  If you use this while users
  52                       are logged into Koha, they will have to reconnect.
  53    --sessdays DAYS    purge only sessions older than DAYS days.
  54    -v --verbose       will cause the script to give you a bit more information
  55                       about the run.
  56    --zebraqueue DAYS  purge completed zebraqueue entries older than DAYS days.
  57                       Defaults to 30 days if no days specified.
  58    -m --mail DAYS     purge items from the mail queue that are older than DAYS days.
  59                       Defaults to 30 days if no days specified.
  60    --merged           purged completed entries from need_merge_authorities.
  61    --import DAYS      purge records from import tables older than DAYS days.
  62                       Defaults to 60 days if no days specified.
  63    --z3950            purge records from import tables that are the result
  64                       of Z39.50 searches
  65    --fees DAYS        purge entries accountlines older than DAYS days, where
  66                       amountoutstanding is 0 or NULL.
  67                       In the case of --fees, DAYS must be greater than
  68                       or equal to 1.
  69                       WARNING: Fees and payments may not be deleted together.
  70                       This will not affect the account balance but may be
  71                       confusing to staff.
  72    --logs DAYS        purge entries from action_logs older than DAYS days.
  73                       Defaults to 180 days if no days specified.
  74    --searchhistory DAYS  purge entries from search_history older than DAYS days.
  75                          Defaults to 30 days if no days specified
  76    --list-invites  DAYS  purge (unaccepted) list share invites older than DAYS
  77                          days.  Defaults to 14 days if no days specified.
  78    --restrictions DAYS   purge patrons restrictions expired since more than DAYS days.
  79                          Defaults to 30 days if no days specified.
  80     --all-restrictions   purge all expired patrons restrictions.
  81    --del-exp-selfreg  Delete expired self registration accounts
  82    --del-unv-selfreg  DAYS  Delete unverified self registrations older than DAYS
  83    --unique-holidays DAYS  Delete all unique holidays older than DAYS
  84    --temp-uploads     Delete temporary uploads.
  85    --temp-uploads-days DAYS Override the corresponding preference value.
  86    --uploads-missing FLAG Delete upload records for missing files when FLAG is true, count them otherwise
  87 USAGE
  88     exit $_[0];
  89 }
  90
  91 my $help;
  92 my $sessions;
  93 my $sess_days;
  94 my $verbose;
  95 my $zebraqueue_days;
  96 my $mail;
  97 my $purge_merged;
  98 my $pImport;
  99 my $pLogs;
 100 my $pSearchhistory;
 101 my $pZ3950;
 102 my $pListShareInvites;
 103 my $pDebarments;
 104 my $allDebarments;
 105 my $pExpSelfReg;
 106 my $pUnvSelfReg;
 107 my $fees_days;
 108 my $special_holidays_days;
 109 my $temp_uploads;
 110 my $temp_uploads_days;
 111 my $uploads_missing;
 112
 113 GetOptions(
 114     'h|help'            => \$help,
 115     'sessions'          => \$sessions,
 116     'sessdays:i'        => \$sess_days,
 117     'v|verbose'         => \$verbose,
 118     'm|mail:i'          => \$mail,
 119     'zebraqueue:i'      => \$zebraqueue_days,
 120     'merged'            => \$purge_merged,
 121     'import:i'          => \$pImport,
 122     'z3950'             => \$pZ3950,
 123     'logs:i'            => \$pLogs,
 124     'fees:i'            => \$fees_days,
 125     'searchhistory:i'   => \$pSearchhistory,
 126     'list-invites:i'    => \$pListShareInvites,
 127     'restrictions:i'    => \$pDebarments,
 128     'all-restrictions'  => \$allDebarments,
 129     'del-exp-selfreg'   => \$pExpSelfReg,
 130     'del-unv-selfreg'   => \$pUnvSelfReg,
 131     'unique-holidays:i' => \$special_holidays_days,
 132     'temp-uploads'      => \$temp_uploads,
 133     'temp-uploads-days:i' => \$temp_uploads_days,
 134     'uploads-missing:i' => \$uploads_missing,
 135 ) || usage(1);
 136
 137 # Use default values
 138 $sessions          = 1                                    if $sess_days                  && $sess_days > 0;
 139 $pImport           = DEFAULT_IMPORT_PURGEDAYS             if defined($pImport)           && $pImport == 0;
 140 $pLogs             = DEFAULT_LOGS_PURGEDAYS               if defined($pLogs)             && $pLogs == 0;
 141 $zebraqueue_days   = DEFAULT_ZEBRAQ_PURGEDAYS             if defined($zebraqueue_days)   && $zebraqueue_days == 0;
 142 $mail              = DEFAULT_MAIL_PURGEDAYS               if defined($mail)              && $mail == 0;
 143 $pSearchhistory    = DEFAULT_SEARCHHISTORY_PURGEDAYS      if defined($pSearchhistory)    && $pSearchhistory == 0;
 144 $pListShareInvites = DEFAULT_SHARE_INVITATION_EXPIRY_DAYS if defined($pListShareInvites) && $pListShareInvites == 0;
 145 $pDebarments       = DEFAULT_DEBARMENTS_PURGEDAYS         if defined($pDebarments)       && $pDebarments == 0;
 146
 147 if ($help) {
 148     usage(0);
 149 }
 150
 151 unless ( $sessions
 152     || $zebraqueue_days
 153     || $mail
 154     || $purge_merged
 155     || $pImport
 156     || $pLogs
 157     || $fees_days
 158     || $pSearchhistory
 159     || $pZ3950
 160     || $pListShareInvites
 161     || $pDebarments
 162     || $allDebarments
 163     || $pExpSelfReg
 164     || $pUnvSelfReg
 165     || $special_holidays_days
 166     || $temp_uploads
 167     || defined $uploads_missing
 168 ) {
 169     print "You did not specify any cleanup work for the script to do.\n\n";
 170     usage(1);
 171 }
 172
 173 if ($pDebarments && $allDebarments) {
 174     print "You can not specify both --restrictions and --all-restrictions.\n\n";
 175     usage(1);
 176 }
 177
 178 cronlogaction();
 179
 180 my $dbh = C4::Context->dbh();
 181 my $sth;
 182 my $sth2;
 183 my $count;
 184
 185 if ( $sessions && !$sess_days ) {
 186     if ($verbose) {
 187         print "Session purge triggered.\n";
 188         $sth = $dbh->prepare(q{ SELECT COUNT(*) FROM sessions });
 189         $sth->execute() or die $dbh->errstr;
 190         my @count_arr = $sth->fetchrow_array;
 191         print "$count_arr[0] entries will be deleted.\n";
 192     }
 193     $sth = $dbh->prepare(q{ TRUNCATE sessions });
 194     $sth->execute() or die $dbh->errstr;
 195     if ($verbose) {
 196         print "Done with session purge.\n";
 197     }
 198 }
 199 elsif ( $sessions && $sess_days > 0 ) {
 200     print "Session purge triggered with days>$sess_days.\n" if $verbose;
 201     RemoveOldSessions();
 202     print "Done with session purge with days>$sess_days.\n" if $verbose;
 203 }
 204
 205 if ($zebraqueue_days) {
 206     $count = 0;
 207     print "Zebraqueue purge triggered for $zebraqueue_days days.\n" if $verbose;
 208     $sth = $dbh->prepare(
 209         q{
 210             SELECT id,biblio_auth_number,server,time
 211             FROM zebraqueue
 212             WHERE done=1 AND time < date_sub(curdate(), INTERVAL ? DAY)
 213         }
 214     );
 215     $sth->execute($zebraqueue_days) or die $dbh->errstr;
 216     $sth2 = $dbh->prepare(q{ DELETE FROM zebraqueue WHERE id=? });
 217     while ( my $record = $sth->fetchrow_hashref ) {
 218         $sth2->execute( $record->{id} ) or die $dbh->errstr;
 219         $count++;
 220     }
 221     print "$count records were deleted.\nDone with zebraqueue purge.\n" if $verbose;
 222 }
 223
 224 if ($mail) {
 225     print "Mail queue purge triggered for $mail days.\n" if $verbose;
 226     $sth = $dbh->prepare(
 227         q{
 228             DELETE FROM message_queue
 229             WHERE time_queued < date_sub(curdate(), INTERVAL ? DAY)
 230         }
 231     );
 232     $sth->execute($mail) or die $dbh->errstr;
 233     $count = $sth->rows;
 234     $sth->finish;
 235     print "$count messages were deleted from the mail queue.\nDone with message_queue purge.\n" if $verbose;
 236 }
 237
 238 if ($purge_merged) {
 239     print "Purging completed entries from need_merge_authorities.\n" if $verbose;
 240     $sth = $dbh->prepare(q{ DELETE FROM need_merge_authorities WHERE done=1 });
 241     $sth->execute() or die $dbh->errstr;
 242     print "Done with purging need_merge_authorities.\n" if $verbose;
 243 }
 244
 245 if ($pImport) {
 246     print "Purging records from import tables.\n" if $verbose;
 247     PurgeImportTables();
 248     print "Done with purging import tables.\n" if $verbose;
 249 }
 250
 251 if ($pZ3950) {
 252     print "Purging Z39.50 records from import tables.\n" if $verbose;
 253     PurgeZ3950();
 254     print "Done with purging Z39.50 records from import tables.\n" if $verbose;
 255 }
 256
 257 if ($pLogs) {
 258     print "Purging records from action_logs.\n" if $verbose;
 259     $sth = $dbh->prepare(
 260         q{
 261             DELETE FROM action_logs
 262             WHERE timestamp < date_sub(curdate(), INTERVAL ? DAY)
 263         }
 264     );
 265     $sth->execute($pLogs) or die $dbh->errstr;
 266     print "Done with purging action_logs.\n" if $verbose;
 267 }
 268
 269 if ($fees_days) {
 270     print "Purging records from accountlines.\n" if $verbose;
 271     purge_zero_balance_fees( $fees_days );
 272     print "Done purging records from accountlines.\n" if $verbose;
 273 }
 274
 275 if ($pSearchhistory) {
 276     print "Purging records older than $pSearchhistory from search_history.\n" if $verbose;
 277     C4::Search::History::delete({ interval => $pSearchhistory });
 278     print "Done with purging search_history.\n" if $verbose;
 279 }
 280
 281 if ($pListShareInvites) {
 282     print "Purging unaccepted list share invites older than $pListShareInvites days.\n" if $verbose;
 283     $sth = $dbh->prepare(
 284         q{
 285             DELETE FROM virtualshelfshares
 286             WHERE invitekey IS NOT NULL
 287             AND (sharedate + INTERVAL ? DAY) < NOW()
 288         }
 289     );
 290     $sth->execute($pListShareInvites);
 291     print "Done with purging unaccepted list share invites.\n" if $verbose;
 292 }
 293
 294 if ($pDebarments) {
 295     print "Expired patrons restrictions purge triggered for $pDebarments days.\n" if $verbose;
 296     $count = PurgeDebarments($pDebarments);
 297     print "$count restrictions were deleted.\nDone with restrictions purge.\n" if $verbose;
 298 }
 299
 300 if($allDebarments) {
 301     print "All expired patrons restrictions purge triggered.\n" if $verbose;
 302     $count = PurgeDebarments(0);
 303     print "$count restrictions were deleted.\nDone with all restrictions purge.\n" if $verbose;
 304 }
 305
 306 if( $pExpSelfReg ) {
 307     DeleteExpiredSelfRegs();
 308 }
 309 if( $pUnvSelfReg ) {
 310     DeleteUnverifiedSelfRegs( $pUnvSelfReg );
 311 }
 312
 313 if ($special_holidays_days) {
 314     DeleteSpecialHolidays( abs($special_holidays_days) );
 315 }
 316
 317 if( $temp_uploads ) {
 318     # Delete temporary uploads, governed by a pref (unless you override)
 319     print "Purging temporary uploads.\n" if $verbose;
 320     Koha::UploadedFiles->delete_temporary({
 321         defined($temp_uploads_days)
 322             ? ( override_pref => $temp_uploads_days )
 323             : ()
 324     });
 325     print "Done purging temporary uploads.\n" if $verbose;
 326 }
 327
 328 if( defined $uploads_missing ) {
 329     print "Looking for missing uploads\n" if $verbose;
 330     my $keep = $uploads_missing == 1 ? 0 : 1;
 331     my $count = Koha::UploadedFiles->delete_missing({ keep_record => $keep });
 332     if( $keep ) {
 333         print "Counted $count missing uploaded files\n";
 334     } else {
 335         print "Removed $count records for missing uploads\n";
 336     }
 337 }
 338
 339 exit(0);
 340
 341 sub RemoveOldSessions {
 342     my ( $id, $a_session, $limit, $lasttime );
 343     $limit = time() - 24 * 3600 * $sess_days;
 344
 345     $sth = $dbh->prepare(q{ SELECT id, a_session FROM sessions });
 346     $sth->execute or die $dbh->errstr;
 347     $sth->bind_columns( \$id, \$a_session );
 348     $sth2  = $dbh->prepare(q{ DELETE FROM sessions WHERE id=? });
 349     $count = 0;
 350
 351     while ( $sth->fetch ) {
 352         $lasttime = 0;
 353         if ( $a_session =~ /lasttime:\s+'?(\d+)/ ) {
 354             $lasttime = $1;
 355         }
 356         elsif ( $a_session =~ /(ATIME|CTIME):\s+'?(\d+)/ ) {
 357             $lasttime = $2;
 358         }
 359         if ( $lasttime && $lasttime < $limit ) {
 360             $sth2->execute($id) or die $dbh->errstr;
 361             $count++;
 362         }
 363     }
 364     if ($verbose) {
 365         print "$count sessions were deleted.\n";
 366     }
 367 }
 368
 369 sub PurgeImportTables {
 370
 371     #First purge import_records
 372     #Delete cascades to import_biblios, import_items and import_record_matches
 373     $sth = $dbh->prepare(
 374         q{
 375             DELETE FROM import_records
 376             WHERE upload_timestamp < date_sub(curdate(), INTERVAL ? DAY)
 377         }
 378     );
 379     $sth->execute($pImport) or die $dbh->errstr;
 380
 381     # Now purge import_batches
 382     # Timestamp cannot be used here without care, because records are added
 383     # continuously to batches without updating timestamp (Z39.50 search).
 384     # So we only delete older empty batches.
 385     # This delete will therefore not have a cascading effect.
 386     $sth = $dbh->prepare(
 387         q{
 388             DELETE ba
 389             FROM import_batches ba
 390             LEFT JOIN import_records re ON re.import_batch_id=ba.import_batch_id
 391             WHERE re.import_record_id IS NULL AND
 392             ba.upload_timestamp < date_sub(curdate(), INTERVAL ? DAY)
 393         }
 394     );
 395     $sth->execute($pImport) or die $dbh->errstr;
 396 }
 397
 398 sub PurgeZ3950 {
 399     $sth = $dbh->prepare(
 400         q{
 401             DELETE FROM import_batches
 402             WHERE batch_type = 'z3950'
 403         }
 404     );
 405     $sth->execute() or die $dbh->errstr;
 406 }
 407
 408 sub PurgeDebarments {
 409     require Koha::Patron::Debarments;
 410     my $days = shift;
 411     $count = 0;
 412     $sth   = $dbh->prepare(
 413         q{
 414             SELECT borrower_debarment_id
 415             FROM borrower_debarments
 416             WHERE expiration < date_sub(curdate(), INTERVAL ? DAY)
 417         }
 418     );
 419     $sth->execute($days) or die $dbh->errstr;
 420     while ( my ($borrower_debarment_id) = $sth->fetchrow_array ) {
 421         Koha::Patron::Debarments::DelDebarment($borrower_debarment_id);
 422         $count++;
 423     }
 424     return $count;
 425 }
 426
 427 sub DeleteExpiredSelfRegs {
 428     my $cnt= C4::Members::DeleteExpiredOpacRegistrations();
 429     print "Removed $cnt expired self-registered borrowers\n" if $verbose;
 430 }
 431
 432 sub DeleteUnverifiedSelfRegs {
 433     my $cnt= C4::Members::DeleteUnverifiedOpacRegistrations( $_[0] );
 434     print "Removed $cnt unverified self-registrations\n" if $verbose;
 435 }
 436
 437 sub DeleteSpecialHolidays {
 438     my ( $days ) = @_;
 439
 440     my $sth = $dbh->prepare(q{
 441         DELETE FROM special_holidays
 442         WHERE DATE( CONCAT( year, '-', month, '-', day ) ) < DATE_SUB( CAST(NOW() AS DATE), INTERVAL ? DAY );
 443     });
 444     my $count = $sth->execute( $days ) + 0;
 445     print "Removed $count unique holidays\n" if $verbose;
 446 }