C4/SIP/ILS.pm

   1 #
   2 # ILS.pm: Koha ILS interface module
   3 #
   4
   5 package C4::SIP::ILS;
   6
   7 use warnings;
   8 use strict;
   9 use Sys::Syslog qw(syslog);
  10 use Data::Dumper;
  11
  12 use C4::SIP::ILS::Item;
  13 use C4::SIP::ILS::Patron;
  14 use C4::SIP::ILS::Transaction;
  15 use C4::SIP::ILS::Transaction::Checkout;
  16 use C4::SIP::ILS::Transaction::Checkin;
  17 use C4::SIP::ILS::Transaction::FeePayment;
  18 use C4::SIP::ILS::Transaction::Hold;
  19 use C4::SIP::ILS::Transaction::Renew;
  20 use C4::SIP::ILS::Transaction::RenewAll;
  21
  22 my $debug = 0;
  23
  24 my %supports = (
  25     'magnetic media'        => 1,
  26     'security inhibit'      => 0,
  27     'offline operation'     => 0,
  28     "patron status request" => 1,
  29     "checkout"              => 1,
  30     "checkin"               => 1,
  31     "block patron"          => 1,
  32     "acs status"            => 1,
  33     "login"                 => 1,
  34     "patron information"    => 1,
  35     "end patron session"    => 1,
  36     "fee paid"              => 1,
  37     "item information"      => 1,
  38     "item status update"    => 0,
  39     "patron enable"         => 1,
  40     "hold"                  => 1,
  41     "renew"                 => 1,
  42     "renew all"             => 1,
  43 );
  44
  45 sub new {
  46     my ($class, $institution) = @_;
  47     my $type = ref($class) || $class;
  48     my $self = {};
  49         $debug and warn "new ILS: INSTITUTION: " . Dumper($institution);
  50     syslog("LOG_DEBUG", "new ILS '%s'", $institution->{id});
  51     $self->{institution} = $institution;
  52     return bless $self, $type;
  53 }
  54
  55 sub find_patron {
  56     my $self = shift;
  57         $debug and warn "ILS: finding patron";
  58     return C4::SIP::ILS::Patron->new(@_);
  59 }
  60
  61 sub find_item {
  62     my $self = shift;
  63         $debug and warn "ILS: finding item";
  64     return C4::SIP::ILS::Item->new(@_);
  65 }
  66
  67 sub institution {
  68     my $self = shift;
  69     return $self->{institution}->{id};  # consider making this return the whole institution
  70 }
  71
  72 sub institution_id {
  73     my $self = shift;
  74     return $self->{institution}->{id};
  75 }
  76
  77 sub supports {
  78     my ($self, $op) = @_;
  79     return (exists($supports{$op}) && $supports{$op});
  80 }
  81
  82 sub check_inst_id {
  83     my ($self, $id, $whence) = @_;
  84     if ($id ne $self->{institution}->{id}) {
  85         syslog("LOG_WARNING", "%s: received institution '%s', expected '%s'", $whence, $id, $self->{institution}->{id});
  86         # Just an FYI check, we don't expect the user to change location from that in SIPconfig.xml
  87     }
  88 }
  89
  90 sub to_bool {
  91     my $bool = shift;
  92     # If it's defined, and matches a true sort of string, or is
  93     # a non-zero number, then it's true.
  94     defined($bool) or return;                   # false
  95     ($bool =~ /true|y|yes/i) and return 1;      # true
  96     return ($bool =~ /^\d+$/ and $bool != 0);   # true for non-zero numbers, false otherwise
  97 }
  98
  99 sub checkout_ok {
 100     my $self = shift;
 101     return (exists($self->{institution}->{policy}->{checkout})
 102             && to_bool($self->{institution}->{policy}->{checkout}));
 103 }
 104 sub checkin_ok {
 105     my $self = shift;
 106     return (exists($self->{institution}->{policy}->{checkin})
 107             && to_bool($self->{institution}->{policy}->{checkin}));
 108 }
 109 sub status_update_ok {
 110     my $self = shift;
 111     return (exists($self->{institution}->{policy}->{status_update})
 112             && to_bool($self->{institution}->{policy}->{status_update}));
 113 }
 114 sub offline_ok {
 115     my $self = shift;
 116     return (exists($self->{institution}->{policy}->{offline})
 117             && to_bool($self->{institution}->{policy}->{offline}));
 118 }
 119
 120 #
 121 # Checkout(patron_id, item_id, sc_renew):
 122 #    patron_id & item_id are the identifiers send by the terminal
 123 #    sc_renew is the renewal policy configured on the terminal
 124 # returns a status opject that can be queried for the various bits
 125 # of information that the protocol (SIP or NCIP) needs to generate
 126 # the response.
 127 #
 128 sub checkout {
 129     my ($self, $patron_id, $item_id, $sc_renew, $fee_ack) = @_;
 130     my ($patron, $item, $circ);
 131
 132     $circ = C4::SIP::ILS::Transaction::Checkout->new();
 133     # BEGIN TRANSACTION
 134     $circ->patron($patron = C4::SIP::ILS::Patron->new( $patron_id));
 135     $circ->item($item = C4::SIP::ILS::Item->new( $item_id));
 136     if ($fee_ack) {
 137         $circ->fee_ack($fee_ack);
 138     }
 139
 140     if (!$patron) {
 141                 $circ->screen_msg("Invalid Patron");
 142     } elsif (!$patron->charge_ok) {
 143                 $circ->screen_msg("Patron Blocked");
 144     } elsif (!$item) {
 145                 $circ->screen_msg("Invalid Item");
 146     # holds checked inside do_checkout
 147     # } elsif ($item->hold_queue && @{$item->hold_queue} && ! $item->barcode_is_borrowernumber($patron_id, $item->hold_queue->[0]->{borrowernumber})) {
 148         #       $circ->screen_msg("Item on Hold for Another User");
 149     } elsif ($item->{patron} && !_ci_cardnumber_cmp($item->{patron},$patron_id)) {
 150                 $circ->screen_msg("Item checked out to another patron");
 151     } else {
 152                 $circ->do_checkout();
 153                 if ($circ->ok){
 154                         $debug and warn "circ is ok";
 155                         # If the item is already associated with this patron, then
 156                         # we're renewing it.
 157                         $circ->renew_ok($item->{patron} && _ci_cardnumber_cmp($item->{patron}, $patron_id));
 158
 159                         $item->{patron} = $patron_id;
 160                         $item->{due_date} = $circ->{due};
 161                         push(@{$patron->{items}}, $item_id);
 162                         $circ->desensitize(!$item->magnetic_media);
 163
 164                         syslog("LOG_DEBUG", "ILS::Checkout: patron %s has checked out %s",
 165                                 $patron_id, join(', ', @{$patron->{items}}));
 166                 }
 167                 else {
 168                         syslog("LOG_ERR", "ILS::Checkout Issue failed");
 169                 }
 170     }
 171     # END TRANSACTION
 172
 173     return $circ;
 174 }
 175
 176 sub _ci_cardnumber_cmp {
 177     my ( $s1, $s2) = @_;
 178     # As the database is case insensitive we need to normalize two strings
 179     # before comparing them
 180     return ( uc($s1) eq uc($s2) );
 181 }
 182
 183 # wrapper which allows above to be called for testing
 184
 185 sub test_cardnumber_compare {
 186     my ($self, $str1, $str2) = @_;
 187     return _ci_cardnumber_cmp($str1, $str2);
 188 }
 189
 190 sub checkin {
 191     my ( $self, $item_id, $trans_date, $return_date, $current_loc, $item_props, $cancel, $checked_in_ok ) = @_;
 192     my ( $patron, $item, $circ );
 193
 194     $circ = C4::SIP::ILS::Transaction::Checkin->new();
 195
 196     # BEGIN TRANSACTION
 197     $circ->item( $item = C4::SIP::ILS::Item->new($item_id) );
 198
 199     if ($item) {
 200         $circ->do_checkin( $current_loc, $return_date );
 201     }
 202     else {
 203         $circ->alert(1);
 204         $circ->alert_type(99);
 205         $circ->screen_msg('Invalid Item');
 206     }
 207
 208     # It's ok to check it in if it exists, and if it was checked out
 209     # or it was not checked out but the checked_in_ok flag was set
 210     $circ->ok( ( $checked_in_ok && $item ) || ( $item && $item->{patron} ) );
 211     syslog("LOG_DEBUG", "C4::SIP::ILS::checkin - using checked_in_ok") if $checked_in_ok;
 212
 213     if ( !defined( $item->{patron} ) ) {
 214         $circ->screen_msg("Item not checked out") unless $checked_in_ok;
 215         syslog("LOG_DEBUG", "C4::SIP::ILS::checkin - item not checked out");
 216     }
 217     else {
 218         if ( $circ->ok ) {
 219             $circ->patron( $patron = C4::SIP::ILS::Patron->new( $item->{patron} ) );
 220             delete $item->{patron};
 221             delete $item->{due_date};
 222             $patron->{items} = [ grep { $_ ne $item_id } @{ $patron->{items} } ];
 223         }
 224     }
 225
 226     # END TRANSACTION
 227
 228     return $circ;
 229 }
 230
 231 # If the ILS caches patron information, this lets it free
 232 # it up
 233 sub end_patron_session {
 234     my ($self, $patron_id) = @_;
 235
 236     # success?, screen_msg, print_line
 237     return (1, 'Thank you !', '');
 238 }
 239
 240 sub pay_fee {
 241     my ($self, $patron_id, $patron_pwd, $fee_amt, $fee_type,
 242         $pay_type, $fee_id, $trans_id, $currency) = @_;
 243     my $trans;
 244
 245     $trans = C4::SIP::ILS::Transaction::FeePayment->new();
 246
 247
 248     $trans->transaction_id($trans_id);
 249     my $patron;
 250     $trans->patron($patron = C4::SIP::ILS::Patron->new($patron_id));
 251     if (!$patron) {
 252         $trans->screen_msg('Invalid patron barcode.');
 253         return $trans;
 254     }
 255     $trans->pay($patron->{borrowernumber},$fee_amt, $pay_type);
 256     $trans->ok(1);
 257
 258     return $trans;
 259 }
 260
 261 sub add_hold {
 262     my ($self, $patron_id, $patron_pwd, $item_id, $title_id,
 263         $expiry_date, $pickup_location, $hold_type, $fee_ack) = @_;
 264     my ($patron, $item);
 265
 266         my $trans = C4::SIP::ILS::Transaction::Hold->new();
 267
 268     $patron = C4::SIP::ILS::Patron->new( $patron_id);
 269     if (!$patron
 270         || (defined($patron_pwd) && !$patron->check_password($patron_pwd))) {
 271                 $trans->screen_msg("Invalid Patron.");
 272                 return $trans;
 273     }
 274
 275         unless ($item = C4::SIP::ILS::Item->new($item_id || $title_id)) {
 276                 $trans->screen_msg("No such item.");
 277                 return $trans;
 278         }
 279
 280     if ( $patron->holds_blocked_by_excessive_fees() ) {
 281         $trans->screen_msg("Excessive fees blocking placement of hold.");
 282     }
 283
 284    if ($item->fee and $fee_ack ne 'Y') {
 285                 $trans->screen_msg = "Fee required to place hold.";
 286                 return $trans;
 287     }
 288
 289     my $hold = {
 290         item_id         => $item->id,
 291         patron_id       => $patron->id,
 292         expiration_date => $expiry_date,
 293         pickup_location => $pickup_location,
 294         hold_type       => $hold_type,
 295     };
 296
 297     $trans->ok(1);
 298     $trans->patron($patron);
 299     $trans->item($item);
 300     $trans->pickup_location($pickup_location);
 301         $trans->do_hold;
 302
 303     push(@{$item->hold_queue},     $hold);
 304     push(@{$patron->{hold_items}}, $hold);
 305
 306     return $trans;
 307 }
 308
 309 sub cancel_hold {
 310     my ($self, $patron_id, $patron_pwd, $item_id, $title_id) = @_;
 311     my ($patron, $item, $hold);
 312
 313         my $trans = C4::SIP::ILS::Transaction::Hold->new();
 314
 315     $patron = C4::SIP::ILS::Patron->new( $patron_id );
 316     if (!$patron) {
 317                 $trans->screen_msg("Invalid patron barcode.");
 318                 return $trans;
 319     } elsif (defined($patron_pwd) && !$patron->check_password($patron_pwd)) {
 320                 $trans->screen_msg('Invalid patron password.');
 321                 return $trans;
 322     }
 323
 324     unless ($item = C4::SIP::ILS::Item->new($item_id || $title_id)) {
 325                 $trans->screen_msg("No such item.");
 326                 return $trans;
 327     }
 328
 329     $trans->patron($patron);
 330     $trans->item($item);
 331         $trans->drop_hold;
 332         unless ($trans->ok) {
 333                 $trans->screen_msg("Error with transaction drop_hold: " . $trans->screen_msg);
 334                 return $trans;
 335         }
 336     # Remove the hold from the patron's record first
 337     $trans->ok($patron->drop_hold($item_id));   # different than the transaction drop!
 338
 339     unless ($trans->ok) {
 340                 # We didn't find it on the patron record
 341                 $trans->screen_msg("No such hold on patron record.");
 342                 return $trans;
 343     }
 344
 345     # Now, remove it from the item record.  If it was on the patron
 346     # record but not on the item record, we'll treat that as success.
 347     foreach my $i (0 .. scalar @{$item->hold_queue}) {
 348                 $hold = $item->hold_queue->[$i];
 349                 if ($item->barcode_is_borrowernumber($patron->id, $hold->{borrowernumber})) {
 350                     # found it: delete it.
 351                     splice @{$item->hold_queue}, $i, 1;
 352                     last;               # ?? should we keep going, in case there are multiples
 353                 }
 354     }
 355
 356     $trans->screen_msg("Hold Cancelled.");
 357
 358     return $trans;
 359 }
 360
 361
 362 # The patron and item id's can't be altered, but the
 363 # date, location, and type can.
 364 sub alter_hold {
 365     my ($self, $patron_id, $patron_pwd, $item_id, $title_id,
 366         $expiry_date, $pickup_location, $hold_type, $fee_ack) = @_;
 367     my ($patron, $item);
 368     my $hold;
 369     my $trans;
 370
 371     $trans = C4::SIP::ILS::Transaction::Hold->new();
 372
 373     # BEGIN TRANSACTION
 374     $patron = C4::SIP::ILS::Patron->new( $patron_id );
 375     unless ($patron) {
 376                 $trans->screen_msg("Invalid patron barcode: '$patron_id'.");
 377                 return $trans;
 378     }
 379
 380     foreach my $i (0 .. scalar @{$patron->{hold_items}}) {
 381                 $hold = $patron->{hold_items}[$i];
 382
 383         if ($hold->{item_id} eq $item_id) {
 384             # Found it.  So fix it.
 385             $hold->{expiration_date} = $expiry_date     if $expiry_date;
 386             $hold->{pickup_location} = $pickup_location if $pickup_location;
 387             $hold->{hold_type}       = $hold_type       if $hold_type;
 388                 $trans->change_hold();
 389             # $trans->ok(1);
 390             $trans->screen_msg("Hold updated.");
 391             $trans->patron($patron);
 392             $trans->item(C4::SIP::ILS::Item->new( $hold->{item_id}));
 393             last;
 394         }
 395     }
 396
 397     # The same hold structure is linked into both the patron's
 398     # list of hold items and into the queue of outstanding holds
 399     # for the item, so we don't need to search the hold queue for
 400     # the item, since it's already been updated by the patron code.
 401
 402     if (!$trans->ok) {
 403                 $trans->screen_msg("No such outstanding hold.");
 404     }
 405
 406     return $trans;
 407 }
 408
 409 sub renew {
 410     my ($self, $patron_id, $patron_pwd, $item_id, $title_id,
 411         $no_block, $nb_due_date, $third_party,
 412         $item_props, $fee_ack) = @_;
 413     my ($patron, $item);
 414     my $trans;
 415
 416     $trans = C4::SIP::ILS::Transaction::Renew->new();
 417     $trans->patron($patron = C4::SIP::ILS::Patron->new( $patron_id ));
 418
 419     if (!$patron) {
 420                 $trans->screen_msg("Invalid patron barcode.");
 421                 return $trans;
 422     } elsif (!$patron->renew_ok) {
 423                 $trans->screen_msg("Renewals not allowed.");
 424                 return $trans;
 425     }
 426
 427         # Previously: renewing a title, rather than an item (sort of)
 428         # This is gross, but in a real ILS it would be better
 429
 430     # if (defined($title_id)) {
 431         #       foreach my $i (@{$patron->{items}}) {
 432         #               $item = new ILS::Item $i;
 433         #               last if ($title_id eq $item->title_id);
 434         #               $item = undef;
 435         #       }
 436     # } else {
 437                 my $j = 0;
 438                 my $count = scalar @{$patron->{items}};
 439                 foreach my $i (@{$patron->{items}}) {
 440             unless (defined $i->{barcode}) {    # FIXME: using data instead of objects may violate the abstraction layer
 441                 syslog("LOG_ERR", "No barcode for item %s of %s: $item_id", $j+1, $count);
 442                 next;
 443             }
 444             syslog("LOG_DEBUG", "checking item %s of %s: $item_id vs. %s", ++$j, $count, $i->{barcode});
 445             if ($i->{barcode} eq $item_id) {
 446                                 # We have it checked out
 447                                 $item = C4::SIP::ILS::Item->new( $item_id );
 448                                 last;
 449                         }
 450                 }
 451     # }
 452
 453     $trans->item($item);
 454
 455     if (!defined($item)) {
 456                 $trans->screen_msg("Item not checked out to " . $patron->name);     # not checked out to $patron_id
 457         $trans->ok(0);
 458     } else {
 459         $trans->do_renew();
 460         if ($trans->renewal_ok()) {
 461             $item->{due_date} = $trans->{due};
 462             $trans->desensitize(0);
 463         }
 464     }
 465
 466     return $trans;
 467 }
 468
 469 sub renew_all {
 470     my ($self, $patron_id, $patron_pwd, $fee_ack) = @_;
 471     my ($patron, $item_id);
 472     my $trans;
 473
 474     $trans = C4::SIP::ILS::Transaction::RenewAll->new();
 475
 476     $trans->patron($patron = C4::SIP::ILS::Patron->new( $patron_id ));
 477     if (defined $patron) {
 478         syslog("LOG_DEBUG", "ILS::renew_all: patron '%s': renew_ok: %s", $patron->name, $patron->renew_ok);
 479     } else {
 480         syslog("LOG_DEBUG", "ILS::renew_all: Invalid patron id: '%s'", $patron_id);
 481     }
 482
 483     if (!defined($patron)) {
 484                 $trans->screen_msg("Invalid patron barcode.");
 485                 return $trans;
 486     } elsif (!$patron->renew_ok) {
 487                 $trans->screen_msg("Renewals not allowed.");
 488                 return $trans;
 489     } elsif (defined($patron_pwd) && !$patron->check_password($patron_pwd)) {
 490                 $trans->screen_msg("Invalid patron password.");
 491                 return $trans;
 492     }
 493
 494         $trans->do_renew_all;
 495     $trans->ok(1);
 496     return $trans;
 497 }
 498
 499 1;
 500 __END__
 501