tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use strict;
  44 use warnings;
  45 use CGI qw ( -utf8 );
  46 use C4::Auth;
  47 use C4::Context;
  48 use C4::Output;
  49 use C4::Letters;
  50 use C4::Members::Attributes;
  51
  52 # $protected_letters = protected_letters()
  53 # - return a hashref of letter_codes representing letters that should never be deleted
  54 sub protected_letters {
  55     my $dbh = C4::Context->dbh;
  56     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  57     return { map { $_->[0] => 1 } @{$codes} };
  58 }
  59
  60 our $input       = new CGI;
  61 my $searchfield = $input->param('searchfield');
  62 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  63 our $branchcode  = $input->param('branchcode');
  64 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $dbh = C4::Context->dbh;
  70
  71 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  72     {
  73         template_name   => 'tools/letter.tt',
  74         query           => $input,
  75         type            => 'intranet',
  76         authnotrequired => 0,
  77         flagsrequired   => { tools => 'edit_notices' },
  78         debug           => 1,
  79     }
  80 );
  81
  82 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  83   ?  C4::Context->userenv()->{'branch'}
  84   : undef;
  85 # we show only the TMPL_VAR names $op
  86
  87 $template->param(
  88     independant_branch => $my_branch,
  89         script_name => $script_name,
  90   searchfield => $searchfield,
  91     branchcode => $branchcode,
  92         action => $script_name
  93 );
  94
  95 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  96     add_validate();
  97     $op = q{}; # we return to the default screen for the next operation
  98 }
  99 if ($op eq 'copy_form') {
 100     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 101     my $branchcode = $input->param('branchcode');
 102     add_form($oldbranchcode, $module, $code);
 103     $template->param(
 104         oldbranchcode => $oldbranchcode,
 105         branchcode => $branchcode,
 106         copying => 1,
 107         modify => 0,
 108     );
 109 }
 110 elsif ( $op eq 'add_form' ) {
 111     add_form($branchcode, $module, $code);
 112 }
 113 elsif ( $op eq 'delete_confirm' ) {
 114     delete_confirm($branchcode, $module, $code);
 115 }
 116 elsif ( $op eq 'delete_confirmed' ) {
 117     delete_confirmed($branchcode, $module, $code);
 118     $op = q{}; # next operation is to return to default screen
 119 }
 120 else {
 121     default_display($branchcode,$searchfield);
 122 }
 123
 124 # Do this last as delete_confirmed resets
 125 if ($op) {
 126     $template->param($op  => 1);
 127 } else {
 128     $template->param(no_op_set => 1);
 129 }
 130
 131 output_html_with_http_headers $input, $cookie, $template->output;
 132
 133 sub add_form {
 134     my ( $branchcode,$module, $code ) = @_;
 135
 136     my $letters;
 137     # if code has been passed we can identify letter and its an update action
 138     if ($code) {
 139         $letters = C4::Letters::GetLetterTemplates(
 140             {
 141                 branchcode => $branchcode,
 142                 module     => $module,
 143                 code       => $code,
 144             }
 145         );
 146     }
 147
 148     my $message_transport_types = GetMessageTransportTypes();
 149     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 150     my %letters = ( default => { templates => $templates } );
 151
 152     if ( C4::Context->preference('TranslateNotices') ) {
 153         my $translated_languages =
 154           C4::Languages::getTranslatedLanguages( 'opac',
 155             C4::Context->preference('template') );
 156         for my $language (@$translated_languages) {
 157             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 158                 if ( $language->{plural} ) {
 159                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 160                         description => $sublanguage->{native_description}
 161                           . ' '
 162                           . $sublanguage->{region_description} . ' ('
 163                           . $sublanguage->{rfc4646_subtag} . ')',
 164                         templates => { %$templates },
 165                     };
 166                 }
 167                 else {
 168                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 169                         description => $sublanguage->{native_description}
 170                           . ' ('
 171                           . $sublanguage->{rfc4646_subtag} . ')',
 172                         templates => { %$templates },
 173                     };
 174                 }
 175             }
 176         }
 177         $template->param( languages => $translated_languages );
 178     }
 179     if ($letters) {
 180         $template->param(
 181             modify     => 1,
 182             code       => $code,
 183         );
 184         my $first_flag_name = 1;
 185         my ( $lang, @templates );
 186         # The letter name is contained into each mtt row.
 187         # So we can only sent the first one to the template.
 188         for my $letter ( @$letters ) {
 189             # The letter_name
 190             if ( $first_flag_name and $letter->{name} ) {
 191                 $template->param(
 192                     letter_name=> $letter->{name},
 193                 );
 194                 $first_flag_name = 0;
 195             }
 196
 197             my $lang = $letter->{lang};
 198             my $mtt = $letter->{message_transport_type};
 199             $letters{ $lang }{templates}{$mtt} = {
 200                 message_transport_type => $letter->{message_transport_type},
 201                 is_html    => $letter->{is_html},
 202                 title      => $letter->{title},
 203                 content    => $letter->{content} // '',
 204             };
 205         }
 206     }
 207     else {
 208         $template->param( adding => 1 );
 209     }
 210
 211     $template->param(
 212         letters => \%letters,
 213     );
 214
 215     my $field_selection;
 216     push @{$field_selection}, add_fields('branches');
 217     if ($module eq 'reserves') {
 218         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 219     }
 220     elsif ( $module eq 'acquisition' ) {
 221         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 222     }
 223     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 224         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 225     }
 226     elsif ($module eq 'claimissues') {
 227         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 228         push @{$field_selection},
 229         {
 230             value => q{},
 231             text => '---BIBLIO---'
 232         };
 233         foreach(qw(title author serial)) {
 234             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 235         }
 236     }
 237     elsif ($module eq 'serial') {
 238         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 239     }
 240     elsif ($module eq 'suggestions') {
 241         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 242     }
 243     else {
 244         push @{$field_selection}, add_fields('biblio','biblioitems'),
 245             add_fields('items'),
 246             {value => 'items.content', text => 'items.content'},
 247             {value => 'items.fine',    text => 'items.fine'},
 248             add_fields('borrowers');
 249         if ($module eq 'circulation') {
 250             push @{$field_selection}, add_fields('opac_news');
 251
 252         }
 253
 254         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 255             push @{$field_selection}, add_fields('old_issues');
 256         } else {
 257             push @{$field_selection}, add_fields('issues');
 258         }
 259
 260         if ( $module eq 'circulation' and $code =~ /^AR_/  ) {
 261             push @{$field_selection}, add_fields('article_requests');
 262         }
 263     }
 264
 265     $template->param(
 266         module     => $module,
 267         SQLfieldnames => $field_selection,
 268         branchcode => $branchcode,
 269     );
 270     return;
 271 }
 272
 273 sub add_validate {
 274     my $dbh        = C4::Context->dbh;
 275     my $branchcode    = $input->param('branchcode');
 276     my $module        = $input->param('module');
 277     my $oldmodule     = $input->param('oldmodule');
 278     my $code          = $input->param('code');
 279     my $name          = $input->param('name');
 280     my @mtt           = $input->multi_param('message_transport_type');
 281     my @title         = $input->multi_param('title');
 282     my @content       = $input->multi_param('content');
 283     my @lang          = $input->multi_param('lang');
 284     for my $mtt ( @mtt ) {
 285         my $is_html = $input->param("is_html_$mtt");
 286         my $title   = shift @title;
 287         my $content = shift @content;
 288         my $lang = shift @lang;
 289         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt, $lang );
 290
 291         # getletter can return the default letter even if we pass a branchcode
 292         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 293         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 294             $letter = undef;
 295         }
 296         unless ( $title and $content ) {
 297             # Delete this mtt if no title or content given
 298             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 299             next;
 300         }
 301         elsif ( $letter and $letter->{message_transport_type} eq $mtt and $letter->{lang} eq $lang ) {
 302             $dbh->do(
 303                 q{
 304                     UPDATE letter
 305                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?, lang = ?
 306                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ?
 307                 },
 308                 undef,
 309                 $branchcode || '', $module, $name, $is_html || 0, $title, $content, $lang,
 310                 $branchcode, $oldmodule, $code, $mtt
 311             );
 312         } else {
 313             $dbh->do(
 314                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type, lang) VALUES (?,?,?,?,?,?,?,?,?)},
 315                 undef,
 316                 $branchcode || '', $module, $code, $name, $is_html || 0, $title, $content, $mtt, $lang
 317             );
 318         }
 319     }
 320     # set up default display
 321     default_display($branchcode);
 322     return 1;
 323 }
 324
 325 sub delete_confirm {
 326     my ($branchcode, $module, $code) = @_;
 327     my $dbh = C4::Context->dbh;
 328     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 329     my @values = values %$letter;
 330     $template->param(
 331         letter => $letter,
 332     );
 333     return;
 334 }
 335
 336 sub delete_confirmed {
 337     my ($branchcode, $module, $code, $mtt, $lang) = @_;
 338     C4::Letters::DelLetter(
 339         {
 340             branchcode => $branchcode || '',
 341             module     => $module,
 342             code       => $code,
 343             mtt        => $mtt,
 344             lang       => $lang,
 345         }
 346     );
 347     # setup default display for screen
 348     default_display($branchcode);
 349     return;
 350 }
 351
 352 sub retrieve_letters {
 353     my ($branchcode, $searchstring) = @_;
 354
 355     $branchcode = $my_branch if $branchcode && $my_branch;
 356
 357     my $dbh = C4::Context->dbh;
 358     my ($sql, @where, @args);
 359     $sql = "SELECT branchcode, module, code, name, branchname
 360             FROM letter
 361             LEFT OUTER JOIN branches USING (branchcode)
 362     ";
 363     if ($searchstring && $searchstring=~m/(\S+)/) {
 364         $searchstring = $1 . q{%};
 365         push @where, 'code LIKE ?';
 366         push @args, $searchstring;
 367     }
 368     elsif ($branchcode) {
 369         push @where, 'branchcode = ?';
 370         push @args, $branchcode || '';
 371     }
 372     elsif ($my_branch) {
 373         push @where, "(branchcode = ? OR branchcode = '')";
 374         push @args, $my_branch;
 375     }
 376
 377     $sql .= " WHERE ".join(" AND ", @where) if @where;
 378     $sql .= " GROUP BY branchcode,module,code";
 379     $sql .= " ORDER BY module, code, branchcode";
 380
 381     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 382 }
 383
 384 sub default_display {
 385     my ($branchcode, $searchfield) = @_;
 386
 387     unless ( defined $branchcode ) {
 388         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 389             $branchcode = C4::Context::mybranch();
 390         }
 391     }
 392
 393     if ( $searchfield  ) {
 394         $template->param( search      => 1 );
 395     }
 396     my $results = retrieve_letters($branchcode,$searchfield);
 397
 398     my $loop_data = [];
 399     my $protected_letters = protected_letters();
 400     foreach my $row (@{$results}) {
 401         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 402         push @{$loop_data}, $row;
 403
 404     }
 405
 406     $template->param(
 407         letter => $loop_data,
 408         branchcode => $branchcode,
 409     );
 410 }
 411
 412 sub add_fields {
 413     my @tables = @_;
 414     my @fields = ();
 415
 416     for my $table (@tables) {
 417         push @fields, get_columns_for($table);
 418
 419     }
 420     return @fields;
 421 }
 422
 423 sub get_columns_for {
 424     my $table = shift;
 425 # FIXME untranslatable
 426     my %column_map = (
 427         aqbooksellers => '---BOOKSELLERS---',
 428         aqorders      => '---ORDERS---',
 429         serial        => '---SERIALS---',
 430         reserves      => '---HOLDS---',
 431         suggestions   => '---SUGGESTIONS---',
 432     );
 433     my @fields = ();
 434     if (exists $column_map{$table} ) {
 435         push @fields, {
 436             value => q{},
 437             text  => $column_map{$table} ,
 438         };
 439     }
 440     else {
 441         my $tlabel = '---' . uc $table;
 442         $tlabel.= '---';
 443         push @fields, {
 444             value => q{},
 445             text  => $tlabel,
 446         };
 447     }
 448
 449     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 450     my $table_prefix = $table . q|.|;
 451     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 452     for my $row (@{$rows}) {
 453         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 454         push @fields, {
 455             value => $table_prefix . $row->{Field},
 456             text  => $table_prefix . $row->{Field},
 457         }
 458     }
 459     if ($table eq 'borrowers') {
 460         if ( my $attributes = C4::Members::Attributes::GetAttributes() ) {
 461             foreach (@$attributes) {
 462                 push @fields, {
 463                     value => "borrower-attribute:$_",
 464                     text  => "attribute:$_",
 465                 }
 466             }
 467         }
 468     }
 469     return @fields;
 470 }