t/db_dependent/Circulation.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use DateTime;
  21 use C4::Biblio;
  22 use C4::Branch;
  23 use C4::Items;
  24 use C4::Members;
  25 use C4::Reserves;
  26 use Koha::DateUtils;
  27 use Koha::Database;
  28
  29 use Test::More tests => 59;
  30
  31 BEGIN {
  32     use_ok('C4::Circulation');
  33 }
  34
  35 my $dbh = C4::Context->dbh;
  36 my $schema = Koha::Database->new()->schema();
  37
  38 # Start transaction
  39 $dbh->{AutoCommit} = 0;
  40 $dbh->{RaiseError} = 1;
  41
  42 # Start with a clean slate
  43 $dbh->do('DELETE FROM issues');
  44
  45 my $CircControl = C4::Context->preference('CircControl');
  46 my $HomeOrHoldingBranch = C4::Context->preference('HomeOrHoldingBranch');
  47
  48 my $item = {
  49     homebranch => 'MPL',
  50     holdingbranch => 'MPL'
  51 };
  52
  53 my $borrower = {
  54     branchcode => 'MPL'
  55 };
  56
  57 # No userenv, PickupLibrary
  58 C4::Context->set_preference('CircControl', 'PickupLibrary');
  59 is(
  60     C4::Context->preference('CircControl'),
  61     'PickupLibrary',
  62     'CircControl changed to PickupLibrary'
  63 );
  64 is(
  65     C4::Circulation::_GetCircControlBranch($item, $borrower),
  66     $item->{$HomeOrHoldingBranch},
  67     '_GetCircControlBranch returned item branch (no userenv defined)'
  68 );
  69
  70 # No userenv, PatronLibrary
  71 C4::Context->set_preference('CircControl', 'PatronLibrary');
  72 is(
  73     C4::Context->preference('CircControl'),
  74     'PatronLibrary',
  75     'CircControl changed to PatronLibrary'
  76 );
  77 is(
  78     C4::Circulation::_GetCircControlBranch($item, $borrower),
  79     $borrower->{branchcode},
  80     '_GetCircControlBranch returned borrower branch'
  81 );
  82
  83 # No userenv, ItemHomeLibrary
  84 C4::Context->set_preference('CircControl', 'ItemHomeLibrary');
  85 is(
  86     C4::Context->preference('CircControl'),
  87     'ItemHomeLibrary',
  88     'CircControl changed to ItemHomeLibrary'
  89 );
  90 is(
  91     $item->{$HomeOrHoldingBranch},
  92     C4::Circulation::_GetCircControlBranch($item, $borrower),
  93     '_GetCircControlBranch returned item branch'
  94 );
  95
  96 # Now, set a userenv
  97 C4::Context->_new_userenv('xxx');
  98 C4::Context::set_userenv(0,0,0,'firstname','surname', 'MPL', 'Midway Public Library', '', '', '');
  99 is(C4::Context->userenv->{branch}, 'MPL', 'userenv set');
 100
 101 # Userenv set, PickupLibrary
 102 C4::Context->set_preference('CircControl', 'PickupLibrary');
 103 is(
 104     C4::Context->preference('CircControl'),
 105     'PickupLibrary',
 106     'CircControl changed to PickupLibrary'
 107 );
 108 is(
 109     C4::Circulation::_GetCircControlBranch($item, $borrower),
 110     'MPL',
 111     '_GetCircControlBranch returned current branch'
 112 );
 113
 114 # Userenv set, PatronLibrary
 115 C4::Context->set_preference('CircControl', 'PatronLibrary');
 116 is(
 117     C4::Context->preference('CircControl'),
 118     'PatronLibrary',
 119     'CircControl changed to PatronLibrary'
 120 );
 121 is(
 122     C4::Circulation::_GetCircControlBranch($item, $borrower),
 123     $borrower->{branchcode},
 124     '_GetCircControlBranch returned borrower branch'
 125 );
 126
 127 # Userenv set, ItemHomeLibrary
 128 C4::Context->set_preference('CircControl', 'ItemHomeLibrary');
 129 is(
 130     C4::Context->preference('CircControl'),
 131     'ItemHomeLibrary',
 132     'CircControl changed to ItemHomeLibrary'
 133 );
 134 is(
 135     C4::Circulation::_GetCircControlBranch($item, $borrower),
 136     $item->{$HomeOrHoldingBranch},
 137     '_GetCircControlBranch returned item branch'
 138 );
 139
 140 # Reset initial configuration
 141 C4::Context->set_preference('CircControl', $CircControl);
 142 is(
 143     C4::Context->preference('CircControl'),
 144     $CircControl,
 145     'CircControl reset to its initial value'
 146 );
 147
 148 # Set a simple circ policy
 149 $dbh->do('DELETE FROM issuingrules');
 150 $dbh->do(
 151     q{INSERT INTO issuingrules (categorycode, branchcode, itemtype, reservesallowed,
 152                                 maxissueqty, issuelength, lengthunit,
 153                                 renewalsallowed, renewalperiod,
 154                                 norenewalbefore, auto_renew,
 155                                 fine, chargeperiod)
 156       VALUES (?, ?, ?, ?,
 157               ?, ?, ?,
 158               ?, ?,
 159               ?, ?,
 160               ?, ?
 161              )
 162     },
 163     {},
 164     '*', '*', '*', 25,
 165     20, 14, 'days',
 166     1, 7,
 167     '', 0,
 168     .10, 1
 169 );
 170
 171 # Test C4::Circulation::ProcessOfflinePayment
 172 my $sth = C4::Context->dbh->prepare("SELECT COUNT(*) FROM accountlines WHERE amount = '-123.45' AND accounttype = 'Pay'");
 173 $sth->execute();
 174 my ( $original_count ) = $sth->fetchrow_array();
 175
 176 C4::Context->dbh->do("INSERT INTO borrowers ( cardnumber, surname, firstname, categorycode, branchcode ) VALUES ( '99999999999', 'Hall', 'Kyle', 'S', 'MPL' )");
 177
 178 C4::Circulation::ProcessOfflinePayment({ cardnumber => '99999999999', amount => '123.45' });
 179
 180 $sth->execute();
 181 my ( $new_count ) = $sth->fetchrow_array();
 182
 183 ok( $new_count == $original_count  + 1, 'ProcessOfflinePayment makes payment correctly' );
 184
 185 C4::Context->dbh->do("DELETE FROM accountlines WHERE borrowernumber IN ( SELECT borrowernumber FROM borrowers WHERE cardnumber = '99999999999' )");
 186 C4::Context->dbh->do("DELETE FROM borrowers WHERE cardnumber = '99999999999'");
 187 C4::Context->dbh->do("DELETE FROM accountlines");
 188 {
 189 # CanBookBeRenewed tests
 190
 191     # Generate test biblio
 192     my $biblio = MARC::Record->new();
 193     my $title = 'Silence in the library';
 194     $biblio->append_fields(
 195         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 196         MARC::Field->new('245', ' ', ' ', a => $title),
 197     );
 198
 199     my ($biblionumber, $biblioitemnumber) = AddBiblio($biblio, '');
 200
 201     my $barcode = 'R00000342';
 202     my $branch = 'MPL';
 203
 204     my ( $item_bibnum, $item_bibitemnum, $itemnumber ) = AddItem(
 205         {
 206             homebranch       => $branch,
 207             holdingbranch    => $branch,
 208             barcode          => $barcode,
 209             replacementprice => 12.00
 210         },
 211         $biblionumber
 212     );
 213
 214     my $barcode2 = 'R00000343';
 215     my ( $item_bibnum2, $item_bibitemnum2, $itemnumber2 ) = AddItem(
 216         {
 217             homebranch       => $branch,
 218             holdingbranch    => $branch,
 219             barcode          => $barcode2,
 220             replacementprice => 23.00
 221         },
 222         $biblionumber
 223     );
 224
 225     my $barcode3 = 'R00000346';
 226     my ( $item_bibnum3, $item_bibitemnum3, $itemnumber3 ) = AddItem(
 227         {
 228             homebranch       => $branch,
 229             holdingbranch    => $branch,
 230             barcode          => $barcode3,
 231             replacementprice => 23.00
 232         },
 233         $biblionumber
 234     );
 235
 236     # Create borrowers
 237     my %renewing_borrower_data = (
 238         firstname =>  'John',
 239         surname => 'Renewal',
 240         categorycode => 'S',
 241         branchcode => $branch,
 242     );
 243
 244     my %reserving_borrower_data = (
 245         firstname =>  'Katrin',
 246         surname => 'Reservation',
 247         categorycode => 'S',
 248         branchcode => $branch,
 249     );
 250
 251     my %hold_waiting_borrower_data = (
 252         firstname =>  'Kyle',
 253         surname => 'Reservation',
 254         categorycode => 'S',
 255         branchcode => $branch,
 256     );
 257
 258     my $renewing_borrowernumber = AddMember(%renewing_borrower_data);
 259     my $reserving_borrowernumber = AddMember(%reserving_borrower_data);
 260     my $hold_waiting_borrowernumber = AddMember(%hold_waiting_borrower_data);
 261
 262     my $renewing_borrower = GetMember( borrowernumber => $renewing_borrowernumber );
 263
 264     my $constraint     = 'a';
 265     my $bibitems       = '';
 266     my $priority       = '1';
 267     my $resdate        = undef;
 268     my $expdate        = undef;
 269     my $notes          = '';
 270     my $checkitem      = undef;
 271     my $found          = undef;
 272
 273     my $datedue = AddIssue( $renewing_borrower, $barcode);
 274     is (defined $datedue, 1, "Item 1 checked out, due date: $datedue");
 275
 276     my $datedue2 = AddIssue( $renewing_borrower, $barcode2);
 277     is (defined $datedue2, 1, "Item 2 checked out, due date: $datedue2");
 278
 279     my $borrowing_borrowernumber = GetItemIssue($itemnumber)->{borrowernumber};
 280     is ($borrowing_borrowernumber, $renewing_borrowernumber, "Item checked out to $renewing_borrower->{firstname} $renewing_borrower->{surname}");
 281
 282     my ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber, 1);
 283     is( $renewokay, 1, 'Can renew, no holds for this title or item');
 284
 285
 286     # Biblio-level hold, renewal test
 287     AddReserve(
 288         $branch, $reserving_borrowernumber, $biblionumber,
 289         $constraint, $bibitems,  $priority, $resdate, $expdate, $notes,
 290         $title, $checkitem, $found
 291     );
 292
 293     # Testing of feature to allow the renewal of reserved items if other items on the record can fill all needed holds
 294     C4::Context->set_preference('AllowOnShelfHolds', 1 );
 295     C4::Context->set_preference('AllowRenewalIfOtherItemsAvailable', 1 );
 296     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber);
 297     is( $renewokay, 1, 'Bug 11634 - Allow renewal of item with unfilled holds if other available items can fill those holds');
 298     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber2);
 299     is( $renewokay, 1, 'Bug 11634 - Allow renewal of item with unfilled holds if other available items can fill those holds');
 300     # Now let's add a waiting hold on the 3rd item, it's no longer available tp check out by just anyone, so we should no longer
 301     # be able to renew these items
 302     my $hold = Koha::Database->new()->schema()->resultset('Reserve')->create(
 303         {
 304             borrowernumber => $hold_waiting_borrowernumber,
 305             biblionumber   => $biblionumber,
 306             itemnumber     => $itemnumber3,
 307             branchcode     => $branch,
 308             priority       => 0,
 309             found          => 'W'
 310         }
 311     );
 312     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber);
 313     is( $renewokay, 0, 'Bug 11634 - Allow renewal of item with unfilled holds if other available items can fill those holds');
 314     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber2);
 315     is( $renewokay, 0, 'Bug 11634 - Allow renewal of item with unfilled holds if other available items can fill those holds');
 316     C4::Context->set_preference('AllowRenewalIfOtherItemsAvailable', 0 );
 317
 318     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber);
 319     is( $renewokay, 0, '(Bug 10663) Cannot renew, reserved');
 320     is( $error, 'on_reserve', '(Bug 10663) Cannot renew, reserved (returned error is on_reserve)');
 321
 322     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber2);
 323     is( $renewokay, 0, '(Bug 10663) Cannot renew, reserved');
 324     is( $error, 'on_reserve', '(Bug 10663) Cannot renew, reserved (returned error is on_reserve)');
 325
 326     my $reserveid = C4::Reserves::GetReserveId({ biblionumber => $biblionumber, borrowernumber => $reserving_borrowernumber});
 327     my $reserving_borrower = GetMember( borrowernumber => $reserving_borrowernumber );
 328     AddIssue($reserving_borrower, $barcode3);
 329     my $reserve = $dbh->selectrow_hashref(
 330         'SELECT * FROM old_reserves WHERE reserve_id = ?',
 331         { Slice => {} },
 332         $reserveid
 333     );
 334     is($reserve->{found}, 'F', 'hold marked completed when checking out item that fills it');
 335
 336     # Item-level hold, renewal test
 337     AddReserve(
 338         $branch, $reserving_borrowernumber, $biblionumber,
 339         $constraint, $bibitems,  $priority, $resdate, $expdate, $notes,
 340         $title, $itemnumber, $found
 341     );
 342
 343     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber, 1);
 344     is( $renewokay, 0, '(Bug 10663) Cannot renew, item reserved');
 345     is( $error, 'on_reserve', '(Bug 10663) Cannot renew, item reserved (returned error is on_reserve)');
 346
 347     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber2, 1);
 348     is( $renewokay, 1, 'Can renew item 2, item-level hold is on item 1');
 349
 350
 351     # Items can't fill hold for reasons
 352     ModItem({ notforloan => 1 }, $biblionumber, $itemnumber);
 353     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber, 1);
 354     is( $renewokay, 1, 'Can renew, item is marked not for loan, hold does not block');
 355     ModItem({ notforloan => 0, itype => '' }, $biblionumber, $itemnumber,1);
 356
 357     # FIXME: Add more for itemtype not for loan etc.
 358
 359     $reserveid = C4::Reserves::GetReserveId({ biblionumber => $biblionumber, itemnumber => $itemnumber, borrowernumber => $reserving_borrowernumber});
 360     CancelReserve({ reserve_id => $reserveid });
 361
 362     # Test automatic renewal before value for "norenewalbefore" in policy is set
 363     my $barcode4 = '11235813';
 364     my ( $item_bibnum4, $item_bibitemnum4, $itemnumber4 ) = AddItem(
 365         {
 366             homebranch       => $branch,
 367             holdingbranch    => $branch,
 368             barcode          => $barcode4,
 369             replacementprice => 16.00
 370         },
 371         $biblionumber
 372     );
 373
 374     AddIssue( $renewing_borrower, $barcode4, undef, undef, undef, undef, { auto_renew => 1 } );
 375     ( $renewokay, $error ) =
 376       CanBookBeRenewed( $renewing_borrowernumber, $itemnumber4 );
 377     is( $renewokay, 0, 'Cannot renew, renewal is automatic' );
 378     is( $error, 'auto_renew',
 379         'Cannot renew, renewal is automatic (returned code is auto_renew)' );
 380
 381     # set policy to require that loans cannot be
 382     # renewed until seven days prior to the due date
 383     $dbh->do('UPDATE issuingrules SET norenewalbefore = 7');
 384     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber);
 385     is( $renewokay, 0, 'Cannot renew, renewal is premature');
 386     is( $error, 'too_soon', 'Cannot renew, renewal is premature (returned code is too_soon)');
 387     is(
 388         GetSoonestRenewDate($renewing_borrowernumber, $itemnumber),
 389         $datedue->clone->add(days => -7),
 390         'renewals permitted 7 days before due date, as expected',
 391     );
 392
 393     # Test automatic renewal again
 394     ( $renewokay, $error ) =
 395       CanBookBeRenewed( $renewing_borrowernumber, $itemnumber4 );
 396     is( $renewokay, 0, 'Cannot renew, renewal is automatic and premature' );
 397     is( $error, 'auto_too_soon',
 398 'Cannot renew, renewal is automatic and premature (returned code is auto_too_soon)'
 399     );
 400
 401     # Too many renewals
 402
 403     # set policy to forbid renewals
 404     $dbh->do('UPDATE issuingrules SET norenewalbefore = NULL, renewalsallowed = 0');
 405
 406     ( $renewokay, $error ) = CanBookBeRenewed($renewing_borrowernumber, $itemnumber);
 407     is( $renewokay, 0, 'Cannot renew, 0 renewals allowed');
 408     is( $error, 'too_many', 'Cannot renew, 0 renewals allowed (returned code is too_many)');
 409
 410     # Test WhenLostForgiveFine and WhenLostChargeReplacementFee
 411     C4::Context->set_preference('WhenLostForgiveFine','1');
 412     C4::Context->set_preference('WhenLostChargeReplacementFee','1');
 413
 414     C4::Overdues::UpdateFine( $itemnumber, $renewing_borrower->{borrowernumber},
 415         15.00, q{}, Koha::DateUtils::output_pref($datedue) );
 416
 417     LostItem( $itemnumber, 1 );
 418
 419     my $item = $schema->resultset('Item')->find( $itemnumber );
 420     ok( !$item->onloan(), "Lost item marked as returned has false onloan value" );
 421
 422     my $total_due = $dbh->selectrow_array(
 423         'SELECT SUM( amountoutstanding ) FROM accountlines WHERE borrowernumber = ?',
 424         undef, $renewing_borrower->{borrowernumber}
 425     );
 426
 427     ok( $total_due == 12, 'Borrower only charged replacement fee with both WhenLostForgiveFine and WhenLostChargeReplacementFee enabled' );
 428
 429     C4::Context->dbh->do("DELETE FROM accountlines");
 430
 431     C4::Context->set_preference('WhenLostForgiveFine','0');
 432     C4::Context->set_preference('WhenLostChargeReplacementFee','0');
 433
 434     C4::Overdues::UpdateFine( $itemnumber2, $renewing_borrower->{borrowernumber},
 435         15.00, q{}, Koha::DateUtils::output_pref($datedue) );
 436
 437     LostItem( $itemnumber2, 0 );
 438
 439     my $item2 = $schema->resultset('Item')->find( $itemnumber2 );
 440     ok( $item2->onloan(), "Lost item *not* marked as returned has true onloan value" );
 441
 442     $total_due = $dbh->selectrow_array(
 443         'SELECT SUM( amountoutstanding ) FROM accountlines WHERE borrowernumber = ?',
 444         undef, $renewing_borrower->{borrowernumber}
 445     );
 446
 447     ok( $total_due == 15, 'Borrower only charged fine with both WhenLostForgiveFine and WhenLostChargeReplacementFee disabled' );
 448
 449     my $now = dt_from_string();
 450     my $future = dt_from_string();
 451     $future->add( days => 7 );
 452     my $units = C4::Overdues::_get_chargeable_units('days', $future, $now, 'MPL');
 453     ok( $units == 0, '_get_chargeable_units returns 0 for items not past due date (Bug 12596)' );
 454 }
 455
 456 {
 457     # GetUpcomingDueIssues tests
 458     my $barcode  = 'R00000342';
 459     my $barcode2 = 'R00000343';
 460     my $barcode3 = 'R00000344';
 461     my $branch   = 'MPL';
 462
 463     #Create another record
 464     my $biblio2 = MARC::Record->new();
 465     my $title2 = 'Something is worng here';
 466     $biblio2->append_fields(
 467         MARC::Field->new('100', ' ', ' ', a => 'Anonymous'),
 468         MARC::Field->new('245', ' ', ' ', a => $title2),
 469     );
 470     my ($biblionumber2, $biblioitemnumber2) = AddBiblio($biblio2, '');
 471
 472     #Create third item
 473     AddItem(
 474         {
 475             homebranch       => $branch,
 476             holdingbranch    => $branch,
 477             barcode          => $barcode3
 478         },
 479         $biblionumber2
 480     );
 481
 482     # Create a borrower
 483     my %a_borrower_data = (
 484         firstname =>  'Fridolyn',
 485         surname => 'SOMERS',
 486         categorycode => 'S',
 487         branchcode => $branch,
 488     );
 489
 490     my $a_borrower_borrowernumber = AddMember(%a_borrower_data);
 491     my $a_borrower = GetMember( borrowernumber => $a_borrower_borrowernumber );
 492
 493     my $yesterday = DateTime->today(time_zone => C4::Context->tz())->add( days => -1 );
 494     my $two_days_ahead = DateTime->today(time_zone => C4::Context->tz())->add( days => 2 );
 495     my $today = DateTime->today(time_zone => C4::Context->tz());
 496
 497     my $datedue  = AddIssue( $a_borrower, $barcode, $yesterday );
 498     my $datedue2 = AddIssue( $a_borrower, $barcode2, $two_days_ahead );
 499
 500     my $upcoming_dues;
 501
 502     # GetUpcomingDueIssues tests
 503     for my $i(0..1) {
 504         $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => $i } );
 505         is ( scalar( @$upcoming_dues ), 0, "No items due in less than one day ($i days in advance)" );
 506     }
 507
 508     #days_in_advance needs to be inclusive, so 1 matches items due tomorrow, 0 items due today etc.
 509     $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => 2 } );
 510     is ( scalar ( @$upcoming_dues), 1, "Only one item due in 2 days or less" );
 511
 512     for my $i(3..5) {
 513         $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => $i } );
 514         is ( scalar( @$upcoming_dues ), 1,
 515             "Bug 9362: Only one item due in more than 2 days ($i days in advance)" );
 516     }
 517
 518     # Bug 11218 - Due notices not generated - GetUpcomingDueIssues needs to select due today items as well
 519
 520     my $datedue3 = AddIssue( $a_borrower, $barcode3, $today );
 521
 522     $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => -1 } );
 523     is ( scalar ( @$upcoming_dues), 0, "Overdues can not be selected" );
 524
 525     $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => 0 } );
 526     is ( scalar ( @$upcoming_dues), 1, "1 item is due today" );
 527
 528     $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => 1 } );
 529     is ( scalar ( @$upcoming_dues), 1, "1 item is due today, none tomorrow" );
 530
 531     $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => 2 }  );
 532     is ( scalar ( @$upcoming_dues), 2, "2 items are due withing 2 days" );
 533
 534     $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => 3 } );
 535     is ( scalar ( @$upcoming_dues), 2, "2 items are due withing 2 days" );
 536
 537     $upcoming_dues = C4::Circulation::GetUpcomingDueIssues();
 538     is ( scalar ( @$upcoming_dues), 2, "days_in_advance is 7 in GetUpcomingDueIssues if not provided" );
 539
 540 }
 541
 542 $dbh->rollback;
 543
 544 1;