misc/cronjobs/reconcile_balances.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2018 Theke Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 reconcile_balances.pl - cron script to reconcile patron's balances
  23
  24 =head1 SYNOPSIS
  25
  26 ./reconcile_balances.pl
  27
  28 or, in crontab:
  29 0 1 * * * reconcile_balances.pl
  30
  31 =head1 DESCRIPTION
  32
  33 This script loops through patrons with outstanding credits and proceeds
  34 to reconcile their balances.
  35
  36 =head1 OPTIONS
  37
  38 =over 8
  39
  40 =item B<--help>
  41
  42 Prints a brief help message and exits.
  43
  44 =item B<--verbose>
  45
  46 Makes the process print information about the taken actions.
  47
  48 =back
  49
  50 =cut
  51
  52 use Modern::Perl;
  53
  54 use Getopt::Long qw( GetOptions );
  55 use Pod::Usage qw( pod2usage );
  56 use Try::Tiny qw( catch try );
  57
  58 use Koha::Script -cron;
  59 use C4::Log qw( cronlogaction );
  60
  61 use Koha::Account::Lines;
  62 use Koha::Patrons;
  63
  64 my $help    = 0;
  65 my $verbose = 0;
  66
  67 my $command_line_options = join(" ",@ARGV);
  68
  69 GetOptions(
  70     'help'    => \$help,
  71     'verbose' => \$verbose
  72 ) or pod2usage(2);
  73
  74 pod2usage(1) if $help;
  75 cronlogaction({ info => $command_line_options });
  76
  77 my @patron_ids = Koha::Account::Lines->search(
  78         {
  79             amountoutstanding => { '<' => 0 },
  80             borrowernumber => { '!=' => undef }
  81         },
  82         {
  83             columns  => [ qw/borrowernumber/ ],
  84             distinct => 1,
  85         }
  86     )->get_column('borrowernumber');
  87
  88 my $patrons = Koha::Patrons->search({ borrowernumber => { -in => \@patron_ids } });
  89
  90 while (my $patron = $patrons->next) {
  91
  92     my $account = $patron->account;
  93     my $total_outstanding_credit = $account->outstanding_credits->total_outstanding;
  94     my $total_outstanding_debit  = $account->outstanding_debits->total_outstanding;
  95
  96     if ( $total_outstanding_credit < 0
  97          and $total_outstanding_debit > 0) {
  98
  99         try {
 100
 101             $account->reconcile_balance;
 102
 103             print $patron->id . ": credit: $total_outstanding_credit " .
 104                                   "debit: $total_outstanding_debit " .
 105                                   "=> outstanding " .
 106                                   "credit: " . $account->outstanding_credits->total_outstanding .
 107                                  " debit: " .  $account->outstanding_debits->total_outstanding . "\n"
 108                 if $verbose;
 109         }
 110         catch {
 111             print "Problem with patron " . $patron->borrowernumber . ": $_";
 112         };
 113     }
 114 }
 115
 116 cronlogaction({ action => 'End', info => "COMPLETED" });
 117
 118 1;
 119
 120 __END__