opac/opac-search.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Garry Collum and the Koha Development team
   4 # Copyright 2010 BibLibre
   5 # Copyright 2011 KohaAloha, NZ
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it under the
  10 # terms of the GNU General Public License as published by the Free Software
  11 # Foundation; either version 2 of the License, or (at your option) any later
  12 # version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  15 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  16 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License along
  19 # with Koha; if not, write to the Free Software Foundation, Inc.,
  20 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  21
  22 # Script to perform searching
  23 # Mostly copied from search.pl, see POD there
  24 use Modern::Perl;
  25
  26 ## STEP 1. Load things that are used in both search page and
  27 # results page and decide which template to load, operations
  28 # to perform, etc.
  29 ## load Koha modules
  30 use C4::Context;
  31
  32 my $searchengine = C4::Context->preference("SearchEngine");
  33 for ( $searchengine ) {
  34     when ( /^Solr$/ ) {
  35         warn "We use Solr";
  36         require 'opac/search.pl';
  37         exit;
  38     }
  39     when ( /^Zebra$/ ) {
  40
  41     }
  42 }
  43
  44 use C4::Output;
  45 use C4::Auth qw(:DEFAULT get_session);
  46 use C4::Languages qw(getAllLanguages);
  47 use C4::Search;
  48 use C4::Biblio;  # GetBiblioData
  49 use C4::Koha;
  50 use C4::Tags qw(get_tags);
  51 use C4::Branch; # GetBranches
  52 use C4::SocialData;
  53 use C4::Ratings;
  54
  55 use POSIX qw(ceil floor strftime);
  56 use URI::Escape;
  57 use Storable qw(thaw freeze);
  58 use Business::ISBN;
  59
  60 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
  61 # create a new CGI object
  62 # FIXME: no_undef_params needs to be tested
  63 use CGI qw('-no_undef_params');
  64 my $cgi = new CGI;
  65
  66 my $branch_group_limit = $cgi->param("branch_group_limit");
  67 if ( $branch_group_limit ) {
  68     if ( $branch_group_limit =~ /^multibranchlimit-/ ) {
  69         # For search groups we are going to convert this branch_group_limit CGI
  70         # parameter into a multibranchlimit CGI parameter for the purposes of
  71         # actually performing the query
  72         $cgi->param(
  73             -name => 'multibranchlimit',
  74             -values => substr($branch_group_limit, 17)
  75         );
  76     } else {
  77         $cgi->append(
  78             -name => 'limit',
  79             -values => [ $branch_group_limit ]
  80         );
  81     }
  82 }
  83
  84 BEGIN {
  85     if (C4::Context->preference('BakerTaylorEnabled')) {
  86         require C4::External::BakerTaylor;
  87         import C4::External::BakerTaylor qw(&image_url &link_url);
  88     }
  89 }
  90
  91 my ($template,$borrowernumber,$cookie);
  92 my $lang = C4::Templates::getlanguage($cgi, 'opac');
  93 # decide which template to use
  94 my $template_name;
  95 my $template_type = 'basic';
  96 my @params = $cgi->param("limit");
  97
  98
  99 my $format = $cgi->param("format") || '';
 100 my $build_grouped_results = C4::Context->preference('OPACGroupResults');
 101 if ($format =~ /(rss|atom|opensearchdescription)/) {
 102     $template_name = 'opac-opensearch.tmpl';
 103 }
 104 elsif (@params && $build_grouped_results) {
 105     $template_name = 'opac-results-grouped.tmpl';
 106 }
 107 elsif ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 108     $template_name = 'opac-results.tmpl';
 109 }
 110 else {
 111     $template_name = 'opac-advsearch.tmpl';
 112     $template_type = 'advsearch';
 113 }
 114 # load the template
 115 ($template, $borrowernumber, $cookie) = get_template_and_user({
 116     template_name => $template_name,
 117     query => $cgi,
 118     type => "opac",
 119     authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
 120     }
 121 );
 122 if ($template_name eq 'opac-results.tmpl') {
 123    $template->param('COinSinOPACResults' => C4::Context->preference('COinSinOPACResults'));
 124 }
 125
 126 # get biblionumbers stored in the cart
 127 my @cart_list;
 128
 129 if($cgi->cookie("bib_list")){
 130     my $cart_list = $cgi->cookie("bib_list");
 131     @cart_list = split(/\//, $cart_list);
 132 }
 133
 134 if ($format eq 'rss2' or $format eq 'opensearchdescription' or $format eq 'atom') {
 135     $template->param($format => 1);
 136     $template->param(timestamp => strftime("%Y-%m-%dT%H:%M:%S-00:00", gmtime)) if ($format eq 'atom');
 137     # FIXME - the timestamp is a hack - the biblio update timestamp should be used for each
 138     # entry, but not sure if that's worth an extra database query for each bib
 139 }
 140 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 141     $template->param('UNIMARC' => 1);
 142 }
 143 elsif (C4::Context->preference("marcflavour") eq "MARC21" ) {
 144     $template->param('usmarc' => 1);
 145 }
 146 $template->param( 'AllowOnShelfHolds' => C4::Context->preference('AllowOnShelfHolds') );
 147 $template->param( 'OPACNoResultsFound' => C4::Context->preference('OPACNoResultsFound') );
 148
 149 $template->param(
 150     OpacStarRatings => C4::Context->preference("OpacStarRatings") );
 151
 152 if (C4::Context->preference('BakerTaylorEnabled')) {
 153     $template->param(
 154         BakerTaylorEnabled  => 1,
 155         BakerTaylorImageURL => &image_url(),
 156         BakerTaylorLinkURL  => &link_url(),
 157         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 158     );
 159 }
 160
 161 if (C4::Context->preference('TagsEnabled')) {
 162     $template->param(TagsEnabled => 1);
 163     foreach (qw(TagsShowOnList TagsInputOnList)) {
 164         C4::Context->preference($_) and $template->param($_ => 1);
 165     }
 166 }
 167
 168 ## URI Re-Writing
 169 # Deprecated, but preserved because it's interesting :-)
 170 # The same thing can be accomplished with mod_rewrite in
 171 # a more elegant way
 172 #
 173 #my $rewrite_flag;
 174 #my $uri = $cgi->url(-base => 1);
 175 #my $relative_url = $cgi->url(-relative=>1);
 176 #$uri.="/".$relative_url."?";
 177 #warn "URI:$uri";
 178 #my @cgi_params_list = $cgi->param();
 179 #my $url_params = $cgi->Vars;
 180 #
 181 #for my $each_param_set (@cgi_params_list) {
 182 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 183 #}
 184 #warn "New URI:$uri";
 185 # Only re-write a URI if there are params or if it already hasn't been re-written
 186 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 187 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 188 #                            -cookie => $cookie);
 189 #    exit;
 190 #}
 191
 192 # load the branches
 193
 194 my $branches = GetBranches();   # used later in *getRecords, probably should be internalized by those functions after caching in C4::Branch is established
 195 $template->param(
 196     searchdomainloop => GetBranchCategories('searchdomain'),
 197 );
 198
 199 # load the language limits (for search)
 200 my $languages_limit_loop = getAllLanguages($lang);
 201 $template->param(search_languages_loop => $languages_limit_loop,);
 202
 203 # load the Type stuff
 204 my $itemtypes = GetItemTypes;
 205 # the index parameter is different for item-level itemtypes
 206 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 207 my @advancedsearchesloop;
 208 my $cnt;
 209 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 210 my @advanced_search_types = split(/\|/, $advanced_search_types);
 211
 212 foreach my $advanced_srch_type (@advanced_search_types) {
 213    if ($advanced_srch_type eq 'itemtypes') {
 214    # itemtype is a special case, since it's not defined in authorized values
 215         my @itypesloop;
 216         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{'description'} cmp $itemtypes->{$b}->{'description'} } keys %$itemtypes ) {
 217             my %row =(  number=>$cnt++,
 218                 ccl => "$itype_or_itemtype,phr",
 219                 code => $thisitemtype,
 220                 description => $itemtypes->{$thisitemtype}->{'description'},
 221                 imageurl=> getitemtypeimagelocation( 'opac', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 222             );
 223             push @itypesloop, \%row;
 224         }
 225         my %search_code = (  advanced_search_type => $advanced_srch_type,
 226                              code_loop => \@itypesloop );
 227         push @advancedsearchesloop, \%search_code;
 228     } else {
 229     # covers all the other cases: non-itemtype authorized values
 230        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type, '', 'opac');
 231         my @authvalueloop;
 232         for my $thisitemtype (@$advsearchtypes) {
 233                 my %row =(
 234                                 number=>$cnt++,
 235                                 ccl => $advanced_srch_type,
 236                 code => $thisitemtype->{authorised_value},
 237                 description => $thisitemtype->{'lib_opac'} || $thisitemtype->{'lib'},
 238                 imageurl => getitemtypeimagelocation( 'opac', $thisitemtype->{'imageurl'} ),
 239                 );
 240                 push @authvalueloop, \%row;
 241         }
 242         my %search_code = (  advanced_search_type => $advanced_srch_type,
 243                              code_loop => \@authvalueloop );
 244         push @advancedsearchesloop, \%search_code;
 245     }
 246 }
 247 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 248
 249 # # load the itypes (Called item types in the template -- just authorized values for searching)
 250 # my ($itypecount,@itype_loop) = GetCcodes();
 251 # $template->param(itypeloop=>\@itype_loop,);
 252
 253 # The following should only be loaded if we're bringing up the advanced search template
 254 if ( $template_type && $template_type eq 'advsearch' ) {
 255     # load the servers (used for searching -- to do federated searching, etc.)
 256     my $primary_servers_loop;# = displayPrimaryServers();
 257     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 258
 259     my $secondary_servers_loop;
 260     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 261
 262     # set the default sorting
 263     if (   C4::Context->preference('OPACdefaultSortField')
 264         && C4::Context->preference('OPACdefaultSortOrder') ) {
 265         my $default_sort_by =
 266             C4::Context->preference('OPACdefaultSortField') . '_'
 267           . C4::Context->preference('OPACdefaultSortOrder');
 268         $template->param( sort_by => $default_sort_by );
 269     }
 270
 271     # determine what to display next to the search boxes (ie, boolean option
 272     # shouldn't appear on the first one, scan indexes should, adding a new
 273     # box should only appear on the last, etc.
 274     my @search_boxes_array;
 275     my $search_boxes_count = 3; # begin whith 3 boxes
 276     for (my $i=1;$i<=$search_boxes_count;$i++) {
 277         # if it's the first one, don't display boolean option, but show scan indexes
 278         if ($i==1) {
 279             push @search_boxes_array,
 280                 {
 281                 scan_index => 1,
 282                 };
 283
 284         }
 285         # if it's the last one, show the 'add field' box
 286         elsif ($i==$search_boxes_count) {
 287             push @search_boxes_array,
 288                 {
 289                 boolean => 1,
 290                 add_field => 1,
 291                 };
 292         }
 293         else {
 294             push @search_boxes_array,
 295                 {
 296                 boolean => 1,
 297                 };
 298         }
 299
 300     }
 301     $template->param(uc(    C4::Context->preference("marcflavour")) => 1,   # we already did this for UNIMARC
 302                             advsearch => 1,
 303                             search_boxes_loop => \@search_boxes_array);
 304
 305     # use the global setting by default
 306     if ( C4::Context->preference("expandedSearchOption") == 1 ) {
 307         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 308     }
 309     # but let the user override it
 310     if (defined $cgi->param('expanded_options')) {
 311         if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 312             $template->param( expanded_options => $cgi->param('expanded_options'));
 313         }
 314     }
 315
 316     if (C4::Context->preference('OPACNumbersPreferPhrase')) {
 317         $template->param('numbersphr' => 1);
 318     }
 319
 320     output_html_with_http_headers $cgi, $cookie, $template->output;
 321     exit;
 322 }
 323
 324 ### OK, if we're this far, we're performing an actual search
 325
 326 # Fetch the paramater list as a hash in scalar context:
 327 #  * returns paramater list as tied hash ref
 328 #  * we can edit the values by changing the key
 329 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 330 my $params = $cgi->Vars;
 331 my $tag;
 332 $tag = $params->{tag} if $params->{tag};
 333
 334
 335 # String with params with the search criteria for the paging in opac-detail
 336 my $pasarParams = '';
 337 my $j = 0;
 338 for (keys %$params) {
 339     my @pasarParam = $cgi->param($_);
 340     for my $paramValue(@pasarParam) {
 341         $pasarParams .= '&amp;' if ($j > 0);
 342         $pasarParams .= $_ . '=' . $paramValue;
 343         $j++;
 344     }
 345 }
 346
 347 # Params that can have more than one value
 348 # sort by is used to sort the query
 349 # in theory can have more than one but generally there's just one
 350 my @sort_by;
 351 my $default_sort_by;
 352 if (   C4::Context->preference('OPACdefaultSortField')
 353     && C4::Context->preference('OPACdefaultSortOrder') ) {
 354     $default_sort_by =
 355         C4::Context->preference('OPACdefaultSortField') . '_'
 356       . C4::Context->preference('OPACdefaultSortOrder');
 357 }
 358
 359 my @allowed_sortby = qw /acqdate_asc acqdate_dsc author_az author_za call_number_asc call_number_dsc popularity_asc popularity_dsc pubdate_asc pubdate_dsc relevance title_az title_za/;
 360 @sort_by = $cgi->param('sort_by');
 361 $sort_by[0] = $default_sort_by if !$sort_by[0] && defined($default_sort_by);
 362 foreach my $sort (@sort_by) {
 363     if ( $sort ~~ @allowed_sortby ) {
 364         $template->param($sort => 1);
 365     }
 366 }
 367 $template->param('sort_by' => $sort_by[0]);
 368
 369 # Use the servers defined, or just search our local catalog(default)
 370 my @servers = $cgi->param('server');
 371 unless (@servers) {
 372     #FIXME: this should be handled using Context.pm
 373     @servers = ("biblioserver");
 374     # @servers = C4::Context->config("biblioserver");
 375 }
 376
 377 # operators include boolean and proximity operators and are used
 378 # to evaluate multiple operands
 379 my @operators = $cgi->param('op');
 380 @operators = map { uri_unescape($_) } @operators;
 381
 382 # indexes are query qualifiers, like 'title', 'author', etc. They
 383 # can be single or multiple parameters separated by comma: kw,right-Truncation
 384 my @indexes = $cgi->param('idx');
 385 @indexes = map { uri_unescape($_) } @indexes;
 386
 387 # if a simple index (only one)  display the index used in the top search box
 388 if ($indexes[0] && !$indexes[1]) {
 389     $template->param("ms_".$indexes[0] => 1);
 390 }
 391 # an operand can be a single term, a phrase, or a complete ccl query
 392 my @operands = $cgi->param('q');
 393 @operands = map { uri_unescape($_) } @operands;
 394
 395 $template->{VARS}->{querystring} = join(' ', @operands);
 396
 397 # if a simple search, display the value in the search box
 398 if ($operands[0] && !$operands[1]) {
 399     my $ms_query = $operands[0];
 400     $ms_query =~ s/ #\S+//;
 401     $template->param(ms_value => $ms_query);
 402 }
 403
 404 # limits are use to limit to results to a pre-defined category such as branch or language
 405 my @limits = $cgi->param('limit');
 406 @limits = map { uri_unescape($_) } @limits;
 407
 408 if($params->{'multibranchlimit'}) {
 409     my $multibranch = '('.join( " or ", map { "branch: $_ " } @{ GetBranchesInCategory( $params->{'multibranchlimit'} ) } ).')';
 410     push @limits, $multibranch if ($multibranch ne  '()');
 411 }
 412
 413 my $available;
 414 foreach my $limit(@limits) {
 415     if ($limit =~/available/) {
 416         $available = 1;
 417     }
 418 }
 419 $template->param(available => $available);
 420
 421 # append year limits if they exist
 422 if ($params->{'limit-yr'}) {
 423     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 424         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 425         push @limits, "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 426     }
 427     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 428         push @limits, "yr,st-numeric=$params->{'limit-yr'}";
 429     }
 430     else {
 431         #FIXME: Should return a error to the user, incorect date format specified
 432     }
 433 }
 434
 435 # Params that can only have one value
 436 my $scan = $params->{'scan'};
 437 my $count = C4::Context->preference('OPACnumSearchResults') || 20;
 438 my $countRSS         = C4::Context->preference('numSearchRSSResults') || 50;
 439 my $results_per_page = $params->{'count'} || $count;
 440 my $offset = $params->{'offset'} || 0;
 441 my $page = $cgi->param('page') || 1;
 442 $offset = ($page-1)*$results_per_page if $page>1;
 443 my $hits;
 444 my $expanded_facet = $params->{'expand'};
 445
 446 # Define some global variables
 447 my ($error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 448
 449 my @results;
 450
 451 ## I. BUILD THE QUERY
 452 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by, 0, $lang);
 453
 454 sub _input_cgi_parse {
 455     my @elements;
 456     for my $this_cgi ( split('&',shift) ) {
 457         next unless $this_cgi;
 458         $this_cgi =~ /(.*?)=(.*)/;
 459         push @elements, { input_name => $1, input_value => $2 };
 460     }
 461     return @elements;
 462 }
 463
 464 ## parse the query_cgi string and put it into a form suitable for <input>s
 465 my @query_inputs = _input_cgi_parse($query_cgi);
 466 $template->param ( QUERY_INPUTS => \@query_inputs );
 467
 468 ## parse the limit_cgi string and put it into a form suitable for <input>s
 469 my @limit_inputs = $limit_cgi ? _input_cgi_parse($limit_cgi) : ();
 470
 471 # add OPAC 'hidelostitems'
 472 #if (C4::Context->preference('hidelostitems') == 1) {
 473 #    # either lost ge 0 or no value in the lost register
 474 #    $query ="($query) and ( (lost,st-numeric <= 0) or ( allrecords,AlwaysMatches='' not lost,AlwaysMatches='') )";
 475 #}
 476 #
 477 # add OPAC suppression - requires at least one item indexed with Suppress
 478 if (C4::Context->preference('OpacSuppression')) {
 479     # OPAC suppression by IP address
 480     if (C4::Context->preference('OpacSuppressionByIPRange')) {
 481         my $IPAddress = $ENV{'REMOTE_ADDR'};
 482         my $IPRange = C4::Context->preference('OpacSuppressionByIPRange');
 483         if ($IPAddress !~ /^$IPRange/)  {
 484             $query = "($query) not Suppress=1";
 485         }
 486     }
 487     else {
 488         $query = "($query) not Suppress=1";
 489     }
 490 }
 491
 492 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 493 $template->param ( OPACResultsSidebar => C4::Context->preference('OPACResultsSidebar'));
 494
 495 ## II. DO THE SEARCH AND GET THE RESULTS
 496 my $total = 0; # the total results for the whole set
 497 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 498 my @results_array;
 499 my $results_hashref;
 500 my @coins;
 501
 502 if ($tag) {
 503     $query_cgi = "tag=" .$tag . "&" . $query_cgi;
 504     my $taglist = get_tags({term=>$tag, approved=>1});
 505     $results_hashref->{biblioserver}->{hits} = scalar (@$taglist);
 506     my @biblist  = (map {GetBiblioData($_->{biblionumber})} @$taglist);
 507     my @marclist = (map {$_->{marc}} @biblist );
 508     $DEBUG and printf STDERR "taglist (%s biblionumber)\nmarclist (%s records)\n", scalar(@$taglist), scalar(@marclist);
 509     $results_hashref->{biblioserver}->{RECORDS} = \@marclist;
 510     # FIXME: tag search and standard search should work together, not exclusively
 511     # FIXME: No facets for tags search.
 512 } elsif ($build_grouped_results) {
 513     eval {
 514         ($error, $results_hashref, $facets) = C4::Search::pazGetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 515     };
 516 } else {
 517     $pasarParams .= '&amp;query=' . $query;
 518     $pasarParams .= '&amp;count=' . $results_per_page;
 519     $pasarParams .= '&amp;simple_query=' . $simple_query;
 520     $pasarParams .= '&amp;query_type=' . $query_type if ($query_type);
 521     eval {
 522         ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$itemtypes,$query_type,$scan,1);
 523     };
 524 }
 525 # This sorts the facets into alphabetical order
 526 if ($facets) {
 527     foreach my $f (@$facets) {
 528         $f->{facets} = [ sort { uc($a->{facet_title_value}) cmp uc($b->{facet_title_value}) } @{ $f->{facets} } ];
 529     }
 530     @$facets = sort {$a->{expand} cmp $b->{expand}} @$facets;
 531 }
 532
 533 # use Data::Dumper; print STDERR "-" x 25, "\n", Dumper($results_hashref);
 534 if ($@ || $error) {
 535     $template->param(query_error => $error.$@);
 536     output_html_with_http_headers $cgi, $cookie, $template->output;
 537     exit;
 538 }
 539
 540 # At this point, each server has given us a result set
 541 # now we build that set for template display
 542 my @sup_results_array;
 543 for (my $i=0;$i<@servers;$i++) {
 544     my $server = $servers[$i];
 545     if ($server && $server =~/biblioserver/) { # this is the local bibliographic server
 546         $hits = $results_hashref->{$server}->{"hits"};
 547         my $page = $cgi->param('page') || 0;
 548         my @newresults;
 549         if ($build_grouped_results) {
 550             foreach my $group (@{ $results_hashref->{$server}->{"GROUPS"} }) {
 551                 # because pazGetRecords handles retieving only the records
 552                 # we want as specified by $offset and $results_per_page,
 553                 # we need to set the offset parameter of searchResults to 0
 554                 my @group_results = searchResults( 'opac', $query_desc, $group->{'group_count'},$results_per_page, 0, $scan,
 555                                                    $group->{"RECORDS"});
 556                 push @newresults, { group_label => $group->{'group_label'}, GROUP_RESULTS => \@group_results };
 557             }
 558         } else {
 559             @newresults = searchResults('opac', $query_desc, $hits, $results_per_page, $offset, $scan,
 560                                         $results_hashref->{$server}->{"RECORDS"});
 561         }
 562
 563         foreach my $res (@newresults) {
 564
 565             # must define a value for size if not present in DB
 566             # in order to avoid problems generated by the default size value in TT
 567             if ( not exists $res->{'size'} ) { $res->{'size'} = "" }
 568             # while we're checking each line, see if item is in the cart
 569             if ( grep {$_ eq $res->{'biblionumber'}} @cart_list) {
 570                 $res->{'incart'} = 1;
 571             }
 572
 573             if (C4::Context->preference('COinSinOPACResults')) {
 574                 my $record = GetMarcBiblio($res->{'biblionumber'});
 575                 $res->{coins} = GetCOinSBiblio($record);
 576             }
 577             if ( C4::Context->preference( "Babeltheque" ) and $res->{normalized_isbn} ) {
 578                 if( my $isbn = Business::ISBN->new( $res->{normalized_isbn} ) ) {
 579                     $isbn = $isbn->as_isbn13->as_string;
 580                     $isbn =~ s/-//g;
 581                     my $social_datas = C4::SocialData::get_data( $isbn );
 582                     if ( $social_datas ) {
 583                         for my $key ( keys %$social_datas ) {
 584                             $res->{$key} = $$social_datas{$key};
 585                             if ( $key eq 'score_avg' ){
 586                                 $res->{score_int} = sprintf("%.0f", $$social_datas{score_avg} );
 587                             }
 588                         }
 589                     }
 590                 }
 591             }
 592
 593             if (C4::Context->preference('TagsEnabled') and
 594                 C4::Context->preference('TagsShowOnList')) {
 595                 if ( my $bibnum = $res->{biblionumber} ) {
 596                     $res->{itemsissued} = CountItemsIssued( $bibnum );
 597                     $res->{'TagLoop'} = get_tags({
 598                         biblionumber => $bibnum,
 599                         approved => 1,
 600                         sort => '-weight',
 601                         limit => C4::Context->preference('TagsShowOnList')
 602                     });
 603                 }
 604             }
 605
 606             if ( C4::Context->preference('OpacStarRatings') eq 'all' ) {
 607                 my $rating = GetRating( $res->{'biblionumber'}, $borrowernumber );
 608                 $res->{'rating_value'}  = $rating->{'rating_value'};
 609                 $res->{'rating_total'}  = $rating->{'rating_total'};
 610                 $res->{'rating_avg'}    = $rating->{'rating_avg'};
 611                 $res->{'rating_avg_int'} = $rating->{'rating_avg_int'};
 612             }
 613         }
 614
 615         if ($results_hashref->{$server}->{"hits"}){
 616             $total = $total + $results_hashref->{$server}->{"hits"};
 617         }
 618
 619         # Opac search history
 620         my $newsearchcookie;
 621         if (C4::Context->preference('EnableOpacSearchHistory')) {
 622             my @recentSearches;
 623
 624             # Getting the (maybe) already sent cookie
 625             my $searchcookie = $cgi->cookie('KohaOpacRecentSearches');
 626             if ($searchcookie){
 627                 $searchcookie = uri_unescape($searchcookie);
 628                 if (thaw($searchcookie)) {
 629                     @recentSearches = @{thaw($searchcookie)};
 630                 }
 631             }
 632
 633             # Adding the new search if needed
 634             my $path_info = $cgi->url(-path_info=>1);
 635             my $query_cgi_history = $cgi->url(-query=>1);
 636             $query_cgi_history =~ s/^$path_info\?//;
 637             $query_cgi_history =~ s/;/&/g;
 638             my $query_desc_history = "$query_desc, $limit_desc";
 639
 640             if (!$borrowernumber || $borrowernumber eq '') {
 641                 # To a cookie (the user is not logged in)
 642                 if (!$offset) {
 643                     push @recentSearches, {
 644                                 "query_desc" => $query_desc_history || "unknown",
 645                                 "query_cgi"  => $query_cgi_history  || "unknown",
 646                                 "time"       => time(),
 647                                 "total"      => $total
 648                               };
 649                     $template->param(ShowOpacRecentSearchLink => 1);
 650                 }
 651
 652                 shift @recentSearches if (@recentSearches > 15);
 653                 # Pushing the cookie back
 654                 $newsearchcookie = $cgi->cookie(
 655                             -name => 'KohaOpacRecentSearches',
 656                             # We uri_escape the whole freezed structure so we're sure we won't have any encoding problems
 657                             -value =>freeze(\@recentSearches),
 658                             -expires => ''
 659                 );
 660                 $cookie = [$cookie, $newsearchcookie];
 661             }
 662             else {
 663                 # To the session (the user is logged in)
 664                 if (!$offset) {
 665                     AddSearchHistory($borrowernumber, $cgi->cookie("CGISESSID"), $query_desc_history, $query_cgi_history, $total);
 666                     $template->param(ShowOpacRecentSearchLink => 1);
 667                 }
 668             }
 669         }
 670         ## If there's just one result, redirect to the detail page
 671         if ($total == 1 && $format ne 'rss2'
 672         && $format ne 'opensearchdescription' && $format ne 'atom') {
 673             my $biblionumber=$newresults[0]->{biblionumber};
 674             if (C4::Context->preference('BiblioDefaultView') eq 'isbd') {
 675                 print $cgi->redirect("/cgi-bin/koha/opac-ISBDdetail.pl?biblionumber=$biblionumber");
 676             } elsif  (C4::Context->preference('BiblioDefaultView') eq 'marc') {
 677                 print $cgi->redirect("/cgi-bin/koha/opac-MARCdetail.pl?biblionumber=$biblionumber");
 678             } else {
 679                 print $cgi->redirect("/cgi-bin/koha/opac-detail.pl?biblionumber=$biblionumber");
 680             }
 681             exit;
 682         }
 683         if ($hits) {
 684             if ( !$build_grouped_results ) {
 685                 # We build the encrypted list of first OPACnumSearchResults biblios to pass with the search criteria for paging on opac-detail
 686                 $pasarParams .= '&amp;listBiblios=';
 687                 my $j = 0;
 688                 foreach (@newresults) {
 689                     my $bibnum = ($_->{biblionumber})?$_->{biblionumber}:0;
 690                     $pasarParams .= $bibnum . ',';
 691                     $j++;
 692                     last if ($j == $results_per_page);
 693                 }
 694                 chop $pasarParams if ($pasarParams =~ /,$/);
 695                 $pasarParams .= '&amp;total=' . int($total) if ($pasarParams !~ /total=(?:[0-9]+)?/);
 696                 if ($pasarParams) {
 697                     my $session = get_session($cgi->cookie("CGISESSID"));
 698                     $session->param('busc' => $pasarParams);
 699                 }
 700                 #
 701             }
 702             $template->param(total => $hits);
 703             my $limit_cgi_not_availablity = $limit_cgi;
 704             $limit_cgi_not_availablity =~ s/&limit=available//g if defined $limit_cgi_not_availablity;
 705             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 706             $template->param(limit_cgi => $limit_cgi);
 707             $template->param(countrss  => $countRSS );
 708             $template->param(query_cgi => $query_cgi);
 709             $template->param(query_desc => $query_desc);
 710             $template->param(limit_desc => $limit_desc);
 711             $template->param(offset     => $offset);
 712             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 713             if ($query_desc || $limit_desc) {
 714                 $template->param(searchdesc => 1);
 715             }
 716             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 717             $template->param(results_per_page =>  $results_per_page);
 718             my $hide = C4::Context->preference('OpacHiddenItems');
 719             $hide = ($hide =~ m/\S/) if $hide; # Just in case it has some spaces/new lines
 720             my $branch = '';
 721             if (C4::Context->userenv){
 722                 $branch = C4::Context->userenv->{branch};
 723             }
 724             if ( C4::Context->preference('HighlightOwnItemsOnOPAC') ) {
 725                 if (
 726                     ( ( C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'PatronBranch' ) && $branch )
 727                     ||
 728                     C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'OpacURLBranch'
 729                 ) {
 730                     my $branchname;
 731                     if ( C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'PatronBranch' ) {
 732                         $branchname = $branches->{$branch}->{'branchname'};
 733                     }
 734                     elsif (  C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'OpacURLBranch' ) {
 735                         $branchname = $branches->{ $ENV{'BRANCHCODE'} }->{'branchname'};
 736                     }
 737
 738                     foreach my $res ( @newresults ) {
 739                         my @new_loop;
 740                         my @top_loop;
 741                         my @old_loop = @{$res->{'available_items_loop'}};
 742                         foreach my $item ( @old_loop ) {
 743                             if ( $item->{'branchname'} eq $branchname ) {
 744                                 $item->{'this_branch'} = 1;
 745                                 push( @top_loop, $item );
 746                             } else {
 747                                 push( @new_loop, $item );
 748                             }
 749                         }
 750                         my @complete_loop = ( @top_loop, @new_loop );
 751                         $res->{'available_items_loop'} = \@complete_loop;
 752                     }
 753                 }
 754             }
 755
 756             $template->param(
 757                 SEARCH_RESULTS => \@newresults,
 758                 OPACItemsResultsDisplay => (C4::Context->preference("OPACItemsResultsDisplay")),
 759                 suppress_result_number => $hide,
 760                             );
 761             if (C4::Context->preference("OPACLocalCoverImages")){
 762                 $template->param(OPACLocalCoverImages => 1);
 763                 $template->param(OPACLocalCoverImagesPriority => C4::Context->preference("OPACLocalCoverImagesPriority"));
 764             }
 765             ## Build the page numbers on the bottom of the page
 766             my @page_numbers;
 767             # total number of pages there will be
 768             my $pages = ceil($hits / $results_per_page);
 769             # default page number
 770             my $current_page_number = 1;
 771             if ($offset) {
 772                 $current_page_number = ( $offset / $results_per_page + 1 );
 773             }
 774             my $previous_page_offset;
 775             if ( $offset >= $results_per_page ) {
 776                 $previous_page_offset = $offset - $results_per_page;
 777             }
 778             my $next_page_offset = $offset + $results_per_page;
 779             # If we're within the first 10 pages, keep it simple
 780             #warn "current page:".$current_page_number;
 781             if ($current_page_number < 10) {
 782                 # just show the first 10 pages
 783                 # Loop through the pages
 784                 my $pages_to_show = 10;
 785                 $pages_to_show = $pages if $pages<10;
 786                 for ($i=1; $i<=$pages_to_show;$i++) {
 787                     # the offset for this page
 788                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 789                     # the page number for this page
 790                     my $this_page_number = $i;
 791                     # put it in the array
 792                     push @page_numbers,
 793                       { offset    => $this_offset,
 794                         pg        => $this_page_number,
 795                         highlight => $this_page_number == $current_page_number,
 796                         sort_by   => join ' ', @sort_by
 797                       };
 798
 799                 }
 800
 801             }
 802             # now, show twenty pages, with the current one smack in the middle
 803             else {
 804                 for ($i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 805                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 806                     my $this_page_number = $i-9;
 807                     if ( $this_page_number <= $pages ) {
 808                         push @page_numbers,
 809                           { offset    => $this_offset,
 810                             pg        => $this_page_number,
 811                             highlight => $this_page_number == $current_page_number,
 812                             sort_by => join ' ', @sort_by
 813                           };
 814                     }
 815                 }
 816
 817             }
 818             $template->param(   PAGE_NUMBERS => \@page_numbers,
 819                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 820             $template->param(next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 821         }
 822         # no hits
 823         else {
 824             my $nohits = C4::Context->preference('OPACNoResultsFound');
 825             if ($nohits and $nohits=~/{QUERY_KW}/){
 826                 # extracting keywords in case of relaunching search
 827                 (my $query_kw=$query_desc)=~s/ and|or / /g;
 828                 $query_kw = Encode::decode_utf8($query_kw);
 829                 my @query_kw=($query_kw=~ /([-\w]+\b)(?:[^,:]|$)/g);
 830                 $query_kw=join('+',@query_kw);
 831                 $nohits=~s/{QUERY_KW}/$query_kw/g;
 832                 $template->param('OPACNoResultsFound' =>$nohits);
 833             }
 834             $template->param(
 835                 searchdesc => 1,
 836                 query_desc => $query_desc,
 837                 limit_desc => $limit_desc,
 838                 query_cgi  => $query_cgi,
 839                 limit_cgi  => $limit_cgi
 840             );
 841         }
 842     } # end of the if local
 843     # asynchronously search the authority server
 844     elsif ($server && $server =~/authorityserver/) { # this is the local authority server
 845         my @inner_sup_results_array;
 846         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 847             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 848             my $title_field = $marc_record_object->field(100);
 849             push @inner_sup_results_array, {
 850                 'title' => $title_field->subfield('a'),
 851                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 852             };
 853         }
 854         my $servername = $server;
 855         push @sup_results_array, {  servername => $servername,
 856                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 857     }
 858     # FIXME: can add support for other targets as needed here
 859     $template->param(           outer_sup_results_loop => \@sup_results_array);
 860 } #/end of the for loop
 861 #$template->param(FEDERATED_RESULTS => \@results_array);
 862
 863 $template->param(
 864             #classlist => $classlist,
 865             total => $total,
 866             opacfacets => 1,
 867             facets_loop => $facets,
 868             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 869             scan => $scan,
 870             search_error => $error,
 871 );
 872
 873 if ($query_desc || $limit_desc) {
 874     $template->param(searchdesc => 1);
 875 }
 876
 877 # VI. BUILD THE TEMPLATE
 878 # Build drop-down list for 'Add To:' menu...
 879 my ($totalref, $pubshelves, $barshelves)=
 880         C4::VirtualShelves::GetSomeShelfNames($borrowernumber,'COMBO',1);
 881 $template->param(
 882         addbarshelves     => $totalref->{bartotal},
 883         addbarshelvesloop => $barshelves,
 884         addpubshelves     => $totalref->{pubtotal},
 885         addpubshelvesloop => $pubshelves,
 886         );
 887
 888 my $content_type = ($format eq 'rss' or $format eq 'atom') ? $format : 'html';
 889
 890 # If GoogleIndicTransliteration system preference is On Set paramter to load Google's javascript in OPAC search screens
 891 if (C4::Context->preference('GoogleIndicTransliteration')) {
 892         $template->param('GoogleIndicTransliteration' => 1);
 893 }
 894
 895 $template->{VARS}->{DidYouMean} =
 896   ( defined C4::Context->preference('OPACdidyoumean')
 897       && C4::Context->preference('OPACdidyoumean') =~ m/enable/ );
 898 $template->{VARS}->{IDreamBooksReviews} = C4::Context->preference('IDreamBooksReviews');
 899 $template->{VARS}->{IDreamBooksReadometer} = C4::Context->preference('IDreamBooksReadometer');
 900 $template->{VARS}->{IDreamBooksResults} = C4::Context->preference('IDreamBooksResults');
 901
 902     $template->param( borrowernumber    => $borrowernumber);
 903 output_with_http_headers $cgi, $cookie, $template->output, $content_type;