t/db_dependent/Members.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 77;
  21 use Test::MockModule;
  22 use Data::Dumper;
  23 use C4::Context;
  24 use Koha::Database;
  25
  26 use t::lib::TestBuilder;
  27
  28 BEGIN {
  29         use_ok('C4::Members');
  30 }
  31
  32 my $schema = Koha::Database->schema;
  33 $schema->storage->txn_begin;
  34 my $builder = t::lib::TestBuilder->new;
  35 my $dbh = C4::Context->dbh;
  36 $dbh->{RaiseError} = 1;
  37
  38 my $library1 = $builder->build({
  39     source => 'Branch',
  40 });
  41 my $library2 = $builder->build({
  42     source => 'Branch',
  43 });
  44 my $CARDNUMBER   = 'TESTCARD01';
  45 my $FIRSTNAME    = 'Marie';
  46 my $SURNAME      = 'Mcknight';
  47 my $CATEGORYCODE = 'S';
  48 my $BRANCHCODE   = $library1->{branchcode};
  49
  50 my $CHANGED_FIRSTNAME = "Marry Ann";
  51 my $EMAIL             = "Marie\@email.com";
  52 my $EMAILPRO          = "Marie\@work.com";
  53 my $PHONE             = "555-12123";
  54
  55 # XXX should be randomised and checked against the database
  56 my $IMPOSSIBLE_CARDNUMBER = "XYZZZ999";
  57
  58 #my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter)= @_;
  59 my @USERENV = (
  60     1,
  61     'test',
  62     'MASTERTEST',
  63     'Test',
  64     'Test',
  65     't',
  66     'Test',
  67     0,
  68 );
  69 my $BRANCH_IDX = 5;
  70
  71 C4::Context->_new_userenv ('DUMMY_SESSION_ID');
  72 C4::Context->set_userenv ( @USERENV );
  73
  74 my $userenv = C4::Context->userenv
  75   or BAIL_OUT("No userenv");
  76
  77 # Make a borrower for testing
  78 my %data = (
  79     cardnumber => $CARDNUMBER,
  80     firstname =>  $FIRSTNAME,
  81     surname => $SURNAME,
  82     categorycode => $CATEGORYCODE,
  83     branchcode => $BRANCHCODE,
  84     dateofbirth => '',
  85     dateexpiry => '9999-12-31',
  86     userid => 'tomasito'
  87 );
  88
  89 testAgeAccessors(\%data); #Age accessor tests don't touch the db so it is safe to run them with just the object.
  90
  91 my $addmem=AddMember(%data);
  92 ok($addmem, "AddMember()");
  93
  94 # It's not really a Move, it's a Copy.
  95 my $result = MoveMemberToDeleted($addmem);
  96 ok($result,"MoveMemberToDeleted()");
  97
  98 my $sth = $dbh->prepare("SELECT * from borrowers WHERE borrowernumber=?");
  99 $sth->execute($addmem);
 100 my $MemberAdded = $sth->fetchrow_hashref;
 101
 102 $sth = $dbh->prepare("SELECT * from deletedborrowers WHERE borrowernumber=?");
 103 $sth->execute($addmem);
 104 my $MemberMoved = $sth->fetchrow_hashref;
 105
 106 is_deeply($MemberMoved,$MemberAdded,"Confirm MoveMemberToDeleted.");
 107
 108 my $member=GetMemberDetails("",$CARDNUMBER)
 109   or BAIL_OUT("Cannot read member with card $CARDNUMBER");
 110
 111 ok ( $member->{firstname}    eq $FIRSTNAME    &&
 112      $member->{surname}      eq $SURNAME      &&
 113      $member->{categorycode} eq $CATEGORYCODE &&
 114      $member->{branchcode}   eq $BRANCHCODE
 115      , "Got member")
 116   or diag("Mismatching member details: ".Dumper(\%data, $member));
 117
 118 is($member->{dateofbirth}, undef, "Empty dates handled correctly");
 119
 120 $member->{firstname} = $CHANGED_FIRSTNAME;
 121 $member->{email}     = $EMAIL;
 122 $member->{phone}     = $PHONE;
 123 $member->{emailpro}  = $EMAILPRO;
 124 ModMember(%$member);
 125 my $changedmember=GetMemberDetails("",$CARDNUMBER);
 126 ok ( $changedmember->{firstname} eq $CHANGED_FIRSTNAME &&
 127      $changedmember->{email}     eq $EMAIL             &&
 128      $changedmember->{phone}     eq $PHONE             &&
 129      $changedmember->{emailpro}  eq $EMAILPRO
 130      , "Member Changed")
 131   or diag("Mismatching member details: ".Dumper($member, $changedmember));
 132
 133 C4::Context->set_preference( 'CardnumberLength', '' );
 134 C4::Context->clear_syspref_cache();
 135
 136 my $checkcardnum=C4::Members::checkcardnumber($CARDNUMBER, "");
 137 is ($checkcardnum, "1", "Card No. in use");
 138
 139 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 140 is ($checkcardnum, "0", "Card No. not used");
 141
 142 C4::Context->set_preference( 'CardnumberLength', '4' );
 143 C4::Context->clear_syspref_cache();
 144
 145 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 146 is ($checkcardnum, "2", "Card number is too long");
 147
 148
 149
 150 C4::Context->set_preference( 'AutoEmailPrimaryAddress', 'OFF' );
 151 C4::Context->clear_syspref_cache();
 152
 153 my $notice_email = GetNoticeEmailAddress($member->{'borrowernumber'});
 154 is ($notice_email, $EMAIL, "GetNoticeEmailAddress returns correct value when AutoEmailPrimaryAddress is off");
 155
 156 C4::Context->set_preference( 'AutoEmailPrimaryAddress', 'emailpro' );
 157 C4::Context->clear_syspref_cache();
 158
 159 $notice_email = GetNoticeEmailAddress($member->{'borrowernumber'});
 160 is ($notice_email, $EMAILPRO, "GetNoticeEmailAddress returns correct value when AutoEmailPrimaryAddress is emailpro");
 161
 162 ok(!$member->{is_expired}, "GetMemberDetails() indicates that patron is not expired");
 163 ModMember(borrowernumber => $member->{'borrowernumber'}, dateexpiry => '2001-01-1');
 164 $member = GetMemberDetails($member->{'borrowernumber'});
 165 ok($member->{is_expired}, "GetMemberDetails() indicates that patron is expired");
 166
 167
 168 my $message_type = 'B';
 169 my $message = 'my message';
 170 my $messages_count = GetMessagesCount($member->{borrowernumber}, $message_type, $BRANCHCODE);
 171 is( $messages_count, 0, 'GetMessagesCount returns the number of messages correclty' );
 172
 173 is( AddMessage(), undef, 'AddMessage without argument returns undef' );
 174 is( AddMessage(undef, $message_type, $message, $BRANCHCODE), undef,  'AddMessage without the borrower number returns undef' );
 175 is( AddMessage($member->{borrowernumber}, undef, $message, $BRANCHCODE), undef,  'AddMessage without the message type returns undef' );
 176 is( AddMessage($member->{borrowernumber}, $message_type, undef, $BRANCHCODE), undef,  'AddMessage without the message returns undef' );
 177 is( AddMessage($member->{borrowernumber}, $message_type, $message, undef), undef,  'AddMessage without the branch code returns undef' );
 178 is( AddMessage($member->{borrowernumber}, $message_type, $message, $BRANCHCODE), 1,  'AddMessage functions correctly' );
 179
 180 $messages_count = GetMessagesCount();
 181 is( $messages_count, 0, 'GetMessagesCount without argument returns 0' );
 182 $messages_count = GetMessagesCount(undef, $message_type, $BRANCHCODE);
 183 is( $messages_count, '0', 'GetMessagesCount without the borrower number returns the number of messages' );
 184 $messages_count = GetMessagesCount($member->{borrowernumber}, undef, $BRANCHCODE);
 185 is( $messages_count, '1', 'GetMessagesCount without the message type returns the total number of messages' );
 186 $messages_count = GetMessagesCount($member->{borrowernumber}, $message_type, undef);
 187 is( $messages_count, '1', 'GetMessagesCount without the branchcode returns the total number of messages' );
 188 $messages_count = GetMessagesCount($member->{borrowernumber}, $message_type, $BRANCHCODE);
 189 is( $messages_count, '1', 'GetMessagesCount returns the number of messages correctly' );
 190
 191 my $messages = GetMessages();
 192 is( @$messages, 0, 'GetMessages without argument returns 0' );
 193 $messages = GetMessages($member->{borrowernumber}, $message_type, $BRANCHCODE);
 194 is( @$messages, 1, 'GetMessages returns the correct number of messages' );
 195 is( $messages->[0]->{borrowernumber}, $member->{borrowernumber}, 'GetMessages returns the borrower number correctly' );
 196 is( $messages->[0]->{message_type}, $message_type, 'GetMessages returns the message type correclty' );
 197 is( $messages->[0]->{message}, $message, 'GetMessages returns the message correctly' );
 198 is( $messages->[0]->{branchcode}, $BRANCHCODE, 'GetMessages returns the branch code correctly' );
 199
 200 $messages_count = GetMessagesCount($member->{borrowernumber}, $message_type, $BRANCHCODE);
 201 is( $messages_count, 1, 'GetMessagesCount returns the number of messages correclty' );
 202
 203 DeleteMessage();
 204 $messages = GetMessages($member->{borrowernumber}, $message_type, $BRANCHCODE);
 205 is( @$messages, 1, 'DeleteMessage without message id does not delete messages' );
 206 DeleteMessage($messages->[0]->{message_id});
 207 $messages = GetMessages($member->{borrowernumber}, $message_type, $BRANCHCODE);
 208 is( @$messages, 0, 'DeleteMessage deletes a message correctly' );
 209
 210
 211 # clean up
 212 DelMember($member->{borrowernumber});
 213 my $borrower = GetMember( cardnumber => $CARDNUMBER );
 214 is( $borrower, undef, 'DelMember should remove the patron' );
 215
 216 # Check_Userid tests
 217 %data = (
 218     cardnumber   => "123456789",
 219     firstname    => "Tomasito",
 220     surname      => "None",
 221     categorycode => "S",
 222     branchcode   => $library2->{branchcode},
 223     dateofbirth  => '',
 224     debarred     => '',
 225     dateexpiry   => '',
 226     dateenrolled => '',
 227 );
 228 # Add a new borrower
 229 my $borrowernumber = AddMember( %data );
 230 is( Check_Userid( 'tomasito.non', $borrowernumber ), 1,
 231     'recently created userid -> unique (borrowernumber passed)' );
 232 is( Check_Userid( 'tomasitoxxx', $borrowernumber ), 1,
 233     'non-existent userid -> unique (borrowernumber passed)' );
 234 is( Check_Userid( 'tomasito.none', '' ), 0,
 235     'userid exists (blank borrowernumber)' );
 236 is( Check_Userid( 'tomasitoxxx', '' ), 1,
 237     'non-existent userid -> unique (blank borrowernumber)' );
 238
 239 $borrower = GetMember( borrowernumber => $borrowernumber );
 240 is( $borrower->{dateofbirth}, undef, 'AddMember should undef dateofbirth if empty string is given');
 241 is( $borrower->{debarred}, undef, 'AddMember should undef debarred if empty string is given');
 242 isnt( $borrower->{dateexpiry}, '0000-00-00', 'AddMember should not set dateexpiry to 0000-00-00 if empty string is given');
 243 isnt( $borrower->{dateenrolled}, '0000-00-00', 'AddMember should not set dateenrolled to 0000-00-00 if empty string is given');
 244
 245 ModMember( borrowernumber => $borrowernumber, dateofbirth => '', debarred => '', dateexpiry => '', dateenrolled => '' );
 246 $borrower = GetMember( borrowernumber => $borrowernumber );
 247 is( $borrower->{dateofbirth}, undef, 'ModMember should undef dateofbirth if empty string is given');
 248 is( $borrower->{debarred}, undef, 'ModMember should undef debarred if empty string is given');
 249 isnt( $borrower->{dateexpiry}, '0000-00-00', 'ModMember should not set dateexpiry to 0000-00-00 if empty string is given');
 250 isnt( $borrower->{dateenrolled}, '0000-00-00', 'ModMember should not set dateenrolled to 0000-00-00 if empty string is given');
 251
 252 ModMember( borrowernumber => $borrowernumber, dateofbirth => '1970-01-01', debarred => '2042-01-01', dateexpiry => '9999-12-31', dateenrolled => '2015-09-06' );
 253 $borrower = GetMember( borrowernumber => $borrowernumber );
 254 is( $borrower->{dateofbirth}, '1970-01-01', 'ModMember should correctly set dateofbirth if a valid date is given');
 255 is( $borrower->{debarred}, '2042-01-01', 'ModMember should correctly set debarred if a valid date is given');
 256 is( $borrower->{dateexpiry}, '9999-12-31', 'ModMember should correctly set dateexpiry if a valid date is given');
 257 is( $borrower->{dateenrolled}, '2015-09-06', 'ModMember should correctly set dateenrolled if a valid date is given');
 258
 259 # Add a new borrower with the same userid but different cardnumber
 260 $data{ cardnumber } = "987654321";
 261 my $new_borrowernumber = AddMember( %data );
 262 is( Check_Userid( 'tomasito.none', '' ), 0,
 263     'userid not unique (blank borrowernumber)' );
 264 is( Check_Userid( 'tomasito.none', $new_borrowernumber ), 0,
 265     'userid not unique (second borrowernumber passed)' );
 266 $borrower = GetMember( borrowernumber => $new_borrowernumber );
 267 ok( $borrower->{userid} ne 'tomasito', "Borrower with duplicate userid has new userid generated" );
 268
 269 $data{ cardnumber } = "234567890";
 270 $data{userid} = 'a_user_id';
 271 $borrowernumber = AddMember( %data );
 272 $borrower = GetMember( borrowernumber => $borrowernumber );
 273 is( $borrower->{userid}, $data{userid}, 'AddMember should insert the given userid' );
 274
 275 # Regression tests for BZ13502
 276 ## Remove all entries with userid='' (should be only 1 max)
 277 $dbh->do(q|DELETE FROM borrowers WHERE userid = ''|);
 278 ## And create a patron with a userid=''
 279 $borrowernumber = AddMember( categorycode => 'S', branchcode => $library2->{branchcode} );
 280 $dbh->do(q|UPDATE borrowers SET userid = '' WHERE borrowernumber = ?|, undef, $borrowernumber);
 281 # Create another patron and verify the userid has been generated
 282 $borrowernumber = AddMember( categorycode => 'S', branchcode => $library2->{branchcode} );
 283 ok( $borrowernumber > 0, 'AddMember should have inserted the patron even if no userid is given' );
 284 $borrower = GetMember( borrowernumber => $borrowernumber );
 285 ok( $borrower->{userid},  'A userid should have been generated correctly' );
 286
 287 # Regression tests for BZ12226
 288 is( Check_Userid( C4::Context->config('user'), '' ), 0,
 289     'Check_Userid should return 0 for the DB user (Bug 12226)');
 290
 291 subtest 'GetMemberAccountBalance' => sub {
 292
 293     plan tests => 10;
 294
 295     my $members_mock = new Test::MockModule('C4::Members');
 296     $members_mock->mock( 'GetMemberAccountRecords', sub {
 297         my ($borrowernumber) = @_;
 298         if ($borrowernumber) {
 299             my @accountlines = (
 300             { amountoutstanding => '7', accounttype => 'Rent' },
 301             { amountoutstanding => '5', accounttype => 'Res' },
 302             { amountoutstanding => '3', accounttype => 'Pay' } );
 303             return ( 15, \@accountlines );
 304         }
 305         else {
 306             my @accountlines;
 307             return ( 0, \@accountlines );
 308         }
 309     });
 310
 311     my $person = GetMemberDetails(undef,undef);
 312     ok( !$person , 'Expected no member details from undef,undef' );
 313     $person = GetMemberDetails(undef,'987654321');
 314     is( $person->{amountoutstanding}, 15,
 315         'Expected 15 outstanding for cardnumber.');
 316     $borrowernumber = $person->{borrowernumber};
 317     $person = GetMemberDetails($borrowernumber,undef);
 318     is( $person->{amountoutstanding}, 15,
 319         'Expected 15 outstanding for borrowernumber.');
 320     $person = GetMemberDetails($borrowernumber,'987654321');
 321     is( $person->{amountoutstanding}, 15,
 322         'Expected 15 outstanding for both borrowernumber and cardnumber.');
 323
 324     # do not count holds charges
 325     C4::Context->set_preference( 'HoldsInNoissuesCharge', '1' );
 326     C4::Context->set_preference( 'ManInvInNoissuesCharge', '0' );
 327     my ($total, $total_minus_charges,
 328         $other_charges) = C4::Members::GetMemberAccountBalance(123);
 329     is( $total, 15 , "Total calculated correctly");
 330     is( $total_minus_charges, 15, "Holds charges are not count if HoldsInNoissuesCharge=1");
 331     is( $other_charges, 0, "Holds charges are not considered if HoldsInNoissuesCharge=1");
 332
 333     C4::Context->set_preference( 'HoldsInNoissuesCharge', '0' );
 334     ($total, $total_minus_charges,
 335         $other_charges) = C4::Members::GetMemberAccountBalance(123);
 336     is( $total, 15 , "Total calculated correctly");
 337     is( $total_minus_charges, 10, "Holds charges are count if HoldsInNoissuesCharge=0");
 338     is( $other_charges, 5, "Holds charges are considered if HoldsInNoissuesCharge=1");
 339 };
 340
 341 subtest 'purgeSelfRegistration' => sub {
 342     plan tests => 2;
 343
 344     #purge unverified
 345     my $d=360;
 346     C4::Members::DeleteUnverifiedOpacRegistrations($d);
 347     foreach(1..3) {
 348         $dbh->do("INSERT INTO borrower_modifications (timestamp, borrowernumber, verification_token) VALUES ('2014-01-01 01:02:03',0,?)", undef, (scalar localtime)."_$_");
 349     }
 350     is( C4::Members::DeleteUnverifiedOpacRegistrations($d), 3, 'Test for DeleteUnverifiedOpacRegistrations' );
 351
 352     #purge members in temporary category
 353     my $c= 'XYZ';
 354     $dbh->do("INSERT IGNORE INTO categories (categorycode) VALUES ('$c')");
 355     C4::Context->set_preference('PatronSelfRegistrationDefaultCategory', $c );
 356     C4::Context->set_preference('PatronSelfRegistrationExpireTemporaryAccountsDelay', 360);
 357     C4::Members::DeleteExpiredOpacRegistrations();
 358     $dbh->do("INSERT INTO borrowers (surname, address, city, branchcode, categorycode, dateenrolled) VALUES ('Testaabbcc', 'Street 1', 'CITY', ?, '$c', '2014-01-01 01:02:03')", undef, $library1->{branchcode});
 359     is( C4::Members::DeleteExpiredOpacRegistrations(), 1, 'Test for DeleteExpiredOpacRegistrations');
 360 };
 361
 362 sub _find_member {
 363     my ($resultset) = @_;
 364     my $found = $resultset && grep( { $_->{cardnumber} && $_->{cardnumber} eq $CARDNUMBER } @$resultset );
 365     return $found;
 366 }
 367
 368 # Regression tests for BZ15343
 369 my $password="";
 370 ( $borrowernumber, $password ) = AddMember_Opac(surname=>"Dick",firstname=>'Philip',branchcode => $library2->{branchcode});
 371 is( $password =~ /^[a-zA-Z]{10}$/ , 1, 'Test for autogenerated password if none submitted');
 372 ( $borrowernumber, $password ) = AddMember_Opac(surname=>"Deckard",firstname=>"Rick",password=>"Nexus-6",branchcode => $library2->{branchcode});
 373 is( $password eq "Nexus-6", 1, 'Test password used if submitted');
 374 $borrower = GetMember(borrowernumber => $borrowernumber);
 375 my $hashed_up =  Koha::AuthUtils::hash_password("Nexus-6", $borrower->{password});
 376 is( $borrower->{password} eq $hashed_up, 1, 'Check password hash equals hash of submitted password' );
 377
 378
 379
 380 ### ------------------------------------- ###
 381 ### Testing GetAge() / SetAge() functions ###
 382 ### ------------------------------------- ###
 383 #USES the package $member-variable to mock a koha.borrowers-object
 384 sub testAgeAccessors {
 385     my ($member) = @_;
 386     my $original_dateofbirth = $member->{dateofbirth};
 387
 388     ##Testing GetAge()
 389     my $age=GetAge("1992-08-14", "2011-01-19");
 390     is ($age, "18", "Age correct");
 391
 392     $age=GetAge("2011-01-19", "1992-01-19");
 393     is ($age, "-19", "Birthday In the Future");
 394
 395     ##Testing SetAge() for now()
 396     my $dt_now = DateTime->now();
 397     $age = DateTime::Duration->new(years => 12, months => 6, days => 1);
 398     C4::Members::SetAge( $member, $age );
 399     $age = C4::Members::GetAge( $member->{dateofbirth} );
 400     is ($age, '12', "SetAge 12 years");
 401
 402     $age = DateTime::Duration->new(years => 18, months => 12, days => 31);
 403     C4::Members::SetAge( $member, $age );
 404     $age = C4::Members::GetAge( $member->{dateofbirth} );
 405     is ($age, '19', "SetAge 18+1 years"); #This is a special case, where months=>12 and days=>31 constitute one full year, hence we get age 19 instead of 18.
 406
 407     $age = DateTime::Duration->new(years => 18, months => 12, days => 30);
 408     C4::Members::SetAge( $member, $age );
 409     $age = C4::Members::GetAge( $member->{dateofbirth} );
 410     is ($age, '19', "SetAge 18 years");
 411
 412     $age = DateTime::Duration->new(years => 0, months => 1, days => 1);
 413     C4::Members::SetAge( $member, $age );
 414     $age = C4::Members::GetAge( $member->{dateofbirth} );
 415     is ($age, '0', "SetAge 0 years");
 416
 417     $age = '0018-12-31';
 418     C4::Members::SetAge( $member, $age );
 419     $age = C4::Members::GetAge( $member->{dateofbirth} );
 420     is ($age, '19', "SetAge ISO_Date 18+1 years"); #This is a special case, where months=>12 and days=>31 constitute one full year, hence we get age 19 instead of 18.
 421
 422     $age = '0018-12-30';
 423     C4::Members::SetAge( $member, $age );
 424     $age = C4::Members::GetAge( $member->{dateofbirth} );
 425     is ($age, '19', "SetAge ISO_Date 18 years");
 426
 427     $age = '18-1-1';
 428     eval { C4::Members::SetAge( $member, $age ); };
 429     is ((length $@ > 1), '1', "SetAge ISO_Date $age years FAILS");
 430
 431     $age = '0018-01-01';
 432     eval { C4::Members::SetAge( $member, $age ); };
 433     is ((length $@ == 0), '1', "SetAge ISO_Date $age years succeeds");
 434
 435     ##Testing SetAge() for relative_date
 436     my $relative_date = DateTime->new(year => 3010, month => 3, day => 15);
 437
 438     $age = DateTime::Duration->new(years => 10, months => 3);
 439     C4::Members::SetAge( $member, $age, $relative_date );
 440     $age = C4::Members::GetAge( $member->{dateofbirth}, $relative_date->ymd() );
 441     is ($age, '10', "SetAge, 10 years and 3 months old person was born on ".$member->{dateofbirth}." if todays is ".$relative_date->ymd());
 442
 443     $age = DateTime::Duration->new(years => 112, months => 1, days => 1);
 444     C4::Members::SetAge( $member, $age, $relative_date );
 445     $age = C4::Members::GetAge( $member->{dateofbirth}, $relative_date->ymd() );
 446     is ($age, '112', "SetAge, 112 years, 1 months and 1 days old person was born on ".$member->{dateofbirth}." if today is ".$relative_date->ymd());
 447
 448     $age = '0112-01-01';
 449     C4::Members::SetAge( $member, $age, $relative_date );
 450     $age = C4::Members::GetAge( $member->{dateofbirth}, $relative_date->ymd() );
 451     is ($age, '112', "SetAge ISO_Date, 112 years, 1 months and 1 days old person was born on ".$member->{dateofbirth}." if today is ".$relative_date->ymd());
 452
 453     $member->{dateofbirth} = $original_dateofbirth; #It is polite to revert made changes in the unit tests.
 454 } #sub testAgeAccessors
 455
 456 1;