C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use CGI;
  27 use List::MoreUtils qw( any );
  28 use C4::Context;
  29 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  30
  31 eval {
  32     if (C4::Context->ismemcached) {
  33         require Memoize::Memcached;
  34         import Memoize::Memcached qw(memoize_memcached);
  35
  36         memoize_memcached('getTranslatedLanguages', memcached => C4::Context->memcached);
  37         memoize_memcached('getFrameworkLanguages' , memcached => C4::Context->memcached);
  38         memoize_memcached('getAllLanguages',        memcached => C4::Context->memcached);
  39     }
  40 };
  41
  42 BEGIN {
  43     require Exporter;
  44     @ISA    = qw(Exporter);
  45     @EXPORT = qw(
  46         &getFrameworkLanguages
  47         &getTranslatedLanguages
  48         &getLanguages
  49         &getAllLanguages
  50     );
  51     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages getLanguages get_bidi regex_lang_subtags language_get_description accept_language getlanguage);
  52     $DEBUG = 0;
  53 }
  54
  55 =head1 NAME
  56
  57 C4::Languages - Perl Module containing language list functions for Koha
  58
  59 =head1 SYNOPSIS
  60
  61 use C4::Languages;
  62
  63 =head1 DESCRIPTION
  64
  65 =cut
  66
  67 =head1 FUNCTIONS
  68
  69 =head2 getFrameworkLanguages
  70
  71 Returns a reference to an array of hashes:
  72
  73  my $languages = getFrameworkLanguages();
  74  for my $language(@$languages) {
  75     print "$language->{language_code}\n"; # language code in iso 639-2
  76     print "$language->{language_name}\n"; # language name in native script
  77     print "$language->{language_locale_name}\n"; # language name in current locale
  78  }
  79
  80 =cut
  81
  82 sub getFrameworkLanguages {
  83     # get a hash with all language codes, names, and locale names
  84     my $all_languages = getAllLanguages();
  85     my @languages;
  86
  87     # find the available directory names
  88     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  89     opendir (MYDIR,$dir);
  90     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  91     closedir MYDIR;
  92
  93     # pull out all data for the dir names that exist
  94     for my $dirname (@listdir) {
  95         for my $language_set (@$all_languages) {
  96
  97             if ($dirname eq $language_set->{language_code}) {
  98                 push @languages, {
  99                     'language_code'=>$dirname,
 100                     'language_description'=>$language_set->{language_description},
 101                     'native_descrition'=>$language_set->{language_native_description} }
 102             }
 103         }
 104     }
 105     return \@languages;
 106 }
 107
 108 =head2 getTranslatedLanguages
 109
 110 Returns a reference to an array of hashes:
 111
 112  my $languages = getTranslatedLanguages();
 113  print "Available translated languages:\n";
 114  for my $language(@$trlanguages) {
 115     print "$language->{language_code}\n"; # language code in iso 639-2
 116     print "$language->{language_name}\n"; # language name in native script
 117     print "$language->{language_locale_name}\n"; # language name in current locale
 118  }
 119
 120 =cut
 121
 122 sub getTranslatedLanguages {
 123     my ($interface, $theme, $current_language, $which) = @_;
 124     my $htdocs;
 125     my @languages;
 126     my @enabled_languages;
 127
 128     if ($interface && $interface eq 'opac' ) {
 129         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 130         $htdocs = C4::Context->config('opachtdocs');
 131         if ( $theme and -d "$htdocs/$theme" ) {
 132             (@languages) = _get_language_dirs($htdocs,$theme);
 133         }
 134         else {
 135             for my $theme ( _get_themes('opac') ) {
 136                 push @languages, _get_language_dirs($htdocs,$theme);
 137             }
 138         }
 139     }
 140     elsif ($interface && $interface eq 'intranet' ) {
 141         @enabled_languages = split ",", C4::Context->preference('language');
 142         $htdocs = C4::Context->config('intrahtdocs');
 143         if ( $theme and -d "$htdocs/$theme" ) {
 144             @languages = _get_language_dirs($htdocs,$theme);
 145         }
 146         else {
 147             foreach my $theme ( _get_themes('intranet') ) {
 148                 push @languages, _get_language_dirs($htdocs,$theme);
 149             }
 150         }
 151     }
 152     else {
 153         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 154         my $htdocs = C4::Context->config('intrahtdocs');
 155         foreach my $theme ( _get_themes('intranet') ) {
 156             push @languages, _get_language_dirs($htdocs,$theme);
 157         }
 158         $htdocs = C4::Context->config('opachtdocs');
 159         foreach my $theme ( _get_themes('opac') ) {
 160             push @languages, _get_language_dirs($htdocs,$theme);
 161         }
 162         my %seen;
 163         $seen{$_}++ for @languages;
 164         @languages = keys %seen;
 165     }
 166     return _build_languages_arrayref(\@languages,$current_language,\@enabled_languages);
 167 }
 168
 169 =head2 getAllLanguages
 170
 171 Returns a reference to an array of hashes:
 172
 173  my $alllanguages = getAllLanguages();
 174  print "Available translated languages:\n";
 175  for my $language(@$alllanguages) {
 176     print "$language->{language_code}\n";
 177     print "$language->{language_name}\n";
 178     print "$language->{language_locale_name}\n";
 179  }
 180
 181 This routine is a wrapper for getLanguages().
 182
 183 =cut
 184
 185 sub getAllLanguages {
 186     return getLanguages(shift);
 187 }
 188
 189 =head2 getLanguages
 190
 191     my $lang_arrayref = getLanguages([$lang[, $isFiltered]]);
 192
 193 Returns a reference to an array of hashes of languages.
 194
 195 - If no parameter is passed to the function, it returns english languages names
 196 - If a $lang parameter conforming to RFC4646 syntax is passed, the function returns languages names translated in $lang
 197   If a language name is not translated in $lang in database, the function returns english language name
 198 - If $isFiltered is set to true, only the detail of the languages selected in system preferences AdvanceSearchLanguages is returned.
 199
 200 =cut
 201
 202 sub getLanguages {
 203     my $lang = shift;
 204     my $isFiltered = shift;
 205
 206     my @languages_loop;
 207     my $dbh=C4::Context->dbh;
 208     my $default_language = 'en';
 209     my $current_language = $default_language;
 210     my $language_list = $isFiltered ? C4::Context->preference("AdvancedSearchLanguages") : undef;
 211     if ($lang) {
 212         $current_language = regex_lang_subtags($lang)->{'language'};
 213     }
 214     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 215     $sth->execute();
 216     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 217         my $desc;
 218         # check if language name is stored in current language
 219         my $sth4= $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag =? AND lang = ?");
 220         $sth4->execute($language_subtag_registry->{subtag},$current_language);
 221         while (my $language_desc = $sth4->fetchrow_hashref) {
 222              $desc=$language_desc->{description};
 223         }
 224         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 225         if ($desc) {
 226             $sth2->execute($language_subtag_registry->{subtag},$current_language);
 227         }
 228         else {
 229             $sth2->execute($language_subtag_registry->{subtag},$default_language);
 230         }
 231         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 232         # add the correct description info
 233         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 234             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 235             my $native_description;
 236             while (my $description = $sth3->fetchrow_hashref) {
 237                 $native_description = $description->{description};
 238             }
 239
 240             # fill in the ISO6329 code
 241             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 242             # fill in the native description of the language, as well as the current language's translation of that if it exists
 243             if ($native_description) {
 244                 $language_subtag_registry->{language_description} = $native_description;
 245                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 246             }
 247             else {
 248                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 249             }
 250         }
 251         # Do not push unless valid iso639-2 code
 252         if ( $language_subtag_registry->{ iso639_2_code } and ( !$language_list || index (  $language_list, $language_subtag_registry->{ iso639_2_code } ) >= 0) ) {
 253             push @languages_loop, $language_subtag_registry;
 254         }
 255     }
 256     return \@languages_loop;
 257 }
 258
 259 =head2 _get_themes
 260
 261 Internal function, returns an array of all available themes.
 262
 263   (@themes) = &_get_themes('opac');
 264   (@themes) = &_get_themes('intranet');
 265
 266 =cut
 267
 268 sub _get_themes {
 269     my $interface = shift;
 270     my $htdocs;
 271     my @themes;
 272     if ( $interface && $interface eq 'intranet' ) {
 273         $htdocs = C4::Context->config('intrahtdocs');
 274     }
 275     else {
 276         $htdocs = C4::Context->config('opachtdocs');
 277     }
 278     opendir D, "$htdocs";
 279     my @dirlist = readdir D;
 280     foreach my $directory (@dirlist) {
 281         # if there's an en dir, it's a valid theme
 282         -d "$htdocs/$directory/en" and push @themes, $directory;
 283     }
 284     return @themes;
 285 }
 286
 287 =head2 _get_language_dirs
 288
 289 Internal function, returns an array of directory names, excluding non-language directories
 290
 291 =cut
 292
 293 sub _get_language_dirs {
 294     my ($htdocs,$theme) = @_;
 295     $htdocs //= '';
 296     $theme //= '';
 297     my @lang_strings;
 298     opendir D, "$htdocs/$theme";
 299     for my $lang_string ( readdir D ) {
 300         next if $lang_string =~/^\./;
 301         next if $lang_string eq 'all';
 302         next if $lang_string =~/png$/;
 303         next if $lang_string =~/js$/;
 304         next if $lang_string =~/css$/;
 305         next if $lang_string =~/CVS$/;
 306         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 307         next if $lang_string =~/img|images|famfam|js|less|lib|sound|pdf/;
 308         push @lang_strings, $lang_string;
 309     }
 310         return (@lang_strings);
 311 }
 312
 313 =head2 _build_languages_arrayref
 314
 315 Internal function for building the ref to array of hashes
 316
 317 FIXME: this could be rewritten and simplified using map
 318
 319 =cut
 320
 321 sub _build_languages_arrayref {
 322         my ($translated_languages,$current_language,$enabled_languages) = @_;
 323         $current_language //= '';
 324         my @translated_languages = @$translated_languages;
 325         my @languages_loop; # the final reference to an array of hashrefs
 326         my @enabled_languages = @$enabled_languages;
 327         # how many languages are enabled, if one, take note, some contexts won't need to display it
 328         my %seen_languages; # the language tags we've seen
 329         my %found_languages;
 330         my $language_groups;
 331         my $track_language_groups;
 332         my $current_language_regex = regex_lang_subtags($current_language);
 333         # Loop through the translated languages
 334         for my $translated_language (@translated_languages) {
 335             # separate the language string into its subtag types
 336             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 337
 338             # is this language string 'enabled'?
 339             for my $enabled_language (@enabled_languages) {
 340                 #warn "Checking out if $translated_language eq $enabled_language";
 341                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 342             }
 343
 344             # group this language, key by langtag
 345             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 346             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 347             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 348             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 349             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 350             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 351             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 352             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 353         }
 354         # $key is a language subtag like 'en'
 355         while( my ($key, $value) = each %$language_groups) {
 356
 357             # is this language group enabled? are any of the languages within it enabled?
 358             my $enabled;
 359             for my $enabled_language (@enabled_languages) {
 360                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 361                 $enabled = 1 if $key eq ($regex_enabled_language->{language} // '');
 362             }
 363             push @languages_loop,  {
 364                             # this is only use if there is one
 365                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 366                             native_description => language_get_description($key,$key,'language'),
 367                             language => $key,
 368                             sublanguages_loop => $value,
 369                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 370                             current => ($current_language_regex->{language} // '') eq $key ? 1 : 0,
 371                             group_enabled => $enabled,
 372                            };
 373         }
 374         return \@languages_loop;
 375 }
 376
 377 sub language_get_description {
 378     my ($script,$lang,$type) = @_;
 379     my $dbh = C4::Context->dbh;
 380     my $desc;
 381     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 382     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 383     $sth->execute($script,$lang,$type);
 384     while (my $descriptions = $sth->fetchrow_hashref) {
 385         $desc = $descriptions->{'description'};
 386     }
 387     unless ($desc) {
 388         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 389         $sth->execute($script,'en',$type);
 390         while (my $descriptions = $sth->fetchrow_hashref) {
 391             $desc = $descriptions->{'description'};
 392         }
 393     }
 394     return $desc;
 395 }
 396 =head2 regex_lang_subtags
 397
 398 This internal sub takes a string composed according to RFC 4646 as
 399 an input and returns a reference to a hash containing keys and values
 400 for ( language, script, region, variant, extension, privateuse )
 401
 402 =cut
 403
 404 sub regex_lang_subtags {
 405     my $string = shift;
 406
 407     # Regex for recognizing RFC 4646 well-formed tags
 408     # http://www.rfc-editor.org/rfc/rfc4646.txt
 409
 410     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 411     # The structure requires no forward references, so it reverses the order.
 412     # The uppercase comments are fragments copied from RFC 4646
 413     #
 414     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 415
 416     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 417     my $digit   = qr/[0-9]/ ;   # DIGIT
 418     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 419     my $x   = qr/[xX]/ ;    # private use singleton
 420     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 421     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 422
 423     # Now do the components. The structure is slightly different to allow for capturing the right components.
 424     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 425
 426     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 427     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 428     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 429
 430     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 431
 432     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 433
 434     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 435     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 436
 437     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 438     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 439
 440     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 441
 442     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 443     # Since these are limited, this is safe even later changes to the registry --
 444     # the only oddity is that it might change the type of the tag, and thus
 445     # the results from the capturing groups.
 446     # http://www.iana.org/assignments/language-subtag-registry
 447     # Note that these have to be compared case insensitively, requiring (?i) below.
 448
 449     my $grandfathered   = qr{(?: (?i)
 450         en $s GB $s oed
 451     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 452     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 453 )}x;
 454
 455     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 456
 457     #   |   art $s lojban
 458     #   |   cel $s gaulish
 459     #   |   en $s (?: boont | GB $s oed | scouse )
 460     #   |   no $s (?: bok | nyn)
 461     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 462
 463     # Here is the final breakdown, with capturing groups for each of these components
 464     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 465
 466     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 467
 468     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 469     my %subtag = (
 470         'rfc4646_subtag' => $string,
 471         'language' => $1,
 472         'script' => $2,
 473         'region' => $3,
 474         'variant' => $4,
 475         'extension' => $5,
 476         'privateuse' => $6,
 477     );
 478     return \%subtag;
 479 }
 480
 481 # Script Direction Resources:
 482 # http://www.w3.org/International/questions/qa-scripts
 483 sub get_bidi {
 484     my ($language_script)= @_;
 485     my $dbh = C4::Context->dbh;
 486     my $bidi;
 487     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 488     $sth->execute($language_script);
 489     while (my $result = $sth->fetchrow_hashref) {
 490         $bidi = $result->{'bidi'};
 491     }
 492     return $bidi;
 493 };
 494
 495 sub accept_language {
 496     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 497     my ($clientPreferences,$supportedLanguages) = @_;
 498     my @languages = ();
 499     if ($clientPreferences) {
 500         # There should be no whitespace anways, but a cleanliness/sanity check
 501         $clientPreferences =~ s/\s//g;
 502         # Prepare the list of client-acceptable languages
 503         foreach my $tag (split(/,/, $clientPreferences)) {
 504             my ($language, $quality) = split(/\;/, $tag);
 505             $quality =~ s/^q=//i if $quality;
 506             $quality = 1 unless $quality;
 507             next if $quality <= 0;
 508             # We want to force the wildcard to be last
 509             $quality = 0 if ($language eq '*');
 510             # Pushing lowercase language here saves processing later
 511             push(@languages, { quality => $quality,
 512                language => $language,
 513                lclanguage => lc($language) });
 514         }
 515     } else {
 516         carp "accept_language(x,y) called with no clientPreferences (x).";
 517     }
 518     # Prepare the list of server-supported languages
 519     my %supportedLanguages = ();
 520     my %secondaryLanguages = ();
 521     foreach my $language (@$supportedLanguages) {
 522         # warn "Language supported: " . $language->{language};
 523         my $subtag = $language->{rfc4646_subtag};
 524         $supportedLanguages{lc($subtag)} = $subtag;
 525         if ( $subtag =~ /^([^-]+)-?/ ) {
 526             $secondaryLanguages{lc($1)} = $subtag;
 527         }
 528     }
 529
 530     # Reverse sort the list, making best quality at the front of the array
 531     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 532     my $secondaryMatch = '';
 533     foreach my $tag (@languages) {
 534         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 535             # Client en-us eq server en-us
 536             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 537             return $supportedLanguages{$tag->{lclanguage}};
 538         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 539             # Client en eq server en-us
 540             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 541             return $supportedLanguages{$tag->{lclanguage}};
 542         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 543             # Client en-gb eq server en-us
 544             $secondaryMatch = $secondaryLanguages{$1};
 545         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 546             # FIXME: We just checked the exact same conditional!
 547             # Client en-us eq server en
 548             $secondaryMatch = $supportedLanguages{$1};
 549         } elsif ($tag->{lclanguage} eq '*') {
 550         # * matches every language not already specified.
 551         # It doesn't care which we pick, so let's pick the default,
 552         # if available, then the first in the array.
 553         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 554         return $supportedLanguages->[0];
 555         }
 556     }
 557     # No primary matches. Secondary? (ie, en-us requested and en supported)
 558     return $secondaryMatch if $secondaryMatch;
 559     return undef;   # else, we got nothing.
 560 }
 561
 562 =head2 getlanguage
 563
 564     Select a language based on the URL parameter 'language', a cookie,
 565     syspref available languages & browser
 566
 567 =cut
 568
 569 sub getlanguage {
 570     my ($cgi) = @_;
 571
 572     $cgi //= new CGI;
 573     my $interface = C4::Context->interface;
 574     my $theme = C4::Context->preference( ( $interface eq 'opac' ) ? 'opacthemes' : 'template' );
 575     my $language;
 576
 577     my $preference_to_check =
 578       $interface eq 'intranet' ? 'language' : 'opaclanguages';
 579     # Get the available/valid languages list
 580     my @languages;
 581     my $preference_value = C4::Context->preference($preference_to_check);
 582     if ($preference_value) {
 583         @languages = split /,/, $preference_value;
 584     }
 585
 586     # Chose language from the URL
 587     $language = $cgi->param( 'language' );
 588     if ( defined $language && any { $_ eq $language } @languages) {
 589         return $language;
 590     }
 591
 592     # cookie
 593     if ($language = $cgi->cookie('KohaOpacLanguage') ) {
 594         $language =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 595     }
 596
 597     # HTTP_ACCEPT_LANGUAGE
 598     if ( !$language && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 599         $language = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 600             getTranslatedLanguages( $interface, $theme ) );
 601     }
 602
 603     # Ignore a lang not selected in sysprefs
 604     if ( $language && any { $_ eq $language } @languages ) {
 605         return $language;
 606     }
 607
 608     # Pick the first selected syspref language
 609     $language = shift @languages;
 610     return $language if $language;
 611
 612     # Fall back to English if necessary
 613     return 'en';
 614 }
 615
 616 1;
 617
 618 __END__
 619
 620 =head1 AUTHOR
 621
 622 Joshua Ferraro
 623
 624 =cut