opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use String::Random qw( random_string );
  23
  24 use C4::Auth;
  25 use C4::Output;
  26 use C4::Members;
  27 use C4::Form::MessagingPreferences;
  28 use Koha::Borrower::Modifications;
  29 use C4::Branch qw(GetBranchesLoop);
  30 use C4::Scrubber;
  31 use Email::Valid;
  32
  33 my $cgi = new CGI;
  34 my $dbh = C4::Context->dbh;
  35
  36 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  37     {
  38         template_name   => "opac-memberentry.tt",
  39         type            => "opac",
  40         query           => $cgi,
  41         authnotrequired => 1,
  42     }
  43 );
  44
  45 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  46 {
  47     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  48     exit;
  49 }
  50
  51 my $action = $cgi->param('action') || q{};
  52 if ( $action eq q{} ) {
  53     if ($borrowernumber) {
  54         $action = 'edit';
  55     }
  56     else {
  57         $action = 'new';
  58     }
  59 }
  60
  61 my $mandatory = GetMandatoryFields($action);
  62 my $hidden = GetHiddenFields($mandatory);
  63
  64 $template->param(
  65     action            => $action,
  66     hidden            => $hidden,
  67     mandatory         => $mandatory,
  68     member_titles     => GetTitles() || undef,
  69     branches          => GetBranchesLoop(),
  70     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  71 );
  72
  73 if ( $action eq 'create' ) {
  74
  75     my %borrower = ParseCgiForBorrower($cgi);
  76
  77     %borrower = DelEmptyFields(%borrower);
  78
  79     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
  80     my $invalidformfields = CheckForInvalidFields(\%borrower);
  81
  82     if (@empty_mandatory_fields || @$invalidformfields) {
  83         $template->param(
  84             empty_mandatory_fields => \@empty_mandatory_fields,
  85             invalid_form_fields    => $invalidformfields,
  86             borrower               => \%borrower
  87         );
  88     }
  89     elsif (
  90         md5_base64( $cgi->param('captcha') ) ne $cgi->param('captcha_digest') )
  91     {
  92         $template->param(
  93             failed_captcha => 1,
  94             borrower       => \%borrower
  95         );
  96     }
  97     else {
  98         if (
  99             C4::Context->boolean_preference(
 100                 'PatronSelfRegistrationVerifyByEmail')
 101           )
 102         {
 103             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 104                 {
 105                     template_name   => "opac-registration-email-sent.tt",
 106                     type            => "opac",
 107                     query           => $cgi,
 108                     authnotrequired => 1,
 109                 }
 110             );
 111             $template->param( 'email' => $borrower{'email'} );
 112
 113             my $verification_token = md5_hex( \%borrower );
 114             $borrower{'password'} = random_string("..........");
 115
 116             Koha::Borrower::Modifications->new(
 117                 verification_token => $verification_token )
 118               ->AddModifications(\%borrower);
 119
 120             #Send verification email
 121             my $letter = C4::Letters::GetPreparedLetter(
 122                 module      => 'members',
 123                 letter_code => 'OPAC_REG_VERIFY',
 124                 tables      => {
 125                     borrower_modifications => $verification_token,
 126                 },
 127             );
 128
 129             C4::Letters::EnqueueLetter(
 130                 {
 131                     letter                 => $letter,
 132                     message_transport_type => 'email',
 133                     to_address             => $borrower{'email'},
 134                     from_address =>
 135                       C4::Context->preference('KohaAdminEmailAddress'),
 136                 }
 137             );
 138         }
 139         else {
 140             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 141                 {
 142                     template_name   => "opac-registration-confirmation.tt",
 143                     type            => "opac",
 144                     query           => $cgi,
 145                     authnotrequired => 1,
 146                 }
 147             );
 148
 149             $template->param( OpacPasswordChange =>
 150                   C4::Context->preference('OpacPasswordChange') );
 151
 152             my ( $borrowernumber, $password ) = AddMember_Opac(%borrower);
 153             C4::Form::MessagingPreferences::handle_form_action($cgi, { borrowernumber => $borrowernumber }, $template, 1, C4::Context->preference('PatronSelfRegistrationDefaultCategory') ) if $borrowernumber && C4::Context->preference('EnhancedMessagingPreferences');
 154
 155             $template->param( password_cleartext => $password );
 156             $template->param(
 157                 borrower => GetMember( borrowernumber => $borrowernumber ) );
 158             $template->param(
 159                 PatronSelfRegistrationAdditionalInstructions =>
 160                   C4::Context->preference(
 161                     'PatronSelfRegistrationAdditionalInstructions')
 162             );
 163         }
 164     }
 165 }
 166 elsif ( $action eq 'update' ) {
 167
 168     my %borrower = ParseCgiForBorrower($cgi);
 169
 170     my %borrower_changes = DelEmptyFields(%borrower);
 171     my @empty_mandatory_fields =
 172       CheckMandatoryFields( \%borrower_changes, $action );
 173     my $invalidformfields = CheckForInvalidFields(\%borrower);
 174
 175     if (@empty_mandatory_fields || @$invalidformfields) {
 176         $template->param(
 177             empty_mandatory_fields => \@empty_mandatory_fields,
 178             invalid_form_fields    => $invalidformfields,
 179             borrower               => \%borrower
 180         );
 181
 182         $template->param( action => 'edit' );
 183     }
 184     else {
 185         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 186         if (%borrower_changes) {
 187             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 188                 {
 189                     template_name   => "opac-memberentry-update-submitted.tt",
 190                     type            => "opac",
 191                     query           => $cgi,
 192                     authnotrequired => 1,
 193                 }
 194             );
 195
 196             my $m =
 197               Koha::Borrower::Modifications->new(
 198                 borrowernumber => $borrowernumber );
 199
 200             $m->DelModifications;
 201             $m->AddModifications(\%borrower_changes);
 202             $template->param(
 203                 borrower => GetMember( borrowernumber => $borrowernumber ),
 204             );
 205         }
 206         else {
 207             $template->param(
 208                 action => 'edit',
 209                 nochanges => 1,
 210                 borrower => GetMember( borrowernumber => $borrowernumber ),
 211             );
 212         }
 213     }
 214 }
 215 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 216     my $borrower = GetMember( borrowernumber => $borrowernumber );
 217
 218     if (C4::Context->preference('ExtendedPatronAttributes')) {
 219         my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber, 'opac');
 220         if (scalar(@$attributes) > 0) {
 221             $borrower->{ExtendedPatronAttributes} = 1;
 222             $borrower->{patron_attributes} = $attributes;
 223         }
 224     }
 225
 226     $template->param(
 227         borrower => $borrower, );
 228
 229     if (C4::Context->preference('OPACpatronimages')) {
 230         my ($image, $dberror) = GetPatronImage($borrower->{borrowernumber});
 231         if ($image) {
 232             $template->param(
 233                 display_patron_image => 1
 234             );
 235         }
 236     }
 237
 238 }
 239
 240 my $captcha = random_string("CCCCC");
 241
 242 $template->param(
 243     captcha        => $captcha,
 244     captcha_digest => md5_base64($captcha)
 245 );
 246
 247 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };
 248
 249 sub GetHiddenFields {
 250     my ($mandatory) = @_;
 251     my %hidden_fields;
 252
 253     my $BorrowerUnwantedField =
 254       C4::Context->preference("PatronSelfRegistrationBorrowerUnwantedField");
 255
 256     my @fields = split( /\|/, $BorrowerUnwantedField );
 257     foreach (@fields) {
 258         next unless m/\w/o;
 259         #Don't hide mandatory fields
 260         next if $mandatory->{$_};
 261         $hidden_fields{$_} = 1;
 262     }
 263
 264     return \%hidden_fields;
 265 }
 266
 267 sub GetMandatoryFields {
 268     my ($action) = @_;
 269
 270     my %mandatory_fields;
 271
 272     my $BorrowerMandatoryField =
 273       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 274
 275     my @fields = split( /\|/, $BorrowerMandatoryField );
 276
 277     foreach (@fields) {
 278         $mandatory_fields{$_} = 1;
 279     }
 280
 281     if ( $action eq 'create' || $action eq 'new' ) {
 282         $mandatory_fields{'email'} = 1
 283           if C4::Context->boolean_preference(
 284             'PatronSelfRegistrationVerifyByEmail');
 285     }
 286
 287     return \%mandatory_fields;
 288 }
 289
 290 sub CheckMandatoryFields {
 291     my ( $borrower, $action ) = @_;
 292
 293     my @empty_mandatory_fields;
 294
 295     my $mandatory_fields = GetMandatoryFields($action);
 296     delete $mandatory_fields->{'cardnumber'};
 297
 298     foreach my $key ( keys %$mandatory_fields ) {
 299         push( @empty_mandatory_fields, $key )
 300           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 301     }
 302
 303     return @empty_mandatory_fields;
 304 }
 305
 306 sub CheckForInvalidFields {
 307     my $borrower = shift;
 308     my @invalidFields;
 309     if ($borrower->{'email'}) {
 310         push(@invalidFields, "email") if (!Email::Valid->address($borrower->{'email'}));
 311     }
 312     if ($borrower->{'emailpro'}) {
 313         push(@invalidFields, "emailpro") if (!Email::Valid->address($borrower->{'emailpro'}));
 314     }
 315     if ($borrower->{'B_email'}) {
 316         push(@invalidFields, "B_email") if (!Email::Valid->address($borrower->{'B_email'}));
 317     }
 318     return \@invalidFields;
 319 }
 320
 321 sub ParseCgiForBorrower {
 322     my ($cgi) = @_;
 323
 324     my $scrubber = C4::Scrubber->new();
 325     my %borrower;
 326
 327     foreach ( $cgi->param ) {
 328         if ( $_ =~ '^borrower_' ) {
 329             my ($key) = substr( $_, 9 );
 330             $borrower{$key} = $scrubber->scrub( $cgi->param($_) );
 331         }
 332     }
 333
 334     $borrower{'dateofbirth'} =
 335       C4::Dates->new( $borrower{'dateofbirth'} )->output("iso")
 336       if ( defined( $borrower{'dateofbirth'} ) );
 337
 338     return %borrower;
 339 }
 340
 341 sub DelUnchangedFields {
 342     my ( $borrowernumber, %new_data ) = @_;
 343
 344     my $current_data = GetMember( borrowernumber => $borrowernumber );
 345
 346     foreach my $key ( keys %new_data ) {
 347         if ( $current_data->{$key} eq $new_data{$key} ) {
 348             delete $new_data{$key};
 349         }
 350     }
 351
 352     return %new_data;
 353 }
 354
 355 sub DelEmptyFields {
 356     my (%borrower) = @_;
 357
 358     foreach my $key ( keys %borrower ) {
 359         delete $borrower{$key} unless $borrower{$key};
 360     }
 361
 362     return %borrower;
 363 }