t/db_dependent/Members.t

   1 #!/usr/bin/perl
   2 #
   3 # This is to test C4/Members
   4 # It requires a working Koha database with the sample data
   5
   6 use strict;
   7 use warnings;
   8
   9 use Test::More tests => 20;
  10 use Data::Dumper;
  11
  12 BEGIN {
  13         use_ok('C4::Members');
  14 }
  15
  16
  17 my $CARDNUMBER   = 'TESTCARD01';
  18 my $FIRSTNAME    = 'Marie';
  19 my $SURNAME      = 'Mcknight';
  20 my $CATEGORYCODE = 'S';
  21 my $BRANCHCODE   = 'CPL';
  22
  23 my $CHANGED_FIRSTNAME = "Marry Ann";
  24 my $EMAIL             = "Marie\@email.com";
  25 my $ETHNICITY         = "German";
  26 my $PHONE             = "555-12123";
  27
  28 # XXX should be randomised and checked against the database
  29 my $IMPOSSIBLE_CARDNUMBER = "XYZZZ999";
  30
  31 my $INDEPENDENT_BRANCHES_PREF = 'IndependantBranches';
  32
  33 # XXX make a non-commit transaction and rollback rather than insert/delete
  34
  35 #my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter)= @_;
  36 my @USERENV = (
  37     1,
  38     'test',
  39     'MASTERTEST',
  40     'Test',
  41     'Test',
  42     't',
  43     'Test',
  44     0,
  45 );
  46 my $BRANCH_IDX = 4;
  47
  48 C4::Context->_new_userenv ('DUMMY_SESSION_ID');
  49 C4::Context->set_userenv ( @USERENV );
  50
  51 my $userenv = C4::Context->userenv
  52   or BAIL_OUT("No userenv");
  53
  54 # Make a borrower for testing
  55 my %data = (
  56     cardnumber => $CARDNUMBER,
  57     firstname =>  $FIRSTNAME,
  58     surname => $SURNAME,
  59     categorycode => $CATEGORYCODE,
  60     branchcode => $BRANCHCODE,
  61 );
  62
  63 my $addmem=AddMember(%data);
  64 ok($addmem, "AddMember()");
  65
  66 my $member=GetMemberDetails("",$CARDNUMBER)
  67   or BAIL_OUT("Cannot read member with card $CARDNUMBER");
  68
  69 ok ( $member->{firstname}    eq $FIRSTNAME    &&
  70      $member->{surname}      eq $SURNAME      &&
  71      $member->{categorycode} eq $CATEGORYCODE &&
  72      $member->{branchcode}   eq $BRANCHCODE
  73      , "Got member")
  74   or diag("Mismatching member details: ".Dumper(\%data, $member));
  75
  76 $member->{firstname} = $CHANGED_FIRSTNAME;
  77 $member->{email}     = $EMAIL;
  78 $member->{ethnicity} = $ETHNICITY;
  79 $member->{phone}     = $PHONE;
  80 ModMember(%$member);
  81 my $changedmember=GetMemberDetails("",$CARDNUMBER);
  82 ok ( $changedmember->{firstname} eq $CHANGED_FIRSTNAME &&
  83      $changedmember->{email}     eq $EMAIL             &&
  84      $changedmember->{ethnicity} eq $ETHNICITY         &&
  85      $changedmember->{phone}     eq $PHONE
  86      , "Member Changed")
  87   or diag("Mismatching member details: ".Dumper($member, $changedmember));
  88
  89 C4::Context->set_preference( $INDEPENDENT_BRANCHES_PREF, '0' );
  90 C4::Context->clear_syspref_cache();
  91
  92 my $results = Search($CARDNUMBER);
  93 ok (@$results == 1, "Search cardnumber returned only one result")
  94   or diag("Multiple members with Card $CARDNUMBER: ".Dumper($results));
  95 ok (_find_member($results), "Search cardnumber")
  96   or diag("Card $CARDNUMBER not found in the resultset: ".Dumper($results));
  97
  98 my @searchstring=($SURNAME);
  99 $results = Search(\@searchstring);
 100 ok (_find_member($results), "Search (arrayref)")
 101   or diag("Card $CARDNUMBER not found in the resultset: ".Dumper($results));
 102
 103 $results = Search(\@searchstring,undef,undef,undef,["surname"]);
 104 ok (_find_member($results), "Surname Search (arrayref)")
 105   or diag("Card $CARDNUMBER not found in the resultset: ".Dumper($results));
 106
 107 $results = Search("$CHANGED_FIRSTNAME $SURNAME", "surname");
 108 ok (_find_member($results), "Full name  Search (string)")
 109   or diag("Card $CARDNUMBER not found in the resultset: ".Dumper($results));
 110
 111 @searchstring=($PHONE);
 112 $results = Search(\@searchstring,undef,undef,undef,["phone"]);
 113 ok (_find_member($results), "Phone Search (arrayref)")
 114   or diag("Card $CARDNUMBER not found in the resultset: ".Dumper($results));
 115
 116 $results = Search($PHONE,undef,undef,undef,["phone"]);
 117 ok (_find_member($results), "Phone Search (string)")
 118   or diag("Card $CARDNUMBER not found in the resultset: ".Dumper($results));
 119
 120 C4::Context->set_preference( $INDEPENDENT_BRANCHES_PREF, '1' );
 121 C4::Context->clear_syspref_cache();
 122
 123 $results = Search("$CHANGED_FIRSTNAME $SURNAME", "surname");
 124 ok (!_find_member($results), "Full name  Search (string) for independent branches, different branch")
 125   or diag("Card $CARDNUMBER found in the resultset for independent branches: ".Dumper(C4::Context->preference($INDEPENDENT_BRANCHES_PREF), $results));
 126
 127 @searchstring=($SURNAME);
 128 $results = Search(\@searchstring);
 129 ok (!_find_member($results), "Search (arrayref) for independent branches, different branch")
 130   or diag("Card $CARDNUMBER found in the resultset for independent branches: ".Dumper(C4::Context->preference($INDEPENDENT_BRANCHES_PREF), $results));
 131
 132 $USERENV[$BRANCH_IDX] = $BRANCHCODE;
 133 C4::Context->set_userenv ( @USERENV );
 134
 135 $results = Search("$CHANGED_FIRSTNAME $SURNAME", "surname");
 136 ok (_find_member($results), "Full name  Search (string) for independent branches, same branch")
 137   or diag("Card $CARDNUMBER not found in the resultset for independent branches: ".Dumper(C4::Context->preference($INDEPENDENT_BRANCHES_PREF), $results));
 138
 139 @searchstring=($SURNAME);
 140 $results = Search(\@searchstring);
 141 ok (_find_member($results), "Search (arrayref) for independent branches, same branch")
 142   or diag("Card $CARDNUMBER not found in the resultset for independent branches: ".Dumper(C4::Context->preference($INDEPENDENT_BRANCHES_PREF), $results));
 143
 144
 145 my $checkcardnum=C4::Members::checkcardnumber($CARDNUMBER, "");
 146 is ($checkcardnum, "1", "Card No. in use");
 147
 148 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 149 is ($checkcardnum, "0", "Card No. not used");
 150
 151 my $age=GetAge("1992-08-14", "2011-01-19");
 152 is ($age, "18", "Age correct");
 153
 154 $age=GetAge("2011-01-19", "1992-01-19");
 155 is ($age, "-19", "Birthday In the Future");
 156
 157 # clean up
 158 DelMember($member->{borrowernumber});
 159 $results = Search($CARDNUMBER,undef,undef,undef,["cardnumber"]);
 160 ok (!_find_member($results), "Delete member")
 161   or diag("Card $CARDNUMBER found for the deleted member in the resultset: ".Dumper($results));
 162
 163
 164 exit;
 165
 166 sub _find_member {
 167     my ($resultset) = @_;
 168     my $found = $resultset && grep( { $_->{cardnumber} && $_->{cardnumber} eq $CARDNUMBER } @$resultset );
 169     return $found;
 170 }