C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use DBIx::Connector;
 101 use Encode;
 102 use ZOOM;
 103 use XML::Simple;
 104 use POSIX ();
 105 use DateTime::TimeZone;
 106 use Module::Load::Conditional qw(can_load);
 107 use Carp;
 108
 109 use C4::Boolean;
 110 use C4::Debug;
 111 use Koha;
 112 use Koha::Config::SysPrefs;
 113
 114 =head1 NAME
 115
 116 C4::Context - Maintain and manipulate the context of a Koha script
 117
 118 =head1 SYNOPSIS
 119
 120   use C4::Context;
 121
 122   use C4::Context("/path/to/koha-conf.xml");
 123
 124   $config_value = C4::Context->config("config_variable");
 125
 126   $koha_preference = C4::Context->preference("preference");
 127
 128   $db_handle = C4::Context->dbh;
 129
 130   $Zconn = C4::Context->Zconn;
 131
 132   $stopwordhash = C4::Context->stopwords;
 133
 134 =head1 DESCRIPTION
 135
 136 When a Koha script runs, it makes use of a certain number of things:
 137 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 138 databases, and so forth. These things make up the I<context> in which
 139 the script runs.
 140
 141 This module takes care of setting up the context for a script:
 142 figuring out which configuration file to load, and loading it, opening
 143 a connection to the right database, and so forth.
 144
 145 Most scripts will only use one context. They can simply have
 146
 147   use C4::Context;
 148
 149 at the top.
 150
 151 Other scripts may need to use several contexts. For instance, if a
 152 library has two databases, one for a certain collection, and the other
 153 for everything else, it might be necessary for a script to use two
 154 different contexts to search both databases. Such scripts should use
 155 the C<&set_context> and C<&restore_context> functions, below.
 156
 157 By default, C4::Context reads the configuration from
 158 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 159 environment variable to the pathname of a configuration file to use.
 160
 161 =head1 METHODS
 162
 163 =cut
 164
 165 #'
 166 # In addition to what is said in the POD above, a Context object is a
 167 # reference-to-hash with the following fields:
 168 #
 169 # config
 170 #    A reference-to-hash whose keys and values are the
 171 #    configuration variables and values specified in the config
 172 #    file (/etc/koha/koha-conf.xml).
 173 # dbh
 174 #    A handle to the appropriate database for this context.
 175 # dbh_stack
 176 #    Used by &set_dbh and &restore_dbh to hold other database
 177 #    handles for this context.
 178 # Zconn
 179 #     A connection object for the Zebra server
 180
 181 # Koha's main configuration file koha-conf.xml
 182 # is searched for according to this priority list:
 183 #
 184 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 185 # 2. Path supplied in KOHA_CONF environment variable.
 186 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 187 #    as value has changed from its default of
 188 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 189 #    when Koha is installed in 'standard' or 'single'
 190 #    mode.
 191 # 4. Path supplied in CONFIG_FNAME.
 192 #
 193 # The first entry that refers to a readable file is used.
 194
 195 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 196                 # Default config file, if none is specified
 197
 198 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 199                 # path to config file set by installer
 200                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 201                 # when Koha is installed in 'standard' or 'single'
 202                 # mode.  If Koha was installed in 'dev' mode,
 203                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 204                 # developers should set the KOHA_CONF environment variable
 205
 206 $context = undef;        # Initially, no context is set
 207 @context_stack = ();        # Initially, no saved contexts
 208
 209
 210 =head2 read_config_file
 211
 212 Reads the specified Koha config file.
 213
 214 Returns an object containing the configuration variables. The object's
 215 structure is a bit complex to the uninitiated ... take a look at the
 216 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 217 here are a few examples that may give you what you need:
 218
 219 The simple elements nested within the <config> element:
 220
 221     my $pass = $koha->{'config'}->{'pass'};
 222
 223 The <listen> elements:
 224
 225     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 226
 227 The elements nested within the <server> element:
 228
 229     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 230
 231 Returns undef in case of error.
 232
 233 =cut
 234
 235 sub read_config_file {          # Pass argument naming config file to read
 236     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 237
 238     if ($ismemcached) {
 239       $memcached->set('kohaconf',$koha);
 240     }
 241
 242     return $koha;                       # Return value: ref-to-hash holding the configuration
 243 }
 244
 245 =head2 ismemcached
 246
 247 Returns the value of the $ismemcached variable (0/1)
 248
 249 =cut
 250
 251 sub ismemcached {
 252     return $ismemcached;
 253 }
 254
 255 =head2 memcached
 256
 257 If $ismemcached is true, returns the $memcache variable.
 258 Returns undef otherwise
 259
 260 =cut
 261
 262 sub memcached {
 263     if ($ismemcached) {
 264       return $memcached;
 265     } else {
 266       return;
 267     }
 268 }
 269
 270 =head2 db_scheme2dbi
 271
 272     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 273
 274 This routines translates a database type to part of the name
 275 of the appropriate DBD driver to use when establishing a new
 276 database connection.  It recognizes 'mysql' and 'Pg'; if any
 277 other scheme is supplied it defaults to 'mysql'.
 278
 279 =cut
 280
 281 sub db_scheme2dbi {
 282     my $scheme = shift // '';
 283     return $scheme eq 'Pg' ? $scheme : 'mysql';
 284 }
 285
 286 sub import {
 287     # Create the default context ($C4::Context::Context)
 288     # the first time the module is called
 289     # (a config file can be optionaly passed)
 290
 291     # default context allready exists?
 292     return if $context;
 293
 294     # no ? so load it!
 295     my ($pkg,$config_file) = @_ ;
 296     my $new_ctx = __PACKAGE__->new($config_file);
 297     return unless $new_ctx;
 298
 299     # if successfully loaded, use it by default
 300     $new_ctx->set_context;
 301     1;
 302 }
 303
 304 =head2 new
 305
 306   $context = new C4::Context;
 307   $context = new C4::Context("/path/to/koha-conf.xml");
 308
 309 Allocates a new context. Initializes the context from the specified
 310 file, which defaults to either the file given by the C<$KOHA_CONF>
 311 environment variable, or F</etc/koha/koha-conf.xml>.
 312
 313 It saves the koha-conf.xml values in the declared memcached server(s)
 314 if currently available and uses those values until them expire and
 315 re-reads them.
 316
 317 C<&new> does not set this context as the new default context; for
 318 that, use C<&set_context>.
 319
 320 =cut
 321
 322 #'
 323 # Revision History:
 324 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 325 sub new {
 326     my $class = shift;
 327     my $conf_fname = shift;        # Config file to load
 328     my $self = {};
 329
 330     # check that the specified config file exists and is not empty
 331     undef $conf_fname unless
 332         (defined $conf_fname && -s $conf_fname);
 333     # Figure out a good config file to load if none was specified.
 334     if (!defined($conf_fname))
 335     {
 336         # If the $KOHA_CONF environment variable is set, use
 337         # that. Otherwise, use the built-in default.
 338         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 339             $conf_fname = $ENV{"KOHA_CONF"};
 340         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 341             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 342             # regex to anything else -- don't want installer to rewrite it
 343             $conf_fname = $INSTALLED_CONFIG_FNAME;
 344         } elsif (-s CONFIG_FNAME) {
 345             $conf_fname = CONFIG_FNAME;
 346         } else {
 347             warn "unable to locate Koha configuration file koha-conf.xml";
 348             return;
 349         }
 350     }
 351
 352     if ($ismemcached) {
 353         # retreive from memcached
 354         $self = $memcached->get('kohaconf');
 355         if (not defined $self) {
 356             # not in memcached yet
 357             $self = read_config_file($conf_fname);
 358         }
 359     } else {
 360         # non-memcached env, read from file
 361         $self = read_config_file($conf_fname);
 362     }
 363
 364     $self->{"config_file"} = $conf_fname;
 365     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 366     return if !defined($self->{"config"});
 367
 368     $self->{"dbh"} = undef;        # Database handle
 369     $self->{"Zconn"} = undef;    # Zebra Connections
 370     $self->{"stopwords"} = undef; # stopwords list
 371     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 372     $self->{"userenv"} = undef;        # User env
 373     $self->{"activeuser"} = undef;        # current active user
 374     $self->{"shelves"} = undef;
 375     $self->{tz} = undef; # local timezone object
 376
 377     bless $self, $class;
 378     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 379     return $self;
 380 }
 381
 382 =head2 set_context
 383
 384   $context = new C4::Context;
 385   $context->set_context();
 386 or
 387   set_context C4::Context $context;
 388
 389   ...
 390   restore_context C4::Context;
 391
 392 In some cases, it might be necessary for a script to use multiple
 393 contexts. C<&set_context> saves the current context on a stack, then
 394 sets the context to C<$context>, which will be used in future
 395 operations. To restore the previous context, use C<&restore_context>.
 396
 397 =cut
 398
 399 #'
 400 sub set_context
 401 {
 402     my $self = shift;
 403     my $new_context;    # The context to set
 404
 405     # Figure out whether this is a class or instance method call.
 406     #
 407     # We're going to make the assumption that control got here
 408     # through valid means, i.e., that the caller used an instance
 409     # or class method call, and that control got here through the
 410     # usual inheritance mechanisms. The caller can, of course,
 411     # break this assumption by playing silly buggers, but that's
 412     # harder to do than doing it properly, and harder to check
 413     # for.
 414     if (ref($self) eq "")
 415     {
 416         # Class method. The new context is the next argument.
 417         $new_context = shift;
 418     } else {
 419         # Instance method. The new context is $self.
 420         $new_context = $self;
 421     }
 422
 423     # Save the old context, if any, on the stack
 424     push @context_stack, $context if defined($context);
 425
 426     # Set the new context
 427     $context = $new_context;
 428 }
 429
 430 =head2 restore_context
 431
 432   &restore_context;
 433
 434 Restores the context set by C<&set_context>.
 435
 436 =cut
 437
 438 #'
 439 sub restore_context
 440 {
 441     my $self = shift;
 442
 443     if ($#context_stack < 0)
 444     {
 445         # Stack underflow.
 446         die "Context stack underflow";
 447     }
 448
 449     # Pop the old context and set it.
 450     $context = pop @context_stack;
 451
 452     # FIXME - Should this return something, like maybe the context
 453     # that was current when this was called?
 454 }
 455
 456 =head2 config
 457
 458   $value = C4::Context->config("config_variable");
 459
 460   $value = C4::Context->config_variable;
 461
 462 Returns the value of a variable specified in the configuration file
 463 from which the current context was created.
 464
 465 The second form is more compact, but of course may conflict with
 466 method names. If there is a configuration variable called "new", then
 467 C<C4::Config-E<gt>new> will not return it.
 468
 469 =cut
 470
 471 sub _common_config {
 472         my $var = shift;
 473         my $term = shift;
 474     return if !defined($context->{$term});
 475        # Presumably $self->{$term} might be
 476        # undefined if the config file given to &new
 477        # didn't exist, and the caller didn't bother
 478        # to check the return value.
 479
 480     # Return the value of the requested config variable
 481     return $context->{$term}->{$var};
 482 }
 483
 484 sub config {
 485         return _common_config($_[1],'config');
 486 }
 487 sub zebraconfig {
 488         return _common_config($_[1],'server');
 489 }
 490 sub ModZebrations {
 491         return _common_config($_[1],'serverinfo');
 492 }
 493
 494 =head2 preference
 495
 496   $sys_preference = C4::Context->preference('some_variable');
 497
 498 Looks up the value of the given system preference in the
 499 systempreferences table of the Koha database, and returns it. If the
 500 variable is not set or does not exist, undef is returned.
 501
 502 In case of an error, this may return 0.
 503
 504 Note: It is impossible to tell the difference between system
 505 preferences which do not exist, and those whose values are set to NULL
 506 with this method.
 507
 508 =cut
 509
 510 # FIXME: running this under mod_perl will require a means of
 511 # flushing the caching mechanism.
 512
 513 my %sysprefs;
 514 my $use_syspref_cache = 1;
 515
 516 sub preference {
 517     my $self = shift;
 518     my $var  = shift;    # The system preference to return
 519
 520     if ($use_syspref_cache && exists $sysprefs{lc $var}) {
 521         return $sysprefs{lc $var};
 522     }
 523
 524     my $dbh  = C4::Context->dbh or return 0;
 525
 526     my $value;
 527     if ( defined $ENV{"OVERRIDE_SYSPREF_$var"} ) {
 528         $value = $ENV{"OVERRIDE_SYSPREF_$var"};
 529     } else {
 530         my $syspref = Koha::Config::SysPrefs->find( lc $var );
 531         $value = $syspref ? $syspref->value() : undef;
 532     }
 533
 534     $sysprefs{lc $var} = $value;
 535     return $value;
 536 }
 537
 538 sub boolean_preference {
 539     my $self = shift;
 540     my $var = shift;        # The system preference to return
 541     my $it = preference($self, $var);
 542     return defined($it)? C4::Boolean::true_p($it): undef;
 543 }
 544
 545 =head2 enable_syspref_cache
 546
 547   C4::Context->enable_syspref_cache();
 548
 549 Enable the in-memory syspref cache used by C4::Context. This is the
 550 default behavior.
 551
 552 =cut
 553
 554 sub enable_syspref_cache {
 555     my ($self) = @_;
 556     $use_syspref_cache = 1;
 557 }
 558
 559 =head2 disable_syspref_cache
 560
 561   C4::Context->disable_syspref_cache();
 562
 563 Disable the in-memory syspref cache used by C4::Context. This should be
 564 used with Plack and other persistent environments.
 565
 566 =cut
 567
 568 sub disable_syspref_cache {
 569     my ($self) = @_;
 570     $use_syspref_cache = 0;
 571     $self->clear_syspref_cache();
 572 }
 573
 574 =head2 clear_syspref_cache
 575
 576   C4::Context->clear_syspref_cache();
 577
 578 cleans the internal cache of sysprefs. Please call this method if
 579 you update the systempreferences table. Otherwise, your new changes
 580 will not be seen by this process.
 581
 582 =cut
 583
 584 sub clear_syspref_cache {
 585     %sysprefs = ();
 586 }
 587
 588 =head2 set_preference
 589
 590   C4::Context->set_preference( $variable, $value );
 591
 592 This updates a preference's value both in the systempreferences table and in
 593 the sysprefs cache.
 594
 595 =cut
 596
 597 sub set_preference {
 598     my $self = shift;
 599     my $var = lc(shift);
 600     my $value = shift;
 601
 602     my $syspref = Koha::Config::SysPrefs->find( $var );
 603     my $type = $syspref ? $syspref->type() : undef;
 604
 605     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 606
 607     if ($syspref) {
 608         $syspref = $syspref->set( { value => $value } )->store();
 609     }
 610     else {
 611         $syspref = Koha::Config::SysPref->new( { variable => $var, value => $value } )->store();
 612     }
 613
 614     if ($syspref) {
 615         $sysprefs{$var} = $value;
 616     }
 617 }
 618
 619 # AUTOLOAD
 620 # This implements C4::Config->foo, and simply returns
 621 # C4::Context->config("foo"), as described in the documentation for
 622 # &config, above.
 623
 624 # FIXME - Perhaps this should be extended to check &config first, and
 625 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 626 # code, so it'd probably be best to delete it altogether so as not to
 627 # encourage people to use it.
 628 sub AUTOLOAD
 629 {
 630     my $self = shift;
 631
 632     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 633                     # leaving only the function name.
 634     return $self->config($AUTOLOAD);
 635 }
 636
 637 =head2 Zconn
 638
 639   $Zconn = C4::Context->Zconn
 640
 641 Returns a connection to the Zebra database
 642
 643 C<$self>
 644
 645 C<$server> one of the servers defined in the koha-conf.xml file
 646
 647 C<$async> whether this is a asynchronous connection
 648
 649 =cut
 650
 651 sub Zconn {
 652     my ($self, $server, $async ) = @_;
 653     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 654     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 655         # if we are running the script from the commandline, lets try to use the caching
 656         return $context->{"Zconn"}->{$cache_key};
 657     }
 658     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 659     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 660     return $context->{"Zconn"}->{$cache_key};
 661 }
 662
 663 =head2 _new_Zconn
 664
 665 $context->{"Zconn"} = &_new_Zconn($server,$async);
 666
 667 Internal function. Creates a new database connection from the data given in the current context and returns it.
 668
 669 C<$server> one of the servers defined in the koha-conf.xml file
 670
 671 C<$async> whether this is a asynchronous connection
 672
 673 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 674
 675 =cut
 676
 677 sub _new_Zconn {
 678     my ( $server, $async ) = @_;
 679
 680     my $tried=0; # first attempt
 681     my $Zconn; # connection object
 682     my $elementSetName;
 683     my $index_mode;
 684     my $syntax;
 685
 686     $server //= "biblioserver";
 687
 688     if ( $server eq 'biblioserver' ) {
 689         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'dom';
 690     } elsif ( $server eq 'authorityserver' ) {
 691         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 692     }
 693
 694     if ( $index_mode eq 'grs1' ) {
 695         $elementSetName = 'F';
 696         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 697                 ? 'unimarc'
 698                 : 'usmarc';
 699
 700     } else { # $index_mode eq 'dom'
 701         $syntax = 'xml';
 702         $elementSetName = 'marcxml';
 703     }
 704
 705     my $host = $context->{'listen'}->{$server}->{'content'};
 706     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 707     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 708     eval {
 709         # set options
 710         my $o = new ZOOM::Options();
 711         $o->option(user => $user) if $user && $password;
 712         $o->option(password => $password) if $user && $password;
 713         $o->option(async => 1) if $async;
 714         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 715         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 716         $o->option(preferredRecordSyntax => $syntax);
 717         $o->option(elementSetName => $elementSetName) if $elementSetName;
 718         $o->option(databaseName => $context->{"config"}->{$server}||"biblios");
 719
 720         # create a new connection object
 721         $Zconn= create ZOOM::Connection($o);
 722
 723         # forge to server
 724         $Zconn->connect($host, 0);
 725
 726         # check for errors and warn
 727         if ($Zconn->errcode() !=0) {
 728             warn "something wrong with the connection: ". $Zconn->errmsg();
 729         }
 730     };
 731     return $Zconn;
 732 }
 733
 734 # _new_dbh
 735 # Internal helper function (not a method!). This creates a new
 736 # database connection from the data given in the current context, and
 737 # returns it.
 738 sub _new_dbh
 739 {
 740
 741     ## $context
 742     ## correct name for db_scheme
 743     my $db_driver = $context->{db_driver};
 744
 745     my $db_name   = $context->config("database");
 746     my $db_host   = $context->config("hostname");
 747     my $db_port   = $context->config("port") || '';
 748     my $db_user   = $context->config("user");
 749     my $db_passwd = $context->config("pass");
 750     # MJR added or die here, as we can't work without dbh
 751     my $dbh = DBIx::Connector->connect(
 752         "dbi:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 753         $db_user, $db_passwd,
 754         {
 755             'RaiseError' => $ENV{DEBUG} ? 1 : 0
 756         }
 757     );
 758
 759     # Check for the existence of a systempreference table; if we don't have this, we don't
 760     # have a valid database and should not set RaiseError in order to allow the installer
 761     # to run; installer will not run otherwise since we raise all db errors
 762
 763     eval {
 764                 local $dbh->{PrintError} = 0;
 765                 local $dbh->{RaiseError} = 1;
 766                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 767     };
 768
 769     if ($@) {
 770         $dbh->{RaiseError} = 0;
 771     }
 772
 773     if ( $db_driver eq 'mysql' ) {
 774         $dbh->{mysql_auto_reconnect} = 1;
 775     }
 776
 777         my $tz = $ENV{TZ};
 778     if ( $db_driver eq 'mysql' ) {
 779         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 780         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 781         $dbh->{'mysql_enable_utf8'}=1; #enable
 782         $dbh->do("set NAMES 'utf8'");
 783         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 784     }
 785     elsif ( $db_driver eq 'Pg' ) {
 786             $dbh->do( "set client_encoding = 'UTF8';" );
 787         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 788     }
 789     return $dbh;
 790 }
 791
 792 =head2 dbh
 793
 794   $dbh = C4::Context->dbh;
 795
 796 Returns a database handle connected to the Koha database for the
 797 current context. If no connection has yet been made, this method
 798 creates one, and connects to the database.
 799
 800 This database handle is cached for future use: if you call
 801 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 802 times. If you need a second database handle, use C<&new_dbh> and
 803 possibly C<&set_dbh>.
 804
 805 =cut
 806
 807 #'
 808 sub dbh
 809 {
 810     my $self = shift;
 811     my $params = shift;
 812     my $sth;
 813
 814     unless ( $params->{new} ) {
 815         if ( defined($context->{db_driver}) && $context->{db_driver} eq 'mysql' && $context->{"dbh"} ) {
 816             return $context->{"dbh"};
 817         } elsif ( defined($context->{"dbh"}) && $context->{"dbh"}->ping() ) {
 818             return $context->{"dbh"};
 819         }
 820     }
 821
 822     # No database handle or it died . Create one.
 823     $context->{"dbh"} = &_new_dbh();
 824
 825     return $context->{"dbh"};
 826 }
 827
 828 =head2 new_dbh
 829
 830   $dbh = C4::Context->new_dbh;
 831
 832 Creates a new connection to the Koha database for the current context,
 833 and returns the database handle (a C<DBI::db> object).
 834
 835 The handle is not saved anywhere: this method is strictly a
 836 convenience function; the point is that it knows which database to
 837 connect to so that the caller doesn't have to know.
 838
 839 =cut
 840
 841 #'
 842 sub new_dbh
 843 {
 844     my $self = shift;
 845
 846     return &_new_dbh();
 847 }
 848
 849 =head2 set_dbh
 850
 851   $my_dbh = C4::Connect->new_dbh;
 852   C4::Connect->set_dbh($my_dbh);
 853   ...
 854   C4::Connect->restore_dbh;
 855
 856 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 857 C<&set_context> and C<&restore_context>.
 858
 859 C<&set_dbh> saves the current database handle on a stack, then sets
 860 the current database handle to C<$my_dbh>.
 861
 862 C<$my_dbh> is assumed to be a good database handle.
 863
 864 =cut
 865
 866 #'
 867 sub set_dbh
 868 {
 869     my $self = shift;
 870     my $new_dbh = shift;
 871
 872     # Save the current database handle on the handle stack.
 873     # We assume that $new_dbh is all good: if the caller wants to
 874     # screw himself by passing an invalid handle, that's fine by
 875     # us.
 876     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 877     $context->{"dbh"} = $new_dbh;
 878 }
 879
 880 =head2 restore_dbh
 881
 882   C4::Context->restore_dbh;
 883
 884 Restores the database handle saved by an earlier call to
 885 C<C4::Context-E<gt>set_dbh>.
 886
 887 =cut
 888
 889 #'
 890 sub restore_dbh
 891 {
 892     my $self = shift;
 893
 894     if ($#{$context->{"dbh_stack"}} < 0)
 895     {
 896         # Stack underflow
 897         die "DBH stack underflow";
 898     }
 899
 900     # Pop the old database handle and set it.
 901     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 902
 903     # FIXME - If it is determined that restore_context should
 904     # return something, then this function should, too.
 905 }
 906
 907 =head2 queryparser
 908
 909   $queryparser = C4::Context->queryparser
 910
 911 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 912
 913 =cut
 914
 915 sub queryparser {
 916     my $self = shift;
 917     unless (defined $context->{"queryparser"}) {
 918         $context->{"queryparser"} = &_new_queryparser();
 919     }
 920
 921     return
 922       defined( $context->{"queryparser"} )
 923       ? $context->{"queryparser"}->new
 924       : undef;
 925 }
 926
 927 =head2 _new_queryparser
 928
 929 Internal helper function to create a new QueryParser object. QueryParser
 930 is loaded dynamically so as to keep the lack of the QueryParser library from
 931 getting in anyone's way.
 932
 933 =cut
 934
 935 sub _new_queryparser {
 936     my $qpmodules = {
 937         'OpenILS::QueryParser'           => undef,
 938         'Koha::QueryParser::Driver::PQF' => undef
 939     };
 940     if ( can_load( 'modules' => $qpmodules ) ) {
 941         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 942         my $config_file = $context->config('queryparser_config');
 943         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 944         if ( $QParser->load_config($config_file) ) {
 945             # Set 'keyword' as the default search class
 946             $QParser->default_search_class('keyword');
 947             # TODO: allow indexes to be configured in the database
 948             return $QParser;
 949         }
 950     }
 951     return;
 952 }
 953
 954 =head2 marcfromkohafield
 955
 956   $dbh = C4::Context->marcfromkohafield;
 957
 958 Returns a hash with marcfromkohafield.
 959
 960 This hash is cached for future use: if you call
 961 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
 962
 963 =cut
 964
 965 #'
 966 sub marcfromkohafield
 967 {
 968     my $retval = {};
 969
 970     # If the hash already exists, return it.
 971     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
 972
 973     # No hash. Create one.
 974     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
 975
 976     return $context->{"marcfromkohafield"};
 977 }
 978
 979 # _new_marcfromkohafield
 980 # Internal helper function (not a method!). This creates a new
 981 # hash with stopwords
 982 sub _new_marcfromkohafield
 983 {
 984     my $dbh = C4::Context->dbh;
 985     my $marcfromkohafield;
 986     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
 987     $sth->execute;
 988     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
 989         my $retval = {};
 990         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
 991     }
 992     return $marcfromkohafield;
 993 }
 994
 995 =head2 stopwords
 996
 997   $dbh = C4::Context->stopwords;
 998
 999 Returns a hash with stopwords.
1000
1001 This hash is cached for future use: if you call
1002 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
1003
1004 =cut
1005
1006 #'
1007 sub stopwords
1008 {
1009     my $retval = {};
1010
1011     # If the hash already exists, return it.
1012     return $context->{"stopwords"} if defined($context->{"stopwords"});
1013
1014     # No hash. Create one.
1015     $context->{"stopwords"} = &_new_stopwords();
1016
1017     return $context->{"stopwords"};
1018 }
1019
1020 # _new_stopwords
1021 # Internal helper function (not a method!). This creates a new
1022 # hash with stopwords
1023 sub _new_stopwords
1024 {
1025     my $dbh = C4::Context->dbh;
1026     my $stopwordlist;
1027     my $sth = $dbh->prepare("select word from stopwords");
1028     $sth->execute;
1029     while (my $stopword = $sth->fetchrow_array) {
1030         $stopwordlist->{$stopword} = uc($stopword);
1031     }
1032     $stopwordlist->{A} = "A" unless $stopwordlist;
1033     return $stopwordlist;
1034 }
1035
1036 =head2 userenv
1037
1038   C4::Context->userenv;
1039
1040 Retrieves a hash for user environment variables.
1041
1042 This hash shall be cached for future use: if you call
1043 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1044
1045 =cut
1046
1047 #'
1048 sub userenv {
1049     my $var = $context->{"activeuser"};
1050     if (defined $var and defined $context->{"userenv"}->{$var}) {
1051         return $context->{"userenv"}->{$var};
1052     } else {
1053         return;
1054     }
1055 }
1056
1057 =head2 set_userenv
1058
1059   C4::Context->set_userenv($usernum, $userid, $usercnum,
1060                            $userfirstname, $usersurname,
1061                            $userbranch, $branchname, $userflags,
1062                            $emailaddress, $branchprinter, $persona);
1063
1064 Establish a hash of user environment variables.
1065
1066 set_userenv is called in Auth.pm
1067
1068 =cut
1069
1070 #'
1071 sub set_userenv {
1072     shift @_;
1073     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona, $shibboleth)=
1074     map { Encode::is_utf8( $_ ) ? $_ : Encode::decode('UTF-8', $_) } # CGI::Session doesn't handle utf-8, so we decode it here
1075     @_;
1076     my $var=$context->{"activeuser"} || '';
1077     my $cell = {
1078         "number"     => $usernum,
1079         "id"         => $userid,
1080         "cardnumber" => $usercnum,
1081         "firstname"  => $userfirstname,
1082         "surname"    => $usersurname,
1083         #possibly a law problem
1084         "branch"     => $userbranch,
1085         "branchname" => $branchname,
1086         "flags"      => $userflags,
1087         "emailaddress"     => $emailaddress,
1088         "branchprinter"    => $branchprinter,
1089         "persona"    => $persona,
1090         "shibboleth" => $shibboleth,
1091     };
1092     $context->{userenv}->{$var} = $cell;
1093     return $cell;
1094 }
1095
1096 sub set_shelves_userenv {
1097         my ($type, $shelves) = @_ or return;
1098         my $activeuser = $context->{activeuser} or return;
1099         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1100         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1101         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1102 }
1103
1104 sub get_shelves_userenv {
1105         my $active;
1106         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1107                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1108                 return;
1109         }
1110         my $totshelves = $active->{totshelves} or undef;
1111         my $pubshelves = $active->{pubshelves} or undef;
1112         my $barshelves = $active->{barshelves} or undef;
1113         return ($totshelves, $pubshelves, $barshelves);
1114 }
1115
1116 =head2 _new_userenv
1117
1118   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1119
1120 Builds a hash for user environment variables.
1121
1122 This hash shall be cached for future use: if you call
1123 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1124
1125 _new_userenv is called in Auth.pm
1126
1127 =cut
1128
1129 #'
1130 sub _new_userenv
1131 {
1132     shift;  # Useless except it compensates for bad calling style
1133     my ($sessionID)= @_;
1134      $context->{"activeuser"}=$sessionID;
1135 }
1136
1137 =head2 _unset_userenv
1138
1139   C4::Context->_unset_userenv;
1140
1141 Destroys the hash for activeuser user environment variables.
1142
1143 =cut
1144
1145 #'
1146
1147 sub _unset_userenv
1148 {
1149     my ($sessionID)= @_;
1150     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1151 }
1152
1153
1154 =head2 get_versions
1155
1156   C4::Context->get_versions
1157
1158 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1159
1160 =cut
1161
1162 #'
1163
1164 # A little example sub to show more debugging info for CGI::Carp
1165 sub get_versions {
1166     my %versions;
1167     $versions{kohaVersion}  = Koha::version();
1168     $versions{kohaDbVersion} = C4::Context->preference('version');
1169     $versions{osVersion} = join(" ", POSIX::uname());
1170     $versions{perlVersion} = $];
1171     {
1172         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1173         $versions{mysqlVersion}  = `mysql -V`;
1174         $versions{apacheVersion} = `httpd -v`;
1175         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1176         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1177         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1178     }
1179     return %versions;
1180 }
1181
1182
1183 =head2 tz
1184
1185   C4::Context->tz
1186
1187   Returns a DateTime::TimeZone object for the system timezone
1188
1189 =cut
1190
1191 sub tz {
1192     my $self = shift;
1193     if (!defined $context->{tz}) {
1194         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1195     }
1196     return $context->{tz};
1197 }
1198
1199
1200 =head2 IsSuperLibrarian
1201
1202     C4::Context->IsSuperlibrarian();
1203
1204 =cut
1205
1206 sub IsSuperLibrarian {
1207     my $userenv = C4::Context->userenv;
1208
1209     unless ( $userenv and exists $userenv->{flags} ) {
1210         # If we reach this without a user environment,
1211         # assume that we're running from a command-line script,
1212         # and act as a superlibrarian.
1213         carp("C4::Context->userenv not defined!");
1214         return 1;
1215     }
1216
1217     return ($userenv->{flags}//0) % 2;
1218 }
1219
1220 =head2 interface
1221
1222 Sets the current interface for later retrieval in any Perl module
1223
1224     C4::Context->interface('opac');
1225     C4::Context->interface('intranet');
1226     my $interface = C4::Context->interface;
1227
1228 =cut
1229
1230 sub interface {
1231     my ($class, $interface) = @_;
1232
1233     if (defined $interface) {
1234         $interface = lc $interface;
1235         if ($interface eq 'opac' || $interface eq 'intranet') {
1236             $context->{interface} = $interface;
1237         } else {
1238             warn "invalid interface : '$interface'";
1239         }
1240     }
1241
1242     return $context->{interface} // 'opac';
1243 }
1244
1245 1;
1246 __END__
1247
1248 =head1 ENVIRONMENT
1249
1250 =head2 C<KOHA_CONF>
1251
1252 Specifies the configuration file to read.
1253
1254 =head1 SEE ALSO
1255
1256 XML::Simple
1257
1258 =head1 AUTHORS
1259
1260 Andrew Arensburger <arensb at ooblick dot com>
1261
1262 Joshua Ferraro <jmf at liblime dot com>
1263