opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth;
  26 use C4::Koha;
  27 use C4::Circulation;
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Members::AttributeTypes;
  31 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  32 use C4::Output;
  33 use C4::Biblio;
  34 use C4::Items;
  35 use C4::Letters;
  36 use C4::Branch; # GetBranches
  37 use Koha::DateUtils;
  38 use Koha::Borrower::Debarments qw(IsDebarred);
  39
  40 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  41
  42 use Date::Calc qw(
  43   Today
  44   Add_Delta_Days
  45   Date_to_Days
  46 );
  47
  48 my $query = new CGI;
  49
  50 BEGIN {
  51     if (C4::Context->preference('BakerTaylorEnabled')) {
  52         require C4::External::BakerTaylor;
  53         import C4::External::BakerTaylor qw(&image_url &link_url);
  54     }
  55 }
  56
  57 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  58     {
  59         template_name   => "opac-user.tt",
  60         query           => $query,
  61         type            => "opac",
  62         authnotrequired => 0,
  63         debug           => 1,
  64     }
  65 );
  66
  67 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') );
  68
  69 my $show_priority;
  70 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  71     m/priority/ and $show_priority = 1;
  72 }
  73
  74 my $patronupdate = $query->param('patronupdate');
  75 my $canrenew = 1;
  76
  77 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  78
  79 # get borrower information ....
  80 my ( $borr ) = GetMemberDetails( $borrowernumber );
  81
  82 my (  $today_year,   $today_month,   $today_day) = Today();
  83 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
  84
  85 my $debar = IsDebarred($borrowernumber);
  86 my $userdebarred;
  87
  88 if ($debar) {
  89     $userdebarred = 1;
  90     $template->param( 'userdebarred' => $userdebarred );
  91     if ( $debar ne "9999-12-31" ) {
  92         $borr->{'userdebarreddate'} = $debar;
  93     }
  94 }
  95
  96 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
  97     $borr->{'flagged'} = 1;
  98     $canrenew = 0;
  99 }
 100
 101 if ( $borr->{'amountoutstanding'} > 5 ) {
 102     $borr->{'amountoverfive'} = 1;
 103 }
 104 if ( 5 >= $borr->{'amountoutstanding'} && $borr->{'amountoutstanding'} > 0 ) {
 105     $borr->{'amountoverzero'} = 1;
 106 }
 107 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 108 $no_renewal_amt ||= 0;
 109
 110 if (  C4::Context->preference( 'OpacRenewalAllowed' ) && $borr->{amountoutstanding} > $no_renewal_amt ) {
 111     $borr->{'flagged'} = 1;
 112     $canrenew = 0;
 113     $template->param(
 114         renewal_blocked_fines => sprintf( '%.02f', $no_renewal_amt ),
 115         renewal_blocked_fines_amountoutstanding => sprintf( '%.02f', $borr->{amountoutstanding} ),
 116     );
 117 }
 118
 119 if ( $borr->{'amountoutstanding'} < 0 ) {
 120     $borr->{'amountlessthanzero'} = 1;
 121     $borr->{'amountoutstanding'} = -1 * ( $borr->{'amountoutstanding'} );
 122 }
 123
 124 $borr->{'amountoutstanding'} = sprintf "%.02f", $borr->{'amountoutstanding'};
 125
 126 my @bordat;
 127 $bordat[0] = $borr;
 128
 129 # Warningdate is the date that the warning starts appearing
 130 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 131     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 132     if ( $days_to_expiry < 0 ) {
 133         #borrower card has expired, warn the borrower
 134         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 135     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 136         # borrower card soon to expire, warn the borrower
 137         $borr->{'warndeparture'} = $borr->{dateexpiry};
 138         if (C4::Context->preference('ReturnBeforeExpiry')){
 139             $borr->{'returnbeforeexpiry'} = 1;
 140         }
 141     }
 142 }
 143
 144 # pass on any renew errors to the template for displaying
 145 my $renew_error = $query->param('renew_error');
 146
 147 $template->param(   BORROWER_INFO     => \@bordat,
 148                     borrowernumber    => $borrowernumber,
 149                     patron_flagged    => $borr->{flagged},
 150                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 151                     surname           => $borr->{surname},
 152                     showname          => $borr->{showname},
 153                     RENEW_ERROR       => $renew_error,
 154                     borrower          => $borr,
 155                 );
 156
 157 #get issued items ....
 158
 159 my $count          = 0;
 160 my $overdues_count = 0;
 161 my @overdues;
 162 my @issuedat;
 163 my $itemtypes = GetItemTypes();
 164 my $issues = GetPendingIssues($borrowernumber);
 165 if ($issues){
 166     foreach my $issue ( sort { $b->{date_due}->datetime() cmp $a->{date_due}->datetime() } @{$issues} ) {
 167         # check for reserves
 168         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 169         if ( $restype ) {
 170             $issue->{'reserved'} = 1;
 171         }
 172
 173         my ( $total , $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 174         my $charges = 0;
 175         foreach my $ac (@$accts) {
 176             if ( $ac->{'itemnumber'} == $issue->{'itemnumber'} ) {
 177                 $charges += $ac->{'amountoutstanding'}
 178                   if $ac->{'accounttype'} eq 'F';
 179                 $charges += $ac->{'amountoutstanding'}
 180                   if $ac->{'accounttype'} eq 'FU';
 181                 $charges += $ac->{'amountoutstanding'}
 182                   if $ac->{'accounttype'} eq 'L';
 183             }
 184         }
 185         $issue->{'charges'} = $charges;
 186         my $marcrecord = GetMarcBiblio( $issue->{'biblionumber'} );
 187         $issue->{'subtitle'} = GetRecordValue('subtitle', $marcrecord, GetFrameworkCode($issue->{'biblionumber'}));
 188         # check if item is renewable
 189         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 190         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 191         if($status && C4::Context->preference("OpacRenewalAllowed")){
 192             $issue->{'status'} = $status;
 193         }
 194
 195         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 196
 197         if ($renewerror) {
 198             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 199             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 200             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 201             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 202
 203             if ( $renewerror eq 'too_soon' ) {
 204                 $issue->{'too_soon'}         = 1;
 205                 $issue->{'soonestrenewdate'} = output_pref(
 206                     C4::Circulation::GetSoonestRenewDate(
 207                         $issue->{borrowernumber},
 208                         $issue->{itemnumber}
 209                     )
 210                 );
 211             }
 212         }
 213
 214         if ( $issue->{'overdue'} ) {
 215             push @overdues, $issue;
 216             $overdues_count++;
 217             $issue->{'overdue'} = 1;
 218         }
 219         else {
 220             $issue->{'issued'} = 1;
 221         }
 222         # imageurl:
 223         my $itemtype = $issue->{'itemtype'};
 224         if ( $itemtype ) {
 225             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 226             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 227         }
 228         push @issuedat, $issue;
 229         $count++;
 230
 231         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 232         $issue->{normalized_isbn} = $isbn;
 233         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 234
 235                 # My Summary HTML
 236                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 237                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 238                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 239                     $issue->{title} =~ s/\s+$//; # remove trailing space
 240                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 241                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 242                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 243                     $issue->{MySummaryHTML} = $my_summary_html;
 244                 }
 245     }
 246 }
 247 $template->param( ISSUES       => \@issuedat );
 248 $template->param( issues_count => $count );
 249 $template->param( canrenew     => $canrenew );
 250 $template->param( OVERDUES       => \@overdues );
 251 $template->param( overdues_count => $overdues_count );
 252
 253 my $show_barcode = C4::Members::AttributeTypes::AttributeTypeExists( ATTRIBUTE_SHOW_BARCODE );
 254 if ($show_barcode) {
 255     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 256     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 257 }
 258 $template->param( show_barcode => 1 ) if $show_barcode;
 259
 260 # load the branches
 261 my $branches = GetBranches();
 262 my @branch_loop;
 263 for my $branch_hash ( sort keys %{$branches} ) {
 264     my $selected;
 265     if ( C4::Context->preference('SearchMyLibraryFirst') ) {
 266         $selected =
 267           ( C4::Context->userenv
 268               && ( $branch_hash eq C4::Context->userenv->{branch} ) );
 269     }
 270     push @branch_loop,
 271       { value      => "branch: $branch_hash",
 272         branchname => $branches->{$branch_hash}->{'branchname'},
 273         selected   => $selected,
 274       };
 275 }
 276 $template->param( branchloop => \@branch_loop );
 277
 278 # now the reserved items....
 279 my @reserves  = GetReservesFromBorrowernumber( $borrowernumber );
 280 foreach my $res (@reserves) {
 281
 282     if ( $res->{'expirationdate'} eq '0000-00-00' ) {
 283       $res->{'expirationdate'} = '';
 284     }
 285     $res->{'subtitle'} = GetRecordValue('subtitle', GetMarcBiblio($res->{'biblionumber'}), GetFrameworkCode($res->{'biblionumber'}));
 286     $res->{'waiting'} = 1 if $res->{'found'} eq 'W';
 287     $res->{'branch'} = $branches->{ $res->{'branchcode'} }->{'branchname'};
 288     my $biblioData = GetBiblioData($res->{'biblionumber'});
 289     $res->{'reserves_title'} = $biblioData->{'title'};
 290     $res->{'author'} = $biblioData->{'author'};
 291
 292     if ($show_priority) {
 293         $res->{'priority'} ||= '';
 294     }
 295     if ( $res->{'suspend_until'} ) {
 296         $res->{'suspend_until'} = output_pref({ dt => dt_from_string( $res->{'suspend_until'} , 'iso' ), dateonly => 1 });
 297     }
 298 }
 299
 300 # use Data::Dumper;
 301 # warn Dumper(@reserves);
 302
 303 $template->param( RESERVES       => \@reserves );
 304 $template->param( reserves_count => $#reserves+1 );
 305 $template->param( showpriority=>$show_priority );
 306
 307 my @waiting;
 308 my $wcount = 0;
 309 foreach my $res (@reserves) {
 310     if ( $res->{'itemnumber'} ) {
 311         my $item = GetItem( $res->{'itemnumber'});
 312         $res->{'holdingbranch'} =
 313           $branches->{ $item->{'holdingbranch'} }->{'branchname'};
 314         $res->{'branch'} = $branches->{ $res->{'branchcode'} }->{'branchname'};
 315         $res->{'enumchron'} = $item->{'enumchron'} if $item->{'enumchron'};
 316         # get document reserve status
 317         my $biblioData = GetBiblioData($res->{'biblionumber'});
 318         $res->{'waiting_title'} = $biblioData->{'title'};
 319         if ( ( $res->{'found'} eq 'W' ) ) {
 320             my $item = $res->{'itemnumber'};
 321             $item = GetBiblioFromItemNumber($item,undef);
 322             $res->{'wait'}= 1;
 323             $res->{'holdingbranch'}=$item->{'holdingbranch'};
 324             $res->{'biblionumber'}=$item->{'biblionumber'};
 325             $res->{'barcode'} = $item->{'barcode'};
 326             $res->{'wbrcode'} = $res->{'branchcode'};
 327             $res->{'itemnumber'}    = $res->{'itemnumber'};
 328             $res->{'wbrname'} = $branches->{$res->{'branchcode'}}->{'branchname'};
 329             if($res->{'holdingbranch'} eq $res->{'wbrcode'}){
 330                 $res->{'atdestination'} = 1;
 331             }
 332             # set found to 1 if reserve is waiting for patron pickup
 333             $res->{'found'} = 1 if $res->{'found'} eq 'W';
 334         } else {
 335             my ($transfertwhen, $transfertfrom, $transfertto) = GetTransfers( $res->{'itemnumber'} );
 336             if ($transfertwhen) {
 337                 $res->{intransit} = 1;
 338                 $res->{datesent}   = $transfertwhen;
 339                 $res->{frombranch} = GetBranchName($transfertfrom);
 340             }
 341         }
 342         push @waiting, $res;
 343         $wcount++;
 344     }
 345     # can be cancelled
 346     #$res->{'cancelable'} = 1 if ($res->{'wait'} && $res->{'atdestination'} && $res->{'found'} ne "1");
 347     $res->{'cancelable'} = 1 if    ($res->{wait} and not $res->{found}) or (not $res->{wait} and not $res->{intransit});
 348
 349 }
 350
 351 $template->param( WAITING => \@waiting );
 352
 353 # current alert subscriptions
 354 my $alerts = getalert($borrowernumber);
 355 foreach ( @$alerts ) {
 356     $_->{ $_->{type} } = 1;
 357     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 358 }
 359
 360 if (C4::Context->preference('BakerTaylorEnabled')) {
 361     $template->param(
 362         BakerTaylorEnabled  => 1,
 363         BakerTaylorImageURL => &image_url(),
 364         BakerTaylorLinkURL  => &link_url(),
 365         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 366     );
 367 }
 368
 369 if (C4::Context->preference("OPACAmazonCoverImages") or
 370     C4::Context->preference("GoogleJackets") or
 371     C4::Context->preference("BakerTaylorEnabled") or
 372     C4::Context->preference("SyndeticsCoverImages")) {
 373         $template->param(JacketImages=>1);
 374 }
 375
 376 if ( GetMessagesCount( $borrowernumber, 'B' ) ) {
 377     $template->param( bor_messages => 1 );
 378 }
 379
 380 if ( $borr->{'opacnote'} ) {
 381   $template->param(
 382     bor_messages => 1,
 383     opacnote => $borr->{'opacnote'},
 384   );
 385 }
 386
 387 $template->param(
 388     bor_messages_loop        => GetMessages( $borrowernumber, 'B', 'NONE' ),
 389     waiting_count            => $wcount,
 390     patronupdate             => $patronupdate,
 391     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 392     userview                 => 1,
 393     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 394     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 395     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 396     failed_holds             => $query->param('failed_holds'),
 397 );
 398
 399 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };