C4/HoldsQueue.pm

   1 package C4::HoldsQueue;
   2
   3 # Copyright 2011 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # FIXME: expand perldoc, explain intended logic
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Context;
  26 use C4::Search;
  27 use C4::Items;
  28 use C4::Circulation;
  29 use C4::Members;
  30 use C4::Biblio;
  31 use Koha::DateUtils;
  32 use Koha::Items;
  33 use Koha::Patrons;
  34
  35 use List::Util qw(shuffle);
  36 use List::MoreUtils qw(any);
  37 use Data::Dumper;
  38
  39 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  40 BEGIN {
  41     require Exporter;
  42     @ISA = qw(Exporter);
  43     @EXPORT_OK = qw(
  44         &CreateQueue
  45         &GetHoldsQueueItems
  46
  47         &TransportCostMatrix
  48         &UpdateTransportCostMatrix
  49      );
  50 }
  51
  52
  53 =head1 FUNCTIONS
  54
  55 =head2 TransportCostMatrix
  56
  57   TransportCostMatrix();
  58
  59 Returns Transport Cost Matrix as a hashref <to branch code> => <from branch code> => cost
  60
  61 =cut
  62
  63 sub TransportCostMatrix {
  64     my $dbh   = C4::Context->dbh;
  65     my $transport_costs = $dbh->selectall_arrayref("SELECT * FROM transport_cost",{ Slice => {} });
  66
  67     my $today = dt_from_string();
  68     my $calendars;
  69     my %transport_cost_matrix;
  70     foreach (@$transport_costs) {
  71         my $from     = $_->{frombranch};
  72         my $to       = $_->{tobranch};
  73         my $cost     = $_->{cost};
  74         my $disabled = $_->{disable_transfer};
  75         $transport_cost_matrix{$to}{$from} = {
  76             cost             => $cost,
  77             disable_transfer => $disabled
  78         };
  79
  80         if ( C4::Context->preference("HoldsQueueSkipClosed") ) {
  81             $calendars->{$from} ||= Koha::Calendar->new( branchcode => $from );
  82             $transport_cost_matrix{$to}{$from}{disable_transfer} ||=
  83               $calendars->{$from}->is_holiday( $today );
  84         }
  85
  86     }
  87     return \%transport_cost_matrix;
  88 }
  89
  90 =head2 UpdateTransportCostMatrix
  91
  92   UpdateTransportCostMatrix($records);
  93
  94 Updates full Transport Cost Matrix table. $records is an arrayref of records.
  95 Records: { frombranch => <code>, tobranch => <code>, cost => <figure>, disable_transfer => <0,1> }
  96
  97 =cut
  98
  99 sub UpdateTransportCostMatrix {
 100     my ($records) = @_;
 101     my $dbh   = C4::Context->dbh;
 102
 103     my $sth = $dbh->prepare("INSERT INTO transport_cost (frombranch, tobranch, cost, disable_transfer) VALUES (?, ?, ?, ?)");
 104
 105     $dbh->do("DELETE FROM transport_cost");
 106     foreach (@$records) {
 107         my $cost = $_->{cost};
 108         my $from = $_->{frombranch};
 109         my $to = $_->{tobranch};
 110         if ($_->{disable_transfer}) {
 111             $cost ||= 0;
 112         }
 113         elsif ( !defined ($cost) || ($cost !~ m/(0|[1-9][0-9]*)(\.[0-9]*)?/o) ) {
 114             warn  "Invalid $from -> $to cost $cost - must be a number >= 0, disabling";
 115             $cost = 0;
 116             $_->{disable_transfer} = 1;
 117         }
 118         $sth->execute( $from, $to, $cost, $_->{disable_transfer} ? 1 : 0 );
 119     }
 120 }
 121
 122 =head2 GetHoldsQueueItems
 123
 124   GetHoldsQueueItems($branch);
 125
 126 Returns hold queue for a holding branch. If branch is omitted, then whole queue is returned
 127
 128 =cut
 129
 130 sub GetHoldsQueueItems {
 131     my ($branchlimit) = @_;
 132     my $dbh   = C4::Context->dbh;
 133
 134     my @bind_params = ();
 135     my $query = q/SELECT tmp_holdsqueue.*, biblio.author, items.ccode, items.itype, biblioitems.itemtype, items.location,
 136                          items.enumchron, items.cn_sort, biblioitems.publishercode,
 137                          biblio.copyrightdate, biblio.subtitle, biblio.medium,
 138                          biblio.part_number, biblio.part_name,
 139                          biblioitems.publicationyear, biblioitems.pages, biblioitems.size,
 140                          biblioitems.isbn, items.copynumber
 141                   FROM tmp_holdsqueue
 142                        JOIN biblio      USING (biblionumber)
 143                   LEFT JOIN biblioitems USING (biblionumber)
 144                   LEFT JOIN items       USING (  itemnumber)
 145                 /;
 146     if ($branchlimit) {
 147         $query .=" WHERE tmp_holdsqueue.holdingbranch = ?";
 148         push @bind_params, $branchlimit;
 149     }
 150     $query .= " ORDER BY ccode, location, cn_sort, author, title, pickbranch, reservedate";
 151     my $sth = $dbh->prepare($query);
 152     $sth->execute(@bind_params);
 153     my $items = [];
 154     while ( my $row = $sth->fetchrow_hashref ){
 155         # return the bib-level or item-level itype per syspref
 156         if (!C4::Context->preference('item-level_itypes')) {
 157             $row->{itype} = $row->{itemtype};
 158         }
 159         delete $row->{itemtype};
 160
 161         push @$items, $row;
 162     }
 163     return $items;
 164 }
 165
 166 =head2 CreateQueue
 167
 168   CreateQueue();
 169
 170 Top level function that turns reserves into tmp_holdsqueue and hold_fill_targets.
 171
 172 =cut
 173
 174 sub CreateQueue {
 175     my $dbh   = C4::Context->dbh;
 176
 177     $dbh->do("DELETE FROM tmp_holdsqueue");  # clear the old table for new info
 178     $dbh->do("DELETE FROM hold_fill_targets");
 179
 180     my $total_bibs            = 0;
 181     my $total_requests        = 0;
 182     my $total_available_items = 0;
 183     my $num_items_mapped      = 0;
 184
 185     my $branches_to_use;
 186     my $transport_cost_matrix;
 187     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
 188     if ($use_transport_cost_matrix) {
 189         $transport_cost_matrix = TransportCostMatrix();
 190         unless (keys %$transport_cost_matrix) {
 191             warn "UseTransportCostMatrix set to yes, but matrix not populated";
 192             undef $transport_cost_matrix;
 193         }
 194     }
 195     unless ($transport_cost_matrix) {
 196         $branches_to_use = load_branches_to_pull_from();
 197     }
 198
 199     my $bibs_with_pending_requests = GetBibsWithPendingHoldRequests();
 200
 201     foreach my $biblionumber (@$bibs_with_pending_requests) {
 202         $total_bibs++;
 203         my $hold_requests   = GetPendingHoldRequestsForBib($biblionumber);
 204         my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_to_use);
 205         $total_requests        += scalar(@$hold_requests);
 206         $total_available_items += scalar(@$available_items);
 207
 208         my $item_map = MapItemsToHoldRequests($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix);
 209         $item_map  or next;
 210         my $item_map_size = scalar(keys %$item_map)
 211           or next;
 212
 213         $num_items_mapped += $item_map_size;
 214         CreatePicklistFromItemMap($item_map);
 215         AddToHoldTargetMap($item_map);
 216         if (($item_map_size < scalar(@$hold_requests  )) and
 217             ($item_map_size < scalar(@$available_items))) {
 218             # DOUBLE CHECK, but this is probably OK - unfilled item-level requests
 219             # FIXME
 220             #warn "unfilled requests for $biblionumber";
 221             #warn Dumper($hold_requests), Dumper($available_items), Dumper($item_map);
 222         }
 223     }
 224 }
 225
 226 =head2 GetBibsWithPendingHoldRequests
 227
 228   my $biblionumber_aref = GetBibsWithPendingHoldRequests();
 229
 230 Return an arrayref of the biblionumbers of all bibs
 231 that have one or more unfilled hold requests.
 232
 233 =cut
 234
 235 sub GetBibsWithPendingHoldRequests {
 236     my $dbh = C4::Context->dbh;
 237
 238     my $bib_query = "SELECT DISTINCT biblionumber
 239                      FROM reserves
 240                      WHERE found IS NULL
 241                      AND priority > 0
 242                      AND reservedate <= CURRENT_DATE()
 243                      AND suspend = 0
 244                      ";
 245     my $sth = $dbh->prepare($bib_query);
 246
 247     $sth->execute();
 248     my $biblionumbers = $sth->fetchall_arrayref();
 249
 250     return [ map { $_->[0] } @$biblionumbers ];
 251 }
 252
 253 =head2 GetPendingHoldRequestsForBib
 254
 255   my $requests = GetPendingHoldRequestsForBib($biblionumber);
 256
 257 Returns an arrayref of hashrefs to pending, unfilled hold requests
 258 on the bib identified by $biblionumber.  The following keys
 259 are present in each hashref:
 260
 261     biblionumber
 262     borrowernumber
 263     itemnumber
 264     priority
 265     branchcode
 266     reservedate
 267     reservenotes
 268     borrowerbranch
 269
 270 The arrayref is sorted in order of increasing priority.
 271
 272 =cut
 273
 274 sub GetPendingHoldRequestsForBib {
 275     my $biblionumber = shift;
 276
 277     my $dbh = C4::Context->dbh;
 278
 279     my $request_query = "SELECT biblionumber, borrowernumber, itemnumber, priority, reserves.branchcode,
 280                                 reservedate, reservenotes, borrowers.branchcode AS borrowerbranch, itemtype
 281                          FROM reserves
 282                          JOIN borrowers USING (borrowernumber)
 283                          WHERE biblionumber = ?
 284                          AND found IS NULL
 285                          AND priority > 0
 286                          AND reservedate <= CURRENT_DATE()
 287                          AND suspend = 0
 288                          ORDER BY priority";
 289     my $sth = $dbh->prepare($request_query);
 290     $sth->execute($biblionumber);
 291
 292     my $requests = $sth->fetchall_arrayref({});
 293     return $requests;
 294
 295 }
 296
 297 =head2 GetItemsAvailableToFillHoldRequestsForBib
 298
 299   my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_ar);
 300
 301 Returns an arrayref of items available to fill hold requests
 302 for the bib identified by C<$biblionumber>.  An item is available
 303 to fill a hold request if and only if:
 304
 305     * it is not on loan
 306     * it is not withdrawn
 307     * it is not marked notforloan
 308     * it is not currently in transit
 309     * it is not lost
 310     * it is not sitting on the hold shelf
 311     * it is not damaged (unless AllowHoldsOnDamagedItems is on)
 312
 313 =cut
 314
 315 sub GetItemsAvailableToFillHoldRequestsForBib {
 316     my ($biblionumber, $branches_to_use) = @_;
 317
 318     my $dbh = C4::Context->dbh;
 319     my $items_query = "SELECT itemnumber, homebranch, holdingbranch, itemtypes.itemtype AS itype
 320                        FROM items ";
 321
 322     if (C4::Context->preference('item-level_itypes')) {
 323         $items_query .=   "LEFT JOIN itemtypes ON (itemtypes.itemtype = items.itype) ";
 324     } else {
 325         $items_query .=   "JOIN biblioitems USING (biblioitemnumber)
 326                            LEFT JOIN itemtypes USING (itemtype) ";
 327     }
 328     $items_query .=   "WHERE items.notforloan = 0
 329                        AND holdingbranch IS NOT NULL
 330                        AND itemlost = 0
 331                        AND withdrawn = 0";
 332     $items_query .= "  AND damaged = 0" unless C4::Context->preference('AllowHoldsOnDamagedItems');
 333     $items_query .= "  AND items.onloan IS NULL
 334                        AND (itemtypes.notforloan IS NULL OR itemtypes.notforloan = 0)
 335                        AND itemnumber NOT IN (
 336                            SELECT itemnumber
 337                            FROM reserves
 338                            WHERE biblionumber = ?
 339                            AND itemnumber IS NOT NULL
 340                            AND (found IS NOT NULL OR priority = 0)
 341                         )
 342                        AND items.biblionumber = ?";
 343
 344     my @params = ($biblionumber, $biblionumber);
 345     if ($branches_to_use && @$branches_to_use) {
 346         $items_query .= " AND holdingbranch IN (" . join (",", map { "?" } @$branches_to_use) . ")";
 347         push @params, @$branches_to_use;
 348     }
 349     my $sth = $dbh->prepare($items_query);
 350     $sth->execute(@params);
 351
 352     my $itm = $sth->fetchall_arrayref({});
 353     my @items = grep { ! scalar GetTransfers($_->{itemnumber}) } @$itm;
 354     return [ grep {
 355         my $rule = GetBranchItemRule($_->{homebranch}, $_->{itype});
 356         $_->{holdallowed} = $rule->{holdallowed};
 357         $_->{hold_fulfillment_policy} = $rule->{hold_fulfillment_policy};
 358     } @items ];
 359 }
 360
 361 =head2 MapItemsToHoldRequests
 362
 363   MapItemsToHoldRequests($hold_requests, $available_items, $branches, $transport_cost_matrix)
 364
 365 =cut
 366
 367 sub MapItemsToHoldRequests {
 368     my ($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix) = @_;
 369
 370     # handle trival cases
 371     return unless scalar(@$hold_requests) > 0;
 372     return unless scalar(@$available_items) > 0;
 373
 374     # identify item-level requests
 375     my %specific_items_requested = map { $_->{itemnumber} => 1 }
 376                                    grep { defined($_->{itemnumber}) }
 377                                    @$hold_requests;
 378
 379     map { $_->{_object} = Koha::Items->find( $_->{itemnumber} ) } @$available_items;
 380     my $libraries = {};
 381     map { $libraries->{$_->id} = $_ } Koha::Libraries->search();
 382
 383     # group available items by itemnumber
 384     my %items_by_itemnumber = map { $_->{itemnumber} => $_ } @$available_items;
 385
 386     # items already allocated
 387     my %allocated_items = ();
 388
 389     # map of items to hold requests
 390     my %item_map = ();
 391
 392     # figure out which item-level requests can be filled
 393     my $num_items_remaining = scalar(@$available_items);
 394
 395     # Look for Local Holds Priority matches first
 396     if ( C4::Context->preference('LocalHoldsPriority') ) {
 397         my $LocalHoldsPriorityPatronControl =
 398           C4::Context->preference('LocalHoldsPriorityPatronControl');
 399         my $LocalHoldsPriorityItemControl =
 400           C4::Context->preference('LocalHoldsPriorityItemControl');
 401
 402         foreach my $request (@$hold_requests) {
 403             next if (defined($request->{itemnumber})); #skip item level holds in local priority checking
 404             last if $num_items_remaining == 0;
 405
 406             my $local_hold_match;
 407             foreach my $item (@$available_items) {
 408                 next
 409                   if ( !$item->{holdallowed} )
 410                   || ( $item->{holdallowed} == 1
 411                     && $item->{homebranch} ne $request->{borrowerbranch} );
 412
 413                 next unless $item->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 414
 415                 my $local_holds_priority_item_branchcode =
 416                   $item->{$LocalHoldsPriorityItemControl};
 417
 418                 my $local_holds_priority_patron_branchcode =
 419                   ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 420                   ? $request->{branchcode}
 421                   : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 422                   ? $request->{borrowerbranch}
 423                   : undef;
 424
 425                 $local_hold_match =
 426                   $local_holds_priority_item_branchcode eq
 427                   $local_holds_priority_patron_branchcode;
 428
 429                 if ($local_hold_match) {
 430                     if ( exists $items_by_itemnumber{ $item->{itemnumber} }
 431                         and not exists $allocated_items{ $item->{itemnumber} }
 432                         and not $request->{allocated})
 433                     {
 434                         $item_map{ $item->{itemnumber} } = {
 435                             borrowernumber => $request->{borrowernumber},
 436                             biblionumber   => $request->{biblionumber},
 437                             holdingbranch  => $item->{holdingbranch},
 438                             pickup_branch  => $request->{branchcode}
 439                               || $request->{borrowerbranch},
 440                             item_level   => 0,
 441                             reservedate  => $request->{reservedate},
 442                             reservenotes => $request->{reservenotes},
 443                         };
 444                         $allocated_items{ $item->{itemnumber} }++;
 445                         $request->{allocated} = 1;
 446                         $num_items_remaining--;
 447                     }
 448                 }
 449             }
 450         }
 451     }
 452
 453     foreach my $request (@$hold_requests) {
 454         last if $num_items_remaining == 0;
 455         next if $request->{allocated};
 456
 457         # is this an item-level request?
 458         if (defined($request->{itemnumber})) {
 459             # fill it if possible; if not skip it
 460             if (
 461                     exists $items_by_itemnumber{ $request->{itemnumber} }
 462                 and not exists $allocated_items{ $request->{itemnumber} }
 463                 and ( # Don't fill item level holds that contravene the hold pickup policy at this time
 464                     ( $items_by_itemnumber{ $request->{itemnumber} }->{hold_fulfillment_policy} eq 'any' )
 465                     || ( $request->{branchcode} eq $items_by_itemnumber{ $request->{itemnumber} }->{ $items_by_itemnumber{ $request->{itemnumber} }->{hold_fulfillment_policy} }  )
 466                 and ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 467                     || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 468                 )
 469                 and $items_by_itemnumber{ $request->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } )
 470
 471               )
 472             {
 473
 474                 $item_map{ $request->{itemnumber} } = {
 475                     borrowernumber => $request->{borrowernumber},
 476                     biblionumber   => $request->{biblionumber},
 477                     holdingbranch  => $items_by_itemnumber{ $request->{itemnumber} }->{holdingbranch},
 478                     pickup_branch  => $request->{branchcode} || $request->{borrowerbranch},
 479                     item_level     => 1,
 480                     reservedate    => $request->{reservedate},
 481                     reservenotes   => $request->{reservenotes},
 482                 };
 483                 $allocated_items{ $request->{itemnumber} }++;
 484                 $num_items_remaining--;
 485             }
 486         } else {
 487             # it's title-level request that will take up one item
 488             $num_items_remaining--;
 489         }
 490     }
 491
 492     # group available items by branch
 493     my %items_by_branch = ();
 494     foreach my $item (@$available_items) {
 495         next unless $item->{holdallowed};
 496
 497         push @{ $items_by_branch{ $item->{holdingbranch} } }, $item
 498           unless exists $allocated_items{ $item->{itemnumber} };
 499     }
 500     return \%item_map unless keys %items_by_branch;
 501
 502     # now handle the title-level requests
 503     $num_items_remaining = scalar(@$available_items) - scalar(keys %allocated_items);
 504     my $pull_branches;
 505     foreach my $request (@$hold_requests) {
 506         last if $num_items_remaining == 0;
 507         next if $request->{allocated};
 508         next if defined($request->{itemnumber}); # already handled these
 509
 510         # look for local match first
 511         my $pickup_branch = $request->{branchcode} || $request->{borrowerbranch};
 512         my ($itemnumber, $holdingbranch);
 513
 514         my $holding_branch_items = $items_by_branch{$pickup_branch};
 515         if ( $holding_branch_items ) {
 516             foreach my $item (@$holding_branch_items) {
 517                 next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 518
 519                 if (
 520                     $request->{borrowerbranch} eq $item->{homebranch}
 521                     && ( ( $item->{hold_fulfillment_policy} eq 'any' ) # Don't fill item level holds that contravene the hold pickup policy at this time
 522                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} } )
 523                     && ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 524                         || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 525                   )
 526                 {
 527                     $itemnumber = $item->{itemnumber};
 528                     last;
 529                 }
 530             }
 531             $holdingbranch = $pickup_branch;
 532         }
 533         elsif ($transport_cost_matrix) {
 534             $pull_branches = [keys %items_by_branch];
 535             $holdingbranch = least_cost_branch( $pickup_branch, $pull_branches, $transport_cost_matrix );
 536             if ( $holdingbranch ) {
 537
 538                 my $holding_branch_items = $items_by_branch{$holdingbranch};
 539                 foreach my $item (@$holding_branch_items) {
 540                     next if $request->{borrowerbranch} ne $item->{homebranch};
 541                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 542
 543                     # Don't fill item level holds that contravene the hold pickup policy at this time
 544                     next unless $item->{hold_fulfillment_policy} eq 'any'
 545                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 546
 547                     # If hold itemtype is set, item's itemtype must match
 548                     next unless ( !$request->{itemtype}
 549                         || $item->{itype} eq $request->{itemtype} );
 550
 551                     $itemnumber = $item->{itemnumber};
 552                     last;
 553                 }
 554             }
 555             else {
 556                 next;
 557             }
 558         }
 559
 560         unless ($itemnumber) {
 561             # not found yet, fall back to basics
 562             if ($branches_to_use) {
 563                 $pull_branches = $branches_to_use;
 564             } else {
 565                 $pull_branches = [keys %items_by_branch];
 566             }
 567
 568             # Try picking items where the home and pickup branch match first
 569             PULL_BRANCHES:
 570             foreach my $branch (@$pull_branches) {
 571                 my $holding_branch_items = $items_by_branch{$branch}
 572                   or next;
 573
 574                 $holdingbranch ||= $branch;
 575                 foreach my $item (@$holding_branch_items) {
 576                     next if $pickup_branch ne $item->{homebranch};
 577                     next if ( $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch} );
 578                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 579
 580                     # Don't fill item level holds that contravene the hold pickup policy at this time
 581                     next unless $item->{hold_fulfillment_policy} eq 'any'
 582                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 583
 584                     # If hold itemtype is set, item's itemtype must match
 585                     next unless ( !$request->{itemtype}
 586                         || $item->{itype} eq $request->{itemtype} );
 587
 588                     $itemnumber = $item->{itemnumber};
 589                     $holdingbranch = $branch;
 590                     last PULL_BRANCHES;
 591                 }
 592             }
 593
 594             # Now try items from the least cost branch based on the transport cost matrix or StaticHoldsQueueWeight
 595             unless ( $itemnumber ) {
 596                 foreach my $current_item ( @{ $items_by_branch{$holdingbranch} } ) {
 597                     if ( $holdingbranch && ( $current_item->{holdallowed} == 2 || $request->{borrowerbranch} eq $current_item->{homebranch} ) ) {
 598
 599                         # Don't fill item level holds that contravene the hold pickup policy at this time
 600                         next unless $current_item->{hold_fulfillment_policy} eq 'any'
 601                             || $request->{branchcode} eq $current_item->{ $current_item->{hold_fulfillment_policy} };
 602
 603                         # If hold itemtype is set, item's itemtype must match
 604                         next unless ( !$request->{itemtype}
 605                             || $current_item->{itype} eq $request->{itemtype} );
 606
 607                         next unless $items_by_itemnumber{ $current_item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 608
 609                         $itemnumber = $current_item->{itemnumber};
 610                         last; # quit this loop as soon as we have a suitable item
 611                     }
 612                 }
 613             }
 614
 615             # Now try for items for any item that can fill this hold
 616             unless ( $itemnumber ) {
 617                 PULL_BRANCHES2:
 618                 foreach my $branch (@$pull_branches) {
 619                     my $holding_branch_items = $items_by_branch{$branch}
 620                       or next;
 621
 622                     foreach my $item (@$holding_branch_items) {
 623                         next if ( $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch} );
 624
 625                         # Don't fill item level holds that contravene the hold pickup policy at this time
 626                         next unless $item->{hold_fulfillment_policy} eq 'any'
 627                             || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 628
 629                         # If hold itemtype is set, item's itemtype must match
 630                         next unless ( !$request->{itemtype}
 631                             || $item->{itype} eq $request->{itemtype} );
 632
 633                         next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 634
 635                         $itemnumber = $item->{itemnumber};
 636                         $holdingbranch = $branch;
 637                         last PULL_BRANCHES2;
 638                     }
 639                 }
 640             }
 641         }
 642
 643         if ($itemnumber) {
 644             my $holding_branch_items = $items_by_branch{$holdingbranch}
 645               or die "Have $itemnumber, $holdingbranch, but no items!";
 646             @$holding_branch_items = grep { $_->{itemnumber} != $itemnumber } @$holding_branch_items;
 647             delete $items_by_branch{$holdingbranch} unless @$holding_branch_items;
 648
 649             $item_map{$itemnumber} = {
 650                 borrowernumber => $request->{borrowernumber},
 651                 biblionumber => $request->{biblionumber},
 652                 holdingbranch => $holdingbranch,
 653                 pickup_branch => $pickup_branch,
 654                 item_level => 0,
 655                 reservedate => $request->{reservedate},
 656                 reservenotes => $request->{reservenotes},
 657             };
 658             $num_items_remaining--;
 659         }
 660     }
 661     return \%item_map;
 662 }
 663
 664 =head2 CreatePickListFromItemMap
 665
 666 =cut
 667
 668 sub CreatePicklistFromItemMap {
 669     my $item_map = shift;
 670
 671     my $dbh = C4::Context->dbh;
 672
 673     my $sth_load=$dbh->prepare("
 674         INSERT INTO tmp_holdsqueue (biblionumber,itemnumber,barcode,surname,firstname,phone,borrowernumber,
 675                                     cardnumber,reservedate,title, itemcallnumber,
 676                                     holdingbranch,pickbranch,notes, item_level_request)
 677         VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 678     ");
 679
 680     foreach my $itemnumber  (sort keys %$item_map) {
 681         my $mapped_item = $item_map->{$itemnumber};
 682         my $biblionumber = $mapped_item->{biblionumber};
 683         my $borrowernumber = $mapped_item->{borrowernumber};
 684         my $pickbranch = $mapped_item->{pickup_branch};
 685         my $holdingbranch = $mapped_item->{holdingbranch};
 686         my $reservedate = $mapped_item->{reservedate};
 687         my $reservenotes = $mapped_item->{reservenotes};
 688         my $item_level = $mapped_item->{item_level};
 689
 690         my $item = Koha::Items->find($itemnumber);
 691         my $barcode = $item->barcode;
 692         my $itemcallnumber = $item->itemcallnumber;
 693
 694         my $patron = Koha::Patrons->find( $borrowernumber );
 695         my $cardnumber = $patron->cardnumber;
 696         my $surname = $patron->surname;
 697         my $firstname = $patron->firstname;
 698         my $phone = $patron->phone;
 699
 700         my $biblio = Koha::Biblios->find( $biblionumber );
 701         my $title = $biblio->title;
 702
 703         $sth_load->execute($biblionumber, $itemnumber, $barcode, $surname, $firstname, $phone, $borrowernumber,
 704                            $cardnumber, $reservedate, $title, $itemcallnumber,
 705                            $holdingbranch, $pickbranch, $reservenotes, $item_level);
 706     }
 707 }
 708
 709 =head2 AddToHoldTargetMap
 710
 711 =cut
 712
 713 sub AddToHoldTargetMap {
 714     my $item_map = shift;
 715
 716     my $dbh = C4::Context->dbh;
 717
 718     my $insert_sql = q(
 719         INSERT INTO hold_fill_targets (borrowernumber, biblionumber, itemnumber, source_branchcode, item_level_request)
 720                                VALUES (?, ?, ?, ?, ?)
 721     );
 722     my $sth_insert = $dbh->prepare($insert_sql);
 723
 724     foreach my $itemnumber (keys %$item_map) {
 725         my $mapped_item = $item_map->{$itemnumber};
 726         $sth_insert->execute($mapped_item->{borrowernumber}, $mapped_item->{biblionumber}, $itemnumber,
 727                              $mapped_item->{holdingbranch}, $mapped_item->{item_level});
 728     }
 729 }
 730
 731 # Helper functions, not part of any interface
 732
 733 sub _trim {
 734     return $_[0] unless $_[0];
 735     $_[0] =~ s/^\s+//;
 736     $_[0] =~ s/\s+$//;
 737     $_[0];
 738 }
 739
 740 sub load_branches_to_pull_from {
 741     my @branches_to_use;
 742
 743     my $static_branch_list = C4::Context->preference("StaticHoldsQueueWeight");
 744     @branches_to_use = map { _trim($_) } split( /,/, $static_branch_list )
 745       if $static_branch_list;
 746
 747     @branches_to_use =
 748       Koha::Database->new()->schema()->resultset('Branch')
 749       ->get_column('branchcode')->all()
 750       unless (@branches_to_use);
 751
 752     @branches_to_use = shuffle(@branches_to_use)
 753       if C4::Context->preference("RandomizeHoldsQueueWeight");
 754
 755     my $today = dt_from_string();
 756     if ( C4::Context->preference('HoldsQueueSkipClosed') ) {
 757         @branches_to_use = grep {
 758             !Koha::Calendar->new( branchcode => $_ )
 759               ->is_holiday( $today )
 760         } @branches_to_use;
 761     }
 762
 763     return \@branches_to_use;
 764 }
 765
 766 sub least_cost_branch {
 767
 768     #$from - arrayref
 769     my ($to, $from, $transport_cost_matrix) = @_;
 770
 771     # Nothing really spectacular: supply to branch, a list of potential from branches
 772     # and find the minimum from - to value from the transport_cost_matrix
 773     return $from->[0] if ( @$from == 1 && $transport_cost_matrix->{$to}{$from->[0]}->{disable_transfer} != 1 );
 774
 775     # If the pickup library is in the list of libraries to pull from,
 776     # return that library right away, it is obviously the least costly
 777     return ($to) if any { $_ eq $to } @$from;
 778
 779     my ($least_cost, @branch);
 780     foreach (@$from) {
 781         my $cell = $transport_cost_matrix->{$to}{$_};
 782         next if $cell->{disable_transfer};
 783
 784         my $cost = $cell->{cost};
 785         next unless defined $cost; # XXX should this be reported?
 786
 787         unless (defined $least_cost) {
 788             $least_cost = $cost;
 789             push @branch, $_;
 790             next;
 791         }
 792
 793         next if $cost > $least_cost;
 794
 795         if ($cost == $least_cost) {
 796             push @branch, $_;
 797             next;
 798         }
 799
 800         @branch = ($_);
 801         $least_cost = $cost;
 802     }
 803
 804     return $branch[0];
 805
 806     # XXX return a random @branch with minimum cost instead of the first one;
 807     # return $branch[0] if @branch == 1;
 808 }
 809
 810
 811 1;