C4/HoldsQueue.pm

   1 package C4::HoldsQueue;
   2
   3 # Copyright 2011 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # FIXME: expand perldoc, explain intended logic
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Context;
  26 use C4::Search;
  27 use C4::Items;
  28 use C4::Circulation;
  29 use C4::Members;
  30 use C4::Biblio;
  31 use Koha::DateUtils;
  32 use Koha::Items;
  33 use Koha::Patrons;
  34
  35 use List::Util qw(shuffle);
  36 use List::MoreUtils qw(any);
  37 use Data::Dumper;
  38
  39 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  40 BEGIN {
  41     require Exporter;
  42     @ISA = qw(Exporter);
  43     @EXPORT_OK = qw(
  44         &CreateQueue
  45         &GetHoldsQueueItems
  46
  47         &TransportCostMatrix
  48         &UpdateTransportCostMatrix
  49      );
  50 }
  51
  52
  53 =head1 FUNCTIONS
  54
  55 =head2 TransportCostMatrix
  56
  57   TransportCostMatrix();
  58
  59 Returns Transport Cost Matrix as a hashref <to branch code> => <from branch code> => cost
  60
  61 =cut
  62
  63 sub TransportCostMatrix {
  64     my $dbh   = C4::Context->dbh;
  65     my $transport_costs = $dbh->selectall_arrayref("SELECT * FROM transport_cost",{ Slice => {} });
  66
  67     my $today = dt_from_string();
  68     my $calendars;
  69     my %transport_cost_matrix;
  70     foreach (@$transport_costs) {
  71         my $from     = $_->{frombranch};
  72         my $to       = $_->{tobranch};
  73         my $cost     = $_->{cost};
  74         my $disabled = $_->{disable_transfer};
  75         $transport_cost_matrix{$to}{$from} = {
  76             cost             => $cost,
  77             disable_transfer => $disabled
  78         };
  79
  80         if ( C4::Context->preference("HoldsQueueSkipClosed") ) {
  81             $calendars->{$from} ||= Koha::Calendar->new( branchcode => $from );
  82             $transport_cost_matrix{$to}{$from}{disable_transfer} ||=
  83               $calendars->{$from}->is_holiday( $today );
  84         }
  85
  86     }
  87     return \%transport_cost_matrix;
  88 }
  89
  90 =head2 UpdateTransportCostMatrix
  91
  92   UpdateTransportCostMatrix($records);
  93
  94 Updates full Transport Cost Matrix table. $records is an arrayref of records.
  95 Records: { frombranch => <code>, tobranch => <code>, cost => <figure>, disable_transfer => <0,1> }
  96
  97 =cut
  98
  99 sub UpdateTransportCostMatrix {
 100     my ($records) = @_;
 101     my $dbh   = C4::Context->dbh;
 102
 103     my $sth = $dbh->prepare("INSERT INTO transport_cost (frombranch, tobranch, cost, disable_transfer) VALUES (?, ?, ?, ?)");
 104
 105     $dbh->do("DELETE FROM transport_cost");
 106     foreach (@$records) {
 107         my $cost = $_->{cost};
 108         my $from = $_->{frombranch};
 109         my $to = $_->{tobranch};
 110         if ($_->{disable_transfer}) {
 111             $cost ||= 0;
 112         }
 113         elsif ( !defined ($cost) || ($cost !~ m/(0|[1-9][0-9]*)(\.[0-9]*)?/o) ) {
 114             warn  "Invalid $from -> $to cost $cost - must be a number >= 0, disabling";
 115             $cost = 0;
 116             $_->{disable_transfer} = 1;
 117         }
 118         $sth->execute( $from, $to, $cost, $_->{disable_transfer} ? 1 : 0 );
 119     }
 120 }
 121
 122 =head2 GetHoldsQueueItems
 123
 124   GetHoldsQueueItems($branch);
 125
 126 Returns hold queue for a holding branch. If branch is omitted, then whole queue is returned
 127
 128 =cut
 129
 130 sub GetHoldsQueueItems {
 131     my ($branchlimit) = @_;
 132     my $dbh   = C4::Context->dbh;
 133
 134     my @bind_params = ();
 135     my $query = q/SELECT tmp_holdsqueue.*, biblio.author, items.ccode, items.itype, biblioitems.itemtype, items.location,
 136                          items.enumchron, items.cn_sort, biblioitems.publishercode,
 137                          biblio.copyrightdate, biblio.subtitle, biblio.part_number,
 138                          biblio.part_name,
 139                          biblioitems.publicationyear, biblioitems.pages, biblioitems.size, biblioitems.publicationyear,
 140                          biblioitems.isbn, items.copynumber
 141                   FROM tmp_holdsqueue
 142                        JOIN biblio      USING (biblionumber)
 143                   LEFT JOIN biblioitems USING (biblionumber)
 144                   LEFT JOIN items       USING (  itemnumber)
 145                 /;
 146     if ($branchlimit) {
 147         $query .=" WHERE tmp_holdsqueue.holdingbranch = ?";
 148         push @bind_params, $branchlimit;
 149     }
 150     $query .= " ORDER BY ccode, location, cn_sort, author, title, pickbranch, reservedate";
 151     my $sth = $dbh->prepare($query);
 152     $sth->execute(@bind_params);
 153     my $items = [];
 154     while ( my $row = $sth->fetchrow_hashref ){
 155         # return the bib-level or item-level itype per syspref
 156         if (!C4::Context->preference('item-level_itypes')) {
 157             $row->{itype} = $row->{itemtype};
 158         }
 159         delete $row->{itemtype};
 160
 161         my @subtitles = split(/ \| /, $row->{'subtitle'} // '' );
 162         $row->{'subtitle'} = \@subtitles;
 163
 164         push @$items, $row;
 165     }
 166     return $items;
 167 }
 168
 169 =head2 CreateQueue
 170
 171   CreateQueue();
 172
 173 Top level function that turns reserves into tmp_holdsqueue and hold_fill_targets.
 174
 175 =cut
 176
 177 sub CreateQueue {
 178     my $dbh   = C4::Context->dbh;
 179
 180     $dbh->do("DELETE FROM tmp_holdsqueue");  # clear the old table for new info
 181     $dbh->do("DELETE FROM hold_fill_targets");
 182
 183     my $total_bibs            = 0;
 184     my $total_requests        = 0;
 185     my $total_available_items = 0;
 186     my $num_items_mapped      = 0;
 187
 188     my $branches_to_use;
 189     my $transport_cost_matrix;
 190     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
 191     if ($use_transport_cost_matrix) {
 192         $transport_cost_matrix = TransportCostMatrix();
 193         unless (keys %$transport_cost_matrix) {
 194             warn "UseTransportCostMatrix set to yes, but matrix not populated";
 195             undef $transport_cost_matrix;
 196         }
 197     }
 198     unless ($transport_cost_matrix) {
 199         $branches_to_use = load_branches_to_pull_from();
 200     }
 201
 202     my $bibs_with_pending_requests = GetBibsWithPendingHoldRequests();
 203
 204     foreach my $biblionumber (@$bibs_with_pending_requests) {
 205         $total_bibs++;
 206         my $hold_requests   = GetPendingHoldRequestsForBib($biblionumber);
 207         my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_to_use);
 208         $total_requests        += scalar(@$hold_requests);
 209         $total_available_items += scalar(@$available_items);
 210
 211         my $item_map = MapItemsToHoldRequests($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix);
 212         $item_map  or next;
 213         my $item_map_size = scalar(keys %$item_map)
 214           or next;
 215
 216         $num_items_mapped += $item_map_size;
 217         CreatePicklistFromItemMap($item_map);
 218         AddToHoldTargetMap($item_map);
 219         if (($item_map_size < scalar(@$hold_requests  )) and
 220             ($item_map_size < scalar(@$available_items))) {
 221             # DOUBLE CHECK, but this is probably OK - unfilled item-level requests
 222             # FIXME
 223             #warn "unfilled requests for $biblionumber";
 224             #warn Dumper($hold_requests), Dumper($available_items), Dumper($item_map);
 225         }
 226     }
 227 }
 228
 229 =head2 GetBibsWithPendingHoldRequests
 230
 231   my $biblionumber_aref = GetBibsWithPendingHoldRequests();
 232
 233 Return an arrayref of the biblionumbers of all bibs
 234 that have one or more unfilled hold requests.
 235
 236 =cut
 237
 238 sub GetBibsWithPendingHoldRequests {
 239     my $dbh = C4::Context->dbh;
 240
 241     my $bib_query = "SELECT DISTINCT biblionumber
 242                      FROM reserves
 243                      WHERE found IS NULL
 244                      AND priority > 0
 245                      AND reservedate <= CURRENT_DATE()
 246                      AND suspend = 0
 247                      ";
 248     my $sth = $dbh->prepare($bib_query);
 249
 250     $sth->execute();
 251     my $biblionumbers = $sth->fetchall_arrayref();
 252
 253     return [ map { $_->[0] } @$biblionumbers ];
 254 }
 255
 256 =head2 GetPendingHoldRequestsForBib
 257
 258   my $requests = GetPendingHoldRequestsForBib($biblionumber);
 259
 260 Returns an arrayref of hashrefs to pending, unfilled hold requests
 261 on the bib identified by $biblionumber.  The following keys
 262 are present in each hashref:
 263
 264     biblionumber
 265     borrowernumber
 266     itemnumber
 267     priority
 268     branchcode
 269     reservedate
 270     reservenotes
 271     borrowerbranch
 272
 273 The arrayref is sorted in order of increasing priority.
 274
 275 =cut
 276
 277 sub GetPendingHoldRequestsForBib {
 278     my $biblionumber = shift;
 279
 280     my $dbh = C4::Context->dbh;
 281
 282     my $request_query = "SELECT biblionumber, borrowernumber, itemnumber, priority, reserves.branchcode,
 283                                 reservedate, reservenotes, borrowers.branchcode AS borrowerbranch, itemtype
 284                          FROM reserves
 285                          JOIN borrowers USING (borrowernumber)
 286                          WHERE biblionumber = ?
 287                          AND found IS NULL
 288                          AND priority > 0
 289                          AND reservedate <= CURRENT_DATE()
 290                          AND suspend = 0
 291                          ORDER BY priority";
 292     my $sth = $dbh->prepare($request_query);
 293     $sth->execute($biblionumber);
 294
 295     my $requests = $sth->fetchall_arrayref({});
 296     return $requests;
 297
 298 }
 299
 300 =head2 GetItemsAvailableToFillHoldRequestsForBib
 301
 302   my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_ar);
 303
 304 Returns an arrayref of items available to fill hold requests
 305 for the bib identified by C<$biblionumber>.  An item is available
 306 to fill a hold request if and only if:
 307
 308     * it is not on loan
 309     * it is not withdrawn
 310     * it is not marked notforloan
 311     * it is not currently in transit
 312     * it is not lost
 313     * it is not sitting on the hold shelf
 314     * it is not damaged (unless AllowHoldsOnDamagedItems is on)
 315
 316 =cut
 317
 318 sub GetItemsAvailableToFillHoldRequestsForBib {
 319     my ($biblionumber, $branches_to_use) = @_;
 320
 321     my $dbh = C4::Context->dbh;
 322     my $items_query = "SELECT itemnumber, homebranch, holdingbranch, itemtypes.itemtype AS itype
 323                        FROM items ";
 324
 325     if (C4::Context->preference('item-level_itypes')) {
 326         $items_query .=   "LEFT JOIN itemtypes ON (itemtypes.itemtype = items.itype) ";
 327     } else {
 328         $items_query .=   "JOIN biblioitems USING (biblioitemnumber)
 329                            LEFT JOIN itemtypes USING (itemtype) ";
 330     }
 331     $items_query .=   "WHERE items.notforloan = 0
 332                        AND holdingbranch IS NOT NULL
 333                        AND itemlost = 0
 334                        AND withdrawn = 0";
 335     $items_query .= "  AND damaged = 0" unless C4::Context->preference('AllowHoldsOnDamagedItems');
 336     $items_query .= "  AND items.onloan IS NULL
 337                        AND (itemtypes.notforloan IS NULL OR itemtypes.notforloan = 0)
 338                        AND itemnumber NOT IN (
 339                            SELECT itemnumber
 340                            FROM reserves
 341                            WHERE biblionumber = ?
 342                            AND itemnumber IS NOT NULL
 343                            AND (found IS NOT NULL OR priority = 0)
 344                         )
 345                        AND items.biblionumber = ?";
 346
 347     my @params = ($biblionumber, $biblionumber);
 348     if ($branches_to_use && @$branches_to_use) {
 349         $items_query .= " AND holdingbranch IN (" . join (",", map { "?" } @$branches_to_use) . ")";
 350         push @params, @$branches_to_use;
 351     }
 352     my $sth = $dbh->prepare($items_query);
 353     $sth->execute(@params);
 354
 355     my $itm = $sth->fetchall_arrayref({});
 356     my @items = grep { ! scalar GetTransfers($_->{itemnumber}) } @$itm;
 357     return [ grep {
 358         my $rule = GetBranchItemRule($_->{homebranch}, $_->{itype});
 359         $_->{holdallowed} = $rule->{holdallowed};
 360         $_->{hold_fulfillment_policy} = $rule->{hold_fulfillment_policy};
 361     } @items ];
 362 }
 363
 364 =head2 MapItemsToHoldRequests
 365
 366   MapItemsToHoldRequests($hold_requests, $available_items, $branches, $transport_cost_matrix)
 367
 368 =cut
 369
 370 sub MapItemsToHoldRequests {
 371     my ($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix) = @_;
 372
 373     # handle trival cases
 374     return unless scalar(@$hold_requests) > 0;
 375     return unless scalar(@$available_items) > 0;
 376
 377     # identify item-level requests
 378     my %specific_items_requested = map { $_->{itemnumber} => 1 }
 379                                    grep { defined($_->{itemnumber}) }
 380                                    @$hold_requests;
 381
 382     map { $_->{_object} = Koha::Items->find( $_->{itemnumber} ) } @$available_items;
 383     my $libraries = {};
 384     map { $libraries->{$_->id} = $_ } Koha::Libraries->search();
 385
 386     # group available items by itemnumber
 387     my %items_by_itemnumber = map { $_->{itemnumber} => $_ } @$available_items;
 388
 389     # items already allocated
 390     my %allocated_items = ();
 391
 392     # map of items to hold requests
 393     my %item_map = ();
 394
 395     # figure out which item-level requests can be filled
 396     my $num_items_remaining = scalar(@$available_items);
 397
 398     # Look for Local Holds Priority matches first
 399     if ( C4::Context->preference('LocalHoldsPriority') ) {
 400         my $LocalHoldsPriorityPatronControl =
 401           C4::Context->preference('LocalHoldsPriorityPatronControl');
 402         my $LocalHoldsPriorityItemControl =
 403           C4::Context->preference('LocalHoldsPriorityItemControl');
 404
 405         foreach my $request (@$hold_requests) {
 406             next if (defined($request->{itemnumber})); #skip item level holds in local priority checking
 407             last if $num_items_remaining == 0;
 408
 409             my $local_hold_match;
 410             foreach my $item (@$available_items) {
 411                 next
 412                   if ( !$item->{holdallowed} )
 413                   || ( $item->{holdallowed} == 1
 414                     && $item->{homebranch} ne $request->{borrowerbranch} );
 415
 416                 next unless $item->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 417
 418                 my $local_holds_priority_item_branchcode =
 419                   $item->{$LocalHoldsPriorityItemControl};
 420
 421                 my $local_holds_priority_patron_branchcode =
 422                   ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 423                   ? $request->{branchcode}
 424                   : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 425                   ? $request->{borrowerbranch}
 426                   : undef;
 427
 428                 $local_hold_match =
 429                   $local_holds_priority_item_branchcode eq
 430                   $local_holds_priority_patron_branchcode;
 431
 432                 if ($local_hold_match) {
 433                     if ( exists $items_by_itemnumber{ $item->{itemnumber} }
 434                         and not exists $allocated_items{ $item->{itemnumber} }
 435                         and not $request->{allocated})
 436                     {
 437                         $item_map{ $item->{itemnumber} } = {
 438                             borrowernumber => $request->{borrowernumber},
 439                             biblionumber   => $request->{biblionumber},
 440                             holdingbranch  => $item->{holdingbranch},
 441                             pickup_branch  => $request->{branchcode}
 442                               || $request->{borrowerbranch},
 443                             item_level   => 0,
 444                             reservedate  => $request->{reservedate},
 445                             reservenotes => $request->{reservenotes},
 446                         };
 447                         $allocated_items{ $item->{itemnumber} }++;
 448                         $request->{allocated} = 1;
 449                         $num_items_remaining--;
 450                     }
 451                 }
 452             }
 453         }
 454     }
 455
 456     foreach my $request (@$hold_requests) {
 457         last if $num_items_remaining == 0;
 458         next if $request->{allocated};
 459
 460         # is this an item-level request?
 461         if (defined($request->{itemnumber})) {
 462             # fill it if possible; if not skip it
 463             if (
 464                     exists $items_by_itemnumber{ $request->{itemnumber} }
 465                 and not exists $allocated_items{ $request->{itemnumber} }
 466                 and ( # Don't fill item level holds that contravene the hold pickup policy at this time
 467                     ( $items_by_itemnumber{ $request->{itemnumber} }->{hold_fulfillment_policy} eq 'any' )
 468                     || ( $request->{branchcode} eq $items_by_itemnumber{ $request->{itemnumber} }->{ $items_by_itemnumber{ $request->{itemnumber} }->{hold_fulfillment_policy} }  )
 469                 and ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 470                     || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 471                 )
 472                 and $items_by_itemnumber{ $request->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } )
 473
 474               )
 475             {
 476
 477                 $item_map{ $request->{itemnumber} } = {
 478                     borrowernumber => $request->{borrowernumber},
 479                     biblionumber   => $request->{biblionumber},
 480                     holdingbranch  => $items_by_itemnumber{ $request->{itemnumber} }->{holdingbranch},
 481                     pickup_branch  => $request->{branchcode} || $request->{borrowerbranch},
 482                     item_level     => 1,
 483                     reservedate    => $request->{reservedate},
 484                     reservenotes   => $request->{reservenotes},
 485                 };
 486                 $allocated_items{ $request->{itemnumber} }++;
 487                 $num_items_remaining--;
 488             }
 489         } else {
 490             # it's title-level request that will take up one item
 491             $num_items_remaining--;
 492         }
 493     }
 494
 495     # group available items by branch
 496     my %items_by_branch = ();
 497     foreach my $item (@$available_items) {
 498         next unless $item->{holdallowed};
 499
 500         push @{ $items_by_branch{ $item->{holdingbranch} } }, $item
 501           unless exists $allocated_items{ $item->{itemnumber} };
 502     }
 503     return \%item_map unless keys %items_by_branch;
 504
 505     # now handle the title-level requests
 506     $num_items_remaining = scalar(@$available_items) - scalar(keys %allocated_items);
 507     my $pull_branches;
 508     foreach my $request (@$hold_requests) {
 509         last if $num_items_remaining == 0;
 510         next if $request->{allocated};
 511         next if defined($request->{itemnumber}); # already handled these
 512
 513         # look for local match first
 514         my $pickup_branch = $request->{branchcode} || $request->{borrowerbranch};
 515         my ($itemnumber, $holdingbranch);
 516
 517         my $holding_branch_items = $items_by_branch{$pickup_branch};
 518         if ( $holding_branch_items ) {
 519             foreach my $item (@$holding_branch_items) {
 520                 next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 521
 522                 if (
 523                     $request->{borrowerbranch} eq $item->{homebranch}
 524                     && ( ( $item->{hold_fulfillment_policy} eq 'any' ) # Don't fill item level holds that contravene the hold pickup policy at this time
 525                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} } )
 526                     && ( !$request->{itemtype} # If hold itemtype is set, item's itemtype must match
 527                         || $items_by_itemnumber{ $request->{itemnumber} }->{itype} eq $request->{itemtype} )
 528                   )
 529                 {
 530                     $itemnumber = $item->{itemnumber};
 531                     last;
 532                 }
 533             }
 534             $holdingbranch = $pickup_branch;
 535         }
 536         elsif ($transport_cost_matrix) {
 537             $pull_branches = [keys %items_by_branch];
 538             $holdingbranch = least_cost_branch( $pickup_branch, $pull_branches, $transport_cost_matrix );
 539             if ( $holdingbranch ) {
 540
 541                 my $holding_branch_items = $items_by_branch{$holdingbranch};
 542                 foreach my $item (@$holding_branch_items) {
 543                     next if $request->{borrowerbranch} ne $item->{homebranch};
 544                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 545
 546                     # Don't fill item level holds that contravene the hold pickup policy at this time
 547                     next unless $item->{hold_fulfillment_policy} eq 'any'
 548                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 549
 550                     # If hold itemtype is set, item's itemtype must match
 551                     next unless ( !$request->{itemtype}
 552                         || $item->{itype} eq $request->{itemtype} );
 553
 554                     $itemnumber = $item->{itemnumber};
 555                     last;
 556                 }
 557             }
 558             else {
 559                 next;
 560             }
 561         }
 562
 563         unless ($itemnumber) {
 564             # not found yet, fall back to basics
 565             if ($branches_to_use) {
 566                 $pull_branches = $branches_to_use;
 567             } else {
 568                 $pull_branches = [keys %items_by_branch];
 569             }
 570
 571             # Try picking items where the home and pickup branch match first
 572             PULL_BRANCHES:
 573             foreach my $branch (@$pull_branches) {
 574                 my $holding_branch_items = $items_by_branch{$branch}
 575                   or next;
 576
 577                 $holdingbranch ||= $branch;
 578                 foreach my $item (@$holding_branch_items) {
 579                     next if $pickup_branch ne $item->{homebranch};
 580                     next if ( $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch} );
 581                     next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 582
 583                     # Don't fill item level holds that contravene the hold pickup policy at this time
 584                     next unless $item->{hold_fulfillment_policy} eq 'any'
 585                         || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 586
 587                     # If hold itemtype is set, item's itemtype must match
 588                     next unless ( !$request->{itemtype}
 589                         || $item->{itype} eq $request->{itemtype} );
 590
 591                     $itemnumber = $item->{itemnumber};
 592                     $holdingbranch = $branch;
 593                     last PULL_BRANCHES;
 594                 }
 595             }
 596
 597             # Now try items from the least cost branch based on the transport cost matrix or StaticHoldsQueueWeight
 598             unless ( $itemnumber ) {
 599                 foreach my $current_item ( @{ $items_by_branch{$holdingbranch} } ) {
 600                     if ( $holdingbranch && ( $current_item->{holdallowed} == 2 || $request->{borrowerbranch} eq $current_item->{homebranch} ) ) {
 601
 602                         # Don't fill item level holds that contravene the hold pickup policy at this time
 603                         next unless $current_item->{hold_fulfillment_policy} eq 'any'
 604                             || $request->{branchcode} eq $current_item->{ $current_item->{hold_fulfillment_policy} };
 605
 606                         # If hold itemtype is set, item's itemtype must match
 607                         next unless ( !$request->{itemtype}
 608                             || $current_item->{itype} eq $request->{itemtype} );
 609
 610                         next unless $items_by_itemnumber{ $current_item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 611
 612                         $itemnumber = $current_item->{itemnumber};
 613                         last; # quit this loop as soon as we have a suitable item
 614                     }
 615                 }
 616             }
 617
 618             # Now try for items for any item that can fill this hold
 619             unless ( $itemnumber ) {
 620                 PULL_BRANCHES2:
 621                 foreach my $branch (@$pull_branches) {
 622                     my $holding_branch_items = $items_by_branch{$branch}
 623                       or next;
 624
 625                     foreach my $item (@$holding_branch_items) {
 626                         next if ( $item->{holdallowed} == 1 && $item->{homebranch} ne $request->{borrowerbranch} );
 627
 628                         # Don't fill item level holds that contravene the hold pickup policy at this time
 629                         next unless $item->{hold_fulfillment_policy} eq 'any'
 630                             || $request->{branchcode} eq $item->{ $item->{hold_fulfillment_policy} };
 631
 632                         # If hold itemtype is set, item's itemtype must match
 633                         next unless ( !$request->{itemtype}
 634                             || $item->{itype} eq $request->{itemtype} );
 635
 636                         next unless $items_by_itemnumber{ $item->{itemnumber} }->{_object}->can_be_transferred( { to => $libraries->{ $request->{branchcode} } } );
 637
 638                         $itemnumber = $item->{itemnumber};
 639                         $holdingbranch = $branch;
 640                         last PULL_BRANCHES2;
 641                     }
 642                 }
 643             }
 644         }
 645
 646         if ($itemnumber) {
 647             my $holding_branch_items = $items_by_branch{$holdingbranch}
 648               or die "Have $itemnumber, $holdingbranch, but no items!";
 649             @$holding_branch_items = grep { $_->{itemnumber} != $itemnumber } @$holding_branch_items;
 650             delete $items_by_branch{$holdingbranch} unless @$holding_branch_items;
 651
 652             $item_map{$itemnumber} = {
 653                 borrowernumber => $request->{borrowernumber},
 654                 biblionumber => $request->{biblionumber},
 655                 holdingbranch => $holdingbranch,
 656                 pickup_branch => $pickup_branch,
 657                 item_level => 0,
 658                 reservedate => $request->{reservedate},
 659                 reservenotes => $request->{reservenotes},
 660             };
 661             $num_items_remaining--;
 662         }
 663     }
 664     return \%item_map;
 665 }
 666
 667 =head2 CreatePickListFromItemMap
 668
 669 =cut
 670
 671 sub CreatePicklistFromItemMap {
 672     my $item_map = shift;
 673
 674     my $dbh = C4::Context->dbh;
 675
 676     my $sth_load=$dbh->prepare("
 677         INSERT INTO tmp_holdsqueue (biblionumber,itemnumber,barcode,surname,firstname,phone,borrowernumber,
 678                                     cardnumber,reservedate,title, itemcallnumber,
 679                                     holdingbranch,pickbranch,notes, item_level_request)
 680         VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 681     ");
 682
 683     foreach my $itemnumber  (sort keys %$item_map) {
 684         my $mapped_item = $item_map->{$itemnumber};
 685         my $biblionumber = $mapped_item->{biblionumber};
 686         my $borrowernumber = $mapped_item->{borrowernumber};
 687         my $pickbranch = $mapped_item->{pickup_branch};
 688         my $holdingbranch = $mapped_item->{holdingbranch};
 689         my $reservedate = $mapped_item->{reservedate};
 690         my $reservenotes = $mapped_item->{reservenotes};
 691         my $item_level = $mapped_item->{item_level};
 692
 693         my $item = Koha::Items->find($itemnumber);
 694         my $barcode = $item->barcode;
 695         my $itemcallnumber = $item->itemcallnumber;
 696
 697         my $patron = Koha::Patrons->find( $borrowernumber );
 698         my $cardnumber = $patron->cardnumber;
 699         my $surname = $patron->surname;
 700         my $firstname = $patron->firstname;
 701         my $phone = $patron->phone;
 702
 703         my $biblio = Koha::Biblios->find( $biblionumber );
 704         my $title = $biblio->title;
 705
 706         $sth_load->execute($biblionumber, $itemnumber, $barcode, $surname, $firstname, $phone, $borrowernumber,
 707                            $cardnumber, $reservedate, $title, $itemcallnumber,
 708                            $holdingbranch, $pickbranch, $reservenotes, $item_level);
 709     }
 710 }
 711
 712 =head2 AddToHoldTargetMap
 713
 714 =cut
 715
 716 sub AddToHoldTargetMap {
 717     my $item_map = shift;
 718
 719     my $dbh = C4::Context->dbh;
 720
 721     my $insert_sql = q(
 722         INSERT INTO hold_fill_targets (borrowernumber, biblionumber, itemnumber, source_branchcode, item_level_request)
 723                                VALUES (?, ?, ?, ?, ?)
 724     );
 725     my $sth_insert = $dbh->prepare($insert_sql);
 726
 727     foreach my $itemnumber (keys %$item_map) {
 728         my $mapped_item = $item_map->{$itemnumber};
 729         $sth_insert->execute($mapped_item->{borrowernumber}, $mapped_item->{biblionumber}, $itemnumber,
 730                              $mapped_item->{holdingbranch}, $mapped_item->{item_level});
 731     }
 732 }
 733
 734 # Helper functions, not part of any interface
 735
 736 sub _trim {
 737     return $_[0] unless $_[0];
 738     $_[0] =~ s/^\s+//;
 739     $_[0] =~ s/\s+$//;
 740     $_[0];
 741 }
 742
 743 sub load_branches_to_pull_from {
 744     my @branches_to_use;
 745
 746     my $static_branch_list = C4::Context->preference("StaticHoldsQueueWeight");
 747     @branches_to_use = map { _trim($_) } split( /,/, $static_branch_list )
 748       if $static_branch_list;
 749
 750     @branches_to_use =
 751       Koha::Database->new()->schema()->resultset('Branch')
 752       ->get_column('branchcode')->all()
 753       unless (@branches_to_use);
 754
 755     @branches_to_use = shuffle(@branches_to_use)
 756       if C4::Context->preference("RandomizeHoldsQueueWeight");
 757
 758     my $today = dt_from_string();
 759     if ( C4::Context->preference('HoldsQueueSkipClosed') ) {
 760         @branches_to_use = grep {
 761             !Koha::Calendar->new( branchcode => $_ )
 762               ->is_holiday( $today )
 763         } @branches_to_use;
 764     }
 765
 766     return \@branches_to_use;
 767 }
 768
 769 sub least_cost_branch {
 770
 771     #$from - arrayref
 772     my ($to, $from, $transport_cost_matrix) = @_;
 773
 774     # Nothing really spectacular: supply to branch, a list of potential from branches
 775     # and find the minimum from - to value from the transport_cost_matrix
 776     return $from->[0] if ( @$from == 1 && $transport_cost_matrix->{$to}{$from->[0]}->{disable_transfer} != 1 );
 777
 778     # If the pickup library is in the list of libraries to pull from,
 779     # return that library right away, it is obviously the least costly
 780     return ($to) if any { $_ eq $to } @$from;
 781
 782     my ($least_cost, @branch);
 783     foreach (@$from) {
 784         my $cell = $transport_cost_matrix->{$to}{$_};
 785         next if $cell->{disable_transfer};
 786
 787         my $cost = $cell->{cost};
 788         next unless defined $cost; # XXX should this be reported?
 789
 790         unless (defined $least_cost) {
 791             $least_cost = $cost;
 792             push @branch, $_;
 793             next;
 794         }
 795
 796         next if $cost > $least_cost;
 797
 798         if ($cost == $least_cost) {
 799             push @branch, $_;
 800             next;
 801         }
 802
 803         @branch = ($_);
 804         $least_cost = $cost;
 805     }
 806
 807     return $branch[0];
 808
 809     # XXX return a random @branch with minimum cost instead of the first one;
 810     # return $branch[0] if @branch == 1;
 811 }
 812
 813
 814 1;