opac/opac-request-article.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright ByWater Solutions 2015
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth qw( get_template_and_user );
  25 use C4::Output qw( output_html_with_http_headers );
  26
  27 use Koha::Biblios;
  28 use Koha::Logger;
  29 use Koha::Patrons;
  30
  31 use Scalar::Util qw( blessed );
  32 use Try::Tiny;
  33
  34 my $cgi = CGI->new;
  35
  36 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  37     {
  38         template_name   => "opac-request-article.tt",
  39         query           => $cgi,
  40         type            => "opac",
  41     }
  42 );
  43
  44 my $action = $cgi->param('action') || q{};
  45 my $biblionumber = $cgi->param('biblionumber');
  46 my $biblio = Koha::Biblios->find($biblionumber);
  47 if( !$biblio ) {
  48     print $cgi->redirect("/cgi-bin/koha/errors/404.pl");
  49     exit;
  50 }
  51
  52 if ( $action eq 'create' ) {
  53     my $branchcode = $cgi->param('branchcode');
  54
  55     my $itemnumber   = $cgi->param('itemnumber')   || undef;
  56     my $title        = $cgi->param('title')        || undef;
  57     my $author       = $cgi->param('author')       || undef;
  58     my $volume       = $cgi->param('volume')       || undef;
  59     my $issue        = $cgi->param('issue')        || undef;
  60     my $date         = $cgi->param('date')         || undef;
  61     my $pages        = $cgi->param('pages')        || undef;
  62     my $chapters     = $cgi->param('chapters')     || undef;
  63     my $patron_notes = $cgi->param('patron_notes') || undef;
  64     my $format       = $cgi->param('format')       || undef;
  65     my $toc_request  = $cgi->param('toc_request');
  66
  67
  68     my $success;
  69
  70     try {
  71         my $ar = Koha::ArticleRequest->new(
  72             {
  73                 borrowernumber => $borrowernumber,
  74                 biblionumber   => $biblionumber,
  75                 branchcode     => $branchcode,
  76                 itemnumber     => $itemnumber,
  77                 title          => $title,
  78                 author         => $author,
  79                 volume         => $volume,
  80                 issue          => $issue,
  81                 date           => $date,
  82                 pages          => $pages,
  83                 chapters       => $chapters,
  84                 patron_notes   => $patron_notes,
  85                 format         => $format,
  86                 toc_request    => $toc_request ? 1 : 0,
  87             }
  88         )->request;
  89         $success = 1;
  90     } catch {
  91         if ( blessed $_ and $_->isa('Koha::Exceptions::ArticleRequest::LimitReached') ) {
  92             $template->param(
  93                 error_message => 'article_request_limit_reached'
  94             );
  95         }
  96         else {
  97             Koha::Logger->get->debug("Unhandled exception when placing an article request ($_)");
  98             $template->param(
  99                 error_message => 'article_request_unhandled_exception'
 100             );
 101         }
 102     };
 103
 104     if ( $success ) {
 105         print $cgi->redirect("/cgi-bin/koha/opac-user.pl#opac-user-article-requests");
 106         exit;
 107     }
 108 # Should we redirect?
 109 }
 110 elsif ( !$action && C4::Context->preference('ArticleRequestsOpacHostRedirection') ) {
 111   # Conditions: no items, host item entry (MARC21 773)
 112   my ( $host, $pageinfo ) = $biblio->get_marc_host( { no_items => 1 } );
 113   if ($host) {
 114       $template->param(
 115           pageinfo => $pageinfo,
 116           title    => $biblio->title,
 117           author   => $biblio->author
 118       );
 119       $biblio = $host;
 120   }
 121 }
 122
 123 my $patron = Koha::Patrons->find($borrowernumber);
 124
 125 if(!$patron->can_request_article) {
 126     $template->param(
 127         error_message => 'article_request_limit_reached'
 128     );
 129 }
 130
 131 $template->param( article_request_fee => $patron->article_request_fee )
 132   if $action ne 'create';
 133
 134 $template->param(
 135     biblio => $biblio,
 136     patron => $patron,
 137     action => $action
 138 );
 139
 140 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };