opac/opac-account.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Katipo Communications 2002
   4 # Copyright Biblibre 2007,2010
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use Modern::Perl;
  23 use CGI qw ( -utf8 );
  24 use C4::Members;
  25 use C4::Auth;
  26 use C4::Output;
  27 use Koha::Account::Lines;
  28 use Koha::Patrons;
  29 use Koha::Plugins;
  30
  31 my $query = new CGI;
  32 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  33     {
  34         template_name   => "opac-account.tt",
  35         query           => $query,
  36         type            => "opac",
  37         authnotrequired => 0,
  38         debug           => 1,
  39     }
  40 );
  41
  42 my $patron = Koha::Patrons->find( $borrowernumber );
  43 my $category = $patron->category;
  44 my $borrower= $patron->unblessed;
  45 $borrower->{description} = $category->description;
  46 $borrower->{category_type} = $category->category_type;
  47 $template->param( BORROWER_INFO => $borrower );
  48
  49 my $total = $patron->account->balance;
  50 my $accts = Koha::Account::Lines->search(
  51     { borrowernumber => $patron->borrowernumber },
  52     { order_by       => { -desc => 'accountlines_id' } }
  53 );
  54
  55 my @accountlines;
  56 while ( my $line = $accts->next ) {
  57     my $accountline = $line->unblessed;
  58     $accountline->{'amount'} = sprintf( "%.2f", $accountline->{'amount'} || '0.00');
  59     if ( $accountline->{'amount'} >= 0 ) {
  60         $accountline->{'amountcredit'} = 1;
  61     }
  62     $accountline->{'amountoutstanding'} =
  63       sprintf( "%.2f", $accountline->{'amountoutstanding'} || '0.00' );
  64     if ( $accountline->{'amountoutstanding'} >= 0 ) {
  65         $accountline->{'amountoutstandingcredit'} = 1;
  66     }
  67     push @accountlines, $accountline;
  68 }
  69
  70 $template->param(
  71     ACCOUNT_LINES => \@accountlines,
  72     total         => sprintf( "%.2f", $total ), # FIXME Use TT plugin Price
  73     accountview   => 1,
  74     message       => scalar $query->param('message') || q{},
  75     message_value => scalar $query->param('message_value') || q{},
  76     payment       => scalar $query->param('payment') || q{},
  77     payment_error => scalar $query->param('payment-error') || q{},
  78 );
  79
  80 my $plugins_enabled = C4::Context->preference('UseKohaPlugins') && C4::Context->config("enable_plugins");
  81 if ( $plugins_enabled ) {
  82     my @plugins = Koha::Plugins->new()->GetPlugins({
  83         method => 'opac_online_payment',
  84     });
  85     # Only pass in plugins where opac online payment is enabled
  86     @plugins = grep { $_->opac_online_payment } @plugins;
  87     $template->param( plugins => \@plugins );
  88 }
  89
  90 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };