Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use DateTime::Format::DateParse;
  24 use C4::Context;
  25
  26 use base 'Exporter';
  27 use version; our $VERSION = qv('1.0.0');
  28
  29 our @EXPORT = (
  30     qw( dt_from_string output_pref format_sqldatetime )
  31 );
  32
  33 =head1 DateUtils
  34
  35 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  36
  37 =head1 DESCRIPTION
  38
  39 Koha has historically only used dates not datetimes and been content to
  40 handle these as strings. It also has confused formatting with actual dates
  41 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  42
  43 =cut
  44
  45 =head2 dt_ftom_string
  46
  47 $dt = dt_from_string($date_string, [$format, $timezone ]);
  48
  49 Passed a date string returns a DateTime object format and timezone default
  50 to the system preferences. If the date string is empty DateTime->now is returned
  51
  52 =cut
  53
  54 sub dt_from_string {
  55     my ( $date_string, $date_format, $tz ) = @_;
  56
  57     # FIXME: see bug 13242 => no TZ for dates 'infinite'
  58     return DateTime::Format::DateParse->parse_datetime($date_string)
  59         if $date_string and $date_string =~ /^9999-/;
  60
  61     if ( !$tz ) {
  62         $tz = C4::Context->tz;
  63     }
  64     if ( !$date_format ) {
  65         $date_format = C4::Context->preference('dateformat');
  66     }
  67     if ($date_string) {
  68         if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  69             return $date_string;
  70         }
  71
  72         if ( $date_format eq 'metric' ) {
  73             $date_string =~ s#-#/#g;
  74             $date_string =~ s/^00/01/;    # system allows the 0th of the month
  75             $date_string =~ s#^(\d{1,2})/(\d{1,2})#$2/$1#;
  76         } else {
  77             if ( $date_format eq 'iso' ) {
  78                 $date_string =~ s/-00/-01/;
  79                 if ( $date_string =~ m/^0000-0/ ) {
  80                     return;               # invalid date in db
  81                 }
  82             } elsif ( $date_format eq 'us' ) {
  83                 $date_string =~ s#-#/#g;
  84                 $date_string =~ s[/00/][/01/];
  85             } elsif ( $date_format eq 'sql' ) {
  86                 $date_string =~
  87 s/(\d{4})(\d{2})(\d{2})\s+(\d{2})(\d{2})(\d{2})/$1-$2-$3T$4:$5:$6/;
  88                 return if ($date_string =~ /^0000-00-00/);
  89                 $date_string =~ s/00T/01T/;
  90             }
  91         }
  92         return DateTime::Format::DateParse->parse_datetime( $date_string,
  93             $tz->name() );
  94     }
  95     return DateTime->now( time_zone => $tz );
  96
  97 }
  98
  99 =head2 output_pref
 100
 101 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 102 $date_string = output_pref( $dt );
 103
 104 Returns a string containing the time & date formatted as per the C4::Context setting,
 105 or C<undef> if C<undef> was provided.
 106
 107 This routine can either be passed a DateTime object or or a hashref.  If it is
 108 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 109 an optional 'dateformat' to override the dateformat system preference, an
 110 optional 'timeformat' to override the TimeFormat system preference value,
 111 and an optional 'dateonly' to specify that only the formatted date string
 112 should be returned without the time.
 113
 114 =cut
 115
 116 sub output_pref {
 117     my $params = shift;
 118     my ( $dt, $force_pref, $force_time, $dateonly, $as_due_date );
 119     if ( ref $params eq 'HASH' ) {
 120         $dt         = $params->{dt};
 121         $force_pref = $params->{dateformat};         # if testing we want to override Context
 122         $force_time = $params->{timeformat};
 123         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 124         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 125     } else {
 126         $dt = $params;
 127     }
 128
 129     return unless defined $dt;
 130
 131     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 132     if ( $dt->ymd !~ /^9999/ ) {
 133         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 134         $dt->set_time_zone( $tz );
 135     }
 136
 137     my $pref =
 138       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 139
 140     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 141     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 142     my $date;
 143     if ( $pref =~ m/^iso/ ) {
 144         $date = $dateonly
 145           ? $dt->strftime("%Y-%m-%d")
 146           : $dt->strftime("%Y-%m-%d $time");
 147     }
 148     elsif ( $pref =~ m/^metric/ ) {
 149         $date = $dateonly
 150           ? $dt->strftime("%d/%m/%Y")
 151           : $dt->strftime("%d/%m/%Y $time");
 152     }
 153     elsif ( $pref =~ m/^us/ ) {
 154         $date = $dateonly
 155           ? $dt->strftime("%m/%d/%Y")
 156           : $dt->strftime("%m/%d/%Y $time");
 157     }
 158     else {
 159         $date = $dateonly
 160           ? $dt->strftime("%Y-%m-%d")
 161           : $dt->strftime("%Y-%m-%d $time");
 162     }
 163
 164     if ( $as_due_date ) {
 165         $time_format eq '12hr'
 166             ? $date =~ s| 11:59 PM$||
 167             : $date =~ s| 23:59$||;
 168     }
 169
 170     return $date;
 171 }
 172
 173 =head2 format_sqldatetime
 174
 175 $string = format_sqldatetime( $string_as_returned_from_db );
 176
 177 a convenience routine for calling dt_from_string and formatting the result
 178 with output_pref as it is a frequent activity in scripts
 179
 180 =cut
 181
 182 sub format_sqldatetime {
 183     my $str        = shift;
 184     my $force_pref = shift;    # if testing we want to override Context
 185     my $force_time = shift;
 186     my $dateonly   = shift;
 187
 188     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 189         my $dt = dt_from_string( $str, 'sql' );
 190         return q{} unless $dt;
 191         $dt->truncate( to => 'minute' );
 192         return output_pref({
 193             dt => $dt,
 194             dateformat => $force_pref,
 195             timeformat => $force_time,
 196             dateonly => $dateonly
 197         });
 198     }
 199     return q{};
 200 }
 201
 202 1;