t/db_dependent/VirtualShelves.t

   1 #!/usr/bin/perl
   2
   3 # This file is a test script for C4::VirtualShelves.pm
   4 # Author : Antoine Farnault, antoine@koha-fr.org
   5 # Larger modifications by Jonathan Druart and Marcel de Rooy
   6
   7 use Modern::Perl;
   8 use Test::More tests => 96;
   9 use MARC::Record;
  10
  11 use C4::Biblio qw( AddBiblio DelBiblio );
  12 use C4::Context;
  13 use C4::Members qw( AddMember );
  14
  15
  16 my $dbh = C4::Context->dbh;
  17 $dbh->{RaiseError} = 1;
  18 $dbh->{AutoCommit} = 0;
  19
  20 # Create some borrowers
  21 my @borrowernumbers;
  22 for my $i ( 1 .. 10 ) {
  23     my $borrowernumber = AddMember(
  24         firstname =>  'my firstname',
  25         surname => 'my surname ' . $i,
  26         categorycode => 'S',
  27         branchcode => 'CPL',
  28     );
  29     push @borrowernumbers, $borrowernumber;
  30 }
  31
  32 # Creating some biblios
  33 my @biblionumbers;
  34 foreach(0..9) {
  35     my ($biblionumber)= AddBiblio(MARC::Record->new, '');
  36         #item number ignored
  37     push @biblionumbers, $biblionumber;
  38 }
  39
  40 #----------------------------------------------------------------------#
  41 #
  42 #           TESTS START HERE
  43 #
  44 #----------------------------------------------------------------------#
  45
  46 use_ok('C4::VirtualShelves');
  47
  48 #-----------------------TEST AddShelf function------------------------#
  49 # usage : $shelfnumber = &AddShelf( $shelfname, $owner, $category);
  50
  51 # creating shelves (could be <10 when names are not unique)
  52 my @shelves;
  53 for my $i (0..9){
  54     my $name= randomname();
  55     my $catg= int(rand(2))+1;
  56     my $ShelfNumber= AddShelf(
  57         {
  58             shelfname => $name,
  59             category  => $catg,
  60         },
  61         $borrowernumbers[$i]);
  62
  63     if($ShelfNumber>-1) {
  64         ok($ShelfNumber > -1, "created shelf");   # Shelf creation successful;
  65     }
  66     else {
  67         my $t= C4::VirtualShelves::_CheckShelfName(
  68             $name, $catg, $borrowernumbers[$i], 0);
  69         is($t, 0, "Name clash expected on shelf creation");
  70     }
  71     push @shelves, {
  72         number => $ShelfNumber,
  73         name   => $name,
  74         catg   => $catg,
  75         owner  => $borrowernumbers[$i],
  76     }; #also push the errors
  77 }
  78
  79 # try to create shelves with duplicate names
  80 for my $i (0..9){
  81     if($shelves[$i]->{number}<0) {
  82         ok(1, 'skip duplicate test for earlier name clash');
  83         next;
  84     }
  85     my @shlf=GetShelf($shelves[$i]->{number}); #number, name, owner, catg, ...
  86
  87     # A shelf name is not per se unique!
  88     if( $shlf[3]==2 ) { #public list: try to create with same name
  89         my $badNumShelf= AddShelf( {
  90             shelfname=> $shelves[$i]->{name},
  91             category => 2
  92         }, $borrowernumbers[$i]);
  93         is($badNumShelf, -1, 'do not create public lists with duplicate names');
  94             #AddShelf returns -1 if name already exist.
  95         DelShelf($badNumShelf) if $badNumShelf>-1; #delete if went wrong..
  96     }
  97     else { #private list, try to add another one for SAME user (owner)
  98         my $badNumShelf= defined($shlf[2])? AddShelf(
  99             {
 100                 shelfname=> $shelves[$i]->{name},
 101                 category => 1,
 102             },
 103             $shlf[2]): -1;
 104         is($badNumShelf, -1, 'do not create private lists with duplicate name for same user');
 105         DelShelf($badNumShelf) if $badNumShelf>-1; #delete if went wrong..
 106     }
 107 }
 108
 109 #-----------TEST AddToShelf & GetShelfContents &  DelFromShelf functions--------------#
 110 # usage : &AddToShelf($biblionumber, $shelfnumber);
 111 # usage : $biblist = &GetShelfContents($shelfnumber);
 112 # usage : $biblist = GetShelfContents($shelfnumber);
 113
 114 my %used = ();
 115 for my $i (0..9){
 116     my $bib = $biblionumbers[int(rand(9))];
 117     my $shelfnumber = $shelves[int(rand(9))]->{number};
 118     if($shelfnumber<0) {
 119         ok(1, 'skip add to list-test for shelf -1');
 120         ok(1, 'skip counting list entries for shelf -1');
 121         next;
 122     }
 123
 124     my $key = "$bib\t$shelfnumber";
 125     my $should_fail = exists($used{$key}) ? 1 : 0;
 126     #FIXME We assume here that we have permission to add..
 127     #The different permissions could be tested too.
 128
 129     my ($biblistBefore,$countbefore) = GetShelfContents($shelfnumber);
 130     my $status = AddToShelf($bib,$shelfnumber,$borrowernumbers[$i]);
 131     my ($biblistAfter,$countafter) = GetShelfContents($shelfnumber);
 132
 133     if ($should_fail) {
 134         ok(!defined($status), 'failed to add to list when we should');
 135     } else {
 136         ok(defined($status), 'added to list when we should');
 137     }
 138
 139     if (defined $status) {
 140         is($countbefore, $countafter - 1, 'added bib to list');  # the bib has been successfuly added.
 141     } else {
 142         is($countbefore, $countafter, 'did not add duplicate bib to list');
 143     }
 144
 145     $used{$key}++;
 146 }
 147
 148 #-----------------------TEST ModShelf & GetShelf functions------------------------#
 149 # usage : ModShelf($shelfnumber, $shelfname, $owner, $category )
 150 # usage : (shelfnumber,shelfname,owner,category) = GetShelf($shelfnumber);
 151
 152 for my $i (0..9){
 153     my $rand = int(rand(9));
 154     my $numA = $shelves[$rand]->{number};
 155     if($numA<0) {
 156         ok(1, 'Skip ModShelf test for shelf -1');
 157         ok(1, 'Skip ModShelf test for shelf -1');
 158         ok(1, 'Skip ModShelf test for shelf -1');
 159         next;
 160     }
 161     my $newname= randomname();
 162     my $shelf = {
 163         shelfname => $newname,
 164         category =>  3-$shelves[$rand]->{catg}, # tric: 1->2 and 2->1
 165     };
 166     #check name change (with category change)
 167     if(C4::VirtualShelves::_CheckShelfName($newname,$shelf->{category},
 168             $shelves[$rand]->{owner}, $numA)) {
 169         ModShelf($numA,$shelf);
 170         my ($numB,$nameB,$ownerB,$categoryB) = GetShelf($numA);
 171         is($numA, $numB, 'modified shelf');
 172         is($shelf->{shelfname}, $nameB,     '... and name change took');
 173         is($shelf->{category}, $categoryB, '... and category change took');
 174     }
 175     else {
 176         ok(1, "No ModShelf for $newname") for 1..3;
 177     }
 178 }
 179
 180 #----------------------- TEST AddShare ----------------------------------------#
 181
 182 #first count the number of shares in the table
 183 my $sql_sharecount="select count(*) from virtualshelfshares";
 184 my $cnt1=$dbh->selectrow_array($sql_sharecount);
 185
 186 #try to add a share without shelfnumber: should fail
 187 AddShare(0, 'abcdefghij');
 188 my $cnt2=$dbh->selectrow_array($sql_sharecount);
 189 is($cnt1,$cnt2, "Did not add an invalid share record");
 190
 191 #add another share: should be okay
 192 #AddShare assumes that you tested if category==private (so we could actually
 193 #be doing something illegal here :)
 194 my $n=$shelves[0]->{number};
 195 if($n<0) {
 196     ok(1, 'Skip AddShare for shelf -1');
 197 }
 198 else {
 199     AddShare($n, 'abcdefghij');
 200     my $cnt3=$dbh->selectrow_array($sql_sharecount);
 201     is(1+$cnt2, $cnt3, "Added one new share record with invitekey");
 202 }
 203
 204 #----------------------- TEST AcceptShare -------------------------------------#
 205
 206 # test accepting a wrong key
 207 my $testkey= 'keyisgone9';
 208 my $acctest="delete from virtualshelfshares where invitekey=?";
 209 $dbh->do($acctest,undef,($testkey)); #just be sure it does not exist
 210 $acctest="select shelfnumber from virtualshelves";
 211 my ($accshelf)= $dbh->selectrow_array($acctest);
 212 is(AcceptShare($accshelf,$testkey,$borrowernumbers[0]),undef,'Did not accept invalid key');
 213
 214 # test accepting a good key
 215 if( AddShare($accshelf,$testkey) && $borrowernumbers[0] ) {
 216     is(AcceptShare($accshelf, $testkey, $borrowernumbers[0]),1,'Accepted share');
 217 }
 218 else { #cannot accept if addshared failed somehow
 219     ok(1, 'Skipped second AcceptShare test');
 220 }
 221
 222 #----------------------- TEST IsSharedList ------------------------------------#
 223
 224 for my $i (0..9) {
 225     my $sql="select count(*) from virtualshelfshares where shelfnumber=? and borrowernumber is not null";
 226     my $sh=$shelves[$i]->{number};
 227     my ($n)=$dbh->selectrow_array($sql,undef,($sh));
 228     is(IsSharedList($sh),$n? 1: '', "Checked IsSharedList for shelf $sh");
 229 }
 230
 231 #----------------TEST DelShelf & DelFromShelf functions------------------------#
 232
 233 for my $i (0..9){
 234     my $shelfnumber = $shelves[$i]->{number};
 235     if($shelfnumber<0) {
 236         ok(1, 'Skip DelShelf for shelf -1');
 237         next;
 238     }
 239     my $status = DelShelf($shelfnumber);
 240     is($status, 1, "deleted shelf $shelfnumber and its contents");
 241 }
 242
 243 #----------------------- TEST RemoveShare -------------------------------------#
 244
 245 my $remshr_test="select borrowernumber, shelfnumber from virtualshelfshares where borrowernumber is not null";
 246 my @remshr_shelf= $dbh->selectrow_array($remshr_test);
 247 if(@remshr_shelf) {
 248     is(RemoveShare(@remshr_shelf),1,'Removed a shelf share');
 249 }
 250 else {
 251     ok(1,'Skipped RemoveShare test');
 252 }
 253
 254 #----------------------- SOME SUBS --------------------------------------------#
 255
 256 sub randomname {
 257     my $rv='';
 258     for(0..19) {
 259         $rv.= ('a'..'z','A'..'Z',0..9) [int(rand()*62)];
 260     }
 261     return $rv;
 262 }
 263
 264 $dbh->rollback;