C4/HoldsQueue.pm

   1 package C4::HoldsQueue;
   2
   3 # Copyright 2011 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # FIXME: expand perldoc, explain intended logic
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Context;
  26 use C4::Search;
  27 use C4::Items;
  28 use C4::Circulation;
  29 use C4::Members;
  30 use C4::Biblio;
  31 use Koha::DateUtils;
  32
  33 use List::Util qw(shuffle);
  34 use List::MoreUtils qw(any);
  35 use Data::Dumper;
  36
  37 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  38 BEGIN {
  39     require Exporter;
  40     @ISA = qw(Exporter);
  41     @EXPORT_OK = qw(
  42         &CreateQueue
  43         &GetHoldsQueueItems
  44
  45         &TransportCostMatrix
  46         &UpdateTransportCostMatrix
  47      );
  48 }
  49
  50
  51 =head1 FUNCTIONS
  52
  53 =head2 TransportCostMatrix
  54
  55   TransportCostMatrix();
  56
  57 Returns Transport Cost Matrix as a hashref <to branch code> => <from branch code> => cost
  58
  59 =cut
  60
  61 sub TransportCostMatrix {
  62     my $dbh   = C4::Context->dbh;
  63     my $transport_costs = $dbh->selectall_arrayref("SELECT * FROM transport_cost",{ Slice => {} });
  64
  65     my $today = dt_from_string();
  66     my $calendars;
  67     my %transport_cost_matrix;
  68     foreach (@$transport_costs) {
  69         my $from     = $_->{frombranch};
  70         my $to       = $_->{tobranch};
  71         my $cost     = $_->{cost};
  72         my $disabled = $_->{disable_transfer};
  73         $transport_cost_matrix{$to}{$from} = {
  74             cost             => $cost,
  75             disable_transfer => $disabled
  76         };
  77
  78         if ( C4::Context->preference("HoldsQueueSkipClosed") ) {
  79             $calendars->{$from} ||= Koha::Calendar->new( branchcode => $from );
  80             $transport_cost_matrix{$to}{$from}{disable_transfer} ||=
  81               $calendars->{$from}->is_holiday( $today );
  82         }
  83
  84     }
  85     return \%transport_cost_matrix;
  86 }
  87
  88 =head2 UpdateTransportCostMatrix
  89
  90   UpdateTransportCostMatrix($records);
  91
  92 Updates full Transport Cost Matrix table. $records is an arrayref of records.
  93 Records: { frombranch => <code>, tobranch => <code>, cost => <figure>, disable_transfer => <0,1> }
  94
  95 =cut
  96
  97 sub UpdateTransportCostMatrix {
  98     my ($records) = @_;
  99     my $dbh   = C4::Context->dbh;
 100
 101     my $sth = $dbh->prepare("INSERT INTO transport_cost (frombranch, tobranch, cost, disable_transfer) VALUES (?, ?, ?, ?)");
 102
 103     $dbh->do("TRUNCATE TABLE transport_cost");
 104     foreach (@$records) {
 105         my $cost = $_->{cost};
 106         my $from = $_->{frombranch};
 107         my $to = $_->{tobranch};
 108         if ($_->{disable_transfer}) {
 109             $cost ||= 0;
 110         }
 111         elsif ( !defined ($cost) || ($cost !~ m/(0|[1-9][0-9]*)(\.[0-9]*)?/o) ) {
 112             warn  "Invalid $from -> $to cost $cost - must be a number >= 0, disablig";
 113             $cost = 0;
 114             $_->{disable_transfer} = 1;
 115         }
 116         $sth->execute( $from, $to, $cost, $_->{disable_transfer} ? 1 : 0 );
 117     }
 118 }
 119
 120 =head2 GetHoldsQueueItems
 121
 122   GetHoldsQueueItems($branch);
 123
 124 Returns hold queue for a holding branch. If branch is omitted, then whole queue is returned
 125
 126 =cut
 127
 128 sub GetHoldsQueueItems {
 129     my ($branchlimit) = @_;
 130     my $dbh   = C4::Context->dbh;
 131
 132     my @bind_params = ();
 133     my $query = q/SELECT tmp_holdsqueue.*, biblio.author, items.ccode, items.itype, biblioitems.itemtype, items.location, items.enumchron, items.cn_sort, biblioitems.publishercode,biblio.copyrightdate,biblioitems.publicationyear,biblioitems.pages,biblioitems.size,biblioitems.publicationyear,biblioitems.isbn,items.copynumber
 134                   FROM tmp_holdsqueue
 135                        JOIN biblio      USING (biblionumber)
 136                   LEFT JOIN biblioitems USING (biblionumber)
 137                   LEFT JOIN items       USING (  itemnumber)
 138                 /;
 139     if ($branchlimit) {
 140         $query .=" WHERE tmp_holdsqueue.holdingbranch = ?";
 141         push @bind_params, $branchlimit;
 142     }
 143     $query .= " ORDER BY ccode, location, cn_sort, author, title, pickbranch, reservedate";
 144     my $sth = $dbh->prepare($query);
 145     $sth->execute(@bind_params);
 146     my $items = [];
 147     while ( my $row = $sth->fetchrow_hashref ){
 148         my $record = GetMarcBiblio($row->{biblionumber});
 149         if ($record){
 150             $row->{subtitle} = [ map { $_->{subfield} } @{ GetRecordValue( 'subtitle', $record, '' ) } ];
 151             $row->{parts} = GetRecordValue('parts',$record,'')->[0]->{subfield};
 152             $row->{numbers} = GetRecordValue('numbers',$record,'')->[0]->{subfield};
 153         }
 154
 155         # return the bib-level or item-level itype per syspref
 156         if (!C4::Context->preference('item-level_itypes')) {
 157             $row->{itype} = $row->{itemtype};
 158         }
 159         delete $row->{itemtype};
 160
 161         push @$items, $row;
 162     }
 163     return $items;
 164 }
 165
 166 =head2 CreateQueue
 167
 168   CreateQueue();
 169
 170 Top level function that turns reserves into tmp_holdsqueue and hold_fill_targets.
 171
 172 =cut
 173
 174 sub CreateQueue {
 175     my $dbh   = C4::Context->dbh;
 176
 177     $dbh->do("DELETE FROM tmp_holdsqueue");  # clear the old table for new info
 178     $dbh->do("DELETE FROM hold_fill_targets");
 179
 180     my $total_bibs            = 0;
 181     my $total_requests        = 0;
 182     my $total_available_items = 0;
 183     my $num_items_mapped      = 0;
 184
 185     my $branches_to_use;
 186     my $transport_cost_matrix;
 187     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
 188     if ($use_transport_cost_matrix) {
 189         $transport_cost_matrix = TransportCostMatrix();
 190         unless (keys %$transport_cost_matrix) {
 191             warn "UseTransportCostMatrix set to yes, but matrix not populated";
 192             undef $transport_cost_matrix;
 193         }
 194     }
 195     unless ($transport_cost_matrix) {
 196         $branches_to_use = load_branches_to_pull_from();
 197     }
 198
 199     my $bibs_with_pending_requests = GetBibsWithPendingHoldRequests();
 200
 201     foreach my $biblionumber (@$bibs_with_pending_requests) {
 202         $total_bibs++;
 203         my $hold_requests   = GetPendingHoldRequestsForBib($biblionumber);
 204         my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_to_use);
 205         $total_requests        += scalar(@$hold_requests);
 206         $total_available_items += scalar(@$available_items);
 207
 208         my $item_map = MapItemsToHoldRequests($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix);
 209         $item_map  or next;
 210         my $item_map_size = scalar(keys %$item_map)
 211           or next;
 212
 213         $num_items_mapped += $item_map_size;
 214         CreatePicklistFromItemMap($item_map);
 215         AddToHoldTargetMap($item_map);
 216         if (($item_map_size < scalar(@$hold_requests  )) and
 217             ($item_map_size < scalar(@$available_items))) {
 218             # DOUBLE CHECK, but this is probably OK - unfilled item-level requests
 219             # FIXME
 220             #warn "unfilled requests for $biblionumber";
 221             #warn Dumper($hold_requests), Dumper($available_items), Dumper($item_map);
 222         }
 223     }
 224 }
 225
 226 =head2 GetBibsWithPendingHoldRequests
 227
 228   my $biblionumber_aref = GetBibsWithPendingHoldRequests();
 229
 230 Return an arrayref of the biblionumbers of all bibs
 231 that have one or more unfilled hold requests.
 232
 233 =cut
 234
 235 sub GetBibsWithPendingHoldRequests {
 236     my $dbh = C4::Context->dbh;
 237
 238     my $bib_query = "SELECT DISTINCT biblionumber
 239                      FROM reserves
 240                      WHERE found IS NULL
 241                      AND priority > 0
 242                      AND reservedate <= CURRENT_DATE()
 243                      AND suspend = 0
 244                      ";
 245     my $sth = $dbh->prepare($bib_query);
 246
 247     $sth->execute();
 248     my $biblionumbers = $sth->fetchall_arrayref();
 249
 250     return [ map { $_->[0] } @$biblionumbers ];
 251 }
 252
 253 =head2 GetPendingHoldRequestsForBib
 254
 255   my $requests = GetPendingHoldRequestsForBib($biblionumber);
 256
 257 Returns an arrayref of hashrefs to pending, unfilled hold requests
 258 on the bib identified by $biblionumber.  The following keys
 259 are present in each hashref:
 260
 261     biblionumber
 262     borrowernumber
 263     itemnumber
 264     priority
 265     branchcode
 266     reservedate
 267     reservenotes
 268     borrowerbranch
 269
 270 The arrayref is sorted in order of increasing priority.
 271
 272 =cut
 273
 274 sub GetPendingHoldRequestsForBib {
 275     my $biblionumber = shift;
 276
 277     my $dbh = C4::Context->dbh;
 278
 279     my $request_query = "SELECT biblionumber, borrowernumber, itemnumber, priority, reserves.branchcode,
 280                                 reservedate, reservenotes, borrowers.branchcode AS borrowerbranch, itemtype
 281                          FROM reserves
 282                          JOIN borrowers USING (borrowernumber)
 283                          WHERE biblionumber = ?
 284                          AND found IS NULL
 285                          AND priority > 0
 286                          AND reservedate <= CURRENT_DATE()
 287                          AND suspend = 0
 288                          ORDER BY priority";
 289     my $sth = $dbh->prepare($request_query);
 290     $sth->execute($biblionumber);
 291
 292     my $requests = $sth->fetchall_arrayref({});
 293     return $requests;
 294
 295 }
 296
 297 =head2 GetItemsAvailableToFillHoldRequestsForBib
 298
 299   my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_ar);
 300
 301 Returns an arrayref of items available to fill hold requests
 302 for the bib identified by C<$biblionumber>.  An item is available
 303 to fill a hold request if and only if:
 304
 305     * it is not on loan
 306     * it is not withdrawn
 307     * it is not marked notforloan
 308     * it is not currently in transit
 309     * it is not lost
 310     * it is not sitting on the hold shelf
 311     * it is not damaged (unless AllowHoldsOnDamagedItems is on)
 312
 313 =cut
 314
 315 sub GetItemsAvailableToFillHoldRequestsForBib {
 316     my ($biblionumber, $branches_to_use) = @_;
 317
 318     my $dbh = C4::Context->dbh;
 319     my $items_query = "SELECT itemnumber, homebranch, holdingbranch, itemtypes.itemtype AS itype
 320                        FROM items ";
 321
 322     if (C4::Context->preference('item-level_itypes')) {
 323         $items_query .=   "LEFT JOIN itemtypes ON (itemtypes.itemtype = items.itype) ";
 324     } else {
 325         $items_query .=   "JOIN biblioitems USING (biblioitemnumber)
 326                            LEFT JOIN itemtypes USING (itemtype) ";
 327     }
 328     $items_query .=   "WHERE items.notforloan = 0
 329                        AND holdingbranch IS NOT NULL
 330                        AND itemlost = 0
 331                        AND withdrawn = 0";
 332     $items_query .= "  AND damaged = 0" unless C4::Context->preference('AllowHoldsOnDamagedItems');
 333     $items_query .= "  AND items.onloan IS NULL
 334                        AND (itemtypes.notforloan IS NULL OR itemtypes.notforloan = 0)
 335                        AND itemnumber NOT IN (
 336                            SELECT itemnumber
 337                            FROM reserves
 338                            WHERE biblionumber = ?
 339                            AND itemnumber IS NOT NULL
 340                            AND (found IS NOT NULL OR priority = 0)
 341                         )
 342                        AND items.biblionumber = ?";
 343
 344     my @params = ($biblionumber, $biblionumber);
 345     if ($branches_to_use && @$branches_to_use) {
 346         $items_query .= " AND holdingbranch IN (" . join (",", map { "?" } @$branches_to_use) . ")";
 347         push @params, @$branches_to_use;
 348     }
 349     my $sth = $dbh->prepare($items_query);
 350     $sth->execute(@params);
 351
 352     my $itm = $sth->fetchall_arrayref({});
 353     my @items = grep { ! scalar GetTransfers($_->{itemnumber}) } @$itm;
 354     return [ grep {
 355         my $rule = GetBranchItemRule($_->{homebranch}, $_->{itype});
 356         $_->{holdallowed} = $rule->{holdallowed};
 357         $_->{hold_fulfillment_policy} = $rule->{hold_fulfillment_policy};
 358     } @items ];
 359 }
 360
 361 =head2 MapItemsToHoldRequests
 362
 363   MapItemsToHoldRequests($hold_requests, $available_items, $branches, $transport_cost_matrix)
 364
 365 =cut
 366
 367 sub MapItemsToHoldRequests {
 368     my ($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix) = @_;
 369
 370
 371     # handle trival cases
 372     return unless scalar(@$hold_requests) > 0;
 373     return unless scalar(@$available_items) > 0;
 374
 375     # identify item-level requests
 376     my %specific_items_requested = map { $_->{itemnumber} => 1 }
 377                                    grep { defined($_->{itemnumber}) }
 378                                    @$hold_requests;
 379
 380     # group available items by itemnumber
 381     my %items_by_itemnumber = map { $_->{itemnumber} => $_ } @$available_items;
 382
 383     # items already allocated
 384     my %allocated_items = ();
 385
 386     # map of items to hold requests
 387     my %item_map = ();
 388
 389     # figure out which item-level requests can be filled
 390     my $num_items_remaining = scalar(@$available_items);
 391
 392     # Look for Local Holds Priority matches first
 393     if ( C4::Context->preference('LocalHoldsPriority') ) {
 394         my $LocalHoldsPriorityPatronControl =
 395           C4::Context->preference('LocalHoldsPriorityPatronControl');
 396         my $LocalHoldsPriorityItemControl =
 397           C4::Context->preference('LocalHoldsPriorityItemControl');
 398
 399         foreach my $request (@$hold_requests) {
 400             last if $num_items_remaining == 0;
 401
 402             my $local_hold_match;
 403             foreach my $item (@$available_items) {
 404                 next
 405                   if ( !$item->{holdallowed} )
 406                   || ( $item->{holdallowed} == 1
 407                     && $item->{homebranch} ne $request->{borrowerbranch} );
 408
 409                 my $local_holds_priority_item_branchcode =
 410                   $item->{$LocalHoldsPriorityItemControl};
 411
 412                 my $local_holds_priority_patron_branchcode =
 413                   ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 414                   ? $request->{branchcode}
 415                   : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 416                   ? $request->{borrowerbranch}
 417                   : undef;
 418
 419                 $local_hold_match =
 420                   $local_holds_priority_item_branchcode eq
 421                   $local_holds_priority_patron_branchcode;
 422
 423                 if ($local_hold_match) {
 424                     if ( exists $items_by_itemnumber{ $item->{itemnumber} }
 425                         and not exists $allocated_items{ $item->{itemnumber} } )
 426                     {
 427                         $item_map{ $item->{itemnumber} } = {
 428                             borrowernumber => $request->{borrowernumber},
 429                             biblionumber   => $request->{biblionumber},
 430                             holdingbranch  => $item->{holdingbranch},
 431                             pickup_branch  => $request->{branchcode}
 432                               || $request->{borrowerbranch},
 433                             item_level   => 0,
 434                             reservedate  => $request->{reservedate},
 435                             reservenotes => $request->{reservenotes},
 436                         };
 437                         $allocated_items{ $item->{itemnumber} }++;
 438                         $num_items_remaining--;
 439                     }
 440                 }
 441             }
 442         }
 443     }
 444
 445     foreach my $request (@$hold_requests) {
 446         last if $num_items_remaining == 0;
 447
 448         # is this an item-level request?
 449         if (defined($request->{itemnumber})) {
 450             # fill it if possible; if not skip it
 451             if (
 452                     exists $items_by_itemnumber{ $request->{itemnumber} }
 453                 and not exists $allocated_items{ $request->{itemnumber} }
 454                 and ( # Don't fill item level holds that contravene the hold pickup policy at this time
 455                     ( $items_by_itemnumber{ $request->{itemnumber} }->{hold_fulfillment_policy} eq 'any' )
 456                     || ( $request->{branchcode} eq $items_by_itemnumber{ $request->{itemnumber} }->{ $items_by_itemnumber{ $request->{itemnumber} }->{hold_fulfillment_policy} }  )
 457                 and ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 458                     || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 459                 )
 460
 461               )
 462             {
 463
 464                 $item_map{ $request->{itemnumber} } = {
 465                     borrowernumber => $request->{borrowernumber},
 466                     biblionumber   => $request->{biblionumber},
 467                     holdingbranch  => $items_by_itemnumber{ $request->{itemnumber} }->{holdingbranch},
 468                     pickup_branch  => $request->{branchcode} || $request->{borrowerbranch},
 469                     item_level     => 1,
 470                     reservedate    => $request->{reservedate},
 471                     reservenotes   => $request->{reservenotes},
 472                 };
 473                 $allocated_items{ $request->{itemnumber} }++;
 474                 $num_items_remaining--;
 475             }
 476         } else {
 477             # it's title-level request that will take up one item
 478             $num_items_remaining--;
 479         }
 480     }
 481
 482     # group available items by branch
 483     my %items_by_branch = ();
 484     foreach my $item (@$available_items) {
 485         next unless $item->{holdallowed};
 486
 487         push @{ $items_by_branch{ $item->{holdingbranch} } }, $item
 488           unless exists $allocated_items{ $item->{itemnumber} };
 489     }
 490     return \%item_map unless keys %items_by_branch;
 491
 492     # now handle the title-level requests
 493     $num_items_remaining = scalar(@$available_items) - scalar(keys %allocated_items);
 494     my $pull_branches;
 495     foreach my $request (@$hold_requests) {
 496         last if $num_items_remaining == 0;
 497         next if defined($request->{itemnumber}); # already handled these
 498
 499         # look for local match first
 500         my $pickup_branch = $request->{branchcode} || $request->{borrowerbranch};
 501         my ($itemnumber, $holdingbranch);
 502
 503         my $holding_branch_items = $items_by_branch{$pickup_branch};
 504         if ( $holding_branch_items ) {
 505             foreach my $item (@$holding_branch_items) {
 506                 if (
 507                     $request->{borrowerbranch} eq $item->{homebranch}
 508                     && ( ( $item->{hold_fulfillment_policy} eq 'any' ) # Don't fill item level holds that contravene the hold pickup policy at this time
 509                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} } )
 510                     && ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 511                         || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 512                   )
 513                 {
 514                     $itemnumber = $item->{itemnumber};
 515                     last;
 516                 }
 517             }
 518             $holdingbranch = $pickup_branch;
 519         }
 520         elsif ($transport_cost_matrix) {
 521             $pull_branches = [keys %items_by_branch];
 522             $holdingbranch = least_cost_branch( $pickup_branch, $pull_branches, $transport_cost_matrix );
 523             if ( $holdingbranch ) {
 524
 525                 my $holding_branch_items = $items_by_branch{$holdingbranch};
 526                 foreach my $item (@$holding_branch_items) {
 527                     next if $request->{borrowerbranch} ne $item->{homebranch};
 528
 529                     # Don't fill item level holds that contravene the hold pickup policy at this time
 530                     next unless $item->{hold_fulfillment_policy} eq 'any'
 531                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 532
 533                     # If hold itemtype is set, item's itemtype must match
 534                     next unless ( !$request->{itemtype}
 535                         || $item->{itype} eq $request->{itemtype} );
 536
 537                     $itemnumber = $item->{itemnumber};
 538                     last;
 539                 }
 540             }
 541             else {
 542                 next;
 543             }
 544         }
 545
 546         unless ($itemnumber) {
 547             # not found yet, fall back to basics
 548             if ($branches_to_use) {
 549                 $pull_branches = $branches_to_use;
 550             } else {
 551                 $pull_branches = [keys %items_by_branch];
 552             }
 553
 554             # Try picking items where the home and pickup branch match first
 555             PULL_BRANCHES:
 556             foreach my $branch (@$pull_branches) {
 557                 my $holding_branch_items = $items_by_branch{$branch}
 558                   or next;
 559
 560                 $holdingbranch ||= $branch;
 561                 foreach my $item (@$holding_branch_items) {
 562                     next if $pickup_branch ne $item->{homebranch};
 563                     next if ( $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch} );
 564
 565                     # Don't fill item level holds that contravene the hold pickup policy at this time
 566                     next unless $item->{hold_fulfillment_policy} eq 'any'
 567                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 568
 569                     # If hold itemtype is set, item's itemtype must match
 570                     next unless ( !$request->{itemtype}
 571                         || $item->{itype} eq $request->{itemtype} );
 572
 573                     $itemnumber = $item->{itemnumber};
 574                     $holdingbranch = $branch;
 575                     last PULL_BRANCHES;
 576                 }
 577             }
 578
 579             # Now try items from the least cost branch based on the transport cost matrix or StaticHoldsQueueWeight
 580             unless ( $itemnumber ) {
 581                 foreach my $current_item ( @{ $items_by_branch{$holdingbranch} } ) {
 582                     if ( $holdingbranch && ( $current_item->{holdallowed} == 2 || $request->{borrowerbranch} eq $current_item->{homebranch} ) ) {
 583
 584                         # Don't fill item level holds that contravene the hold pickup policy at this time
 585                         next unless $current_item->{hold_fulfillment_policy} eq 'any'
 586                             || $request->{branchcode} eq $current_item->{ $current_item->{hold_fulfillment_policy} };
 587
 588                         # If hold itemtype is set, item's itemtype must match
 589                         next unless ( !$request->{itemtype}
 590                             || $current_item->{itype} eq $request->{itemtype} );
 591
 592                         $itemnumber = $current_item->{itemnumber};
 593                         last; # quit this loop as soon as we have a suitable item
 594                     }
 595                 }
 596             }
 597
 598             # Now try for items for any item that can fill this hold
 599             unless ( $itemnumber ) {
 600                 PULL_BRANCHES2:
 601                 foreach my $branch (@$pull_branches) {
 602                     my $holding_branch_items = $items_by_branch{$branch}
 603                       or next;
 604
 605                     foreach my $item (@$holding_branch_items) {
 606                         next if ( $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch} );
 607
 608                         # Don't fill item level holds that contravene the hold pickup policy at this time
 609                         next unless $item->{hold_fulfillment_policy} eq 'any'
 610                             || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 611
 612                         # If hold itemtype is set, item's itemtype must match
 613                         next unless ( !$request->{itemtype}
 614                             || $item->{itype} eq $request->{itemtype} );
 615
 616                         $itemnumber = $item->{itemnumber};
 617                         $holdingbranch = $branch;
 618                         last PULL_BRANCHES2;
 619                     }
 620                 }
 621             }
 622         }
 623
 624         if ($itemnumber) {
 625             my $holding_branch_items = $items_by_branch{$holdingbranch}
 626               or die "Have $itemnumber, $holdingbranch, but no items!";
 627             @$holding_branch_items = grep { $_->{itemnumber} != $itemnumber } @$holding_branch_items;
 628             delete $items_by_branch{$holdingbranch} unless @$holding_branch_items;
 629
 630             $item_map{$itemnumber} = {
 631                 borrowernumber => $request->{borrowernumber},
 632                 biblionumber => $request->{biblionumber},
 633                 holdingbranch => $holdingbranch,
 634                 pickup_branch => $pickup_branch,
 635                 item_level => 0,
 636                 reservedate => $request->{reservedate},
 637                 reservenotes => $request->{reservenotes},
 638             };
 639             $num_items_remaining--;
 640         }
 641     }
 642     return \%item_map;
 643 }
 644
 645 =head2 CreatePickListFromItemMap
 646
 647 =cut
 648
 649 sub CreatePicklistFromItemMap {
 650     my $item_map = shift;
 651
 652     my $dbh = C4::Context->dbh;
 653
 654     my $sth_load=$dbh->prepare("
 655         INSERT INTO tmp_holdsqueue (biblionumber,itemnumber,barcode,surname,firstname,phone,borrowernumber,
 656                                     cardnumber,reservedate,title, itemcallnumber,
 657                                     holdingbranch,pickbranch,notes, item_level_request)
 658         VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 659     ");
 660
 661     foreach my $itemnumber  (sort keys %$item_map) {
 662         my $mapped_item = $item_map->{$itemnumber};
 663         my $biblionumber = $mapped_item->{biblionumber};
 664         my $borrowernumber = $mapped_item->{borrowernumber};
 665         my $pickbranch = $mapped_item->{pickup_branch};
 666         my $holdingbranch = $mapped_item->{holdingbranch};
 667         my $reservedate = $mapped_item->{reservedate};
 668         my $reservenotes = $mapped_item->{reservenotes};
 669         my $item_level = $mapped_item->{item_level};
 670
 671         my $item = GetItem($itemnumber);
 672         my $barcode = $item->{barcode};
 673         my $itemcallnumber = $item->{itemcallnumber};
 674
 675         my $borrower = GetMember('borrowernumber'=>$borrowernumber);
 676         my $cardnumber = $borrower->{'cardnumber'};
 677         my $surname = $borrower->{'surname'};
 678         my $firstname = $borrower->{'firstname'};
 679         my $phone = $borrower->{'phone'};
 680
 681         my $bib = GetBiblioData($biblionumber);
 682         my $title = $bib->{title};
 683
 684         $sth_load->execute($biblionumber, $itemnumber, $barcode, $surname, $firstname, $phone, $borrowernumber,
 685                            $cardnumber, $reservedate, $title, $itemcallnumber,
 686                            $holdingbranch, $pickbranch, $reservenotes, $item_level);
 687     }
 688 }
 689
 690 =head2 AddToHoldTargetMap
 691
 692 =cut
 693
 694 sub AddToHoldTargetMap {
 695     my $item_map = shift;
 696
 697     my $dbh = C4::Context->dbh;
 698
 699     my $insert_sql = q(
 700         INSERT INTO hold_fill_targets (borrowernumber, biblionumber, itemnumber, source_branchcode, item_level_request)
 701                                VALUES (?, ?, ?, ?, ?)
 702     );
 703     my $sth_insert = $dbh->prepare($insert_sql);
 704
 705     foreach my $itemnumber (keys %$item_map) {
 706         my $mapped_item = $item_map->{$itemnumber};
 707         $sth_insert->execute($mapped_item->{borrowernumber}, $mapped_item->{biblionumber}, $itemnumber,
 708                              $mapped_item->{holdingbranch}, $mapped_item->{item_level});
 709     }
 710 }
 711
 712 # Helper functions, not part of any interface
 713
 714 sub _trim {
 715     return $_[0] unless $_[0];
 716     $_[0] =~ s/^\s+//;
 717     $_[0] =~ s/\s+$//;
 718     $_[0];
 719 }
 720
 721 sub load_branches_to_pull_from {
 722     my @branches_to_use;
 723
 724     my $static_branch_list = C4::Context->preference("StaticHoldsQueueWeight");
 725     @branches_to_use = map { _trim($_) } split( /,/, $static_branch_list )
 726       if $static_branch_list;
 727
 728     @branches_to_use =
 729       Koha::Database->new()->schema()->resultset('Branch')
 730       ->get_column('branchcode')->all()
 731       unless (@branches_to_use);
 732
 733     @branches_to_use = shuffle(@branches_to_use)
 734       if C4::Context->preference("RandomizeHoldsQueueWeight");
 735
 736     my $today = dt_from_string();
 737     if ( C4::Context->preference('HoldsQueueSkipClosed') ) {
 738         @branches_to_use = grep {
 739             !Koha::Calendar->new( branchcode => $_ )
 740               ->is_holiday( $today )
 741         } @branches_to_use;
 742     }
 743
 744     return \@branches_to_use;
 745 }
 746
 747 sub least_cost_branch {
 748
 749     #$from - arrayref
 750     my ($to, $from, $transport_cost_matrix) = @_;
 751
 752     # Nothing really spectacular: supply to branch, a list of potential from branches
 753     # and find the minimum from - to value from the transport_cost_matrix
 754     return $from->[0] if ( @$from == 1 && $transport_cost_matrix->{$to}{$from->[0]}->{disable_transfer} != 1 );
 755
 756     # If the pickup library is in the list of libraries to pull from,
 757     # return that library right away, it is obviously the least costly
 758     return ($to) if any { $_ eq $to } @$from;
 759
 760     my ($least_cost, @branch);
 761     foreach (@$from) {
 762         my $cell = $transport_cost_matrix->{$to}{$_};
 763         next if $cell->{disable_transfer};
 764
 765         my $cost = $cell->{cost};
 766         next unless defined $cost; # XXX should this be reported?
 767
 768         unless (defined $least_cost) {
 769             $least_cost = $cost;
 770             push @branch, $_;
 771             next;
 772         }
 773
 774         next if $cost > $least_cost;
 775
 776         if ($cost == $least_cost) {
 777             push @branch, $_;
 778             next;
 779         }
 780
 781         @branch = ($_);
 782         $least_cost = $cost;
 783     }
 784
 785     return $branch[0];
 786
 787     # XXX return a random @branch with minimum cost instead of the first one;
 788     # return $branch[0] if @branch == 1;
 789 }
 790
 791
 792 1;