C4/Stats.pm

   1 package C4::Stats;
   2
   3
   4 # Copyright 2000-2002 Katipo Communications
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use strict;
  22 use warnings;
  23 require Exporter;
  24 use Carp;
  25 use C4::Context;
  26 use C4::Debug;
  27 use vars qw(@ISA @EXPORT);
  28
  29 our $debug;
  30
  31 BEGIN {
  32         @ISA    = qw(Exporter);
  33         @EXPORT = qw(
  34                 &UpdateStats
  35         );
  36 }
  37
  38
  39 =head1 NAME
  40
  41 C4::Stats - Update Koha statistics (log)
  42
  43 =head1 SYNOPSIS
  44
  45   use C4::Stats;
  46
  47 =head1 DESCRIPTION
  48
  49 The functions of this module deals with statistics table of Koha database.
  50
  51 =head1 FUNCTIONS
  52
  53 =head2 UpdateStats
  54
  55   &UpdateStats($params);
  56
  57 Adds an entry to the statistics table in the Koha database, which acts as an activity log.
  58
  59 C<$params> is an hashref whose expected keys are:
  60     branch             : the branch where the transaction occurred
  61     type               : the type of transaction (renew, issue, localuse, return, writeoff, payment
  62     itemnumber         : the itemnumber of the item
  63     borrowernumber     : the borrowernumber of the patron
  64     amount             : the amount of the transaction
  65     other              : sipmode
  66     itemtype           : the type of the item
  67     accountno          : the count
  68     ccode              : the collection code of the item
  69
  70 type key is mandatory.
  71 For types used in C4::Circulation (renew,issue,localuse,return), the following other keys are mandatory:
  72 branch, borrowernumber, itemnumber, ccode, itemtype
  73 For types used in C4::Accounts (writeoff, payment), the following other keys are mandatory:
  74 branch, borrowernumber, itemnumber, ccode, itemtype
  75 If an optional key is not provided, the value '' is used for this key.
  76
  77 Returns undef if no C<$param> is given
  78
  79 =cut
  80
  81 sub UpdateStats {
  82     my ($params) = @_;
  83 # make some controls
  84     return () if ! defined $params;
  85 # change these arrays if new types of transaction or new parameters are allowed
  86     my @allowed_keys = qw (type branch amount other itemnumber itemtype borrowernumber accountno ccode location);
  87     my @allowed_circulation_types = qw (renew issue localuse return onsite_checkout);
  88     my @allowed_accounts_types = qw (writeoff payment);
  89     my @circulation_mandatory_keys = qw (type branch borrowernumber itemnumber ccode itemtype);
  90     my @accounts_mandatory_keys = qw (type branch borrowernumber amount);
  91
  92     my @mandatory_keys = ();
  93     if (! exists $params->{type} or ! defined $params->{type}) {
  94         croak ("UpdateStats did not received type param");
  95     }
  96     if (grep ($_ eq $params->{type}, @allowed_circulation_types  )) {
  97         @mandatory_keys = @circulation_mandatory_keys;
  98     } elsif (grep ($_ eq $params->{type}, @allowed_accounts_types )) {
  99         @mandatory_keys = @accounts_mandatory_keys;
 100     } else {
 101         croak ("UpdateStats received forbidden type param: ".$params->{type});
 102     }
 103     my @missing_params = ();
 104     for my $mykey (@mandatory_keys ) {
 105         push @missing_params, $mykey if !grep (/^$mykey/, keys %$params);
 106     }
 107     if (scalar @missing_params > 0 ) {
 108         croak ("UpdateStats did not received mandatory param(s): ".join (", ",@missing_params ));
 109     }
 110     my @invalid_params = ();
 111     for my $myparam (keys %$params ) {
 112         push @invalid_params, $myparam unless grep (/^$myparam$/, @allowed_keys);
 113     }
 114     if (scalar @invalid_params > 0 ) {
 115         croak ("UpdateStats received invalid param(s): ".join (", ",@invalid_params ));
 116     }
 117 # get the parameters
 118     my $branch            = $params->{branch};
 119     my $type              = $params->{type};
 120     my $borrowernumber    = exists $params->{borrowernumber} ? $params->{borrowernumber} : '';
 121     my $itemnumber        = exists $params->{itemnumber}     ? $params->{itemnumber}     : undef;
 122     my $amount            = exists $params->{amount}         ? $params->{amount}         : 0;
 123     my $other             = exists $params->{other}          ? $params->{other}          : '';
 124     my $itemtype          = exists $params->{itemtype}       ? $params->{itemtype}       : '';
 125     my $location          = exists $params->{location}       ? $params->{location}       : undef;
 126     my $accountno         = exists $params->{accountno}      ? $params->{accountno}      : '';
 127     my $ccode             = exists $params->{ccode}          ? $params->{ccode}          : '';
 128
 129     my $dbh = C4::Context->dbh;
 130     my $sth = $dbh->prepare(
 131         "INSERT INTO statistics
 132         (datetime,
 133          branch,          type,        value,
 134          other,           itemnumber,  itemtype, location,
 135          borrowernumber,  proccode,    ccode)
 136          VALUES (now(),?,?,?,?,?,?,?,?,?,?)"
 137     );
 138     $sth->execute(
 139         $branch,     $type,     $amount,   $other,
 140         $itemnumber, $itemtype, $location, $borrowernumber,
 141         $accountno,  $ccode
 142     );
 143 }
 144
 145 1;
 146 __END__
 147
 148 =head1 AUTHOR
 149
 150 Koha Development Team <http://koha-community.org/>
 151
 152 =cut
 153