Koha/Hold.pm

   1 package Koha::Hold;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2017 Koha Development team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 3 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use Data::Dumper qw(Dumper);
  25
  26 use C4::Context qw(preference);
  27 use C4::Log;
  28
  29 use Koha::DateUtils qw(dt_from_string output_pref);
  30 use Koha::Patrons;
  31 use Koha::Biblios;
  32 use Koha::Items;
  33 use Koha::Libraries;
  34 use Koha::Old::Holds;
  35 use Koha::Calendar;
  36
  37 use base qw(Koha::Object);
  38
  39 =head1 NAME
  40
  41 Koha::Hold - Koha Hold object class
  42
  43 =head1 API
  44
  45 =head2 Class Methods
  46
  47 =cut
  48
  49 =head3 age
  50
  51 returns the number of days since a hold was placed, optionally
  52 using the calendar
  53
  54 my $age = $hold->age( $use_calendar );
  55
  56 =cut
  57
  58 sub age {
  59     my ( $self, $use_calendar ) = @_;
  60
  61     my $today = dt_from_string;
  62     my $age;
  63
  64     if ( $use_calendar ) {
  65         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
  66         $age = $calendar->days_between( dt_from_string( $self->reservedate ), $today );
  67     }
  68     else {
  69         $age = $today->delta_days( dt_from_string( $self->reservedate ) );
  70     }
  71
  72     $age = $age->in_units( 'days' );
  73
  74     return $age;
  75 }
  76
  77 =head3 suspend_hold
  78
  79 my $hold = $hold->suspend_hold( $suspend_until_dt );
  80
  81 =cut
  82
  83 sub suspend_hold {
  84     my ( $self, $dt ) = @_;
  85
  86     $dt = $dt ? $dt->clone()->truncate( to => 'day' ) : undef;
  87
  88     if ( $self->is_waiting ) {    # We can't suspend waiting holds
  89         carp "Unable to suspend waiting hold!";
  90         return $self;
  91     }
  92
  93     $self->suspend(1);
  94     $self->suspend_until( $dt );
  95
  96     $self->store();
  97
  98     logaction( 'HOLDS', 'SUSPEND', $self->reserve_id, Dumper($self->unblessed) )
  99         if C4::Context->preference('HoldsLog');
 100
 101     return $self;
 102 }
 103
 104 =head3 resume
 105
 106 my $hold = $hold->resume();
 107
 108 =cut
 109
 110 sub resume {
 111     my ( $self ) = @_;
 112
 113     $self->suspend(0);
 114     $self->suspend_until( undef );
 115
 116     $self->store();
 117
 118     logaction( 'HOLDS', 'RESUME', $self->reserve_id, Dumper($self->unblessed) )
 119         if C4::Context->preference('HoldsLog');
 120
 121     return $self;
 122 }
 123
 124 =head3 delete
 125
 126 $hold->delete();
 127
 128 =cut
 129
 130 sub delete {
 131     my ( $self ) = @_;
 132
 133     my $deleted = $self->SUPER::delete($self);
 134
 135     logaction( 'HOLDS', 'DELETE', $self->reserve_id, Dumper($self->unblessed) )
 136         if C4::Context->preference('HoldsLog');
 137
 138     return $deleted;
 139 }
 140
 141 =head3 set_waiting
 142
 143 =cut
 144
 145 sub set_waiting {
 146     my ( $self, $transferToDo ) = @_;
 147
 148     $self->priority(0);
 149
 150     if ($transferToDo) {
 151         $self->found('T')->store();
 152         return $self;
 153     }
 154
 155     my $today = dt_from_string();
 156     my $values = {
 157         found => 'W',
 158         waitingdate => $today->ymd,
 159     };
 160
 161     my $requested_expiration;
 162     if ($self->expirationdate) {
 163         $requested_expiration = dt_from_string($self->expirationdate);
 164     }
 165
 166     my $max_pickup_delay = C4::Context->preference("ReservesMaxPickUpDelay");
 167     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 168     my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
 169
 170     my $expirationdate = $today->clone;
 171     $expirationdate->add(days => $max_pickup_delay);
 172
 173     if ( C4::Context->preference("ExcludeHolidaysFromMaxPickUpDelay") ) {
 174         $expirationdate = $calendar->days_forward( dt_from_string(), $max_pickup_delay );
 175     }
 176
 177     # If patron's requested expiration date is prior to the
 178     # calculated one, we keep the patron's one.
 179     my $cmp = $requested_expiration ? DateTime->compare($requested_expiration, $expirationdate) : 0;
 180     $values->{expirationdate} = $cmp == -1 ? $requested_expiration->ymd : $expirationdate->ymd;
 181
 182     $self->set($values)->store();
 183
 184     return $self;
 185 }
 186
 187 =head3 is_found
 188
 189 Returns true if hold is a waiting or in transit
 190
 191 =cut
 192
 193 sub is_found {
 194     my ($self) = @_;
 195
 196     return 0 unless $self->found();
 197     return 1 if $self->found() eq 'W';
 198     return 1 if $self->found() eq 'T';
 199 }
 200
 201 =head3 is_waiting
 202
 203 Returns true if hold is a waiting hold
 204
 205 =cut
 206
 207 sub is_waiting {
 208     my ($self) = @_;
 209
 210     my $found = $self->found;
 211     return $found && $found eq 'W';
 212 }
 213
 214 =head3 is_in_transit
 215
 216 Returns true if hold is a in_transit hold
 217
 218 =cut
 219
 220 sub is_in_transit {
 221     my ($self) = @_;
 222
 223     return 0 unless $self->found();
 224     return $self->found() eq 'T';
 225 }
 226
 227 =head3 is_cancelable
 228
 229 Returns true if hold is a cancelable hold
 230
 231 Holds may be canceled if they not found, or
 232 are found and waiting. A hold found but in
 233 transit cannot be canceled.
 234
 235 =cut
 236
 237 sub is_cancelable {
 238     my ($self) = @_;
 239
 240     return 1 unless $self->is_found();
 241     return 0 if $self->is_in_transit();
 242     return 1 if $self->is_waiting();
 243     return 0;
 244 }
 245
 246 =head3 is_at_destination
 247
 248 Returns true if hold is waiting
 249 and the hold's pickup branch matches
 250 the hold item's holding branch
 251
 252 =cut
 253
 254 sub is_at_destination {
 255     my ($self) = @_;
 256
 257     return $self->is_waiting() && ( $self->branchcode() eq $self->item()->holdingbranch() );
 258 }
 259
 260 =head3 biblio
 261
 262 Returns the related Koha::Biblio object for this hold
 263
 264 =cut
 265
 266 sub biblio {
 267     my ($self) = @_;
 268
 269     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 270
 271     return $self->{_biblio};
 272 }
 273
 274 =head3 item
 275
 276 Returns the related Koha::Item object for this Hold
 277
 278 =cut
 279
 280 sub item {
 281     my ($self) = @_;
 282
 283     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 284
 285     return $self->{_item};
 286 }
 287
 288 =head3 branch
 289
 290 Returns the related Koha::Library object for this Hold
 291
 292 =cut
 293
 294 sub branch {
 295     my ($self) = @_;
 296
 297     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 298
 299     return $self->{_branch};
 300 }
 301
 302 =head3 borrower
 303
 304 Returns the related Koha::Patron object for this Hold
 305
 306 =cut
 307
 308 sub borrower {
 309     my ($self) = @_;
 310
 311     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 312
 313     return $self->{_borrower};
 314 }
 315
 316 =head3 is_suspended
 317
 318 my $bool = $hold->is_suspended();
 319
 320 =cut
 321
 322 sub is_suspended {
 323     my ( $self ) = @_;
 324
 325     return $self->suspend();
 326 }
 327
 328
 329 =head3 cancel
 330
 331 my $cancel_hold = $hold->cancel();
 332
 333 Cancel a hold:
 334 - The hold will be moved to the old_reserves table with a priority=0
 335 - The priority of other holds will be updated
 336 - The patron will be charge (see ExpireReservesMaxPickUpDelayCharge) if the charge_cancel_fee parameter is set
 337 - a CANCEL HOLDS log will be done if the pref HoldsLog is on
 338
 339 =cut
 340
 341 sub cancel {
 342     my ( $self, $params ) = @_;
 343     $self->_result->result_source->schema->txn_do(
 344         sub {
 345             $self->cancellationdate(dt_from_string);
 346             $self->priority(0);
 347             $self->_move_to_old;
 348             $self->SUPER::delete(); # Do not add a DELETE log
 349
 350             # now fix the priority on the others....
 351             C4::Reserves::_FixPriority({ biblionumber => $self->biblionumber });
 352
 353             # and, if desired, charge a cancel fee
 354             my $charge = C4::Context->preference("ExpireReservesMaxPickUpDelayCharge");
 355             if ( $charge && $params->{'charge_cancel_fee'} ) {
 356                 C4::Accounts::manualinvoice($self->borrowernumber, $self->itemnumber, '', 'HE', $charge);
 357             }
 358
 359             C4::Log::logaction( 'HOLDS', 'CANCEL', $self->reserve_id, Dumper($self->unblessed) )
 360                 if C4::Context->preference('HoldsLog');
 361         }
 362     );
 363     return $self;
 364 }
 365
 366 =head3 _move_to_old
 367
 368 my $is_moved = $hold->_move_to_old;
 369
 370 Move a hold to the old_reserve table following the same pattern as Koha::Patron->move_to_deleted
 371
 372 =cut
 373
 374 sub _move_to_old {
 375     my ($self) = @_;
 376     my $hold_infos = $self->unblessed;
 377     return Koha::Old::Hold->new( $hold_infos )->store;
 378 }
 379
 380 =head3 type
 381
 382 =cut
 383
 384 sub _type {
 385     return 'Reserve';
 386 }
 387
 388 =head1 AUTHORS
 389
 390 Kyle M Hall <kyle@bywatersolutions.com>
 391
 392 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 393
 394 =cut
 395
 396 1;