misc/import_patrons.pl

   1 #!/usr/bin/perl
   2
   3 # Parts copyright 2014 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Getopt::Long qw( GetOptions );
  23 use Pod::Usage qw( pod2usage );
  24
  25 use Koha::Script;
  26 use Koha::Patrons::Import;
  27 use C4::Log qw( cronlogaction );
  28 my $Import = Koha::Patrons::Import->new();
  29
  30 my $csv_file;
  31 my $matchpoint;
  32 my $overwrite_cardnumber;
  33 my $overwrite_passwords;
  34 my $welcome_new = 0;
  35 my %defaults;
  36 my $ext_preserve = 0;
  37 my $confirm;
  38 my $verbose      = 0;
  39 my $help;
  40 my @preserve_fields;
  41 my $update_dateexpiry;
  42 my $update_dateexpiry_from_today;
  43
  44 my $command_line_options = join( " ", @ARGV );
  45
  46 GetOptions(
  47     'c|confirm'                      => \$confirm,
  48     'f|file=s'                       => \$csv_file,
  49     'm|matchpoint=s'                 => \$matchpoint,
  50     'd|default=s'                    => \%defaults,
  51     'o|overwrite'                    => \$overwrite_cardnumber,
  52     'op|overwrite_passwords'         => \$overwrite_passwords,
  53     'ue|update-expiration'           => \$update_dateexpiry,
  54     'et|expiration-from-today'       => \$update_dateexpiry_from_today,
  55     'en|email-new'                   => \$welcome_new,
  56     'p|preserve-extended-attributes' => \$ext_preserve,
  57     'pf|preserve-field=s'            => \@preserve_fields,
  58     'v|verbose+'                     => \$verbose,
  59     'h|help|?'                       => \$help,
  60 ) or pod2usage(2);
  61
  62 pod2usage(1) if $help;
  63 pod2usage(q|--file is required|) unless $csv_file;
  64 pod2usage(q|--matchpoint is required|) unless $matchpoint;
  65
  66 if ($confirm) {
  67     cronlogaction( { action => 'Run', info => $command_line_options } );
  68 } else {
  69     warn "Running in dry-run mode, provide --confirm to apply the changes\n";
  70 }
  71
  72 my $handle;
  73 open( $handle, "<", $csv_file ) or die $!;
  74
  75 my $return = $Import->import_patrons(
  76     {
  77         file                         => $handle,
  78         defaults                     => \%defaults,
  79         matchpoint                   => $matchpoint,
  80         overwrite_cardnumber         => $overwrite_cardnumber,
  81         overwrite_passwords          => $overwrite_passwords,
  82         preserve_extended_attributes => $ext_preserve,
  83         preserve_fields              => \@preserve_fields,
  84         update_dateexpiry            => $update_dateexpiry,
  85         update_dateexpiry_from_today => $update_dateexpiry_from_today,
  86         send_welcome                 => $welcome_new,
  87         dry_run                      => !$confirm,
  88     }
  89 );
  90
  91 my $feedback    = $return->{feedback};
  92 my $errors      = $return->{errors};
  93 my $imported    = $return->{imported};
  94 my $overwritten = $return->{overwritten};
  95 my $alreadyindb = $return->{already_in_db};
  96 my $invalid     = $return->{invalid};
  97 my $total       = $imported + $alreadyindb + $invalid + $overwritten;
  98
  99 if ($verbose) {
 100     say q{};
 101     say "Import complete:";
 102     say "Imported:    $imported";
 103     say "Overwritten: $overwritten";
 104     say "Skipped:     $alreadyindb";
 105     say "Invalid:     $invalid";
 106     say "Total:       $total";
 107     say q{};
 108 }
 109
 110 if ($verbose > 1 ) {
 111     say "Errors:";
 112     say Data::Dumper::Dumper( $errors );
 113 }
 114
 115 if ($verbose > 2 ) {
 116     say "Feedback:";
 117     say Data::Dumper::Dumper( $feedback );
 118 }
 119
 120 my $info =
 121       "Import complete. "
 122     . "Imported: "
 123     . $imported
 124     . " Overwritten: "
 125     . $overwritten
 126     . " Skipped: "
 127     . $alreadyindb
 128     . " Invalid: "
 129     . $invalid
 130     . " Total: "
 131     . $total;
 132
 133 if ($confirm) {
 134     cronlogaction( { action => 'End', info => $info } );
 135 }
 136
 137 =head1 NAME
 138
 139 import_patrons.pl - CLI script to import patrons data into Koha
 140
 141 =head1 SYNOPSIS
 142
 143 import_patrons.pl --file /path/to/patrons.csv --matchpoint cardnumber --confirm [--default branchcode=MPL] [--overwrite] [--preserve-field <column>] [--preserve-extended-attributes] [--update-expiration] [--expiration-from-today] [--verbose]
 144
 145 =head1 OPTIONS
 146
 147 =over 8
 148
 149 =item B<-h|--help>
 150
 151 Prints a brief help message and exits
 152
 153 =item B<-c|--confirm>
 154
 155 Confirms you really want to import these patrons, otherwise prints this help
 156
 157 =item B<-f|--file>
 158
 159 Path to the CSV file of patrons to import
 160
 161 =item B<-m|--matchpoint>
 162
 163 Field on which to match incoming patrons to existing patrons
 164
 165 =item B<-d|--default>
 166
 167 Set defaults to patron fields, repeatable e.g. --default branchcode=MPL --default categorycode=PT
 168
 169 =item B<-k|--preserve-field>
 170
 171 Prevent specified patron fields for existing patrons from being overwritten
 172
 173 =item B<-o|--overwrite>
 174
 175 Overwrite existing patrons with new data if a match is found
 176
 177 =item B<-p|--preserve-extended-attributes>
 178
 179 Retain extended patron attributes for existing patrons being overwritten
 180
 181 =item B<-en|--email-new>
 182
 183 Send the WELCOME notice email to new users
 184
 185 =item B<-ue|--update-expiration>
 186
 187 If a matching patron is found, extend the expiration date of their account using the patron's enrollment date as the base
 188
 189 =item B<-et|--expiration-from-today>
 190
 191 If a matching patron is found, extend the expiration date of their account using today's date as the base
 192
 193 =item B<-v|--verbose>
 194
 195 Be verbose
 196
 197 Multiple -v options increase the verbosity
 198
 199 2 repetitions or above will report lines in error
 200
 201 3 repetitions or above will report feedback
 202
 203 =back
 204
 205 =cut