misc/maintenance/borrowers-force-messaging-defaults.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright (C) 2011 Tamil s.a.r.l.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use Koha::Script;
  24 use C4::Context;
  25 use C4::Members::Messaging;
  26 use Getopt::Long qw( GetOptions );
  27 use Pod::Usage qw( pod2usage );
  28
  29
  30 sub usage {
  31     pod2usage( -verbose => 2 );
  32     exit;
  33 }
  34
  35
  36 sub force_borrower_messaging_defaults {
  37     my ($doit, $since, $not_expired, $no_overwrite, $category, $branchcode, $message_name ) = @_;
  38
  39     print "Since: $since\n" if $since;
  40
  41     my $dbh = C4::Context->dbh;
  42     $dbh->{AutoCommit} = 0;
  43
  44     my $sql =
  45 q|SELECT DISTINCT bo.borrowernumber, bo.categorycode FROM borrowers bo
  46 LEFT JOIN borrower_message_preferences mp USING (borrowernumber)
  47 WHERE 1|;
  48
  49     if ( $since ) {
  50         $sql .= " AND bo.dateenrolled >= ?";
  51     }
  52     if ($not_expired) {
  53         $sql .= " AND bo.dateexpiry >= NOW()"
  54     }
  55     if( $no_overwrite ) {
  56         $sql .= " AND mp.borrowernumber IS NULL";
  57     }
  58     $sql .= " AND bo.categorycode = ?" if $category;
  59     $sql .= " AND bo.branchcode = ?" if $branchcode;
  60     my $sth = $dbh->prepare($sql);
  61     $sth->execute($since || (), $category || (), $branchcode || () );
  62     my $cnt = 0;
  63     while ( my ($borrowernumber, $categorycode) = $sth->fetchrow ) {
  64         print "$borrowernumber: $categorycode\n";
  65         next unless $doit;
  66         my $options = {
  67             borrowernumber => $borrowernumber,
  68             categorycode   => $categorycode,
  69         };
  70         $options->{message_name} = $message_name if defined $message_name;
  71         C4::Members::Messaging::SetMessagingPreferencesFromDefaults($options);
  72         $cnt++;
  73     }
  74     $dbh->commit();
  75     print "Total borrowers updated: $cnt\n" if $doit;
  76 }
  77
  78
  79 my ( $doit, $since, $help, $not_expired, $no_overwrite, $category, $branchcode, $message_name );
  80 my $result = GetOptions(
  81     'doit'           => \$doit,
  82     'since:s'        => \$since,
  83     'not-expired'    => \$not_expired,
  84     'no-overwrite'   => \$no_overwrite,
  85     'category:s'     => \$category,
  86     'library:s'      => \$branchcode,
  87     'message-name:s' => \$message_name,
  88     'help|h'         => \$help,
  89 );
  90
  91 usage() if $help;
  92
  93 force_borrower_messaging_defaults( $doit, $since, $not_expired, $no_overwrite, $category, $branchcode, $message_name );
  94
  95 =head1 NAME
  96
  97 borrowers-force-messaging-defaults.pl
  98
  99 =head1 SYNOPSIS
 100
 101   borrowers-force-messaging-defaults.pl
 102   borrowers-force-messaging-defaults.pl --help
 103   borrowers-force-messaging-defaults.pl --doit
 104   borrowers-force-messaging-defaults.pl --doit --not-expired
 105   borrowers-force-messaging-defaults.pl --doit --category PT
 106   borrowers-force-messaging-defaults.pl --doit --library CPL
 107   borrowers-force-messaging-defaults.pl --doit --message-name 'Item_Due'
 108
 109 =head1 DESCRIPTION
 110
 111 If the EnhancedMessagingPreferences syspref is enabled after borrowers have
 112 been created in the DB, those borrowers won't have messaging transport
 113 preferences default values as defined for their borrower category. So you would
 114 have to modify each borrower one by one if you would like to send them 'Hold
 115 Filled' notice for example.
 116
 117 This script creates/overwrites messaging preferences for all borrowers and sets
 118 them to default values defined for the category they belong to (unless you
 119 use the options -not-expired or -no-overwrite to update a subset).
 120
 121 =over 8
 122
 123 =item B<--help>
 124
 125 Prints this help
 126
 127 =item B<--doit>
 128
 129 Actually update the borrowers.
 130
 131 =item B<--not-expired>
 132
 133 Will only update active borrowers (borrowers who didn't pass their expiration date).
 134
 135 =item B<--no-overwrite>
 136
 137 Will only update patrons without messaging preferences and skip patrons that
 138 already set their preferences.
 139
 140 =item B<--category>
 141
 142 Will only update patrons in the category specified.
 143
 144 =item B<--library>
 145
 146 Will only update patrons whose home library matches the given library id.
 147
 148 =item B<--message-name>
 149
 150 Will only update the specified message name.
 151 List of values can be found in installer/data/mysql/mandatory/sample_notices_message_attributes.sql
 152 or in message_attributes.message_name in the database.
 153
 154 =item B<--since>
 155
 156 Will only update borrowers enrolled since the specified date.
 157
 158 Examples:
 159
 160 --since "2022-07-13"
 161
 162 --since `date -d "1 day ago" '+%Y-%m-%d'
 163
 164 =back
 165
 166 =cut