opac/opac-MARCdetail.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 #       Copyright (C) 2000-2002 Katipo Communications
   6 # Parts Copyright (C) 2010      BibLibre
   7 # Parts Copyright (C) 2013      Mark Tompsett
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22
  23 =head1 NAME
  24
  25 opac-MARCdetail.pl : script to show a biblio in MARC format
  26
  27 =head1 SYNOPSIS
  28
  29 =cut
  30
  31 =head1 DESCRIPTION
  32
  33 This script needs a biblionumber as  parameter
  34
  35 It shows the biblio in a (nice) MARC format depending on MARC
  36 parameters tables.
  37
  38 The template is in <templates_dir>/catalogue/MARCdetail.tt.
  39 this template must be divided into 11 "tabs".
  40
  41 The first 10 tabs present the biblio, the 11th one presents
  42 the items attached to the biblio
  43
  44 =cut
  45
  46 use Modern::Perl;
  47
  48 use C4::Auth qw( get_template_and_user );
  49 use C4::Context;
  50 use C4::Output qw( parametrized_url output_html_with_http_headers );
  51 use CGI qw ( -utf8 );
  52 use C4::Biblio qw(
  53     CountItemsIssued
  54     GetAuthorisedValueDesc
  55     GetMarcControlnumber
  56     GetMarcFromKohaField
  57     GetMarcISSN
  58     GetMarcStructure
  59     TransformMarcToKoha
  60 );
  61 use C4::Reserves;
  62 use C4::Members;
  63 use C4::Koha qw( GetNormalizedISBN );
  64 use List::MoreUtils qw( uniq );
  65 use Koha::Biblios;
  66 use Koha::CirculationRules;
  67 use Koha::Items;
  68 use Koha::ItemTypes;
  69 use Koha::Patrons;
  70 use Koha::RecordProcessor;
  71 use Koha::DateUtils qw( output_pref );
  72 use Koha::Util::MARC;
  73
  74 my $query = CGI->new();
  75
  76 my $biblionumber = $query->param('biblionumber');
  77 if ( ! $biblionumber ) {
  78     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  79     exit;
  80 }
  81 $biblionumber = int($biblionumber);
  82
  83 # open template
  84 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  85     {
  86         template_name   => "opac-MARCdetail.tt",
  87         query           => $query,
  88         type            => "opac",
  89         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  90     }
  91 );
  92
  93 my $patron = Koha::Patrons->find($loggedinuser);
  94 my $biblio = Koha::Biblios->find($biblionumber);
  95 my $record = $biblio->metadata->record(
  96     {
  97         embed_items => 1,
  98         opac        => 1,
  99         patron      => $patron,
 100     }
 101 );
 102 if ( ! $record ) {
 103     print $query->redirect("/cgi-bin/koha/errors/404.pl");
 104     exit;
 105 }
 106
 107 unless ( $patron and $patron->category->override_hidden_items ) {
 108     # only skip this check if there's a logged in user
 109     # and its category overrides OpacHiddenItems
 110     if ( $biblio->hidden_in_opac({ rules => C4::Context->yaml_preference('OpacHiddenItems') }) ) {
 111         print $query->redirect('/cgi-bin/koha/errors/404.pl'); # escape early
 112         exit;
 113     }
 114 }
 115
 116 my $framework = $biblio ? $biblio->frameworkcode : q{};
 117 my $tagslib   = &GetMarcStructure( 0, $framework );
 118
 119 my $record_processor = Koha::RecordProcessor->new({
 120     filters => 'ViewPolicy',
 121     options => {
 122         interface => 'opac',
 123         frameworkcode => $framework
 124     }
 125 });
 126 $record_processor->process($record);
 127
 128 # get biblionumbers stored in the cart
 129 if(my $cart_list = $query->cookie("bib_list")){
 130     my @cart_list = split(/\//, $cart_list);
 131     if ( grep {$_ eq $biblionumber} @cart_list) {
 132         $template->param( incart => 1 );
 133     }
 134 }
 135
 136 my ($bt_tag,$bt_subtag) = GetMarcFromKohaField( 'biblio.title' );
 137 $template->param(
 138     bibliotitle => $biblio->title,
 139 ) if $tagslib->{$bt_tag}->{$bt_subtag}->{hidden} <= 0 && # <=0 OPAC visible.
 140      $tagslib->{$bt_tag}->{$bt_subtag}->{hidden} > -8;   # except -8;
 141
 142 my $allow_onshelf_holds;
 143 my $items = $biblio->items;
 144
 145 while ( my $item = $items->next ) {
 146     $allow_onshelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } )
 147       unless $allow_onshelf_holds;
 148 }
 149
 150 if( $allow_onshelf_holds || CountItemsIssued($biblionumber) || $biblio->has_items_waiting_or_intransit ) {
 151     $template->param( ReservableItems => 1 );
 152 }
 153
 154 # fill arrays
 155 my @loop_data = ();
 156
 157 # loop through each tab 0 through 9
 158 for ( my $tabloop = 0 ; $tabloop <= 9 ; $tabloop++ ) {
 159
 160     # loop through each tag
 161     my @loop_data = ();
 162     my @subfields_data;
 163
 164     # deal with leader
 165     unless ( $tagslib->{'000'}->{'@'}->{tab} ne $tabloop
 166         or $tagslib->{'000'}->{'@'}->{hidden} > 0 )
 167     {
 168         my %subfield_data;
 169         $subfield_data{marc_lib}      = $tagslib->{'000'}->{'@'}->{lib};
 170         $subfield_data{marc_value}    = $record->leader();
 171         $subfield_data{marc_subfield} = '@';
 172         $subfield_data{marc_tag}      = '000';
 173         push( @subfields_data, \%subfield_data );
 174         my %tag_data;
 175         $tag_data{tag} = '000 -' . $tagslib->{'000'}->{lib};
 176         my @tmp = @subfields_data;
 177         $tag_data{subfield} = \@tmp;
 178         push( @loop_data, \%tag_data );
 179         undef @subfields_data;
 180     }
 181     my @fields = $record->fields();
 182     for ( my $x_i = 0 ; $x_i <= $#fields ; $x_i++ ) {
 183
 184         # if tag <10, there's no subfield, use the "@" trick
 185         if ( $fields[$x_i]->tag() < 10 ) {
 186             next
 187               if (
 188                 $tagslib->{ $fields[$x_i]->tag() }->{'@'}->{tab} ne $tabloop );
 189             next if ( $tagslib->{ $fields[$x_i]->tag() }->{'@'}->{hidden} > 0 );
 190             my %subfield_data;
 191             $subfield_data{marc_lib} =
 192               $tagslib->{ $fields[$x_i]->tag() }->{'@'}->{lib};
 193             $subfield_data{marc_value}    = $fields[$x_i]->data();
 194             $subfield_data{marc_subfield} = '@';
 195             $subfield_data{marc_tag}      = $fields[$x_i]->tag();
 196             push( @subfields_data, \%subfield_data );
 197         }
 198         else {
 199             my @subf = $fields[$x_i]->subfields;
 200             my $previous = '';
 201             # loop through each subfield
 202             for my $i ( 0 .. $#subf ) {
 203                 $subf[$i][0] = "@" unless defined($subf[$i][0]);
 204                 my $sf_def = $tagslib->{ $fields[$x_i]->tag() };
 205                 $sf_def = $sf_def->{ $subf[$i][0] } if defined($sf_def);
 206                 my ($tab,$hidden,$lib);
 207                 $tab = $sf_def->{tab} if defined($sf_def);
 208                 $tab = $tab // int($fields[$x_i]->tag()/100);
 209                 $hidden = $sf_def->{hidden} if defined($sf_def);
 210                 $hidden = $hidden // 0;
 211                 next if ( $tab != $tabloop );
 212                 next if ( $hidden > 0 );
 213                 my %subfield_data;
 214                 $lib = $sf_def->{lib} if defined($sf_def);
 215                 $lib = $lib // '--';
 216                 $subfield_data{marc_lib} = ($lib eq $previous) ?  '--' : $lib;
 217                 $previous = $lib;
 218                 $subfield_data{link} = $sf_def->{link};
 219                 $subf[$i][1] =~ s/\n/<br\/>/g;
 220                 if ( $sf_def->{isurl} ) {
 221                     $subfield_data{marc_value} = "<a href=\"$subf[$i][1]\">$subf[$i][1]</a>";
 222                 }
 223                 elsif ( defined($sf_def->{kohafield}) && $sf_def->{kohafield} eq "biblioitems.isbn" ) {
 224                     $subfield_data{marc_value} = $subf[$i][1];
 225                 }
 226                 else {
 227                     if ( $sf_def->{authtypecode} ) {
 228                         $subfield_data{authority} = $fields[$x_i]->subfield(9);
 229                     }
 230                     $subfield_data{marc_value} = GetAuthorisedValueDesc( $fields[$x_i]->tag(),
 231                         $subf[$i][0], $subf[$i][1], '', $tagslib, '', 'opac' );
 232                 }
 233                 $subfield_data{marc_subfield} = $subf[$i][0];
 234                 $subfield_data{marc_tag}      = $fields[$x_i]->tag();
 235                 push( @subfields_data, \%subfield_data );
 236             }
 237         }
 238         if ( $#subfields_data >= 0 ) {
 239             my %tag_data;
 240             if (   ( $fields[$x_i]->tag() eq $fields[ $x_i - 1 ]->tag() )
 241                 && ( C4::Context->preference('LabelMARCView') eq 'economical' )
 242               )
 243             {
 244                 $tag_data{tag} = "";
 245             }
 246             else {
 247                 if ( C4::Context->preference('hide_marc') ) {
 248                     $tag_data{tag} = $tagslib->{ $fields[$x_i]->tag() }->{lib};
 249                 }
 250                 else {
 251                     my $sf_def = $tagslib->{ $fields[$x_i]->tag() };
 252                     my $lib;
 253                     $lib = $sf_def->{lib} if defined($sf_def);
 254                     $lib = $lib // '';
 255                     $tag_data{tag} = $fields[$x_i]->tag() . ' '
 256                       . C4::Koha::display_marc_indicators($fields[$x_i])
 257                       . " - $lib";
 258                 }
 259             }
 260             my @tmp = @subfields_data;
 261             $tag_data{subfield} = \@tmp;
 262             push( @loop_data, \%tag_data );
 263             undef @subfields_data;
 264         }
 265     }
 266     $template->param( "tab" . $tabloop . "XX" => \@loop_data );
 267 }
 268
 269
 270 # now, build item tab !
 271 # the main difference is that datas are in lines and not in columns : thus, we build the <th> first, then the values...
 272 # loop through each tag
 273 # warning : we may have differents number of columns in each row. Thus, we first build a hash, complete it if necessary
 274 # then construct template.
 275 # $record has already had all the item fields filtered above.
 276 my @fields = $record->fields();
 277 my %witness
 278   ; #---- stores the list of subfields used at least once, with the "meaning" of the code
 279 my @item_subfield_codes;
 280 my @item_loop;
 281 foreach my $field (@fields) {
 282     next if ( $field->tag() < 10 );
 283     my @subf = $field->subfields;
 284     my $item;
 285
 286     # loop through each subfield
 287     for my $i ( 0 .. $#subf ) {
 288         my $sf_def = $tagslib->{ $field->tag() }->{ $subf[$i][0] };
 289         next if ( ($sf_def->{tab}||0) != 10 );
 290         next if ( ($sf_def->{hidden}||0) > 0 );
 291
 292         push @item_subfield_codes, $subf[$i][0];
 293         $witness{ $subf[$i][0] } = $sf_def->{lib};
 294
 295         # Allow repeatables (BZ 13574)
 296         if( $item->{$subf[$i][0]} ) {
 297             $item->{$subf[$i][0]} .= ' | ';
 298         } else {
 299             $item->{$subf[$i][0]} = q{};
 300         }
 301
 302         if ( $sf_def->{isurl} ) {
 303             $item->{ $subf[$i][0] } .= "<a href=\"$subf[$i][1]\">$subf[$i][1]</a>";
 304         }
 305         elsif ( $sf_def->{kohafield} eq "biblioitems.isbn" ) {
 306             $item->{ $subf[$i][0] } .= $subf[$i][1];
 307         }
 308         else {
 309             $item->{ $subf[$i][0] } .= GetAuthorisedValueDesc( $field->tag(), $subf[$i][0],
 310                 $subf[$i][1], '', $tagslib, '', 'opac' ) // q{};
 311         }
 312
 313         my $kohafield = $tagslib->{ $field->tag() }->{ $subf[$i][0] }->{kohafield};
 314         $item->{ $subf[$i][0] } = output_pref( { str => $item->{ $subf[$i][0] }, dateonly => 1 } )
 315           if grep { $kohafield eq $_ }
 316               qw( items.dateaccessioned items.onloan items.datelastseen items.datelastborrowed items.replacementpricedate );
 317
 318     }
 319     push @item_loop, $item if $item;
 320 }
 321 my ( $holdingbrtagf, $holdingbrtagsubf ) =
 322   &GetMarcFromKohaField( "items.holdingbranch" );
 323 @item_loop =
 324   sort { ($a->{$holdingbrtagsubf}||'') cmp ($b->{$holdingbrtagsubf}||'') } @item_loop;
 325
 326 @item_subfield_codes = uniq @item_subfield_codes;
 327 # fill item info
 328 my @item_header_loop;
 329 for my $subfield_code ( @item_subfield_codes ) {
 330     push @item_header_loop, $witness{$subfield_code};
 331     for my $item_data ( @item_loop ) {
 332         $item_data->{$subfield_code} ||= "&nbsp;"
 333      }
 334 }
 335
 336 if ( C4::Context->preference("OPACISBD") ) {
 337     $template->param( ISBD => 1 );
 338 }
 339
 340 #Search for title in links
 341 my $marcflavour  = C4::Context->preference("marcflavour");
 342 my $dat = TransformMarcToKoha({ record => $record });
 343 my $isbn = GetNormalizedISBN(undef,$record,$marcflavour);
 344 my $marccontrolnumber   = GetMarcControlnumber ($record, $marcflavour);
 345 my $marcissns = GetMarcISSN( $record, $marcflavour );
 346 my $issn = $marcissns->[0] || '';
 347
 348 if (my $search_for_title = C4::Context->preference('OPACSearchForTitleIn')){
 349     $dat->{title} =~ s/\/+$//; # remove trailing slash
 350     $dat->{title} =~ s/\s+$//; # remove trailing space
 351     my $oclc_no = Koha::Util::MARC::oclc_number( $record );
 352     $search_for_title = parametrized_url(
 353         $search_for_title,
 354         {
 355             TITLE         => $dat->{title},
 356             AUTHOR        => $dat->{author},
 357             ISBN          => $isbn,
 358             ISSN          => $issn,
 359             CONTROLNUMBER => $marccontrolnumber,
 360             BIBLIONUMBER  => $biblionumber,
 361             OCLC_NO       => $oclc_no,
 362         }
 363     );
 364     $template->param('OPACSearchForTitleIn' => $search_for_title);
 365 }
 366
 367 if( C4::Context->preference('ArticleRequests') ) {
 368     my $itemtype = Koha::ItemTypes->find($biblio->itemtype);
 369     my $artreqpossible = $patron
 370         ? $biblio->can_article_request( $patron )
 371         : $itemtype
 372         ? $itemtype->may_article_request
 373         : q{};
 374     $template->param( artreqpossible => $artreqpossible );
 375 }
 376
 377 my $norequests = ! $biblio->items->filter_by_for_hold->count;
 378 $template->param(
 379     item_loop           => \@item_loop,
 380     item_header_loop    => \@item_header_loop,
 381     item_subfield_codes => \@item_subfield_codes,
 382     biblio              => $biblio,
 383     norequests          => $norequests,
 384 );
 385
 386 output_html_with_http_headers $query, $cookie, $template->output;